configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19
  20 # We need a recent Autoconf to run a recent Autotest.
  21 AC_PREREQ(2.54)
  22
  23 AC_INIT([GNU Bison], [1.875a], [bug-bison@gnu.org])
  24 AC_CONFIG_AUX_DIR(config)
  25
  26 AM_INIT_AUTOMAKE([1.7 check-news readme-alpha dist-bzip2])
  27 AC_CONFIG_HEADERS([config.h:config.hin])
  28
  29 # Checks for the compiler.
  30 AC_PROG_CC
  31 # Remove with Automake 1.8.
  32 AC_ISC_POSIX
  33 AC_GNU_SOURCE
  34 AC_MINIX
  35 AM_PROG_CC_STDC
  36 AC_ARG_ENABLE(gcc-warnings,
  37 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  38 [case "${enableval}" in
  39    yes|no) ;;
  40    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  41  esac],
  42               [enableval=no])
  43 if test "${enableval}" = yes; then
  44   BISON_WARNING(-Werror)
  45   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  46   WARNING_CFLAGS=
  47   BISON_WARNING(-Wall)
  48   BISON_WARNING(-W)
  49   BISON_WARNING(-Wbad-function-cast)
  50   BISON_WARNING(-Wcast-align)
  51   BISON_WARNING(-Wcast-qual)
  52   BISON_WARNING(-Wformat)
  53   BISON_WARNING(-Wmissing-declarations)
  54   BISON_WARNING(-Wmissing-prototypes)
  55   BISON_WARNING(-Wnested-externs)
  56   BISON_WARNING(-Wshadow)
  57   BISON_WARNING(-Wstrict-prototypes)
  58   BISON_WARNING(-Wwrite-strings)
  59   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  60 fi
  61
  62 AC_ARG_ENABLE([yacc],
  63   [AC_HELP_STRING([--disable-yacc],
  64      [do not build a yacc command or an -ly library])],
  65   , [enable_yacc=yes])
  66 case $enable_yacc in
  67 yes)
  68   YACC_SCRIPT=yacc
  69   YACC_LIBRARY=liby.a;;
  70 *)
  71   YACC_SCRIPT=
  72   YACC_LIBRARY=;;
  73 esac
  74 AC_SUBST([YACC_SCRIPT])
  75 AC_SUBST([YACC_LIBRARY])
  76
  77 # Checks for programs.
  78 AC_PROG_LEX
  79 AC_PROG_YACC
  80 AC_PROG_RANLIB
  81 BISON_PROG_GNU_M4
  82 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  83   AC_MSG_ERROR([GNU M4 1.4 is required])
  84 fi
  85 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  86
  87 # Checks for header files.
  88 AC_HEADER_STDC
  89 AC_CHECK_HEADERS([ctype.h locale.h memory.h stdlib.h string.h unistd.h])
  90 AC_HEADER_STDBOOL
  91
  92 # Checks for compiler characteristics.
  93 AC_C_INLINE
  94
  95 # Checks for types.
  96 AC_CHECK_TYPES([uintptr_t])
  97
  98 # Checks for library functions.
  99 AC_FUNC_ALLOCA
 100 AC_FUNC_OBSTACK
 101 AC_FUNC_ERROR_AT_LINE
 102 AC_FUNC_STRNLEN
 103 AC_CHECK_FUNCS(setlocale)
 104 AC_CHECK_DECLS([free, getenv, getopt,
 105                 stpcpy, strchr, strspn, strnlen,
 106                 malloc, memchr, memrchr])
 107 AC_REPLACE_FUNCS(memchr memrchr \
 108                  strchr stpcpy strrchr strspn strtol strtoul)
 109 AC_FUNC_MALLOC
 110 AC_FUNC_REALLOC
 111 jm_PREREQ_MBSWIDTH
 112 jm_PREREQ_QUOTEARG
 113 jm_FUNC_ARGMATCH
 114 jm_PREREQ_ERROR
 115 AM_WITH_DMALLOC
 116 BISON_PREREQ_SUBPIPE
 117 BISON_PREREQ_TIMEVAR
 118
 119 # Gettext.
 120 AM_GNU_GETTEXT(external, need-ngettext)
 121 AM_GNU_GETTEXT_VERSION(0.11.5)
 122
 123 # Initialize the test suite.
 124 AC_CONFIG_TESTDIR(tests)
 125 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 126 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 127 AC_CHECK_PROGS([VALGRIND], [valgrind])
 128 AC_CHECK_PROGS([GXX], [g++])
 129 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 130 # Needed by tests/atlocal.in.
 131 AC_SUBST([GCC])
 132 O0CFLAGS=`echo $CFLAGS | sed 's/-O[0-9] *//'`
 133 AC_SUBST([O0CFLAGS])
 134
 135 AC_CONFIG_FILES([Makefile
 136                  config/Makefile
 137                  po/Makefile.in
 138                  data/Makefile
 139                  lib/Makefile src/Makefile doc/Makefile
 140                  m4/Makefile])
 141 AC_OUTPUT