tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003-2010 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 ## ------------------------------- ##
  40 ## Macros decoding Bison options.  ##
  41 ## ------------------------------- ##
  42
  43
  44 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  45 # -----------------------------------------
  46 m4_define([AT_BISON_OPTION_PUSHDEFS],
  47 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  48
  49
  50 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  51 # --------------------------------------------------
  52 # This macro works around the impossibility to define macros
  53 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  54 # This sucks hard, GNU M4 should really provide M5-like $$1.
  55 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  56 [m4_if([$1$2], $[1]$[2], [],
  57        [m4_fatal([$0: Invalid arguments: $@])])dnl
  58 m4_pushdef([AT_DEFINES_IF],
  59 [m4_bmatch([$3], [%defines], [$1], [$2])])
  60 m4_pushdef([AT_SKEL_CC_IF],
  61 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  62 m4_pushdef([AT_GLR_IF],
  63 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  64 m4_pushdef([AT_LALR1_CC_IF],
  65 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  66 m4_pushdef([AT_GLR_CC_IF],
  67 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  68 # Using yacc.c?
  69 m4_pushdef([AT_YACC_IF],
  70 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  71 m4_pushdef([AT_LEXPARAM_IF],
  72 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  73 m4_pushdef([AT_LOCATION_IF],
  74 [m4_bmatch([$3], [%locations], [$1], [$2])])
  75 m4_pushdef([AT_LOCATION_TYPE_IF],
  76 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  77 m4_pushdef([AT_PARAM_IF],
  78 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  79 m4_pushdef([AT_PURE_IF],
  80 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  81            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
  82            [$2])])
  83 m4_pushdef([AT_PURE_AND_LOC_IF],
  84 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  85 m4_pushdef([AT_GLR_OR_PARAM_IF],
  86 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  87 m4_pushdef([AT_NAME_PREFIX],
  88 [m4_bmatch([$3], [%name-prefix ".*"],
  89            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  90            [yy])])
  91 m4_pushdef([AT_TOKEN_PREFIX],
  92 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
  93            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
  94 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  95 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  96 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  97                     [$2])])
  98 # yyerror always sees the locations (when activated), except if
  99 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 100 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 101 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 102                                         [$1])],
 103                             [$1])],
 104                 [$2])])
 105
 106 # The interface is pure: either because %define api.pure, or because we
 107 # are using the C++ parsers.
 108 m4_pushdef([AT_PURE_LEX_IF],
 109 [AT_PURE_IF([$1],
 110             [AT_SKEL_CC_IF([$1], [$2])])])
 111
 112 AT_PURE_LEX_IF(
 113 [m4_pushdef([AT_LOC], [(*llocp)])
 114  m4_pushdef([AT_VAL], [(*lvalp)])
 115  m4_pushdef([AT_LEX_FORMALS],
 116             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 117  m4_pushdef([AT_LEX_ARGS],
 118             [lvalp[]AT_LOCATION_IF([, llocp])])
 119  m4_pushdef([AT_USE_LEX_ARGS],
 120             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 121  m4_pushdef([AT_LEX_PRE_FORMALS],
 122             [AT_LEX_FORMALS, ])
 123  m4_pushdef([AT_LEX_PRE_ARGS],
 124             [AT_LEX_ARGS, ])
 125 ],
 126 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 127  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 128  m4_pushdef([AT_LEX_FORMALS],     [void])
 129  m4_pushdef([AT_LEX_ARGS],        [])
 130  m4_pushdef([AT_USE_LEX_ARGS],    [])
 131  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 132  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 133 ])
 134 AT_GLR_IF([AT_KEYWORDS([glr])])
 135 ])# _AT_BISON_OPTION_PUSHDEFS
 136
 137
 138 # AT_BISON_OPTION_POPDEFS
 139 # -----------------------
 140 m4_define([AT_BISON_OPTION_POPDEFS],
 141 [m4_popdef([AT_LEX_PRE_ARGS])
 142 m4_popdef([AT_LEX_PRE_FORMALS])
 143 m4_popdef([AT_USE_LEX_ARGS])
 144 m4_popdef([AT_LEX_ARGS])
 145 m4_popdef([AT_LEX_FORMALS])
 146 m4_popdef([AT_VAL])
 147 m4_popdef([AT_LOC])
 148 m4_popdef([AT_PURE_LEX_IF])
 149 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 150 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 151 m4_popdef([AT_NAME_PREFIX])
 152 m4_popdef([AT_GLR_OR_PARAM_IF])
 153 m4_popdef([AT_PURE_AND_LOC_IF])
 154 m4_popdef([AT_LOCATION_TYPE_IF])
 155 m4_popdef([AT_LOCATION_IF])
 156 m4_popdef([AT_PARAM_IF])
 157 m4_popdef([AT_LEXPARAM_IF])
 158 m4_popdef([AT_YACC_IF])
 159 m4_popdef([AT_GLR_IF])
 160 m4_popdef([AT_SKEL_CC_IF])
 161 m4_popdef([AT_GLR_CC_IF])
 162 m4_popdef([AT_LALR1_CC_IF])
 163 m4_popdef([AT_DEFINES_IF])
 164 ])# AT_BISON_OPTION_POPDEFS
 165
 166
 167
 168 ## -------------------------- ##
 169 ## Generating Grammar Files.  ##
 170 ## -------------------------- ##
 171
 172 # AT_DATA_SOURCE_PROLOGUE
 173 # ------------------------
 174 # The prologue that should be included in any source code that is
 175 # meant to be compiled.
 176 m4_define([AT_DATA_SOURCE_PROLOGUE],
 177 [[#include <config.h>
 178 /* We don't need perfect functions for these tests. */
 179 #undef malloc
 180 #undef memcmp
 181 #undef realloc
 182 ]])
 183
 184 # AT_DATA_GRAMMAR_PROLOGUE
 185 # ------------------------
 186 # The prologue that should be included in any grammar which parser is
 187 # meant to be compiled.
 188 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 189 [[%code top {
 190 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 191 [}
 192 ]])
 193
 194 # AT_DATA_SOURCE(NAME, CONTENT)
 195 # -----------------------------
 196 # Generate the file NAME, which CONTENT is preceded by
 197 # AT_DATA_SOURCE_PROLOGUE.
 198 m4_define([AT_DATA_SOURCE],
 199 [AT_DATA([$1],
 200 [AT_DATA_SOURCE_PROLOGUE
 201 $2])
 202 ])
 203
 204 # AT_DATA_GRAMMAR(NAME, CONTENT)
 205 # ------------------------------
 206 # Generate the file NAME, which CONTENT is preceded by
 207 # AT_DATA_GRAMMAR_PROLOGUE.
 208 m4_define([AT_DATA_GRAMMAR],
 209 [AT_DATA([$1],
 210 [AT_DATA_GRAMMAR_PROLOGUE
 211 $2])
 212 ])
 213
 214 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 215 # -------------------------------------------------
 216 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 217 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 218 #
 219 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 220 # Bison in the test suite.  For now it ensures that:
 221 #
 222 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 223 #      a non-zero exit status since Bison doesn't always try to free all memory
 224 #      in that case.
 225 #
 226 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 227 #      --graph and --report=all output for every working grammar.
 228 m4_define([AT_BISON_CHECK],
 229 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 230        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 231 AT_BISON_CHECK_NO_XML($@)])
 232
 233 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 234 # --------------------------------------------------------
 235 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 236 # when a tortured grammar's XML is known to be too large for xsltproc to
 237 # handle.
 238 m4_define([AT_BISON_CHECK_NO_XML],
 239 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 240                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 241
 242 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 243 # -----------------------------------------------------
 244 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 245 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 246 # have a non-zero exit status.
 247 m4_define([AT_BISON_CHECK_XML],
 248 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 249   mkdir xml-tests]
 250   m4_pushdef([AT_BISON_ARGS],
 251              [m4_bpatsubsts([[$1]],
 252                             [--report(-file)?=[^][ ]*], [],
 253                             [--graph=[^][ ]*], [],
 254                             [--xml=[^][ ]*], [])])dnl
 255   # Don't combine these Bison invocations since we want to be sure that
 256   # --report=all isn't required to get the full XML file.
 257   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 258              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 259            [[0]], [ignore], [ignore])
 260   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 261            [[0]], [ignore], [ignore])
 262   m4_popdef([AT_BISON_ARGS])dnl
 263   [cp xml-tests/test.output expout]
 264   AT_CHECK([[$XSLTPROC \
 265              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 266              xml-tests/test.xml]], [[0]], [expout])
 267   [cp xml-tests/test.dot expout]
 268   AT_CHECK([[$XSLTPROC \
 269              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 270              xml-tests/test.xml]], [[0]], [expout])
 271   [rm -rf xml-tests expout
 272 fi]])
 273
 274 # AT_QUELL_VALGRIND
 275 # -----------------
 276 # Put this before a Bison invocation to keep Valgrind from complaining about
 277 # reachable memory.
 278 #
 279 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 280 # The triple quoting below will cause test cases to fail if you do.  If you do
 281 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 282 # will then fail to shell-escape its contents when attempting to print them.
 283 # The testsuite verbose output, at least, will be incorrect, but nothing may
 284 # fail to make sure you notice.
 285 m4_define([AT_QUELL_VALGRIND],
 286 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 287
 288 ## ------------------------ ##
 289 ## Compiling C, C++ Files.  ##
 290 ## ------------------------ ##
 291
 292
 293 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 294 # ----------------------------------------
 295 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 296 # assume that we are linking too; this is a hack.
 297 m4_define([AT_COMPILE],
 298 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 299            0, [ignore], [ignore])])
 300
 301 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 302 # --------------------------------------------
 303 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 304 # assume that we are linking too; this is a hack.
 305 # If the C++ compiler does not work, ignore the test.
 306 m4_define([AT_COMPILE_CXX],
 307 [AT_KEYWORDS(c++)
 308 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 309 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 310          0, [ignore], [ignore])])
 311
 312
 313 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 314 # --------------------------------
 315 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 316 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 317 # along with it.
 318 # Relies on AT_SKEL_CC_IF.
 319 m4_define([AT_FULL_COMPILE],
 320 [AT_SKEL_CC_IF(
 321   [AT_BISON_CHECK([-o $1.cc $1.y])
 322    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 323   [AT_BISON_CHECK([-o $1.c $1.y])
 324    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 325 ])
 326
 327
 328 ## ---------------------------- ##
 329 ## Running a generated parser.  ##
 330 ## ---------------------------- ##
 331
 332 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 333 # ------------------------------------------------------------
 334 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 335 m4_define([AT_PARSER_CHECK],
 336 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 337
 338 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 339 #                          DECLS, GRAMMAR, INPUT,
 340 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 341 #                          [OTHER-CHECKS],
 342 #                          [PARSER-EXIT-VALUE],
 343 #                          [PARSER-STDOUT], [PARSER-STDERR])
 344 # -------------------------------------------------------------
 345 # Using TITLE as the test group title, check the generated parser tables
 346 # and parser for a specified grammar file under a condition labeled by
 347 # COND-VALUE.
 348 #
 349 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 350 # recognized attribute is described below where it is relevant.
 351 #
 352 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 353 # the grammar file.  Insert basic yyerror, yylex, and main function
 354 # definitions as well.  Hardcode yylex to return the (possibly empty)
 355 # comma-delimited series of tokens in INPUT followed by token 0.
 356 #
 357 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 358 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 359 # On the bison command-line, specify `--report=all --defines'.  Check
 360 # that Bison exits with value 0, has no stdout, and has stderr
 361 # BISON-STDERR.
 362 #
 363 # If TEST-SPEC contains the attribute `last-state', check that the value
 364 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 365 # the grammar; in other words, check the number of states (minus one).
 366 # Otherwise, check that everything in the `.output' file starting with
 367 # the definition of state 0 is the same as the entire value of
 368 # TABLES-OR-LAST-STATE.
 369 #
 370 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 371 # `.output' file, which is named `input.output', and/or grammar file,
 372 # which is named `input.y'.
 373 #
 374 # Finally, compile the generated parser and then run it using
 375 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 376 # PARSER-STDERR as the 2nd-4th arguments.
 377 #
 378 # As a precondition, you must properly double-quote all arguments that
 379 # are to be interpreted as strings.
 380 #
 381 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 382 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 383 # first argument.  This is useful, for example, when wrapping multiple
 384 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 385 # condition, in another macro.
 386 #
 387 # For example:
 388 #
 389 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 390 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 391 #   # ---------------------------------------------------------------------
 392 #   m4_define([AT_TEST_SYNTAX_ERROR],
 393 #   [
 394 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 395 #                              [[last-state]],
 396 #                              [[%error-verbose ]$2], [$3], [$4],
 397 #                              [[]], [$5], [], [$6], [$7], [$8])
 398 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 399 #                              [[last-state]],
 400 #                              [$2], [$3], [$4],
 401 #                              [[]], [$5], [], [$6], [$7], [$8])
 402 #   ])
 403 #
 404 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 405 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 406 #                        [[3]],
 407 #                        [[1]], [[]],
 408 #                        [AT_COND_CASE([[no verbose]],
 409 #                                      [[syntax error
 410 #   ]],
 411 #                                      [[syntax error, unexpected 'b', expecting $end
 412 #   ]])])
 413 m4_define([AT_TEST_TABLES_AND_PARSE],
 414 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 415
 416 AT_SETUP([$1])
 417
 418 AT_DATA_GRAMMAR([[input.y]],
 419 [[%code {
 420   #include <stdio.h>
 421   static void yyerror (char const *msg);
 422   static int yylex (void);
 423 }
 424
 425 ]$4[
 426
 427 %%
 428
 429 ]$5[
 430
 431 %%
 432
 433 static void
 434 yyerror (char const *msg)
 435 {
 436   fprintf (stderr, "%s\n", msg);
 437 }
 438
 439 static int
 440 yylex (void)
 441 {
 442   static int const input[] = {
 443     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 444   };
 445   static int const *inputp = input;
 446   return *inputp++;
 447 }
 448
 449 int
 450 main (void)
 451 {
 452   return yyparse ();
 453 }
 454 ]])
 455
 456 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 457 # expanding macros, so it corrupts some special characters in the
 458 # macros.  To avoid this, expand now and pass it the result with proper
 459 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 460 # strings.
 461
 462 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 463       [AT_BISON_CHECK],
 464       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 465                                [0], [], m4_dquote($7))
 466
 467 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 468       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 469                 m4_dquote($8))],
 470       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 471                 m4_dquote($8)[[
 472 ]])])
 473
 474 $9
 475
 476 AT_COMPILE([[input]])
 477
 478 AT_PARSER_CHECK([[./input]],
 479                 m4_ifval([$10], [m4_dquote($10)]),
 480                 m4_ifval([$11], [m4_dquote($11)]),
 481                 m4_ifval([$12], [m4_dquote($12)]))
 482
 483 AT_CLEANUP
 484
 485 m4_popdef([AT_COND_CASE])])
 486
 487
 488
 489 ## ----------------------- ##
 490 ## Launch the test suite.  ##
 491 ## ----------------------- ##
 492
 493 AT_INIT
 494
 495 AT_TESTED([bison])