configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2013 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2013])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz silent-rules]
  49                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  50                            [gnu], [gnits]))
  51 AM_SILENT_RULES([yes])
  52 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  53
  54 # Checks for the compiler.
  55 AC_PROG_CC_STDC
  56 AC_PROG_CXX
  57
  58 # Gnulib (early checks).
  59 gl_EARLY
  60
  61 # Gnulib uses '#pragma GCC diagnostic push' to silence some
  62 # warnings, but older gcc doesn't support this.
  63 AC_CACHE_CHECK([whether pragma GCC diagnostic push works],
  64   [lv_cv_gcc_pragma_push_works], [
  65   save_CFLAGS=$CFLAGS
  66   CFLAGS='-Wunknown-pragmas -Werror'
  67   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  68     #pragma GCC diagnostic push
  69     #pragma GCC diagnostic pop
  70   ]])],
  71   [lv_cv_gcc_pragma_push_works=yes],
  72   [lv_cv_gcc_pragma_push_works=no])
  73   CFLAGS=$save_CFLAGS])
  74
  75 AC_ARG_ENABLE([gcc-warnings],
  76 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  77 [case $enable_gcc_warnings in
  78    yes|no) ;;
  79    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  80  esac],
  81               [enable_gcc_warnings=no])
  82 if test "$enable_gcc_warnings" = yes; then
  83   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  84     -Wformat -Wpointer-arith -Wwrite-strings'
  85   warn_c='-Wbad-function-cast -Wshadow -Wstrict-prototypes'
  86   warn_cxx='-Wnoexcept'
  87   # Warnings for the test suite only.
  88   #
  89   # -fno-color-diagnostics: Clang's use of colors in the error
  90   # messages is confusing the tests looking at the compiler's output
  91   # (e.g., synclines.at).
  92   warn_tests='-Wundef -pedantic -fno-color-diagnostics'
  93
  94   AC_LANG_PUSH([C])
  95   # Clang supports many of GCC's -W options, but only issues warnings
  96   # on the ones it does not recognize.  In that case, gl_WARN_ADD
  97   # thinks the option is supported, and unknown options are then added
  98   # to CFLAGS.  But then, when -Werror is added in the test suite for
  99   # instance, the warning about the unknown option turns into an
 100   # error.
 101   #
 102   # This should be addressed by gnulib's gl_WARN_ADD, but in the
 103   # meanwhile, turn warnings about unknown options into errors in
 104   # CFLAGS, and restore CFLAGS after the tests.
 105   save_CFLAGS=$CFLAGS
 106   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
 107   for i in $warn_common $warn_c;
 108   do
 109     gl_WARN_ADD([$i], [WARN_CFLAGS])
 110   done
 111   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 112
 113   # Warnings for the test suite, and maybe for bison if GCC is modern
 114   # enough.
 115   gl_WARN_ADD([-Wmissing-declarations], [WARN_CFLAGS_TEST])
 116   gl_WARN_ADD([-Wmissing-prototypes], [WARN_CFLAGS_TEST])
 117   test $lv_cv_gcc_pragma_push_works = yes &&
 118     AS_VAR_APPEND([WARN_CFLAGS], [" $WARN_CFLAGS_TEST"])
 119
 120   # Warnings for the test suite only.
 121   for i in $warn_tests;
 122   do
 123     gl_WARN_ADD([$i], [WARN_CFLAGS_TEST])
 124   done
 125   CFLAGS=$save_CFLAGS
 126   AC_LANG_POP([C])
 127
 128   AC_LANG_PUSH([C++])
 129   save_CXXFLAGS=$CXXFLAGS
 130   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 131   for i in $warn_common $warn_cxx;
 132   do
 133     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 134   done
 135   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 136               [AC_LANG_PROGRAM([], [nullptr])])
 137   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 138   # Warnings for the test suite only.
 139   for i in $warn_tests;
 140   do
 141     gl_WARN_ADD([$i], [WARN_CXXFLAGS_TEST])
 142   done
 143   # Clang++ 3.2+ reject C code generated by Flex.
 144   gl_WARN_ADD([-Wno-null-conversion], [WARN_NO_NULL_CONVERSION_CXXFLAGS])
 145   # Variants break strict aliasing analysis.
 146   gl_WARN_ADD([-fno-strict-aliasing], [NO_STRICT_ALIAS_CXXFLAGS])
 147   CXXFLAGS=$save_CXXFLAGS
 148   AC_LANG_POP([C++])
 149 fi
 150
 151 BISON_TEST_FOR_WORKING_C_COMPILER
 152 BISON_C_COMPILER_POSIXLY_CORRECT
 153 BISON_TEST_FOR_WORKING_CXX_COMPILER
 154 BISON_CXX_COMPILER_POSIXLY_CORRECT
 155
 156 AC_ARG_ENABLE([yacc],
 157   [AC_HELP_STRING([--disable-yacc],
 158      [do not build a yacc command or an -ly library])],
 159   , [enable_yacc=yes])
 160 case $enable_yacc in
 161 yes)
 162   YACC_SCRIPT=yacc
 163   YACC_LIBRARY=liby.a;;
 164 *)
 165   YACC_SCRIPT=
 166   YACC_LIBRARY=;;
 167 esac
 168 AC_SUBST([YACC_SCRIPT])
 169 AC_SUBST([YACC_LIBRARY])
 170
 171 # Checks for programs.
 172 AM_MISSING_PROG([DOT], [dot])
 173 AC_PROG_LEX
 174 $LEX_IS_FLEX || AC_MSG_ERROR([Flex is required])
 175 AC_PROG_YACC
 176 AC_PROG_RANLIB
 177 AC_PROG_GNU_M4
 178 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 179 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 180 supports -g, otherwise to "".])
 181 AC_PATH_PROG([PERL], [perl])
 182 if test -z "$PERL"; then
 183    AC_MSG_ERROR([perl not found])
 184 fi
 185 AM_MISSING_PROG([HELP2MAN], [help2man])
 186 AC_PATH_PROG([XSLTPROC], [xsltproc])
 187 AC_SUBST([XSLTPROC])
 188
 189 # Checks for header files.
 190 AC_CHECK_HEADERS_ONCE([locale.h])
 191
 192 # Checks for compiler characteristics.
 193 AC_C_INLINE
 194
 195 # Gnulib (later checks).  Putting them here rather than right after
 196 # gl_EARLY avoids some redundant checks.
 197 gl_INIT
 198
 199 # Checks for library functions.
 200 AC_CHECK_FUNCS_ONCE([setlocale])
 201 AM_WITH_DMALLOC
 202 BISON_PREREQ_TIMEVAR
 203
 204 # Gettext.
 205 # We use gnulib, which is only guaranteed to work properly with the
 206 # latest Gettext.
 207 AM_GNU_GETTEXT([external], [need-ngettext])
 208 AM_GNU_GETTEXT_VERSION([0.18])
 209 BISON_I18N
 210
 211 # Internationalized parsers.
 212 AC_CONFIG_FILES([runtime-po/Makefile.in])
 213 # Autoconf macros for packages using internationalized parsers.
 214 aclocaldir='${datadir}/aclocal'
 215 AC_SUBST([aclocaldir])
 216
 217 # Create the benchmark script.
 218 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 219
 220 # Initialize the test suite.
 221 AC_CONFIG_TESTDIR(tests)
 222 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 223 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 224 AC_CHECK_PROGS([VALGRIND], [valgrind])
 225 case $VALGRIND:$host_os in
 226   '':*) ;;
 227   *:darwin*)
 228     # See README-hacking.
 229     # VALGRIND+=' --suppressions=$(abs_top_srcdir)/build-aux/darwin11.4.0.valgrind'
 230     VALGRIND=;;
 231   *:*)
 232     AC_SUBST([VALGRIND_PREBISON], ["$VALGRIND -q"]);;
 233 esac
 234
 235 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 236 # Needed by tests/atlocal.in.
 237 AC_SUBST([GCC])
 238
 239 gt_JAVACOMP([1.3])
 240 gt_JAVAEXEC
 241
 242 AC_CONFIG_FILES([Makefile
 243                  build-aux/Makefile
 244                  po/Makefile.in
 245                  data/Makefile
 246                  etc/Makefile
 247                  examples/Makefile
 248                     examples/calc++/Makefile
 249                  lib/Makefile src/Makefile
 250                  doc/Makefile
 251                    doc/yacc.1])
 252 AC_OUTPUT