src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 /* Only NUMBERS have a value.  */
  97 %union
  98 {
  99   symbol *symbol;
 100   symbol_list *list;
 101   int integer;
 102   char *chars;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_AFTER_HEADER    "%after-header"
 135   PERCENT_BEFORE_HEADER   "%before-header"
 136   PERCENT_DEBUG           "%debug"
 137   PERCENT_DEFAULT_PREC    "%default-prec"
 138   PERCENT_DEFINE          "%define"
 139   PERCENT_DEFINES         "%defines"
 140   PERCENT_END_HEADER      "%end-header"
 141   PERCENT_ERROR_VERBOSE   "%error-verbose"
 142   PERCENT_EXPECT          "%expect"
 143   PERCENT_EXPECT_RR       "%expect-rr"
 144   PERCENT_FILE_PREFIX     "%file-prefix"
 145   PERCENT_GLR_PARSER      "%glr-parser"
 146   PERCENT_INITIAL_ACTION  "%initial-action"
 147   PERCENT_LEX_PARAM       "%lex-param"
 148   PERCENT_LOCATIONS       "%locations"
 149   PERCENT_NAME_PREFIX     "%name-prefix"
 150   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 151   PERCENT_NO_LINES        "%no-lines"
 152   PERCENT_NONDETERMINISTIC_PARSER
 153                           "%nondeterministic-parser"
 154   PERCENT_OUTPUT          "%output"
 155   PERCENT_PARSE_PARAM     "%parse-param"
 156   PERCENT_PURE_PARSER     "%pure-parser"
 157   PERCENT_REQUIRE         "%require"
 158   PERCENT_SKELETON        "%skeleton"
 159   PERCENT_START           "%start"
 160   PERCENT_START_HEADER    "%start-header"
 161   PERCENT_TOKEN_TABLE     "%token-table"
 162   PERCENT_VERBOSE         "%verbose"
 163   PERCENT_YACC            "%yacc"
 164 ;
 165
 166 %token BRACED_CODE     "{...}"
 167 %token CHAR            "char"
 168 %token EPILOGUE        "epilogue"
 169 %token EQUAL           "="
 170 %token ID              "identifier"
 171 %token ID_COLON        "identifier:"
 172 %token PERCENT_PERCENT "%%"
 173 %token PIPE            "|"
 174 %token PROLOGUE        "%{...%}"
 175 %token SEMICOLON       ";"
 176 %token TYPE            "type"
 177
 178 %type <character> CHAR
 179 %printer { fputs (char_name ($$), stderr); } CHAR
 180
 181 /* braceless is not to be used for rule or symbol actions, as it
 182    calls translate_code. */
 183 %type <chars> STRING "{...}" "%{...%}" EPILOGUE braceless content content.opt
 184 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 185          STRING
 186 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 187          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 188
 189 %type <uniqstr> TYPE ID ID_COLON
 190 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 191 %printer { fputs ($$, stderr); } ID
 192 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 193
 194 %type <integer> INT
 195 %printer { fprintf (stderr, "%d", $$); } INT
 196
 197 %type <symbol> id id_colon symbol string_as_id
 198 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 199 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 200
 201 %type <assoc> precedence_declarator
 202 %type <list>  symbols.1
 203 %%
 204
 205 input:
 206   prologue_declarations "%%" grammar epilogue.opt
 207 ;
 208
 209
 210         /*------------------------------------.
 211         | Declarations: before the first %%.  |
 212         `------------------------------------*/
 213
 214 prologue_declarations:
 215   /* Nothing */
 216 | prologue_declarations prologue_declaration
 217 ;
 218
 219 prologue_declaration:
 220   grammar_declaration
 221 | "%{...%}"     { prologue_augment (translate_code ($1, @1), @1, union_seen); }
 222 | "%after-header" braceless        { prologue_augment ($2, @2, true); }
 223 | "%before-header" braceless       { prologue_augment ($2, @2, false); }
 224 | "%debug"                         { debug_flag = true; }
 225 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 226 | "%defines"                       { defines_flag = true; }
 227 | "%end-header" braceless          { muscle_code_grow ("end_header", $2, @2); }
 228 | "%error-verbose"                 { error_verbose = true; }
 229 | "%expect" INT                    { expected_sr_conflicts = $2; }
 230 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 231 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; }
 232 | "%glr-parser"
 233     {
 234       nondeterministic_parser = true;
 235       glr_parser = true;
 236     }
 237 | "%initial-action" "{...}"
 238     {
 239       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 240     }
 241 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 242 | "%locations"                  { locations_flag = true; }
 243 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; }
 244 | "%no-lines"                   { no_lines_flag = true; }
 245 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 246 | "%output" "=" STRING          { spec_outfile = $3; }
 247 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 248 | "%pure-parser"                { pure_parser = true; }
 249 | "%require" STRING             { version_check (&@2, $2); }
 250 | "%skeleton" STRING            { skeleton = $2; }
 251 | "%start-header" braceless     { muscle_code_grow ("start_header", $2, @2); }
 252 | "%token-table"                { token_table_flag = true; }
 253 | "%verbose"                    { report_flag = report_states; }
 254 | "%yacc"                       { yacc_flag = true; }
 255 | /*FIXME: Err?  What is this horror doing here? */ ";"
 256 ;
 257
 258 grammar_declaration:
 259   precedence_declaration
 260 | symbol_declaration
 261 | "%start" symbol
 262     {
 263       grammar_start_symbol_set ($2, @2);
 264     }
 265 | "%destructor" "{...}"
 266     {
 267       default_destructor_set (translate_symbol_action ($2, @2), @2);
 268     }
 269 | "%destructor" "{...}" symbols.1
 270     {
 271       symbol_list *list;
 272       const char *action = translate_symbol_action ($2, @2);
 273       for (list = $3; list; list = list->next)
 274         symbol_destructor_set (list->sym, action, @2);
 275       symbol_list_free ($3);
 276     }
 277 | "%printer" "{...}" symbols.1
 278     {
 279       symbol_list *list;
 280       const char *action = translate_symbol_action ($2, @2);
 281       for (list = $3; list; list = list->next)
 282         symbol_printer_set (list->sym, action, @2);
 283       symbol_list_free ($3);
 284     }
 285 | "%printer" "{...}"
 286     {
 287       default_printer_set (translate_symbol_action ($2, @2), @2);
 288     }
 289 | "%default-prec"
 290     {
 291       default_prec = true;
 292     }
 293 | "%no-default-prec"
 294     {
 295       default_prec = false;
 296     }
 297 ;
 298
 299
 300 /*----------*
 301  | %union.  |
 302  *----------*/
 303
 304 %token PERCENT_UNION "%union";
 305
 306 union_name:
 307   /* Nothing. */ {}
 308 | ID             { muscle_code_grow ("union_name", $1, @1); }
 309 ;
 310
 311 grammar_declaration:
 312   "%union" union_name "{...}"
 313     {
 314       char const *body = $3;
 315
 316       /* Concatenate the %union bodies.  If this is the first %union, make sure
 317          the synchronization line appears after the opening '{' so as not to
 318          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 319          into '\n', and omit the new %union's leading '{'.  */
 320       if (!union_seen)
 321         {
 322           muscle_grow ("stype", "{", "");
 323         }
 324       else
 325         {
 326           char *code = muscle_find ("stype");
 327           code[strlen (code) - 1] = '\n';
 328         }
 329       body++;
 330
 331       union_seen = true;
 332       muscle_code_grow ("stype", body, @3);
 333     }
 334 ;
 335
 336
 337
 338
 339 symbol_declaration:
 340   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 341     {
 342       current_class = unknown_sym;
 343       current_type = NULL;
 344     }
 345 | "%token" { current_class = token_sym; } symbol_defs.1
 346     {
 347       current_class = unknown_sym;
 348       current_type = NULL;
 349     }
 350 | "%type" TYPE symbols.1
 351     {
 352       tag_seen = true;
 353       symbol_list *list;
 354       for (list = $3; list; list = list->next)
 355         symbol_type_set (list->sym, $2, @2);
 356       symbol_list_free ($3);
 357     }
 358 ;
 359
 360 precedence_declaration:
 361   precedence_declarator type.opt symbols.1
 362     {
 363       symbol_list *list;
 364       ++current_prec;
 365       for (list = $3; list; list = list->next)
 366         {
 367           symbol_type_set (list->sym, current_type, @2);
 368           symbol_precedence_set (list->sym, current_prec, $1, @1);
 369         }
 370       symbol_list_free ($3);
 371       current_type = NULL;
 372     }
 373 ;
 374
 375 precedence_declarator:
 376   "%left"     { $$ = left_assoc; }
 377 | "%right"    { $$ = right_assoc; }
 378 | "%nonassoc" { $$ = non_assoc; }
 379 ;
 380
 381 type.opt:
 382   /* Nothing. */ { current_type = NULL; }
 383 | TYPE           { current_type = $1; tag_seen = true; }
 384 ;
 385
 386 /* One or more nonterminals to be %typed. */
 387 symbols.1:
 388   symbol            { $$ = symbol_list_new ($1, @1); }
 389 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 390 ;
 391
 392 /* One token definition.  */
 393 symbol_def:
 394   TYPE
 395      {
 396        current_type = $1;
 397        tag_seen = true;
 398      }
 399 | id
 400      {
 401        symbol_class_set ($1, current_class, @1, true);
 402        symbol_type_set ($1, current_type, @1);
 403      }
 404 | id INT
 405     {
 406       symbol_class_set ($1, current_class, @1, true);
 407       symbol_type_set ($1, current_type, @1);
 408       symbol_user_token_number_set ($1, $2, @2);
 409     }
 410 | id string_as_id
 411     {
 412       symbol_class_set ($1, current_class, @1, true);
 413       symbol_type_set ($1, current_type, @1);
 414       symbol_make_alias ($1, $2, @$);
 415     }
 416 | id INT string_as_id
 417     {
 418       symbol_class_set ($1, current_class, @1, true);
 419       symbol_type_set ($1, current_type, @1);
 420       symbol_user_token_number_set ($1, $2, @2);
 421       symbol_make_alias ($1, $3, @$);
 422     }
 423 ;
 424
 425 /* One or more symbol definitions. */
 426 symbol_defs.1:
 427   symbol_def
 428 | symbol_defs.1 symbol_def
 429 ;
 430
 431
 432         /*------------------------------------------.
 433         | The grammar section: between the two %%.  |
 434         `------------------------------------------*/
 435
 436 grammar:
 437   rules_or_grammar_declaration
 438 | grammar rules_or_grammar_declaration
 439 ;
 440
 441 /* As a Bison extension, one can use the grammar declarations in the
 442    body of the grammar.  */
 443 rules_or_grammar_declaration:
 444   rules
 445 | grammar_declaration ";"
 446 | error ";"
 447     {
 448       yyerrok;
 449     }
 450 ;
 451
 452 rules:
 453   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 454 ;
 455
 456 rhses.1:
 457   rhs                { grammar_current_rule_end (@1); }
 458 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 459 | rhses.1 ";"
 460 ;
 461
 462 rhs:
 463   /* Nothing.  */
 464     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 465 | rhs symbol
 466     { grammar_current_rule_symbol_append ($2, @2); }
 467 | rhs "{...}"
 468     { grammar_current_rule_action_append ($2, @2); }
 469 | rhs "%prec" symbol
 470     { grammar_current_rule_prec_set ($3, @3); }
 471 | rhs "%dprec" INT
 472     { grammar_current_rule_dprec_set ($3, @3); }
 473 | rhs "%merge" TYPE
 474     { grammar_current_rule_merge_set ($3, @3); }
 475 ;
 476
 477
 478 /*-----------*
 479  | content.  |
 480  *-----------*/
 481
 482 content:
 483   STRING
 484 | braceless
 485 ;
 486
 487 /* Some content or "1" by default. */
 488 content.opt:
 489   /* Nothing. */
 490     {
 491       static char one[] = "1";
 492       $$ = one;
 493     }
 494 | content
 495 ;
 496
 497
 498 braceless:
 499   "{...}"
 500     {
 501       $1[strlen ($1) - 1] = '\n';
 502       $$ = translate_code ($1 + 1, @1);
 503     }
 504 ;
 505
 506
 507 /*---------------*
 508  | Identifiers.  |
 509  *---------------*/
 510
 511 /* Identifiers are returned as uniqstr values by the scanner.
 512    Depending on their use, we may need to make them genuine symbols.  */
 513
 514 id:
 515   ID
 516     { $$ = symbol_from_uniqstr ($1, @1); }
 517 | CHAR
 518     {
 519       $$ = symbol_get (char_name ($1), @1);
 520       symbol_class_set ($$, token_sym, @1, false);
 521       symbol_user_token_number_set ($$, $1, @1);
 522     }
 523 ;
 524
 525 id_colon:
 526   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 527 ;
 528
 529
 530 symbol:
 531   id
 532 | string_as_id
 533 ;
 534
 535 /* A string used as an ID: quote it.  */
 536 string_as_id:
 537   STRING
 538     {
 539       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 540       symbol_class_set ($$, token_sym, @1, false);
 541     }
 542 ;
 543
 544 epilogue.opt:
 545   /* Nothing.  */
 546 | "%%" EPILOGUE
 547     {
 548       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 549       gram_scanner_last_string_free ();
 550     }
 551 ;
 552
 553 %%
 554
 555
 556 /* Return the location of the left-hand side of a rule whose
 557    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 558    the right-hand side, and return an empty location equal to the end
 559    boundary of RHS[0] if the right-hand side is empty.  */
 560
 561 static YYLTYPE
 562 lloc_default (YYLTYPE const *rhs, int n)
 563 {
 564   int i;
 565   YYLTYPE loc;
 566
 567   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 568      The bug is fixed in 7.4.2m, but play it safe for now.  */
 569   loc.start = rhs[n].end;
 570   loc.end = rhs[n].end;
 571
 572   /* Ignore empty nonterminals the start of the the right-hand side.
 573      Do not bother to ignore them at the end of the right-hand side,
 574      since empty nonterminals have the same end as their predecessors.  */
 575   for (i = 1; i <= n; i++)
 576     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 577       {
 578         loc.start = rhs[i].start;
 579         break;
 580       }
 581
 582   return loc;
 583 }
 584
 585
 586 /* Add a lex-param or a parse-param (depending on TYPE) with
 587    declaration DECL and location LOC.  */
 588
 589 static void
 590 add_param (char const *type, char *decl, location loc)
 591 {
 592   static char const alphanum[26 + 26 + 1 + 10] =
 593     "abcdefghijklmnopqrstuvwxyz"
 594     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 595     "_"
 596     "0123456789";
 597   char const *name_start = NULL;
 598   char *p;
 599
 600   /* Stop on last actual character.  */
 601   for (p = decl; p[1]; p++)
 602     if ((p == decl
 603          || ! memchr (alphanum, p[-1], sizeof alphanum))
 604         && memchr (alphanum, p[0], sizeof alphanum - 10))
 605       name_start = p;
 606
 607   /* Strip the surrounding '{' and '}', and any blanks just inside
 608      the braces.  */
 609   while (*--p == ' ' || *p == '\t')
 610     continue;
 611   p[1] = '\0';
 612   while (*++decl == ' ' || *decl == '\t')
 613     continue;
 614
 615   if (! name_start)
 616     complain_at (loc, _("missing identifier in parameter declaration"));
 617   else
 618     {
 619       char *name;
 620       size_t name_len;
 621
 622       for (name_len = 1;
 623            memchr (alphanum, name_start[name_len], sizeof alphanum);
 624            name_len++)
 625         continue;
 626
 627       name = xmalloc (name_len + 1);
 628       memcpy (name, name_start, name_len);
 629       name[name_len] = '\0';
 630       muscle_pair_list_grow (type, decl, name);
 631       free (name);
 632     }
 633
 634   gram_scanner_last_string_free ();
 635 }
 636
 637
 638 static void
 639 version_check (location const *loc, char const *version)
 640 {
 641   if (strverscmp (version, PACKAGE_VERSION) > 0)
 642     {
 643       complain_at (*loc, "require bison %s, but have %s",
 644                    version, PACKAGE_VERSION);
 645       exit (63);
 646     }
 647 }
 648
 649 static void
 650 gram_error (location const *loc, char const *msg)
 651 {
 652   complain_at (*loc, "%s", msg);
 653 }
 654
 655 char const *
 656 token_name (int type)
 657 {
 658   return yytname[YYTRANSLATE (type)];
 659 }
 660
 661 static char const *
 662 char_name (char c)
 663 {
 664   if (c == '\'')
 665     return "'\\''";
 666   else
 667     {
 668       char buf[4];
 669       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 670       return quotearg_style (escape_quoting_style, buf);
 671     }
 672 }