src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 /* Only NUMBERS have a value.  */
  97 %union
  98 {
  99   symbol *symbol;
 100   symbol_list *list;
 101   int integer;
 102   char *chars;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119 %token PERCENT_SYMBOL_DEFAULT
 120                            "%symbol-default"
 121
 122 %token PERCENT_LEFT        "%left"
 123 %token PERCENT_RIGHT       "%right"
 124 %token PERCENT_NONASSOC    "%nonassoc"
 125
 126 %token PERCENT_PREC          "%prec"
 127 %token PERCENT_DPREC         "%dprec"
 128 %token PERCENT_MERGE         "%merge"
 129
 130
 131 /*----------------------.
 132 | Global Declarations.  |
 133 `----------------------*/
 134
 135 %token
 136   PERCENT_AFTER_HEADER    "%after-header"
 137   PERCENT_BEFORE_HEADER   "%before-header"
 138   PERCENT_DEBUG           "%debug"
 139   PERCENT_DEFAULT_PREC    "%default-prec"
 140   PERCENT_DEFINE          "%define"
 141   PERCENT_DEFINES         "%defines"
 142   PERCENT_END_HEADER      "%end-header"
 143   PERCENT_ERROR_VERBOSE   "%error-verbose"
 144   PERCENT_EXPECT          "%expect"
 145   PERCENT_EXPECT_RR       "%expect-rr"
 146   PERCENT_FILE_PREFIX     "%file-prefix"
 147   PERCENT_GLR_PARSER      "%glr-parser"
 148   PERCENT_INITIAL_ACTION  "%initial-action"
 149   PERCENT_LEX_PARAM       "%lex-param"
 150   PERCENT_LOCATIONS       "%locations"
 151   PERCENT_NAME_PREFIX     "%name-prefix"
 152   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 153   PERCENT_NO_LINES        "%no-lines"
 154   PERCENT_NONDETERMINISTIC_PARSER
 155                           "%nondeterministic-parser"
 156   PERCENT_OUTPUT          "%output"
 157   PERCENT_PARSE_PARAM     "%parse-param"
 158   PERCENT_PURE_PARSER     "%pure-parser"
 159   PERCENT_REQUIRE         "%require"
 160   PERCENT_SKELETON        "%skeleton"
 161   PERCENT_START           "%start"
 162   PERCENT_START_HEADER    "%start-header"
 163   PERCENT_TOKEN_TABLE     "%token-table"
 164   PERCENT_VERBOSE         "%verbose"
 165   PERCENT_YACC            "%yacc"
 166 ;
 167
 168 %token BRACED_CODE     "{...}"
 169 %token CHAR            "char"
 170 %token EPILOGUE        "epilogue"
 171 %token EQUAL           "="
 172 %token ID              "identifier"
 173 %token ID_COLON        "identifier:"
 174 %token PERCENT_PERCENT "%%"
 175 %token PIPE            "|"
 176 %token PROLOGUE        "%{...%}"
 177 %token SEMICOLON       ";"
 178 %token TYPE            "type"
 179
 180 %type <character> CHAR
 181 %printer { fputs (char_name ($$), stderr); } CHAR
 182
 183 /* braceless is not to be used for rule or symbol actions, as it
 184    calls translate_code. */
 185 %type <chars> STRING "{...}" "%{...%}" EPILOGUE braceless content content.opt
 186 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 187          STRING
 188 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 189          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 190
 191 %type <uniqstr> TYPE ID ID_COLON
 192 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 193 %printer { fputs ($$, stderr); } ID
 194 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 195
 196 %type <integer> INT
 197 %printer { fprintf (stderr, "%d", $$); } INT
 198
 199 %type <symbol> id id_colon symbol string_as_id
 200 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 201 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 202
 203 %type <assoc> precedence_declarator
 204 %type <list>  symbols.1 generic_symlist generic_symlist_item
 205 %%
 206
 207 input:
 208   prologue_declarations "%%" grammar epilogue.opt
 209 ;
 210
 211
 212         /*------------------------------------.
 213         | Declarations: before the first %%.  |
 214         `------------------------------------*/
 215
 216 prologue_declarations:
 217   /* Nothing */
 218 | prologue_declarations prologue_declaration
 219 ;
 220
 221 prologue_declaration:
 222   grammar_declaration
 223 | "%{...%}"     { prologue_augment (translate_code ($1, @1), @1, union_seen); }
 224 | "%after-header" braceless        { prologue_augment ($2, @2, true); }
 225 | "%before-header" braceless       { prologue_augment ($2, @2, false); }
 226 | "%debug"                         { debug_flag = true; }
 227 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 228 | "%defines"                       { defines_flag = true; }
 229 | "%end-header" braceless          { muscle_code_grow ("end_header", $2, @2); }
 230 | "%error-verbose"                 { error_verbose = true; }
 231 | "%expect" INT                    { expected_sr_conflicts = $2; }
 232 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 233 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; }
 234 | "%glr-parser"
 235     {
 236       nondeterministic_parser = true;
 237       glr_parser = true;
 238     }
 239 | "%initial-action" "{...}"
 240     {
 241       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 242     }
 243 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 244 | "%locations"                  { locations_flag = true; }
 245 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; }
 246 | "%no-lines"                   { no_lines_flag = true; }
 247 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 248 | "%output" "=" STRING          { spec_outfile = $3; }
 249 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 250 | "%pure-parser"                { pure_parser = true; }
 251 | "%require" STRING             { version_check (&@2, $2); }
 252 | "%skeleton" STRING            { skeleton = $2; }
 253 | "%start-header" braceless     { muscle_code_grow ("start_header", $2, @2); }
 254 | "%token-table"                { token_table_flag = true; }
 255 | "%verbose"                    { report_flag = report_states; }
 256 | "%yacc"                       { yacc_flag = true; }
 257 | /*FIXME: Err?  What is this horror doing here? */ ";"
 258 ;
 259
 260 grammar_declaration:
 261   precedence_declaration
 262 | symbol_declaration
 263 | "%start" symbol
 264     {
 265       grammar_start_symbol_set ($2, @2);
 266     }
 267 | "%destructor" "{...}" generic_symlist
 268     {
 269       symbol_list *list;
 270       const char *action = translate_symbol_action ($2, @2);
 271       for (list = $3; list; list = list->next)
 272         symbol_list_destructor_set (list, action, @2);
 273       symbol_list_free ($3);
 274     }
 275 | "%printer" "{...}" generic_symlist
 276     {
 277       symbol_list *list;
 278       const char *action = translate_symbol_action ($2, @2);
 279       for (list = $3; list; list = list->next)
 280         symbol_list_printer_set (list, action, @2);
 281       symbol_list_free ($3);
 282     }
 283 | "%default-prec"
 284     {
 285       default_prec = true;
 286     }
 287 | "%no-default-prec"
 288     {
 289       default_prec = false;
 290     }
 291 ;
 292
 293
 294 /*----------*
 295  | %union.  |
 296  *----------*/
 297
 298 %token PERCENT_UNION "%union";
 299
 300 union_name:
 301   /* Nothing. */ {}
 302 | ID             { muscle_code_grow ("union_name", $1, @1); }
 303 ;
 304
 305 grammar_declaration:
 306   "%union" union_name "{...}"
 307     {
 308       char const *body = $3;
 309
 310       /* Concatenate the %union bodies.  If this is the first %union, make sure
 311          the synchronization line appears after the opening '{' so as not to
 312          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 313          into '\n', and omit the new %union's leading '{'.  */
 314       if (!union_seen)
 315         {
 316           muscle_grow ("stype", "{", "");
 317         }
 318       else
 319         {
 320           char *code = muscle_find ("stype");
 321           code[strlen (code) - 1] = '\n';
 322         }
 323       body++;
 324
 325       union_seen = true;
 326       muscle_code_grow ("stype", body, @3);
 327     }
 328 ;
 329
 330
 331
 332
 333 symbol_declaration:
 334   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 335     {
 336       current_class = unknown_sym;
 337       current_type = NULL;
 338     }
 339 | "%token" { current_class = token_sym; } symbol_defs.1
 340     {
 341       current_class = unknown_sym;
 342       current_type = NULL;
 343     }
 344 | "%type" TYPE symbols.1
 345     {
 346       tag_seen = true;
 347       symbol_list *list;
 348       for (list = $3; list; list = list->next)
 349         symbol_type_set (list->content.sym, $2, @2);
 350       symbol_list_free ($3);
 351     }
 352 ;
 353
 354 precedence_declaration:
 355   precedence_declarator type.opt symbols.1
 356     {
 357       symbol_list *list;
 358       ++current_prec;
 359       for (list = $3; list; list = list->next)
 360         {
 361           symbol_type_set (list->content.sym, current_type, @2);
 362           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 363         }
 364       symbol_list_free ($3);
 365       current_type = NULL;
 366     }
 367 ;
 368
 369 precedence_declarator:
 370   "%left"     { $$ = left_assoc; }
 371 | "%right"    { $$ = right_assoc; }
 372 | "%nonassoc" { $$ = non_assoc; }
 373 ;
 374
 375 type.opt:
 376   /* Nothing. */ { current_type = NULL; }
 377 | TYPE           { current_type = $1; tag_seen = true; }
 378 ;
 379
 380 /* One or more symbols to be %typed. */
 381 symbols.1:
 382   symbol
 383     { $$ = symbol_list_sym_new ($1, @1); }
 384 | symbols.1 symbol
 385     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 386 ;
 387
 388 generic_symlist:
 389   generic_symlist_item { $$ = $1; }
 390 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 391 ;
 392
 393 generic_symlist_item:
 394   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 395 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 396 | "%symbol-default" { $$ = symbol_list_default_new (@1); }
 397 ;
 398
 399 /* One token definition.  */
 400 symbol_def:
 401   TYPE
 402      {
 403        current_type = $1;
 404        tag_seen = true;
 405      }
 406 | id
 407      {
 408        symbol_class_set ($1, current_class, @1, true);
 409        symbol_type_set ($1, current_type, @1);
 410      }
 411 | id INT
 412     {
 413       symbol_class_set ($1, current_class, @1, true);
 414       symbol_type_set ($1, current_type, @1);
 415       symbol_user_token_number_set ($1, $2, @2);
 416     }
 417 | id string_as_id
 418     {
 419       symbol_class_set ($1, current_class, @1, true);
 420       symbol_type_set ($1, current_type, @1);
 421       symbol_make_alias ($1, $2, @$);
 422     }
 423 | id INT string_as_id
 424     {
 425       symbol_class_set ($1, current_class, @1, true);
 426       symbol_type_set ($1, current_type, @1);
 427       symbol_user_token_number_set ($1, $2, @2);
 428       symbol_make_alias ($1, $3, @$);
 429     }
 430 ;
 431
 432 /* One or more symbol definitions. */
 433 symbol_defs.1:
 434   symbol_def
 435 | symbol_defs.1 symbol_def
 436 ;
 437
 438
 439         /*------------------------------------------.
 440         | The grammar section: between the two %%.  |
 441         `------------------------------------------*/
 442
 443 grammar:
 444   rules_or_grammar_declaration
 445 | grammar rules_or_grammar_declaration
 446 ;
 447
 448 /* As a Bison extension, one can use the grammar declarations in the
 449    body of the grammar.  */
 450 rules_or_grammar_declaration:
 451   rules
 452 | grammar_declaration ";"
 453 | error ";"
 454     {
 455       yyerrok;
 456     }
 457 ;
 458
 459 rules:
 460   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 461 ;
 462
 463 rhses.1:
 464   rhs                { grammar_current_rule_end (@1); }
 465 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 466 | rhses.1 ";"
 467 ;
 468
 469 rhs:
 470   /* Nothing.  */
 471     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 472 | rhs symbol
 473     { grammar_current_rule_symbol_append ($2, @2); }
 474 | rhs "{...}"
 475     { grammar_current_rule_action_append ($2, @2); }
 476 | rhs "%prec" symbol
 477     { grammar_current_rule_prec_set ($3, @3); }
 478 | rhs "%dprec" INT
 479     { grammar_current_rule_dprec_set ($3, @3); }
 480 | rhs "%merge" TYPE
 481     { grammar_current_rule_merge_set ($3, @3); }
 482 ;
 483
 484
 485 /*-----------*
 486  | content.  |
 487  *-----------*/
 488
 489 content:
 490   STRING
 491 | braceless
 492 ;
 493
 494 /* Some content or "1" by default. */
 495 content.opt:
 496   /* Nothing. */
 497     {
 498       static char one[] = "1";
 499       $$ = one;
 500     }
 501 | content
 502 ;
 503
 504
 505 braceless:
 506   "{...}"
 507     {
 508       $1[strlen ($1) - 1] = '\n';
 509       $$ = translate_code ($1 + 1, @1);
 510     }
 511 ;
 512
 513
 514 /*---------------*
 515  | Identifiers.  |
 516  *---------------*/
 517
 518 /* Identifiers are returned as uniqstr values by the scanner.
 519    Depending on their use, we may need to make them genuine symbols.  */
 520
 521 id:
 522   ID
 523     { $$ = symbol_from_uniqstr ($1, @1); }
 524 | CHAR
 525     {
 526       $$ = symbol_get (char_name ($1), @1);
 527       symbol_class_set ($$, token_sym, @1, false);
 528       symbol_user_token_number_set ($$, $1, @1);
 529     }
 530 ;
 531
 532 id_colon:
 533   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 534 ;
 535
 536
 537 symbol:
 538   id
 539 | string_as_id
 540 ;
 541
 542 /* A string used as an ID: quote it.  */
 543 string_as_id:
 544   STRING
 545     {
 546       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 547       symbol_class_set ($$, token_sym, @1, false);
 548     }
 549 ;
 550
 551 epilogue.opt:
 552   /* Nothing.  */
 553 | "%%" EPILOGUE
 554     {
 555       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 556       gram_scanner_last_string_free ();
 557     }
 558 ;
 559
 560 %%
 561
 562
 563 /* Return the location of the left-hand side of a rule whose
 564    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 565    the right-hand side, and return an empty location equal to the end
 566    boundary of RHS[0] if the right-hand side is empty.  */
 567
 568 static YYLTYPE
 569 lloc_default (YYLTYPE const *rhs, int n)
 570 {
 571   int i;
 572   YYLTYPE loc;
 573
 574   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 575      The bug is fixed in 7.4.2m, but play it safe for now.  */
 576   loc.start = rhs[n].end;
 577   loc.end = rhs[n].end;
 578
 579   /* Ignore empty nonterminals the start of the the right-hand side.
 580      Do not bother to ignore them at the end of the right-hand side,
 581      since empty nonterminals have the same end as their predecessors.  */
 582   for (i = 1; i <= n; i++)
 583     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 584       {
 585         loc.start = rhs[i].start;
 586         break;
 587       }
 588
 589   return loc;
 590 }
 591
 592
 593 /* Add a lex-param or a parse-param (depending on TYPE) with
 594    declaration DECL and location LOC.  */
 595
 596 static void
 597 add_param (char const *type, char *decl, location loc)
 598 {
 599   static char const alphanum[26 + 26 + 1 + 10] =
 600     "abcdefghijklmnopqrstuvwxyz"
 601     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 602     "_"
 603     "0123456789";
 604   char const *name_start = NULL;
 605   char *p;
 606
 607   /* Stop on last actual character.  */
 608   for (p = decl; p[1]; p++)
 609     if ((p == decl
 610          || ! memchr (alphanum, p[-1], sizeof alphanum))
 611         && memchr (alphanum, p[0], sizeof alphanum - 10))
 612       name_start = p;
 613
 614   /* Strip the surrounding '{' and '}', and any blanks just inside
 615      the braces.  */
 616   while (*--p == ' ' || *p == '\t')
 617     continue;
 618   p[1] = '\0';
 619   while (*++decl == ' ' || *decl == '\t')
 620     continue;
 621
 622   if (! name_start)
 623     complain_at (loc, _("missing identifier in parameter declaration"));
 624   else
 625     {
 626       char *name;
 627       size_t name_len;
 628
 629       for (name_len = 1;
 630            memchr (alphanum, name_start[name_len], sizeof alphanum);
 631            name_len++)
 632         continue;
 633
 634       name = xmalloc (name_len + 1);
 635       memcpy (name, name_start, name_len);
 636       name[name_len] = '\0';
 637       muscle_pair_list_grow (type, decl, name);
 638       free (name);
 639     }
 640
 641   gram_scanner_last_string_free ();
 642 }
 643
 644
 645 static void
 646 version_check (location const *loc, char const *version)
 647 {
 648   if (strverscmp (version, PACKAGE_VERSION) > 0)
 649     {
 650       complain_at (*loc, "require bison %s, but have %s",
 651                    version, PACKAGE_VERSION);
 652       exit (63);
 653     }
 654 }
 655
 656 static void
 657 gram_error (location const *loc, char const *msg)
 658 {
 659   complain_at (*loc, "%s", msg);
 660 }
 661
 662 char const *
 663 token_name (int type)
 664 {
 665   return yytname[YYTRANSLATE (type)];
 666 }
 667
 668 static char const *
 669 char_name (char c)
 670 {
 671   if (c == '\'')
 672     return "'\\''";
 673   else
 674     {
 675       char buf[4];
 676       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 677       return quotearg_style (escape_quoting_style, buf);
 678     }
 679 }