tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   6 # Software Foundation, Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # We want a recent Autotest.
  22 m4_version_prereq([2.58])
  23
  24
  25 ## ------------- ##
  26 ## Basic tests.  ##
  27 ## ------------- ##
  28
  29 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  30 # ------------------------------------------
  31 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  32 # taken in "slurp" mode, i.e., one can match end-of-lines.
  33 m4_define([AT_MATCHES_CHECK],
  34 [AT_CHECK([perl -0777 -ne '
  35 my $count = 0;
  36 s{$2}{ ++$count; "" }gem;
  37 printf "$count\n";' $1], [0], [$3
  38 ])])
  39
  40
  41 ## ------------------------------- ##
  42 ## Macros decoding Bison options.  ##
  43 ## ------------------------------- ##
  44
  45 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  46 # ----------------------------------------------------------------
  47 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  48 m4_define([AT_LOC_PUSHDEF],
  49 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  50 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  51 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  52 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  53
  54 # AT_LOC_POPDEF
  55 # -------------
  56 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  57 m4_define([AT_LOC_POPDEF],
  58 [m4_popdef([AT_LOC_FIRST_LINE])
  59 m4_popdef([AT_LOC_FIRST_COLUMN])
  60 m4_popdef([AT_LOC_LAST_LINE])
  61 m4_popdef([AT_LOC_LAST_COLUMN])])
  62
  63
  64
  65 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  66 # -----------------------------------------
  67 m4_define([AT_BISON_OPTION_PUSHDEFS],
  68 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  69
  70
  71 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  72 # --------------------------------------------------
  73 # This macro works around the impossibility to define macros
  74 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  75 # This sucks hard, GNU M4 should really provide M5-like $$1.
  76 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  77 [m4_if([$1$2], $[1]$[2], [],
  78        [m4_fatal([$0: Invalid arguments: $@])])dnl
  79 m4_pushdef([AT_DEFINES_IF],
  80 [m4_bmatch([$3], [%defines], [$1], [$2])])
  81 m4_pushdef([AT_SKEL_CC_IF],
  82 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  83 m4_pushdef([AT_GLR_IF],
  84 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  85 m4_pushdef([AT_LALR1_CC_IF],
  86 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  87 m4_pushdef([AT_GLR_CC_IF],
  88 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  89 # Using yacc.c?
  90 m4_pushdef([AT_YACC_IF],
  91 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  92 m4_pushdef([AT_LEXPARAM_IF],
  93 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  94 m4_pushdef([AT_LOCATION_IF],
  95 [m4_bmatch([$3], [%locations], [$1], [$2])])
  96 m4_pushdef([AT_LOCATION_TYPE_IF],
  97 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  98 m4_pushdef([AT_PARAM_IF],
  99 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 100 m4_pushdef([AT_PURE_IF],
 101 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 102            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 103            [$2])])
 104 m4_pushdef([AT_PURE_AND_LOC_IF],
 105 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 106 m4_pushdef([AT_GLR_OR_PARAM_IF],
 107 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 108 m4_pushdef([AT_NAME_PREFIX],
 109 [m4_bmatch([$3], [%name-prefix ".*"],
 110            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 111            [yy])])
 112 m4_pushdef([AT_TOKEN_PREFIX],
 113 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
 114            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
 115 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 116 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 117 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 118                     [$2])])
 119 # yyerror always sees the locations (when activated), except if
 120 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 121 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 122 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 123                                         [$1])],
 124                             [$1])],
 125                 [$2])])
 126
 127 # The interface is pure: either because %define api.pure, or because we
 128 # are using the C++ parsers.
 129 m4_pushdef([AT_PURE_LEX_IF],
 130 [AT_PURE_IF([$1],
 131             [AT_SKEL_CC_IF([$1], [$2])])])
 132
 133 AT_PURE_LEX_IF(
 134 [m4_pushdef([AT_LOC], [(*llocp)])
 135  m4_pushdef([AT_VAL], [(*lvalp)])
 136  m4_pushdef([AT_LEX_FORMALS],
 137             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 138  m4_pushdef([AT_LEX_ARGS],
 139             [lvalp[]AT_LOCATION_IF([, llocp])])
 140  m4_pushdef([AT_USE_LEX_ARGS],
 141             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 142  m4_pushdef([AT_LEX_PRE_FORMALS],
 143             [AT_LEX_FORMALS, ])
 144  m4_pushdef([AT_LEX_PRE_ARGS],
 145             [AT_LEX_ARGS, ])
 146 ],
 147 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 148  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 149  m4_pushdef([AT_LEX_FORMALS],     [void])
 150  m4_pushdef([AT_LEX_ARGS],        [])
 151  m4_pushdef([AT_USE_LEX_ARGS],    [])
 152  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 153  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 154 ])
 155
 156 # Handle the different types of location components.
 157
 158 AT_SKEL_CC_IF(
 159   [AT_LOCATION_TYPE_IF(
 160     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 161     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 162   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 163
 164
 165 AT_GLR_IF([AT_KEYWORDS([glr])])
 166 ])# _AT_BISON_OPTION_PUSHDEFS
 167
 168
 169 # AT_BISON_OPTION_POPDEFS
 170 # -----------------------
 171 m4_define([AT_BISON_OPTION_POPDEFS],
 172 [m4_popdef([AT_LEX_PRE_ARGS])
 173 m4_popdef([AT_LEX_PRE_FORMALS])
 174 m4_popdef([AT_USE_LEX_ARGS])
 175 m4_popdef([AT_LEX_ARGS])
 176 m4_popdef([AT_LEX_FORMALS])
 177 m4_popdef([AT_VAL])
 178 m4_popdef([AT_LOC])
 179 m4_popdef([AT_PURE_LEX_IF])
 180 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 181 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 182 m4_popdef([AT_NAME_PREFIX])
 183 m4_popdef([AT_GLR_OR_PARAM_IF])
 184 m4_popdef([AT_PURE_AND_LOC_IF])
 185 m4_popdef([AT_LOCATION_TYPE_IF])
 186 m4_popdef([AT_LOCATION_IF])
 187 m4_popdef([AT_PARAM_IF])
 188 m4_popdef([AT_LEXPARAM_IF])
 189 m4_popdef([AT_YACC_IF])
 190 m4_popdef([AT_GLR_IF])
 191 m4_popdef([AT_SKEL_CC_IF])
 192 m4_popdef([AT_GLR_CC_IF])
 193 m4_popdef([AT_LALR1_CC_IF])
 194 m4_popdef([AT_DEFINES_IF])
 195 AT_LOC_POPDEF
 196 ])# AT_BISON_OPTION_POPDEFS
 197
 198
 199
 200 ## -------------------------- ##
 201 ## Generating Grammar Files.  ##
 202 ## -------------------------- ##
 203
 204 # AT_DATA_SOURCE_PROLOGUE
 205 # ------------------------
 206 # The prologue that should be included in any source code that is
 207 # meant to be compiled.
 208 m4_define([AT_DATA_SOURCE_PROLOGUE],
 209 [[#include <config.h>
 210 /* We don't need perfect functions for these tests. */
 211 #undef malloc
 212 #undef memcmp
 213 #undef realloc
 214 ]])
 215
 216 # AT_DATA_GRAMMAR_PROLOGUE
 217 # ------------------------
 218 # The prologue that should be included in any grammar which parser is
 219 # meant to be compiled.
 220 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 221 [[%code top {
 222 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 223 [}
 224 ]])
 225
 226 # AT_DATA_SOURCE(NAME, CONTENT)
 227 # -----------------------------
 228 # Generate the file NAME, which CONTENT is preceded by
 229 # AT_DATA_SOURCE_PROLOGUE.
 230 m4_define([AT_DATA_SOURCE],
 231 [AT_DATA([$1],
 232 [AT_DATA_SOURCE_PROLOGUE
 233 $2])
 234 ])
 235
 236 # AT_DATA_GRAMMAR(NAME, CONTENT)
 237 # ------------------------------
 238 # Generate the file NAME, which CONTENT is preceded by
 239 # AT_DATA_GRAMMAR_PROLOGUE.
 240 m4_define([AT_DATA_GRAMMAR],
 241 [AT_DATA([$1],
 242 [AT_DATA_GRAMMAR_PROLOGUE
 243 $2])
 244 ])
 245
 246 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 247 # -------------------------------------------------
 248 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 249 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 250 #
 251 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 252 # Bison in the test suite.  For now it ensures that:
 253 #
 254 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 255 #      a non-zero exit status since Bison doesn't always try to free all memory
 256 #      in that case.
 257 #
 258 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 259 #      --graph and --report=all output for every working grammar.
 260 m4_define([AT_BISON_CHECK],
 261 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 262        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 263 AT_BISON_CHECK_NO_XML($@)])
 264
 265 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 266 # --------------------------------------------------------
 267 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 268 # when a tortured grammar's XML is known to be too large for xsltproc to
 269 # handle.
 270 m4_define([AT_BISON_CHECK_NO_XML],
 271 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 272                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 273
 274 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 275 # -----------------------------------------------------
 276 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 277 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 278 # have a non-zero exit status.
 279 m4_define([AT_BISON_CHECK_XML],
 280 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 281   mkdir xml-tests]
 282   m4_pushdef([AT_BISON_ARGS],
 283              [m4_bpatsubsts([[$1]],
 284                             [--report(-file)?=[^][ ]*], [],
 285                             [--graph=[^][ ]*], [],
 286                             [--xml=[^][ ]*], [])])dnl
 287   # Don't combine these Bison invocations since we want to be sure that
 288   # --report=all isn't required to get the full XML file.
 289   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 290              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 291            [[0]], [ignore], [ignore])
 292   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 293            [[0]], [ignore], [ignore])
 294   m4_popdef([AT_BISON_ARGS])dnl
 295   [cp xml-tests/test.output expout]
 296   AT_CHECK([[$XSLTPROC \
 297              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 298              xml-tests/test.xml]], [[0]], [expout])
 299   [cp xml-tests/test.dot expout]
 300   AT_CHECK([[$XSLTPROC \
 301              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 302              xml-tests/test.xml]], [[0]], [expout])
 303   [rm -rf xml-tests expout
 304 fi]])
 305
 306 # AT_QUELL_VALGRIND
 307 # -----------------
 308 # Put this before a Bison invocation to keep Valgrind from complaining about
 309 # reachable memory.
 310 #
 311 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 312 # The triple quoting below will cause test cases to fail if you do.  If you do
 313 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 314 # will then fail to shell-escape its contents when attempting to print them.
 315 # The testsuite verbose output, at least, will be incorrect, but nothing may
 316 # fail to make sure you notice.
 317 m4_define([AT_QUELL_VALGRIND],
 318 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 319
 320 ## ------------------------ ##
 321 ## Compiling C, C++ Files.  ##
 322 ## ------------------------ ##
 323
 324
 325 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 326 # ----------------------------------------
 327 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 328 # assume that we are linking too; this is a hack.
 329 m4_define([AT_COMPILE],
 330 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 331            0, [ignore], [ignore])])
 332
 333 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 334 # --------------------------------------------
 335 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 336 # assume that we are linking too; this is a hack.
 337 # If the C++ compiler does not work, ignore the test.
 338 m4_define([AT_COMPILE_CXX],
 339 [AT_KEYWORDS(c++)
 340 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 341 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 342          0, [ignore], [ignore])])
 343
 344
 345 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 346 # --------------------------------
 347 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 348 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 349 # along with it.
 350 # Relies on AT_SKEL_CC_IF.
 351 m4_define([AT_FULL_COMPILE],
 352 [AT_SKEL_CC_IF(
 353   [AT_BISON_CHECK([-o $1.cc $1.y])
 354    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 355   [AT_BISON_CHECK([-o $1.c $1.y])
 356    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 357 ])
 358
 359
 360 ## ---------------------------- ##
 361 ## Running a generated parser.  ##
 362 ## ---------------------------- ##
 363
 364 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 365 # ------------------------------------------------------------
 366 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 367 m4_define([AT_PARSER_CHECK],
 368 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 369
 370 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 371 #                          DECLS, GRAMMAR, INPUT,
 372 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 373 #                          [OTHER-CHECKS],
 374 #                          [PARSER-EXIT-VALUE],
 375 #                          [PARSER-STDOUT], [PARSER-STDERR])
 376 # -------------------------------------------------------------
 377 # Using TITLE as the test group title, check the generated parser tables
 378 # and parser for a specified grammar file under a condition labeled by
 379 # COND-VALUE.
 380 #
 381 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 382 # recognized attribute is described below where it is relevant.
 383 #
 384 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 385 # the grammar file.  Insert basic yyerror, yylex, and main function
 386 # definitions as well.  Hardcode yylex to return the (possibly empty)
 387 # comma-delimited series of tokens in INPUT followed by token 0.
 388 #
 389 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 390 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 391 # On the bison command-line, specify `--report=all --defines'.  Check
 392 # that Bison exits with value 0, has no stdout, and has stderr
 393 # BISON-STDERR.
 394 #
 395 # If TEST-SPEC contains the attribute `last-state', check that the value
 396 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 397 # the grammar; in other words, check the number of states (minus one).
 398 # Otherwise, check that everything in the `.output' file starting with
 399 # the definition of state 0 is the same as the entire value of
 400 # TABLES-OR-LAST-STATE.
 401 #
 402 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 403 # `.output' file, which is named `input.output', and/or grammar file,
 404 # which is named `input.y'.
 405 #
 406 # Finally, compile the generated parser and then run it using
 407 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 408 # PARSER-STDERR as the 2nd-4th arguments.
 409 #
 410 # As a precondition, you must properly double-quote all arguments that
 411 # are to be interpreted as strings.
 412 #
 413 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 414 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 415 # first argument.  This is useful, for example, when wrapping multiple
 416 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 417 # condition, in another macro.
 418 #
 419 # For example:
 420 #
 421 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 422 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 423 #   # ---------------------------------------------------------------------
 424 #   m4_define([AT_TEST_SYNTAX_ERROR],
 425 #   [
 426 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 427 #                              [[last-state]],
 428 #                              [[%error-verbose ]$2], [$3], [$4],
 429 #                              [[]], [$5], [], [$6], [$7], [$8])
 430 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 431 #                              [[last-state]],
 432 #                              [$2], [$3], [$4],
 433 #                              [[]], [$5], [], [$6], [$7], [$8])
 434 #   ])
 435 #
 436 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 437 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 438 #                        [[3]],
 439 #                        [[1]], [[]],
 440 #                        [AT_COND_CASE([[no verbose]],
 441 #                                      [[syntax error
 442 #   ]],
 443 #                                      [[syntax error, unexpected 'b', expecting $end
 444 #   ]])])
 445 m4_define([AT_TEST_TABLES_AND_PARSE],
 446 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 447
 448 AT_SETUP([$1])
 449
 450 AT_DATA_GRAMMAR([[input.y]],
 451 [[%code {
 452   #include <stdio.h>
 453   static void yyerror (char const *msg);
 454   static int yylex (void);
 455 }
 456
 457 ]$4[
 458
 459 %%
 460
 461 ]$5[
 462
 463 %%
 464
 465 static void
 466 yyerror (char const *msg)
 467 {
 468   fprintf (stderr, "%s\n", msg);
 469 }
 470
 471 static int
 472 yylex (void)
 473 {
 474   static int const input[] = {
 475     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 476   };
 477   static int const *inputp = input;
 478   return *inputp++;
 479 }
 480
 481 int
 482 main (void)
 483 {
 484   return yyparse ();
 485 }
 486 ]])
 487
 488 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 489 # expanding macros, so it corrupts some special characters in the
 490 # macros.  To avoid this, expand now and pass it the result with proper
 491 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 492 # strings.
 493
 494 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 495       [AT_BISON_CHECK],
 496       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 497                                [0], [], m4_dquote($7))
 498
 499 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 500       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 501                 m4_dquote($8))],
 502       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 503                 m4_dquote($8)[[
 504 ]])])
 505
 506 $9
 507
 508 AT_COMPILE([[input]])
 509
 510 AT_PARSER_CHECK([[./input]],
 511                 m4_ifval([$10], [m4_dquote($10)]),
 512                 m4_ifval([$11], [m4_dquote($11)]),
 513                 m4_ifval([$12], [m4_dquote($12)]))
 514
 515 AT_CLEANUP
 516
 517 m4_popdef([AT_COND_CASE])])
 518
 519
 520
 521 ## ----------------------- ##
 522 ## Launch the test suite.  ##
 523 ## ----------------------- ##
 524
 525 AT_INIT
 526
 527 AT_TESTED([bison])