data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, [YEARS])
  26 # ----------------------------
  27 # If YEARS are not defined, use b4_copyright_years.
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 ]m4_dquote(m4_text_wrap([Copyright (C)
  34 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  35 Free Software Foundation, Inc.]))[
  36
  37 This program is free software: you can redistribute it and/or modify
  38 it under the terms of the GNU General Public License as published by
  39 the Free Software Foundation, either version 3 of the License, or
  40 (at your option) any later version.
  41
  42 This program is distributed in the hope that it will be useful,
  43 but WITHOUT ANY WARRANTY; without even the implied warranty of
  44 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  45 GNU General Public License for more details.
  46
  47 You should have received a copy of the GNU General Public License
  48 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # The following error handling macros print error directives that should not
  69 # become arguments of other macro invocations since they would likely then be
  70 # mangled.  Thus, they print to stdout directly.
  71
  72 # b4_cat(TEXT)
  73 # ------------
  74 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  75 # escaped.  For example:
  76 #
  77 #   b4_cat([[@complain(invalid input@)]])
  78 m4_define([b4_cat],
  79 [m4_syscmd([cat <<'_m4eof'
  80 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  81 _m4eof
  82 ])dnl
  83 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  84
  85 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  86 # -------------------------------------------
  87 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  88 #
  89 # For example:
  90 #
  91 #   b4_error([[warn]], [[invalid value for '%s': %s]], [[foo]], [[3]])
  92 m4_define([b4_error],
  93 [b4_cat([[@]$1[(]$2[]]dnl
  94 [m4_if([$#], [2], [],
  95        [m4_foreach([b4_arg],
  96                    m4_dquote(m4_shift(m4_shift($@))),
  97                    [[@,]b4_arg])])[@)]])])
  98
  99 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 100 # ----------------------------------------------------------
 101 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 102 #
 103 # For example:
 104 #
 105 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 106 #               [[invalid %s]], [[foo]])
 107 m4_define([b4_error_at],
 108 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 109 [m4_if([$#], [4], [],
 110        [m4_foreach([b4_arg],
 111                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 112                    [[@,]b4_arg])])[@)]])])
 113
 114 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 115 # ------------------------------------
 116 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 117 #
 118 # For example:
 119 #
 120 #   b4_warn([[invalid value for '%s': %s]], [[foo]], [[3]])
 121 #
 122 # As a simple test suite, this:
 123 #
 124 #   m4_divert(-1)
 125 #   m4_define([asdf], [ASDF])
 126 #   m4_define([fsa], [FSA])
 127 #   m4_define([fdsa], [FDSA])
 128 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 129 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 130 #   b4_warn()
 131 #   b4_warn(1)
 132 #   b4_warn(1, 2)
 133 #
 134 # Should produce this without newlines:
 135 #
 136 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 137 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 138 #   @warn(@)
 139 #   @warn(1@)
 140 #   @warn(1@,2@)
 141 m4_define([b4_warn],
 142 [b4_error([[warn]], $@)])
 143
 144 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 145 # ---------------------------------------------------
 146 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 147 #
 148 # For example:
 149 #
 150 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 151 m4_define([b4_warn_at],
 152 [b4_error_at([[warn]], $@)])
 153
 154 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 155 # ----------------------------------------
 156 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 157 #
 158 # See b4_warn example.
 159 m4_define([b4_complain],
 160 [b4_error([[complain]], $@)])
 161
 162 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 163 # -------------------------------------------------------
 164 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 165 #
 166 # See b4_warn_at example.
 167 m4_define([b4_complain_at],
 168 [b4_error_at([[complain]], $@)])
 169
 170 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 171 # -------------------------------------
 172 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 173 #
 174 # See b4_warn example.
 175 m4_define([b4_fatal],
 176 [b4_error([[fatal]], $@)dnl
 177 m4_exit(1)])
 178
 179 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 180 # ----------------------------------------------------
 181 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 182 #
 183 # See b4_warn_at example.
 184 m4_define([b4_fatal_at],
 185 [b4_error_at([[fatal]], $@)dnl
 186 m4_exit(1)])
 187
 188
 189 ## ------------ ##
 190 ## Data Types.  ##
 191 ## ------------ ##
 192
 193 # b4_ints_in(INT1, INT2, LOW, HIGH)
 194 # ---------------------------------
 195 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 196 m4_define([b4_ints_in],
 197 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 198
 199
 200 # b4_subtract(LHS, RHS)
 201 # ---------------------
 202 # Evaluate LHS - RHS if they are integer literals, otherwise expand
 203 # to (LHS) - (RHS).
 204 m4_define([b4_subtract],
 205 [m4_bmatch([$1$2], [^[0123456789]*$],
 206            [m4_eval([$1 - $2])],
 207            [($1) - ($2)])])
 208
 209 # b4_join(ARG1, ...)
 210 # _b4_join(ARG1, ...)
 211 # -------------------
 212 # Join with comma, skipping empty arguments.
 213 # b4_join calls itself recursively until it sees the first non-empty
 214 # argument, then calls _b4_join which prepends each non-empty argument
 215 # with a comma.
 216 m4_define([b4_join],
 217 [m4_if([$#$1],
 218        [1], [],
 219        [m4_ifval([$1],
 220                  [$1[]_$0(m4_shift($@))],
 221                  [$0(m4_shift($@))])])])
 222
 223 # _b4_join(ARGS1, ...)
 224 # --------------------
 225 m4_define([_b4_join],
 226 [m4_if([$#$1],
 227        [1], [],
 228        [m4_ifval([$1], [, $1])[]$0(m4_shift($@))])])
 229
 230
 231
 232
 233 # b4_integral_parser_tables_map(MACRO)
 234 # -------------------------------------
 235 # Map MACRO on all the integral tables.  MACRO is expected to have
 236 # the signature MACRO(TABLE-NAME, CONTENT, COMMENT).
 237 m4_define([b4_integral_parser_tables_map],
 238 [$1([pact], [b4_pact],
 239     [[YYPACT[STATE-NUM] -- Index in YYTABLE of the portion describing
 240 STATE-NUM.]])
 241
 242 $1([defact], [b4_defact],
 243    [[YYDEFACT[S] -- default reduction number in state S.  Performed when
 244 YYTABLE does not specify something else to do.  Zero means the default
 245 is an error.]])
 246
 247 $1([pgoto], [b4_pgoto], [[YYPGOTO[NTERM-NUM].]])
 248
 249 $1([defgoto], [b4_defgoto], [[YYDEFGOTO[NTERM-NUM].]])
 250
 251 $1([table], [b4_table],
 252    [[YYTABLE[YYPACT[STATE-NUM]].  What to do in state STATE-NUM.  If
 253 positive, shift that token.  If negative, reduce the rule which
 254 number is the opposite.  If YYTABLE_NINF, syntax error.]])
 255
 256 $1([check], [b4_check])
 257
 258 $1([stos], [b4_stos],
 259    [[STOS_[STATE-NUM] -- The (internal number of the) accessing
 260 symbol of state STATE-NUM.]])
 261
 262 $1([r1], [b4_r1],
 263    [[YYR1[YYN] -- Symbol number of symbol that rule YYN derives.]])
 264
 265 $1([r2], [b4_r2],
 266    [[YYR2[YYN] -- Number of symbols composing right hand side of rule YYN.]])
 267 ])
 268
 269
 270 # b4_parser_tables_declare
 271 # b4_parser_tables_define
 272 # ------------------------
 273 # Define/declare the (deterministic) parser tables.
 274 m4_define([b4_parser_tables_declare],
 275 [b4_integral_parser_tables_map([b4_integral_parser_table_declare])])
 276
 277 m4_define([b4_parser_tables_define],
 278 [b4_integral_parser_tables_map([b4_integral_parser_table_define])])
 279
 280
 281
 282 ## ------------------ ##
 283 ## Decoding options.  ##
 284 ## ------------------ ##
 285
 286 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 287 # -----------------------------------
 288 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 289 m4_define([b4_flag_if],
 290 [m4_case(b4_$1_flag,
 291          [0], [$3],
 292          [1], [$2],
 293          [m4_fatal([invalid $1 value: ]$1)])])
 294
 295
 296 # b4_define_flag_if(FLAG)
 297 # -----------------------
 298 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 299 # value of the Boolean FLAG.
 300 m4_define([b4_define_flag_if],
 301 [_b4_define_flag_if($[1], $[2], [$1])])
 302
 303 # _b4_define_flag_if($1, $2, FLAG)
 304 # --------------------------------
 305 # Work around the impossibility to define macros inside macros,
 306 # because issuing `[$1]' is not possible in M4.  GNU M4 should provide
 307 # $$1 a la M5/TeX.
 308 m4_define([_b4_define_flag_if],
 309 [m4_if([$1$2], $[1]$[2], [],
 310        [m4_fatal([$0: Invalid arguments: $@])])dnl
 311 m4_define([b4_$3_if],
 312           [b4_flag_if([$3], [$1], [$2])])])
 313
 314
 315 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 316 # -----------------------------
 317 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 318 b4_define_flag_if([defines])            # Whether headers are requested.
 319 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 320 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 321 b4_define_flag_if([token_table])        # Whether yytoken_table is demanded.
 322 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 323
 324
 325 ## --------- ##
 326 ## Symbols.  ##
 327 ## --------- ##
 328
 329 # In order to unify the handling of the various aspects of symbols
 330 # (tag, type_name, whether terminal, etc.), bison.exe defines one
 331 # macro per (token, field), where field can has_id, id, etc.: see
 332 # src/output.c:prepare_symbols_definitions().
 333 #
 334 # The following macros provide access to these values.
 335
 336 # b4_symbol_(NUM, FIELD)
 337 # ----------------------
 338 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 339 # undefined.
 340 m4_define([b4_symbol_],
 341 [m4_indir([b4_symbol($1, $2)])])
 342
 343
 344 # b4_symbol(NUM, FIELD)
 345 # ---------------------
 346 # Recover a FIELD about symbol #NUM.  Thanks to m4_indir, fails if
 347 # undefined.  If FIELD = id, prepend the prefix.
 348 m4_define([b4_symbol],
 349 [m4_case([$2],
 350          [id],    [m4_do([b4_percent_define_get([api.tokens.prefix])],
 351                          [b4_symbol_([$1], [id])])],
 352          [b4_symbol_($@)])])
 353
 354
 355 # b4_symbol_if(NUM, FIELD, IF-TRUE, IF-FALSE)
 356 # -------------------------------------------
 357 # If FIELD about symbol #NUM is 1 expand IF-TRUE, if is 0, expand IF-FALSE.
 358 # Otherwise an error.
 359 m4_define([b4_symbol_if],
 360 [m4_case(b4_symbol([$1], [$2]),
 361          [1], [$3],
 362          [0], [$4],
 363          [m4_fatal([$0: field $2 of $1 is not a Boolean:] b4_symbol([$1], [$2]))])])
 364
 365
 366 # b4_symbol_action_location(SYMBOL-NUM, KIND)
 367 # -------------------------------------------
 368 # Report the location of the KIND action as FILE:LINE.
 369 m4_define([b4_symbol_action_location],
 370 [b4_symbol([$1], [$2_file]):b4_syncline([b4_symbol([$1], [$2_line])])])
 371
 372
 373 # b4_symbol_action(SYMBOL-NUM, KIND)
 374 # ----------------------------------
 375 # Run the action KIND (destructor or printer) for SYMBOL-NUM.
 376 # Same as in C, but using references instead of pointers.
 377 m4_define([b4_symbol_action],
 378 [b4_symbol_if([$1], [has_$2],
 379 [b4_dollar_pushdef([(*yyvaluep)],
 380                    b4_symbol_if([$1], [has_type],
 381                                 [m4_dquote(b4_symbol([$1], [type]))]),
 382                    [(*yylocationp)])dnl
 383       b4_symbol_case_([$1])[]dnl
 384 b4_syncline([b4_symbol([$1], [$2_line])], ["b4_symbol([$1], [$2_file])"])
 385         b4_symbol([$1], [$2])
 386 b4_syncline([@oline@], [@ofile@])
 387         break;
 388
 389 b4_dollar_popdef[]dnl
 390 ])])
 391
 392
 393 # b4_symbol_destructor(SYMBOL-NUM)
 394 # b4_symbol_printer(SYMBOL-NUM)
 395 # --------------------------------
 396 m4_define([b4_symbol_destructor], [b4_symbol_action([$1], [destructor])])
 397 m4_define([b4_symbol_printer],    [b4_symbol_action([$1], [printer])])
 398
 399
 400 # b4_symbol_case_(SYMBOL-NUM)
 401 # ---------------------------
 402 # Issue a "case NUM" for SYMBOL-NUM.
 403 m4_define([b4_symbol_case_],
 404 [      case b4_symbol([$1], [number]): // b4_symbol([$1], [tag])
 405 ])
 406
 407
 408 # b4_symbol_foreach(MACRO)
 409 # ------------------------
 410 # Invoke MACRO(SYMBOL-NUM) for each SYMBOL-NUM.
 411 m4_define([b4_symbol_foreach],
 412           [m4_map([$1], m4_defn([b4_symbol_numbers]))])
 413
 414 # b4_symbol_map(MACRO)
 415 # --------------------
 416 # Return a list (possibly empty elements) of MACRO invoked for each
 417 # SYMBOL-NUM.
 418 m4_define([b4_symbol_map],
 419 [m4_map_args_sep([$1(], [)], [,], b4_symbol_numbers)])
 420
 421
 422 # b4_token_visible_if(NUM, IF-TRUE, IF-FALSE)
 423 # -------------------------------------------
 424 # Whether NUM denotes a token that has an exported definition (i.e.,
 425 # shows in enum yytokentype).
 426 m4_define([b4_token_visible_if],
 427 [b4_symbol_if([$1], [is_token],
 428               [b4_symbol_if([$1], [has_id], [$2], [$3])],
 429               [$3])])
 430
 431 # b4_token_has_definition(NUM)
 432 # ----------------------------
 433 # 1 if NUM is visible, nothing otherwise.
 434 m4_define([b4_token_has_definition],
 435 [b4_token_visible_if([$1], [1])])
 436
 437 # b4_any_token_visible_if([IF-TRUE], [IF-FALSE])
 438 # ----------------------------------------------
 439 # Whether there is a token that needs to be defined.
 440 m4_define([b4_any_token_visible_if],
 441 [m4_ifval(b4_symbol_foreach([b4_token_has_definition]),
 442           [$1], [$2])])
 443
 444
 445 # b4_token_format(FORMAT, NUM)
 446 # ----------------------------
 447 m4_define([b4_token_format],
 448 [b4_token_visible_if([$2],
 449 [m4_quote(m4_format([$1],
 450                      [b4_symbol([$2], [id])],
 451                      [b4_symbol([$2], [user_number])]))])])
 452
 453
 454 ## ------- ##
 455 ## Types.  ##
 456 ## ------- ##
 457
 458 # b4_type_action_(NUMS)
 459 # ---------------------
 460 # Run actions for the symbol NUMS that all have the same type-name.
 461 # Skip NUMS that have no type-name.
 462 m4_define([b4_type_action_],
 463 [b4_symbol_if([$1], [has_type],
 464 [m4_map([b4_symbol_case_], [$@])[]dnl
 465         b4_dollar_dollar([b4_symbol([$1], [number])],
 466                          [b4_symbol([$1], [tag])],
 467                          [b4_symbol([$1], [type])]);
 468         break;
 469
 470 ])])
 471
 472 # b4_type_foreach(MACRO)
 473 # ----------------------
 474 # Invoke MACRO(SYMBOL-NUMS) for each set of SYMBOL-NUMS for each type set.
 475 m4_define([b4_type_foreach],
 476           [m4_map([$1], m4_defn([b4_type_names]))])
 477
 478
 479
 480 ## ----------- ##
 481 ## Synclines.  ##
 482 ## ----------- ##
 483
 484 # b4_basename(NAME)
 485 # -----------------
 486 # Similar to POSIX basename; the differences don't matter here.
 487 # Beware that NAME is not evaluated.
 488 m4_define([b4_basename],
 489 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 490
 491
 492 # b4_syncline(LINE, FILE)
 493 # -----------------------
 494 m4_define([b4_syncline],
 495 [b4_flag_if([synclines],
 496 [b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 497 b4_sync_start([$1], [$2])])])
 498
 499 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 500 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 501
 502 # b4_user_code(USER-CODE)
 503 # -----------------------
 504 # Emit code from the user, ending it with synclines.
 505 m4_define([b4_user_code],
 506 [$1
 507 b4_syncline([@oline@], [@ofile@])])
 508
 509
 510 # b4_define_user_code(MACRO)
 511 # --------------------------
 512 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 513 m4_define([b4_define_user_code],
 514 [m4_define([b4_user_$1],
 515 [b4_user_code([b4_$1])])])
 516
 517
 518 # b4_user_actions
 519 # b4_user_initial_action
 520 # b4_user_post_prologue
 521 # b4_user_pre_prologue
 522 # b4_user_stype
 523 # ----------------------
 524 # Macros that issue user code, ending with synclines.
 525 b4_define_user_code([actions])
 526 b4_define_user_code([initial_action])
 527 b4_define_user_code([post_prologue])
 528 b4_define_user_code([pre_prologue])
 529 b4_define_user_code([stype])
 530
 531
 532 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 533 # -----------------------------------------------------
 534 # Complain if any name of type WHAT is used by the user (as recorded in
 535 # USER-LIST) but is not used by Bison (as recorded by macros in the
 536 # namespace BISON-NAMESPACE).
 537 #
 538 # USER-LIST must expand to a list specifying all user occurrences of all names
 539 # of type WHAT.   Each item in the list must be a triplet specifying one
 540 # occurrence: name, start boundary, and end boundary.  Empty string names are
 541 # fine.  An empty list is fine.
 542 #
 543 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 544 # name occurrences and with correct quoting:
 545 #
 546 #   m4_define([b4_foo_user_names],
 547 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 548 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 549 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 550 #
 551 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 552 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 553 # are fine, but it would be ugly for Bison to actually use one.
 554 #
 555 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 556 # the names bar and baz are used by Bison:
 557 #
 558 #   m4_define([b4_foo_bison_names(bar)])
 559 #   m4_define([b4_foo_bison_names(baz)])
 560 #
 561 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 562 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 563 # quoting:
 564 #
 565 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 566 #                       [[b4_foo_bison_names]])
 567 m4_define([b4_check_user_names],
 568 [m4_foreach([b4_occurrence], $2,
 569 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 570 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 571 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 572 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 573 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 574           [b4_complain_at([b4_start], [b4_end],
 575                           [[%s '%s' is not used]],
 576                           [$1], [b4_user_name])])[]dnl
 577 m4_popdef([b4_occurrence])dnl
 578 m4_popdef([b4_user_name])dnl
 579 m4_popdef([b4_start])dnl
 580 m4_popdef([b4_end])dnl
 581 ])])
 582
 583
 584
 585 ## --------------------- ##
 586 ## b4_percent_define_*.  ##
 587 ## --------------------- ##
 588
 589
 590 # b4_percent_define_use(VARIABLE)
 591 # -------------------------------
 592 # Declare that VARIABLE was used.
 593 m4_define([b4_percent_define_use],
 594 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 595 ])
 596
 597 # b4_percent_define_get(VARIABLE, [DEFAULT])
 598 # ------------------------------------------
 599 # Mimic muscle_percent_define_get in ../src/muscle-tab.h.  That is, if
 600 # the %define variable VARIABLE is defined, emit its value.  Contrary
 601 # to its C counterpart, return DEFAULT otherwise.  Also, record
 602 # Bison's usage of VARIABLE by defining
 603 # b4_percent_define_bison_variables(VARIABLE).
 604 #
 605 # For example:
 606 #
 607 #   b4_percent_define_get([[foo]])
 608 m4_define([b4_percent_define_get],
 609 [b4_percent_define_use([$1])dnl
 610 m4_ifdef([b4_percent_define(]$1[)],
 611          [m4_indir([b4_percent_define(]$1[)])],
 612          [$2])])
 613
 614 # b4_percent_define_get_loc(VARIABLE)
 615 # -----------------------------------
 616 # Mimic muscle_percent_define_get_loc in ../src/muscle-tab.h exactly.  That is,
 617 # if the %define variable VARIABLE is undefined, complain fatally since that's
 618 # a Bison or skeleton error.  Otherwise, return its definition location in a
 619 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 620 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 621 # reason to suspect that the user-supplied value has yet influenced the output.
 622 #
 623 # For example:
 624 #
 625 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 626 m4_define([b4_percent_define_get_loc],
 627 [m4_ifdef([b4_percent_define_loc(]$1[)],
 628           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 629 b4_loc[]dnl
 630 m4_popdef([b4_loc])],
 631           [b4_fatal([[b4_percent_define_get_loc: undefined %%define variable '%s']], [$1])])])
 632
 633 # b4_percent_define_get_syncline(VARIABLE)
 634 # ----------------------------------------
 635 # Mimic muscle_percent_define_get_syncline in ../src/muscle-tab.h exactly.
 636 # That is, if the %define variable VARIABLE is undefined, complain fatally
 637 # since that's a Bison or skeleton error.  Otherwise, return its definition
 638 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 639 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 640 # influenced the output.
 641 #
 642 # For example:
 643 #
 644 #   b4_percent_define_get_syncline([[foo]])
 645 m4_define([b4_percent_define_get_syncline],
 646 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 647           [m4_indir([b4_percent_define_syncline(]$1[)])],
 648           [b4_fatal([[b4_percent_define_get_syncline: undefined %%define variable '%s']], [$1])])])
 649
 650 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 651 # ------------------------------------------------------
 652 # Mimic muscle_percent_define_ifdef in ../src/muscle-tab.h exactly.  That is,
 653 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 654 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 655 # b4_percent_define_bison_variables(VARIABLE).
 656 #
 657 # For example:
 658 #
 659 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 660 m4_define([b4_percent_define_ifdef],
 661 [m4_ifdef([b4_percent_define(]$1[)],
 662           [b4_percent_define_use([$1])$2],
 663           [$3])])
 664
 665
 666 ## --------- ##
 667 ## Options.  ##
 668 ## --------- ##
 669
 670
 671 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 672 # --------------------------------------------------------
 673 # Mimic muscle_percent_define_flag_if in ../src/muscle-tab.h exactly.  That is,
 674 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 675 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 676 # (a Bison or skeleton error since the default value should have been set
 677 # already) or defined to any other value (possibly a user error).  Also, record
 678 # Bison's usage of VARIABLE by defining
 679 # b4_percent_define_bison_variables(VARIABLE).
 680 #
 681 # For example:
 682 #
 683 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 684 m4_define([b4_percent_define_flag_if],
 685 [b4_percent_define_ifdef([$1],
 686   [m4_case(b4_percent_define_get([$1]),
 687            [], [$2], [true], [$2], [false], [$3],
 688            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 689                                            [[invalid value for %%define Boolean variable '%s']],
 690                                            [$1])],
 691                            [[b4_percent_define_flag_if($1)]])])],
 692   [b4_fatal([[b4_percent_define_flag_if: undefined %%define variable '%s']], [$1])])])
 693
 694
 695 # b4_percent_define_default(VARIABLE, DEFAULT)
 696 # --------------------------------------------
 697 # Mimic muscle_percent_define_default in ../src/muscle-tab.h exactly.  That is,
 698 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 699 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 700 # suspect that the value has yet influenced the output.
 701 #
 702 # For example:
 703 #
 704 #   b4_percent_define_default([[foo]], [[default value]])
 705 m4_define([b4_percent_define_default],
 706 [m4_ifndef([b4_percent_define(]$1[)],
 707            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 708             m4_define([b4_percent_define_loc(]$1[)],
 709                       [[[[<skeleton default value>:-1.-1]],
 710                         [[<skeleton default value>:-1.-1]]]])dnl
 711             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 712
 713
 714 # b4_percent_define_if_define(VARIABLE)
 715 # -------------------------------------
 716 # Define b4_VARIABLE_if that executes its $1 or $2 depending whether
 717 # VARIABLE was %defined.  The characters `.' and `-' in VARIABLE are mapped
 718 # to `_'.
 719 m4_define([b4_percent_define_if_define_],
 720 [m4_define(m4_bpatsubst([b4_$1_if], [[-.]], [_]),
 721            [b4_percent_define_flag_if([$1], [$2], [$3])])])
 722 m4_define([b4_percent_define_if_define],
 723 [b4_percent_define_default([[$1]], [[false]])
 724 b4_percent_define_if_define_([$1], $[1], $[2])])
 725
 726
 727 # b4_percent_define_check_values(VALUES)
 728 # --------------------------------------
 729 # Mimic muscle_percent_define_check_values in ../src/muscle-tab.h exactly
 730 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 731 # is a list of sublists of strings.  For each sublist, the first string is the
 732 # name of a %define variable, and all remaining strings in that sublist are the
 733 # valid values for that variable.  Complain if such a variable is undefined (a
 734 # Bison error since the default value should have been set already) or defined
 735 # to any other value (possibly a user error).  Don't record this as a Bison
 736 # usage of the variable as there's no reason to suspect that the value has yet
 737 # influenced the output.
 738 #
 739 # For example:
 740 #
 741 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 742 #                                  [[[[bar]], [[bar-value1]]]])
 743 m4_define([b4_percent_define_check_values],
 744 [m4_foreach([b4_sublist], m4_quote($@),
 745             [_b4_percent_define_check_values(b4_sublist)])])
 746
 747 m4_define([_b4_percent_define_check_values],
 748 [m4_ifdef([b4_percent_define(]$1[)],
 749   [m4_pushdef([b4_good_value], [0])dnl
 750    m4_if($#, 1, [],
 751          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 752                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 753                             [m4_define([b4_good_value], [1])])])])dnl
 754    m4_if(b4_good_value, [0],
 755          [b4_complain_at(b4_percent_define_get_loc([$1]),
 756                          [[invalid value for %%define variable '%s': '%s']],
 757                          [$1],
 758                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 759           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 760                      [b4_complain_at(b4_percent_define_get_loc([$1]),
 761                                      [[accepted value: '%s']],
 762                                      m4_dquote(b4_value))])])dnl
 763    m4_popdef([b4_good_value])],
 764   [b4_fatal([[b4_percent_define_check_values: undefined %%define variable '%s']], [$1])])])
 765
 766 # b4_percent_code_get([QUALIFIER])
 767 # --------------------------------
 768 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 769 # comment and ending with synclines and a newline.  If QUALIFIER is not
 770 # specified or empty, do this for the unqualified %code blocks.  Also, record
 771 # Bison's usage of QUALIFIER (if specified) by defining
 772 # b4_percent_code_bison_qualifiers(QUALIFIER).
 773 #
 774 # For example, to emit any unqualified %code blocks followed by any %code
 775 # blocks for the qualifier foo:
 776 #
 777 #   b4_percent_code_get
 778 #   b4_percent_code_get([[foo]])
 779 m4_define([b4_percent_code_get],
 780 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 781 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 782 m4_ifdef(b4_macro_name,
 783 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 784                    [["%code ]$1["]])[ blocks.]])
 785 b4_user_code([m4_indir(b4_macro_name)])
 786 ])dnl
 787 m4_popdef([b4_macro_name])])
 788
 789 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 790 # -----------------------------------------------------
 791 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 792 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 793 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 794 # b4_percent_code_bison_qualifiers(QUALIFIER).
 795 m4_define([b4_percent_code_ifdef],
 796 [m4_ifdef([b4_percent_code(]$1[)],
 797           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 798           [$3])])
 799
 800
 801 ## ------------------ ##
 802 ## Common variables.  ##
 803 ## ------------------ ##
 804
 805 # Default values for %define.
 806 # ---------------------------
 807 # If the api.tokens.prefix, it is empty.
 808 m4_percent_define_default([[api.tokens.prefix]], [[]])
 809
 810 # b4_parse_assert_if([IF-ASSERTIONS-ARE-USED], [IF-NOT])
 811 # b4_parse_trace_if([IF-DEBUG-TRACES-ARE-ENABLED], [IF-NOT])
 812 # b4_lex_symbol_if([IF-YYLEX-RETURNS-A-COMPLETE-SYMBOL], [IF-NOT])
 813 # b4_variant_if([IF-VARIANT-ARE-USED], [IF-NOT])
 814 # ----------------------------------------------
 815 b4_percent_define_if_define([lex_symbol])
 816 b4_percent_define_if_define([locations])     # Whether locations are tracked.
 817 b4_percent_define_if_define([parse.assert])
 818 b4_percent_define_if_define([parse.trace])
 819 b4_percent_define_if_define([variant])
 820
 821
 822 # b4_error_verbose_if([IF-ERRORS-ARE-VERBOSE], [IF-NOT])
 823 # ------------------------------------------------------
 824 # Map %define parse.error "(simple|verbose)" to b4_error_verbose_if and
 825 # b4_error_verbose_flag.
 826 b4_percent_define_default([[parse.error]], [[simple]])
 827 b4_percent_define_check_values([[[[parse.error]],
 828                                  [[simple]], [[verbose]]]])
 829 m4_define([b4_error_verbose_flag],
 830           [m4_case(b4_percent_define_get([[parse.error]]),
 831                    [simple],  [[0]],
 832                    [verbose], [[1]])])
 833 b4_define_flag_if([error_verbose])
 834
 835 # yytoken_table is needed to support verbose errors.
 836 b4_error_verbose_if([m4_define([b4_token_table_flag], [1])])
 837
 838
 839 ## ----------------------------------------------------------- ##
 840 ## After processing the skeletons, check that all the user's   ##
 841 ## %define variables and %code qualifiers were used by Bison.  ##
 842 ## ----------------------------------------------------------- ##
 843
 844 m4_define([b4_check_user_names_wrap],
 845 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 846           [b4_check_user_names([[%]$1 $2],
 847                                [b4_percent_]$1[_user_]$2[s],
 848                                [[b4_percent_]$1[_bison_]$2[s]])])])
 849
 850 m4_wrap_lifo([
 851 b4_check_user_names_wrap([[define]], [[variable]])
 852 b4_check_user_names_wrap([[code]], [[qualifier]])
 853 ])
 854
 855
 856 ## ---------------- ##
 857 ## Default values.  ##
 858 ## ---------------- ##
 859
 860 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 861 m4_define_default([b4_pre_prologue], [])
 862 m4_define_default([b4_post_prologue], [])
 863 m4_define_default([b4_epilogue], [])
 864 m4_define_default([b4_parse_param], [])
 865
 866 # The initial column and line.
 867 m4_define_default([b4_location_initial_column], [1])
 868 m4_define_default([b4_location_initial_line],   [1])
 869
 870 # Sanity checks.
 871 b4_percent_define_ifdef([api.prefix],
 872 [m4_ifdef([b4_prefix],
 873 [b4_complain_at(b4_percent_define_get_loc([api.prefix]),
 874                 [['%s' and '%s' cannot be used together]],
 875                 [%name-prefix],
 876                 [%define api.prefix])])])