tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software
   5 # Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 ## ------------------------------- ##
  41 ## Macros decoding Bison options.  ##
  42 ## ------------------------------- ##
  43
  44
  45 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  46 # -----------------------------------------
  47 m4_define([AT_BISON_OPTION_PUSHDEFS],
  48 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  49
  50
  51 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  52 # --------------------------------------------------
  53 # This macro works around the impossibility to define macros
  54 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  55 # This sucks hard, GNU M4 should really provide M5 like $$1.
  56 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  57 [m4_if([$1$2], $[1]$[2], [],
  58        [m4_fatal([$0: Invalid arguments: $@])])dnl
  59 m4_pushdef([AT_DEFINES_IF],
  60 [m4_bmatch([$3], [%defines], [$1], [$2])])
  61 m4_pushdef([AT_SKEL_CC_IF],
  62 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  63 m4_pushdef([AT_GLR_IF],
  64 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  65 m4_pushdef([AT_LALR1_CC_IF],
  66 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  67 m4_pushdef([AT_GLR_CC_IF],
  68 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  69 # Using yacc.c?
  70 m4_pushdef([AT_YACC_IF],
  71 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  72 m4_pushdef([AT_LEXPARAM_IF],
  73 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  74 m4_pushdef([AT_PARAM_IF],
  75 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  76 m4_pushdef([AT_LOCATION_IF],
  77 [m4_bmatch([$3], [%locations], [$1], [$2])])
  78 m4_pushdef([AT_PURE_IF],
  79 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  80            [m4_bmatch([$3], [%define  *api\.pure *"false"], [$2], [$1])],
  81            [$2])])
  82 m4_pushdef([AT_PURE_AND_LOC_IF],
  83 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  84 m4_pushdef([AT_GLR_OR_PARAM_IF],
  85 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  86 m4_pushdef([AT_NAME_PREFIX],
  87 [m4_bmatch([$3], [%name-prefix ".*"],
  88            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  89            [yy])])
  90 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  91 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  92 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  93                     [$2])])
  94 # yyerror always sees the locations (when activated), except if
  95 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  96 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  97 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  98                                         [$1])],
  99                             [$1])],
 100                 [$2])])
 101
 102 # The interface is pure: either because %define api.pure, or because we
 103 # are using the C++ parsers.
 104 m4_pushdef([AT_PURE_LEX_IF],
 105 [AT_PURE_IF([$1],
 106             [AT_SKEL_CC_IF([$1], [$2])])])
 107
 108 AT_PURE_LEX_IF(
 109 [m4_pushdef([AT_LOC], [(*llocp)])
 110  m4_pushdef([AT_VAL], [(*lvalp)])
 111  m4_pushdef([AT_LEX_FORMALS],
 112             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 113  m4_pushdef([AT_LEX_ARGS],
 114             [lvalp[]AT_LOCATION_IF([, llocp])])
 115  m4_pushdef([AT_USE_LEX_ARGS],
 116             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 117  m4_pushdef([AT_LEX_PRE_FORMALS],
 118             [AT_LEX_FORMALS, ])
 119  m4_pushdef([AT_LEX_PRE_ARGS],
 120             [AT_LEX_ARGS, ])
 121 ],
 122 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 123  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 124  m4_pushdef([AT_LEX_FORMALS],     [void])
 125  m4_pushdef([AT_LEX_ARGS],        [])
 126  m4_pushdef([AT_USE_LEX_ARGS],    [])
 127  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 128  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 129 ])
 130 ])# _AT_BISON_OPTION_PUSHDEFS
 131
 132
 133 # AT_BISON_OPTION_POPDEFS
 134 # -----------------------
 135 m4_define([AT_BISON_OPTION_POPDEFS],
 136 [m4_popdef([AT_LEX_PRE_ARGS])
 137 m4_popdef([AT_LEX_PRE_FORMALS])
 138 m4_popdef([AT_USE_LEX_ARGS])
 139 m4_popdef([AT_LEX_ARGS])
 140 m4_popdef([AT_LEX_FORMALS])
 141 m4_popdef([AT_VAL])
 142 m4_popdef([AT_LOC])
 143 m4_popdef([AT_PURE_LEX_IF])
 144 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 145 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 146 m4_popdef([AT_NAME_PREFIX])
 147 m4_popdef([AT_GLR_OR_PARAM_IF])
 148 m4_popdef([AT_PURE_AND_LOC_IF])
 149 m4_popdef([AT_LOCATION_IF])
 150 m4_popdef([AT_PARAM_IF])
 151 m4_popdef([AT_LEXPARAM_IF])
 152 m4_popdef([AT_YACC_IF])
 153 m4_popdef([AT_GLR_IF])
 154 m4_popdef([AT_SKEL_CC_IF])
 155 m4_popdef([AT_GLR_CC_IF])
 156 m4_popdef([AT_LALR1_CC_IF])
 157 m4_popdef([AT_DEFINES_IF])
 158 ])# AT_BISON_OPTION_POPDEFS
 159
 160
 161
 162 ## -------------------------- ##
 163 ## Generating Grammar Files.  ##
 164 ## -------------------------- ##
 165
 166 # AT_DATA_SOURCE_PROLOGUE
 167 # ------------------------
 168 # The prologue that should be included in any source code that is
 169 # meant to be compiled.
 170 m4_define([AT_DATA_SOURCE_PROLOGUE],
 171 [[#include <config.h>
 172 /* We don't need perfect functions for these tests. */
 173 #undef malloc
 174 #undef memcmp
 175 #undef realloc
 176 ]])
 177
 178 # AT_DATA_GRAMMAR_PROLOGUE
 179 # ------------------------
 180 # The prologue that should be included in any grammar which parser is
 181 # meant to be compiled.
 182 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 183 [[%code top {
 184 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 185 [}
 186 ]])
 187
 188 # AT_DATA_SOURCE(NAME, CONTENT)
 189 # -----------------------------
 190 # Generate the file NAME, which CONTENT is preceded by
 191 # AT_DATA_SOURCE_PROLOGUE.
 192 m4_define([AT_DATA_SOURCE],
 193 [AT_DATA([$1],
 194 [AT_DATA_SOURCE_PROLOGUE
 195 $2])
 196 ])
 197
 198 # AT_DATA_GRAMMAR(NAME, CONTENT)
 199 # ------------------------------
 200 # Generate the file NAME, which CONTENT is preceded by
 201 # AT_DATA_GRAMMAR_PROLOGUE.
 202 m4_define([AT_DATA_GRAMMAR],
 203 [AT_DATA([$1],
 204 [AT_DATA_GRAMMAR_PROLOGUE
 205 $2])
 206 ])
 207
 208 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 209 # -------------------------------------------------
 210 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 211 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 212 #
 213 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 214 # Bison in the test suite.  For now it ensures that:
 215 #
 216 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 217 #      a non-zero exit status since Bison doesn't always try to free all memory
 218 #      in that case.
 219 #
 220 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 221 #      --graph and --report=all output for every working grammar.
 222 m4_define([AT_BISON_CHECK],
 223 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 224        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 225 AT_BISON_CHECK_NO_XML($@)])
 226
 227 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 228 # --------------------------------------------------------
 229 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 230 # when a tortured grammar's XML is known to be too large for xsltproc to
 231 # handle.
 232 m4_define([AT_BISON_CHECK_NO_XML],
 233 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 234                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 235
 236 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 237 # -----------------------------------------------------
 238 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 239 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 240 # have a non-zero exit status.
 241 m4_define([AT_BISON_CHECK_XML],
 242 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 243   mkdir xml-tests]
 244   m4_pushdef([AT_BISON_ARGS],
 245              [m4_bpatsubsts([[$1]],
 246                             [--report(-file)?=[^][ ]*], [],
 247                             [--graph=[^][ ]*], [],
 248                             [--xml=[^][ ]*], [])])dnl
 249   # Don't combine these Bison invocations since we want to be sure that
 250   # --report=all isn't required to get the full XML file.
 251   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 252              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 253            [[0]], [ignore], [ignore])
 254   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 255            [[0]], [ignore], [ignore])
 256   m4_popdef([AT_BISON_ARGS])dnl
 257   [cp xml-tests/test.output expout]
 258   AT_CHECK([[$XSLTPROC \
 259              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 260              xml-tests/test.xml]], [[0]], [expout])
 261   [cp xml-tests/test.dot expout]
 262   AT_CHECK([[$XSLTPROC \
 263              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 264              xml-tests/test.xml]], [[0]], [expout])
 265   [rm -rf xml-tests expout
 266 fi]])
 267
 268 # AT_QUELL_VALGRIND
 269 # -----------------
 270 # Put this before a Bison invocation to keep Valgrind from complaining about
 271 # reachable memory.
 272 #
 273 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 274 # The triple quoting below will cause test cases to fail if you do.  If you do
 275 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 276 # will then fail to shell-escape its contents when attempting to print them.
 277 # The testsuite verbose output, at least, will be incorrect, but nothing may
 278 # fail to make sure you notice.
 279 m4_define([AT_QUELL_VALGRIND],
 280 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 281
 282 ## ------------------------ ##
 283 ## Compiling C, C++ Files.  ##
 284 ## ------------------------ ##
 285
 286
 287 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 288 # ----------------------------------------
 289 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 290 # assume that we are linking too; this is a hack.
 291 m4_define([AT_COMPILE],
 292 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 293            0, [ignore], [ignore])])
 294
 295 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 296 # --------------------------------------------
 297 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 298 # assume that we are linking too; this is a hack.
 299 # If the C++ compiler does not work, ignore the test.
 300 m4_define([AT_COMPILE_CXX],
 301 [AT_KEYWORDS(c++)
 302 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 303 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 304          0, [ignore], [ignore])])
 305
 306
 307 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 308 # --------------------------------
 309 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 310 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 311 # along with it.
 312 # Relies on AT_SKEL_CC_IF.
 313 m4_define([AT_FULL_COMPILE],
 314 [AT_SKEL_CC_IF(
 315   [AT_BISON_CHECK([-o $1.cc $1.y])
 316    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 317   [AT_BISON_CHECK([-o $1.c $1.y])
 318    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 319 ])
 320
 321
 322 ## ---------------------------- ##
 323 ## Running a generated parser.  ##
 324 ## ---------------------------- ##
 325
 326 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 327 # ------------------------------------------------------------
 328 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 329 m4_define([AT_PARSER_CHECK],
 330 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 331
 332 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 333 #                          DECLS, GRAMMAR, INPUT,
 334 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 335 #                          [OTHER-CHECKS],
 336 #                          [PARSER-EXIT-VALUE],
 337 #                          [PARSER-STDOUT], [PARSER-STDERR])
 338 # -------------------------------------------------------------
 339 # Using TITLE as the test group title, check the generated parser tables
 340 # and parser for a specified grammar file under a condition labeled by
 341 # COND-VALUE.
 342 #
 343 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 344 # recognized attribute is described below where it is relevant.
 345 #
 346 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 347 # the grammar file.  Insert basic yyerror, yylex, and main function
 348 # definitions as well.  Hardcode yylex to return the (possibly empty)
 349 # comma-delimited series of tokens in INPUT followed by token 0.
 350 #
 351 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 352 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 353 # On the bison command-line, specify `--report=all --defines'.  Check
 354 # that Bison exits with value 0, has no stdout, and has stderr
 355 # BISON-STDERR.
 356 #
 357 # If TEST-SPEC contains the attribute `last-state', check that the value
 358 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 359 # the grammar; in other words, check the number of states (minus one).
 360 # Otherwise, check that everything in the `.output' file starting with
 361 # the definition of state 0 is the same as the entire value of
 362 # TABLES-OR-LAST-STATE.
 363 #
 364 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 365 # `.output' file, which is named `input.output', and/or grammar file,
 366 # which is named `input.y'.
 367 #
 368 # Finally, compile the generated parser and then run it using
 369 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 370 # PARSER-STDERR as the 2nd-4th arguments.
 371 #
 372 # As a precondition, you must properly double-quote all arguments that
 373 # are to be interpreted as strings.
 374 #
 375 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 376 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 377 # first argument.  This is useful, for example, when wrapping multiple
 378 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 379 # condition, in another macro.
 380 #
 381 # For example:
 382 #
 383 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 384 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 385 #   # ---------------------------------------------------------------------
 386 #   m4_define([AT_TEST_SYNTAX_ERROR],
 387 #   [
 388 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 389 #                              [[last-state]],
 390 #                              [[%error-verbose ]$2], [$3], [$4],
 391 #                              [[]], [$5], [], [$6], [$7], [$8])
 392 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 393 #                              [[last-state]],
 394 #                              [$2], [$3], [$4],
 395 #                              [[]], [$5], [], [$6], [$7], [$8])
 396 #   ])
 397 #
 398 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 399 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 400 #                        [[3]],
 401 #                        [[1]], [[]],
 402 #                        [AT_COND_CASE([[no verbose]],
 403 #                                      [[syntax error
 404 #   ]],
 405 #                                      [[syntax error, unexpected 'b', expecting $end
 406 #   ]])])
 407 m4_define([AT_TEST_TABLES_AND_PARSE],
 408 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 409
 410 AT_SETUP([$1])
 411
 412 AT_DATA_GRAMMAR([[input.y]],
 413 [[%code {
 414   #include <stdio.h>
 415   static void yyerror (char const *msg);
 416   static int yylex (void);
 417 }
 418
 419 ]$4[
 420
 421 %%
 422
 423 ]$5[
 424
 425 %%
 426
 427 static void
 428 yyerror (char const *msg)
 429 {
 430   fprintf (stderr, "%s\n", msg);
 431 }
 432
 433 static int
 434 yylex (void)
 435 {
 436   static int const input[] = {
 437     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 438   };
 439   static int const *inputp = input;
 440   return *inputp++;
 441 }
 442
 443 int
 444 main (void)
 445 {
 446   return yyparse ();
 447 }
 448 ]])
 449
 450 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 451 # expanding macros, so it corrupts some special characters in the
 452 # macros.  To avoid this, expand now and pass it the result with proper
 453 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 454 # strings.
 455
 456 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 457       [AT_BISON_CHECK],
 458       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 459                                [0], [], m4_dquote($7))
 460
 461 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 462       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 463                 m4_dquote($8))],
 464       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 465                 m4_dquote($8)[[
 466 ]])])
 467
 468 $9
 469
 470 AT_COMPILE([[input]])
 471
 472 AT_PARSER_CHECK([[./input]],
 473                 m4_ifval([$10], [m4_dquote($10)]),
 474                 m4_ifval([$11], [m4_dquote($11)]),
 475                 m4_ifval([$12], [m4_dquote($12)]))
 476
 477 AT_CLEANUP
 478
 479 m4_popdef([AT_COND_CASE])])
 480
 481
 482
 483 ## ----------------------- ##
 484 ## Launch the test suite.  ##
 485 ## ----------------------- ##
 486
 487 AT_INIT
 488
 489 AT_TESTED([bison])