data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, [YEARS])
  26 # ----------------------------
  27 # If YEARS are not defined, use b4_copyright_years.
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 ]m4_dquote(m4_text_wrap([Copyright (C)
  34 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  35 Free Software Foundation, Inc.]))[
  36
  37 This program is free software: you can redistribute it and/or modify
  38 it under the terms of the GNU General Public License as published by
  39 the Free Software Foundation, either version 3 of the License, or
  40 (at your option) any later version.
  41
  42 This program is distributed in the hope that it will be useful,
  43 but WITHOUT ANY WARRANTY; without even the implied warranty of
  44 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  45 GNU General Public License for more details.
  46
  47 You should have received a copy of the GNU General Public License
  48 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## -------- ##
  65 ## Output.  ##
  66 ## -------- ##
  67
  68 # b4_output_begin(FILE)
  69 # ---------------------
  70 # Enable output, i.e., send to diversion 0, expand after "#", and
  71 # generate the tag to output into FILE.  Must be followed by EOL.
  72 m4_define([b4_output_begin],
  73 [m4_changecom()
  74 m4_divert_push(0)dnl
  75 @output(m4_unquote([$1])@)@dnl
  76 ])
  77
  78
  79 # b4_output_end()
  80 # ---------------
  81 # Output nothing, restore # as comment character (no expansions after #).
  82 m4_define([b4_output_end],
  83 [m4_divert_pop(0)
  84 m4_changecom([#])
  85 ])
  86
  87
  88 ## ---------------- ##
  89 ## Error handling.  ##
  90 ## ---------------- ##
  91
  92 # The following error handling macros print error directives that should not
  93 # become arguments of other macro invocations since they would likely then be
  94 # mangled.  Thus, they print to stdout directly.
  95
  96 # b4_cat(TEXT)
  97 # ------------
  98 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  99 # escaped.  For example:
 100 #
 101 #   b4_cat([[@complain(invalid input@)]])
 102 m4_define([b4_cat],
 103 [m4_syscmd([cat <<'_m4eof'
 104 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
 105 _m4eof
 106 ])dnl
 107 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
 108
 109 # b4_error(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 110 # -------------------------------------------------------
 111 # Write @KIND(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 112 #
 113 # For example:
 114 #
 115 #   b4_error([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 116 #            [[invalid %s]], [[foo]])
 117 m4_define([b4_error],
 118 [b4_cat([[@complain][(]$1[@,]$2[@,]$3[@,]$4[]]dnl
 119 [m4_if([$#], [4], [],
 120        [m4_foreach([b4_arg],
 121                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 122                    [[@,]b4_arg])])[@)]])])
 123
 124 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 125 # ------------------------------------
 126 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 127 #
 128 # For example:
 129 #
 130 #   b4_warn([[invalid value for '%s': %s]], [[foo]], [[3]])
 131 #
 132 # As a simple test suite, this:
 133 #
 134 #   m4_divert(-1)
 135 #   m4_define([asdf], [ASDF])
 136 #   m4_define([fsa], [FSA])
 137 #   m4_define([fdsa], [FDSA])
 138 #   b4_warn_at([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 139 #   b4_warn_at([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 140 #   b4_warn_at()
 141 #   b4_warn_at(1)
 142 #   b4_warn_at(1, 2)
 143 #
 144 # Should produce this without newlines:
 145 #
 146 #   @warn_at([asdf), asdf]@,@,@,[fsa), fsa]@,[fdsa), fdsa]@)
 147 #   @warn(asdf), asdf@,@,@,fsa), fsa@,fdsa), fdsa@)
 148 #   @warn(@)
 149 #   @warn(1@)
 150 #   @warn(1@,2@)
 151 m4_define([b4_warn],
 152 [b4_error([[warn]], [], [], $@)])
 153
 154 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 155 # ---------------------------------------------------
 156 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 157 #
 158 # For example:
 159 #
 160 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 161 m4_define([b4_warn_at],
 162 [b4_error([[warn]], $@)])
 163
 164 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 165 # ----------------------------------------
 166 # Bounce to b4_complain_at.
 167 #
 168 # See b4_warn example.
 169 m4_define([b4_complain],
 170 [b4_error([[complain]], [], [], $@)])
 171
 172 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 173 # -------------------------------------------------------
 174 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 175 #
 176 # See b4_warn_at example.
 177 m4_define([b4_complain_at],
 178 [b4_error([[complain]], $@)])
 179
 180 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 181 # -------------------------------------
 182 # Bounce to b4_fatal_at.
 183 #
 184 # See b4_warn example.
 185 m4_define([b4_fatal],
 186 [b4_error([[fatal]], [], [], $@)dnl
 187 m4_exit(1)])
 188
 189 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 190 # ----------------------------------------------------
 191 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 192 #
 193 # See b4_warn_at example.
 194 m4_define([b4_fatal_at],
 195 [b4_error([[fatal]], $@)dnl
 196 m4_exit(1)])
 197
 198
 199 ## ------------ ##
 200 ## Data Types.  ##
 201 ## ------------ ##
 202
 203 # b4_ints_in(INT1, INT2, LOW, HIGH)
 204 # ---------------------------------
 205 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 206 m4_define([b4_ints_in],
 207 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 208
 209
 210 # b4_subtract(LHS, RHS)
 211 # ---------------------
 212 # Evaluate LHS - RHS if they are integer literals, otherwise expand
 213 # to (LHS) - (RHS).
 214 m4_define([b4_subtract],
 215 [m4_bmatch([$1$2], [^[0123456789]*$],
 216            [m4_eval([$1 - $2])],
 217            [($1) - ($2)])])
 218
 219 # b4_join(ARG1, ...)
 220 # _b4_join(ARG1, ...)
 221 # -------------------
 222 # Join with comma, skipping empty arguments.
 223 # b4_join calls itself recursively until it sees the first non-empty
 224 # argument, then calls _b4_join which prepends each non-empty argument
 225 # with a comma.
 226 m4_define([b4_join],
 227 [m4_if([$#$1],
 228        [1], [],
 229        [m4_ifval([$1],
 230                  [$1[]_$0(m4_shift($@))],
 231                  [$0(m4_shift($@))])])])
 232
 233 # _b4_join(ARGS1, ...)
 234 # --------------------
 235 m4_define([_b4_join],
 236 [m4_if([$#$1],
 237        [1], [],
 238        [m4_ifval([$1], [, $1])[]$0(m4_shift($@))])])
 239
 240
 241
 242
 243 # b4_integral_parser_tables_map(MACRO)
 244 # -------------------------------------
 245 # Map MACRO on all the integral tables.  MACRO is expected to have
 246 # the signature MACRO(TABLE-NAME, CONTENT, COMMENT).
 247 m4_define([b4_integral_parser_tables_map],
 248 [$1([pact], [b4_pact],
 249     [[YYPACT[STATE-NUM] -- Index in YYTABLE of the portion describing
 250 STATE-NUM.]])
 251
 252 $1([defact], [b4_defact],
 253    [[YYDEFACT[STATE-NUM] -- Default reduction number in state STATE-NUM.
 254 Performed when YYTABLE does not specify something else to do.  Zero
 255 means the default is an error.]])
 256
 257 $1([pgoto], [b4_pgoto], [[YYPGOTO[NTERM-NUM].]])
 258
 259 $1([defgoto], [b4_defgoto], [[YYDEFGOTO[NTERM-NUM].]])
 260
 261 $1([table], [b4_table],
 262    [[YYTABLE[YYPACT[STATE-NUM]] -- What to do in state STATE-NUM.  If
 263 positive, shift that token.  If negative, reduce the rule whose
 264 number is the opposite.  If YYTABLE_NINF, syntax error.]])
 265
 266 $1([check], [b4_check])
 267
 268 $1([stos], [b4_stos],
 269    [[YYSTOS[STATE-NUM] -- The (internal number of the) accessing
 270 symbol of state STATE-NUM.]])
 271
 272 $1([r1], [b4_r1],
 273    [[YYR1[YYN] -- Symbol number of symbol that rule YYN derives.]])
 274
 275 $1([r2], [b4_r2],
 276    [[YYR2[YYN] -- Number of symbols on the right hand side of rule YYN.]])
 277 ])
 278
 279
 280 # b4_parser_tables_declare
 281 # b4_parser_tables_define
 282 # ------------------------
 283 # Define/declare the (deterministic) parser tables.
 284 m4_define([b4_parser_tables_declare],
 285 [b4_integral_parser_tables_map([b4_integral_parser_table_declare])])
 286
 287 m4_define([b4_parser_tables_define],
 288 [b4_integral_parser_tables_map([b4_integral_parser_table_define])])
 289
 290
 291
 292 ## ------------------ ##
 293 ## Decoding options.  ##
 294 ## ------------------ ##
 295
 296 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 297 # -----------------------------------
 298 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 299 m4_define([b4_flag_if],
 300 [m4_case(b4_$1_flag,
 301          [0], [$3],
 302          [1], [$2],
 303          [m4_fatal([invalid $1 value: ]b4_$1_flag)])])
 304
 305
 306 # b4_define_flag_if(FLAG)
 307 # -----------------------
 308 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 309 # value of the Boolean FLAG.
 310 m4_define([b4_define_flag_if],
 311 [_b4_define_flag_if($[1], $[2], [$1])])
 312
 313 # _b4_define_flag_if($1, $2, FLAG)
 314 # --------------------------------
 315 # Work around the impossibility to define macros inside macros,
 316 # because issuing `[$1]' is not possible in M4.  GNU M4 should provide
 317 # $$1 a la M5/TeX.
 318 m4_define([_b4_define_flag_if],
 319 [m4_if([$1$2], $[1]$[2], [],
 320        [m4_fatal([$0: Invalid arguments: $@])])dnl
 321 m4_define([b4_$3_if],
 322           [b4_flag_if([$3], [$1], [$2])])])
 323
 324
 325 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 326 # -----------------------------
 327 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 328 b4_define_flag_if([defines])            # Whether headers are requested.
 329 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 330 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 331 b4_define_flag_if([token_table])        # Whether yytoken_table is demanded.
 332 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 333
 334
 335 ## --------- ##
 336 ## Symbols.  ##
 337 ## --------- ##
 338
 339 # In order to unify the handling of the various aspects of symbols
 340 # (tag, type_name, whether terminal, etc.), bison.exe defines one
 341 # macro per (token, field), where field can has_id, id, etc.: see
 342 # src/output.c:prepare_symbols_definitions().
 343 #
 344 # The various FIELDS are:
 345 #
 346 # - has_id: 0 or 1.
 347 #   Whether the symbol has an id.
 348 # - id: string
 349 #   If has_id, the id.  Guaranteed to be usable as a C identifier.
 350 # - tag: string.
 351 #   A representat of the symbol.  Can be 'foo', 'foo.id', '"foo"' etc.
 352 # - user_number: integer
 353 #   The assigned (external) number as used by yylex.
 354 # - is_token: 0 or 1
 355 #   Whether this is a terminal symbol.
 356 # - number: integer
 357 #   The internalized number (used after yytranslate).
 358 # - has_type: 0, 1
 359 #   Whether has a semantic value.
 360 # - type
 361 #   If it has a semantic value, its type tag, or, if variant are used,
 362 #   its type.
 363 # - has_printer: 0, 1
 364 # - printer: string
 365 # - printer_file: string
 366 # - printer_line: integer
 367 #   If the symbol has a printer, everything about it.
 368 # - has_destructor, destructor, destructor_file, destructor_line
 369 #   Likewise.
 370 #
 371 # The following macros provide access to these values.
 372
 373 # b4_symbol_(NUM, FIELD)
 374 # ----------------------
 375 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 376 # undefined.
 377 m4_define([b4_symbol_],
 378 [m4_indir([b4_symbol($1, $2)])])
 379
 380
 381 # b4_symbol(NUM, FIELD)
 382 # ---------------------
 383 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 384 # undefined.  If FIELD = id, prepend the token prefix.
 385 m4_define([b4_symbol],
 386 [m4_case([$2],
 387          [id],    [m4_do([b4_percent_define_get([api.token.prefix])],
 388                          [b4_symbol_([$1], [id])])],
 389          [b4_symbol_($@)])])
 390
 391
 392 # b4_symbol_if(NUM, FIELD, IF-TRUE, IF-FALSE)
 393 # -------------------------------------------
 394 # If FIELD about symbol #NUM is 1 expand IF-TRUE, if is 0, expand IF-FALSE.
 395 # Otherwise an error.
 396 m4_define([b4_symbol_if],
 397 [m4_case(b4_symbol([$1], [$2]),
 398          [1], [$3],
 399          [0], [$4],
 400          [m4_fatal([$0: field $2 of $1 is not a Boolean:] b4_symbol([$1], [$2]))])])
 401
 402
 403 # b4_symbol_tag_comment(SYMBOL-NUM)
 404 # ---------------------------------
 405 # Issue a comment giving the tag of symbol NUM.
 406 m4_define([b4_symbol_tag_comment],
 407 [b4_comment([b4_symbol([$1], [tag])])
 408 ])
 409
 410
 411 # b4_symbol_action_location(SYMBOL-NUM, KIND)
 412 # -------------------------------------------
 413 # Report the location of the KIND action as FILE:LINE.
 414 m4_define([b4_symbol_action_location],
 415 [b4_symbol([$1], [$2_file]):b4_syncline([b4_symbol([$1], [$2_line])])])
 416
 417
 418 # b4_symbol_action(SYMBOL-NUM, KIND)
 419 # ----------------------------------
 420 # Run the action KIND (destructor or printer) for SYMBOL-NUM.
 421 # Same as in C, but using references instead of pointers.
 422 m4_define([b4_symbol_action],
 423 [b4_symbol_if([$1], [has_$2],
 424 [b4_dollar_pushdef([(*yyvaluep)],
 425                    b4_symbol_if([$1], [has_type],
 426                                 [m4_dquote(b4_symbol([$1], [type]))]),
 427                    [(*yylocationp)])dnl
 428     b4_symbol_case_([$1])[]dnl
 429 b4_syncline([b4_symbol([$1], [$2_line])], ["b4_symbol([$1], [$2_file])"])
 430       b4_symbol([$1], [$2])
 431 b4_syncline([@oline@], [@ofile@])
 432         break;
 433
 434 b4_dollar_popdef[]dnl
 435 ])])
 436
 437
 438 # b4_symbol_destructor(SYMBOL-NUM)
 439 # b4_symbol_printer(SYMBOL-NUM)
 440 # --------------------------------
 441 m4_define([b4_symbol_destructor], [b4_symbol_action([$1], [destructor])])
 442 m4_define([b4_symbol_printer],    [b4_symbol_action([$1], [printer])])
 443
 444
 445 # b4_symbol_case_(SYMBOL-NUM)
 446 # ---------------------------
 447 # Issue a "case NUM" for SYMBOL-NUM.
 448 m4_define([b4_symbol_case_],
 449 [case b4_symbol([$1], [number]): b4_symbol_tag_comment([$1])])
 450 ])
 451
 452
 453 # b4_symbol_foreach(MACRO)
 454 # ------------------------
 455 # Invoke MACRO(SYMBOL-NUM) for each SYMBOL-NUM.
 456 m4_define([b4_symbol_foreach],
 457           [m4_map([$1], m4_defn([b4_symbol_numbers]))])
 458
 459 # b4_symbol_map(MACRO)
 460 # --------------------
 461 # Return a list (possibly empty elements) of MACRO invoked for each
 462 # SYMBOL-NUM.
 463 m4_define([b4_symbol_map],
 464 [m4_map_args_sep([$1(], [)], [,], b4_symbol_numbers)])
 465
 466
 467 # b4_token_visible_if(NUM, IF-TRUE, IF-FALSE)
 468 # -------------------------------------------
 469 # Whether NUM denotes a token that has an exported definition (i.e.,
 470 # shows in enum yytokentype).
 471 m4_define([b4_token_visible_if],
 472 [b4_symbol_if([$1], [is_token],
 473               [b4_symbol_if([$1], [has_id], [$2], [$3])],
 474               [$3])])
 475
 476 # b4_token_has_definition(NUM)
 477 # ----------------------------
 478 # 1 if NUM is visible, nothing otherwise.
 479 m4_define([b4_token_has_definition],
 480 [b4_token_visible_if([$1], [1])])
 481
 482 # b4_any_token_visible_if([IF-TRUE], [IF-FALSE])
 483 # ----------------------------------------------
 484 # Whether there is a token that needs to be defined.
 485 m4_define([b4_any_token_visible_if],
 486 [m4_ifval(b4_symbol_foreach([b4_token_has_definition]),
 487           [$1], [$2])])
 488
 489
 490 # b4_token_format(FORMAT, NUM)
 491 # ----------------------------
 492 m4_define([b4_token_format],
 493 [b4_token_visible_if([$2],
 494 [m4_quote(m4_format([$1],
 495                      [b4_symbol([$2], [id])],
 496                      [b4_symbol([$2], [user_number])]))])])
 497
 498
 499 ## ------- ##
 500 ## Types.  ##
 501 ## ------- ##
 502
 503 # b4_type_action_(NUMS)
 504 # ---------------------
 505 # Run actions for the symbol NUMS that all have the same type-name.
 506 # Skip NUMS that have no type-name.
 507 #
 508 # To specify the action to run, define b4_dollar_dollar(NUMBER,
 509 # TAG, TYPE).
 510 m4_define([b4_type_action_],
 511 [b4_symbol_if([$1], [has_type],
 512 [m4_map([b4_symbol_case_], [$@])[]dnl
 513         b4_dollar_dollar([b4_symbol([$1], [number])],
 514                          [b4_symbol([$1], [tag])],
 515                          [b4_symbol([$1], [type])]);
 516         break;
 517
 518 ])])
 519
 520 # b4_type_foreach(MACRO)
 521 # ----------------------
 522 # Invoke MACRO(SYMBOL-NUMS) for each set of SYMBOL-NUMS for each type set.
 523 m4_define([b4_type_foreach],
 524           [m4_map([$1], m4_defn([b4_type_names]))])
 525
 526
 527
 528 ## ----------- ##
 529 ## Synclines.  ##
 530 ## ----------- ##
 531
 532 # b4_basename(NAME)
 533 # -----------------
 534 # Similar to POSIX basename; the differences don't matter here.
 535 # Beware that NAME is not evaluated.
 536 m4_define([b4_basename],
 537 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 538
 539
 540 # b4_syncline(LINE, FILE)
 541 # -----------------------
 542 m4_define([b4_syncline],
 543 [b4_flag_if([synclines],
 544 [b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 545 b4_sync_start([$1], [$2])])])
 546
 547 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 548 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 549
 550 # b4_user_code(USER-CODE)
 551 # -----------------------
 552 # Emit code from the user, ending it with synclines.
 553 m4_define([b4_user_code],
 554 [$1
 555 b4_syncline([@oline@], [@ofile@])])
 556
 557
 558 # b4_define_user_code(MACRO)
 559 # --------------------------
 560 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 561 m4_define([b4_define_user_code],
 562 [m4_define([b4_user_$1],
 563 [b4_user_code([b4_$1])])])
 564
 565
 566 # b4_user_actions
 567 # b4_user_initial_action
 568 # b4_user_post_prologue
 569 # b4_user_pre_prologue
 570 # b4_user_stype
 571 # ----------------------
 572 # Macros that issue user code, ending with synclines.
 573 b4_define_user_code([actions])
 574 b4_define_user_code([initial_action])
 575 b4_define_user_code([post_prologue])
 576 b4_define_user_code([pre_prologue])
 577 b4_define_user_code([stype])
 578
 579
 580 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 581 # -----------------------------------------------------
 582 # Complain if any name of type WHAT is used by the user (as recorded in
 583 # USER-LIST) but is not used by Bison (as recorded by macros in the
 584 # namespace BISON-NAMESPACE).
 585 #
 586 # USER-LIST must expand to a list specifying all user occurrences of all names
 587 # of type WHAT.   Each item in the list must be a triplet specifying one
 588 # occurrence: name, start boundary, and end boundary.  Empty string names are
 589 # fine.  An empty list is fine.
 590 #
 591 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 592 # name occurrences and with correct quoting:
 593 #
 594 #   m4_define([b4_foo_user_names],
 595 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 596 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 597 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 598 #
 599 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 600 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 601 # are fine, but it would be ugly for Bison to actually use one.
 602 #
 603 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 604 # the names bar and baz are used by Bison:
 605 #
 606 #   m4_define([b4_foo_bison_names(bar)])
 607 #   m4_define([b4_foo_bison_names(baz)])
 608 #
 609 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 610 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 611 # quoting:
 612 #
 613 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 614 #                       [[b4_foo_bison_names]])
 615 m4_define([b4_check_user_names],
 616 [m4_foreach([b4_occurrence], $2,
 617 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 618 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 619 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 620 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 621 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 622           [b4_complain_at([b4_start], [b4_end],
 623                           [[%s '%s' is not used]],
 624                           [$1], [b4_user_name])])[]dnl
 625 m4_popdef([b4_occurrence])dnl
 626 m4_popdef([b4_user_name])dnl
 627 m4_popdef([b4_start])dnl
 628 m4_popdef([b4_end])dnl
 629 ])])
 630
 631
 632
 633 ## --------------------- ##
 634 ## b4_percent_define_*.  ##
 635 ## --------------------- ##
 636
 637
 638 # b4_percent_define_use(VARIABLE)
 639 # -------------------------------
 640 # Declare that VARIABLE was used.
 641 m4_define([b4_percent_define_use],
 642 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 643 ])
 644
 645 # b4_percent_define_get(VARIABLE, [DEFAULT])
 646 # ------------------------------------------
 647 # Mimic muscle_percent_define_get in ../src/muscle-tab.h.  That is, if
 648 # the %define variable VARIABLE is defined, emit its value.  Contrary
 649 # to its C counterpart, return DEFAULT otherwise.  Also, record
 650 # Bison's usage of VARIABLE by defining
 651 # b4_percent_define_bison_variables(VARIABLE).
 652 #
 653 # For example:
 654 #
 655 #   b4_percent_define_get([[foo]])
 656 m4_define([b4_percent_define_get],
 657 [b4_percent_define_use([$1])dnl
 658 m4_ifdef([b4_percent_define(]$1[)],
 659          [m4_indir([b4_percent_define(]$1[)])],
 660          [$2])])
 661
 662 # b4_percent_define_get_loc(VARIABLE)
 663 # -----------------------------------
 664 # Mimic muscle_percent_define_get_loc in ../src/muscle-tab.h exactly.  That is,
 665 # if the %define variable VARIABLE is undefined, complain fatally since that's
 666 # a Bison or skeleton error.  Otherwise, return its definition location in a
 667 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 668 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 669 # reason to suspect that the user-supplied value has yet influenced the output.
 670 #
 671 # For example:
 672 #
 673 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 674 m4_define([b4_percent_define_get_loc],
 675 [m4_ifdef([b4_percent_define_loc(]$1[)],
 676           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 677 b4_loc[]dnl
 678 m4_popdef([b4_loc])],
 679           [b4_fatal([[b4_percent_define_get_loc: undefined %%define variable '%s']], [$1])])])
 680
 681 # b4_percent_define_get_syncline(VARIABLE)
 682 # ----------------------------------------
 683 # Mimic muscle_percent_define_get_syncline in ../src/muscle-tab.h exactly.
 684 # That is, if the %define variable VARIABLE is undefined, complain fatally
 685 # since that's a Bison or skeleton error.  Otherwise, return its definition
 686 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 687 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 688 # influenced the output.
 689 #
 690 # For example:
 691 #
 692 #   b4_percent_define_get_syncline([[foo]])
 693 m4_define([b4_percent_define_get_syncline],
 694 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 695           [m4_indir([b4_percent_define_syncline(]$1[)])],
 696           [b4_fatal([[b4_percent_define_get_syncline: undefined %%define variable '%s']], [$1])])])
 697
 698 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 699 # ------------------------------------------------------
 700 # Mimic muscle_percent_define_ifdef in ../src/muscle-tab.h exactly.  That is,
 701 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 702 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 703 # b4_percent_define_bison_variables(VARIABLE).
 704 #
 705 # For example:
 706 #
 707 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 708 m4_define([b4_percent_define_ifdef],
 709 [m4_ifdef([b4_percent_define(]$1[)],
 710           [b4_percent_define_use([$1])$2],
 711           [$3])])
 712
 713
 714 ## --------- ##
 715 ## Options.  ##
 716 ## --------- ##
 717
 718
 719 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 720 # --------------------------------------------------------
 721 # Mimic muscle_percent_define_flag_if in ../src/muscle-tab.h exactly.  That is,
 722 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 723 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 724 # (a Bison or skeleton error since the default value should have been set
 725 # already) or defined to any other value (possibly a user error).  Also, record
 726 # Bison's usage of VARIABLE by defining
 727 # b4_percent_define_bison_variables(VARIABLE).
 728 #
 729 # For example:
 730 #
 731 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 732 m4_define([b4_percent_define_flag_if],
 733 [b4_percent_define_ifdef([$1],
 734   [m4_case(b4_percent_define_get([$1]),
 735            [], [$2], [true], [$2], [false], [$3],
 736            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 737                                            [[invalid value for %%define Boolean variable '%s']],
 738                                            [$1])],
 739                            [[b4_percent_define_flag_if($1)]])])],
 740   [b4_fatal([[b4_percent_define_flag_if: undefined %%define variable '%s']], [$1])])])
 741
 742
 743 # b4_percent_define_default(VARIABLE, DEFAULT)
 744 # --------------------------------------------
 745 # Mimic muscle_percent_define_default in ../src/muscle-tab.h exactly.  That is,
 746 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 747 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 748 # suspect that the value has yet influenced the output.
 749 #
 750 # For example:
 751 #
 752 #   b4_percent_define_default([[foo]], [[default value]])
 753 m4_define([b4_percent_define_default],
 754 [m4_ifndef([b4_percent_define(]$1[)],
 755            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 756             m4_define([b4_percent_define_loc(]$1[)],
 757                       [[[[<skeleton default value>:-1.-1]],
 758                         [[<skeleton default value>:-1.-1]]]])dnl
 759             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 760
 761
 762 # b4_percent_define_if_define(NAME, [VARIABLE = NAME])
 763 # ----------------------------------------------------
 764 # Define b4_NAME_if that executes its $1 or $2 depending whether
 765 # VARIABLE was %defined.  The characters `.' and `-' in VARIABLE are mapped
 766 # to `_'.
 767 m4_define([b4_percent_define_if_define_],
 768 [m4_define(m4_bpatsubst([b4_$1_if], [[-.]], [_]),
 769            [b4_percent_define_flag_if(m4_default([$2], [$1]),
 770                                       [$3], [$4])])])
 771 m4_define([b4_percent_define_if_define],
 772 [b4_percent_define_default([m4_default([$2], [$1])], [[false]])
 773 b4_percent_define_if_define_([$1], [$2], $[1], $[2])])
 774
 775
 776 # b4_percent_define_check_values(VALUES)
 777 # --------------------------------------
 778 # Mimic muscle_percent_define_check_values in ../src/muscle-tab.h exactly
 779 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 780 # is a list of sublists of strings.  For each sublist, the first string is the
 781 # name of a %define variable, and all remaining strings in that sublist are the
 782 # valid values for that variable.  Complain if such a variable is undefined (a
 783 # Bison error since the default value should have been set already) or defined
 784 # to any other value (possibly a user error).  Don't record this as a Bison
 785 # usage of the variable as there's no reason to suspect that the value has yet
 786 # influenced the output.
 787 #
 788 # For example:
 789 #
 790 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 791 #                                  [[[[bar]], [[bar-value1]]]])
 792 m4_define([b4_percent_define_check_values],
 793 [m4_foreach([b4_sublist], m4_quote($@),
 794             [_b4_percent_define_check_values(b4_sublist)])])
 795
 796 m4_define([_b4_percent_define_check_values],
 797 [m4_ifdef([b4_percent_define(]$1[)],
 798   [m4_pushdef([b4_good_value], [0])dnl
 799    m4_if($#, 1, [],
 800          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 801                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 802                             [m4_define([b4_good_value], [1])])])])dnl
 803    m4_if(b4_good_value, [0],
 804          [b4_complain_at(b4_percent_define_get_loc([$1]),
 805                          [[invalid value for %%define variable '%s': '%s']],
 806                          [$1],
 807                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 808           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 809                      [b4_error([[note]], b4_percent_define_get_loc([$1]), []
 810                                      [[accepted value: '%s']],
 811                                      m4_dquote(b4_value))])])dnl
 812    m4_popdef([b4_good_value])],
 813   [b4_fatal([[b4_percent_define_check_values: undefined %%define variable '%s']], [$1])])])
 814
 815 # b4_percent_code_get([QUALIFIER])
 816 # --------------------------------
 817 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 818 # comment and ending with synclines and a newline.  If QUALIFIER is not
 819 # specified or empty, do this for the unqualified %code blocks.  Also, record
 820 # Bison's usage of QUALIFIER (if specified) by defining
 821 # b4_percent_code_bison_qualifiers(QUALIFIER).
 822 #
 823 # For example, to emit any unqualified %code blocks followed by any %code
 824 # blocks for the qualifier foo:
 825 #
 826 #   b4_percent_code_get
 827 #   b4_percent_code_get([[foo]])
 828 m4_define([b4_percent_code_get],
 829 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 830 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 831 m4_ifdef(b4_macro_name,
 832 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 833                    [["%code ]$1["]])[ blocks.]])
 834 b4_user_code([m4_indir(b4_macro_name)])
 835 ])dnl
 836 m4_popdef([b4_macro_name])])
 837
 838 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 839 # -----------------------------------------------------
 840 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 841 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 842 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 843 # b4_percent_code_bison_qualifiers(QUALIFIER).
 844 m4_define([b4_percent_code_ifdef],
 845 [m4_ifdef([b4_percent_code(]$1[)],
 846           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 847           [$3])])
 848
 849
 850 ## ------------------ ##
 851 ## Common variables.  ##
 852 ## ------------------ ##
 853
 854 # Default values for %define.
 855 # ---------------------------
 856 # If the api.token.prefix, it is empty.
 857 m4_percent_define_default([[api.token.prefix]], [[]])
 858
 859 # b4_parse_assert_if([IF-ASSERTIONS-ARE-USED], [IF-NOT])
 860 # b4_parse_trace_if([IF-DEBUG-TRACES-ARE-ENABLED], [IF-NOT])
 861 # b4_token_ctor_if([IF-YYLEX-RETURNS-A-TOKEN], [IF-NOT])
 862 # ----------------------------------------------
 863 b4_percent_define_if_define([token_ctor], [api.token.constructor])
 864 b4_percent_define_if_define([locations])     # Whether locations are tracked.
 865 b4_percent_define_if_define([parse.assert])
 866 b4_percent_define_if_define([parse.trace])
 867
 868
 869 # b4_bison_locations_if([IF-TRUE])
 870 # --------------------------------
 871 # Expand IF-TRUE if using locations, and using the default location
 872 # type.
 873 m4_define([b4_bison_locations_if],
 874 [b4_locations_if([b4_percent_define_ifdef([[api.location.type]], [], [$1])])])
 875
 876
 877 # b4_error_verbose_if([IF-ERRORS-ARE-VERBOSE], [IF-NOT])
 878 # ------------------------------------------------------
 879 # Map %define parse.error "(simple|verbose)" to b4_error_verbose_if and
 880 # b4_error_verbose_flag.
 881 b4_percent_define_default([[parse.error]], [[simple]])
 882 b4_percent_define_check_values([[[[parse.error]],
 883                                  [[simple]], [[verbose]]]])
 884 m4_define([b4_error_verbose_flag],
 885           [m4_case(b4_percent_define_get([[parse.error]]),
 886                    [simple],  [[0]],
 887                    [verbose], [[1]])])
 888 b4_define_flag_if([error_verbose])
 889
 890 # yytoken_table is needed to support verbose errors.
 891 b4_error_verbose_if([m4_define([b4_token_table_flag], [1])])
 892
 893
 894 # b4_variant_if([IF-VARIANT-ARE-USED], [IF-NOT])
 895 # ----------------------------------------------
 896 b4_percent_define_if_define([variant])
 897 m4_case(b4_percent_define_get([[api.value.type]]),
 898         [variant], [m4_define([b4_variant_flag], [[1]])],
 899                    [m4_define([b4_variant_flag], [[0]])])
 900 b4_define_flag_if([variant])
 901
 902
 903 ## ----------------------------------------------------------- ##
 904 ## After processing the skeletons, check that all the user's   ##
 905 ## %define variables and %code qualifiers were used by Bison.  ##
 906 ## ----------------------------------------------------------- ##
 907
 908 m4_define([b4_check_user_names_wrap],
 909 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 910           [b4_check_user_names([[%]$1 $2],
 911                                [b4_percent_]$1[_user_]$2[s],
 912                                [[b4_percent_]$1[_bison_]$2[s]])])])
 913
 914 m4_wrap_lifo([
 915 b4_check_user_names_wrap([[define]], [[variable]])
 916 b4_check_user_names_wrap([[code]], [[qualifier]])
 917 ])
 918
 919
 920 ## ---------------- ##
 921 ## Default values.  ##
 922 ## ---------------- ##
 923
 924 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 925 m4_define_default([b4_pre_prologue], [])
 926 m4_define_default([b4_post_prologue], [])
 927 m4_define_default([b4_epilogue], [])
 928 m4_define_default([b4_parse_param], [])
 929
 930 # The initial column and line.
 931 m4_define_default([b4_location_initial_column], [1])
 932 m4_define_default([b4_location_initial_line],   [1])
 933
 934 # Sanity checks.
 935 b4_percent_define_ifdef([api.prefix],
 936 [m4_ifdef([b4_prefix],
 937 [b4_complain_at(b4_percent_define_get_loc([api.prefix]),
 938                 [['%s' and '%s' cannot be used together]],
 939                 [%name-prefix],
 940                 [%define api.prefix])])])