src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle_tab.h"
  30 #include "quotearg.h"
  31 #include "reader.h"
  32 #include "symlist.h"
  33 #include "scan-gram.h"
  34 #include "scan-code.h"
  35
  36 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  37 static YYLTYPE lloc_default (YYLTYPE const *, int);
  38
  39 #define YY_LOCATION_PRINT(File, Loc) \
  40           location_print (File, Loc)
  41
  42 static void version_check (location const *loc, char const *version);
  43
  44 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  45    FIXME: depends on the undocumented availability of YYLLOC.  */
  46 #undef  yyerror
  47 #define yyerror(Msg) \
  48         gram_error (&yylloc, Msg)
  49 static void gram_error (location const *, char const *);
  50
  51 static char const *char_name (char);
  52
  53 /** Add a lex-param or a parse-param.
  54  *
  55  * \param type  \a lex_param or \a parse_param
  56  * \param decl  the formal argument
  57  * \param loc   the location in the source.
  58  */
  59 static void add_param (char const *type, char *decl, location loc);
  60
  61
  62 static symbol_class current_class = unknown_sym;
  63 static uniqstr current_type = NULL;
  64 static symbol *current_lhs;
  65 static location current_lhs_location;
  66 static int current_prec = 0;
  67
  68 #define YYTYPE_INT16 int_fast16_t
  69 #define YYTYPE_INT8 int_fast8_t
  70 #define YYTYPE_UINT16 uint_fast16_t
  71 #define YYTYPE_UINT8 uint_fast8_t
  72 %}
  73
  74 %debug
  75 %verbose
  76 %defines
  77 %locations
  78 %pure-parser
  79 %error-verbose
  80 %name-prefix="gram_"
  81 %expect 0
  82
  83 %initial-action
  84 {
  85   /* Bison's grammar can initial empty locations, hence a default
  86      location is needed. */
  87   boundary_set (&@$.start, current_file, 1, 1);
  88   boundary_set (&@$.end, current_file, 1, 1);
  89 }
  90
  91 %union
  92 {
  93   symbol *symbol;
  94   symbol_list *list;
  95   int integer;
  96   char const *chars;
  97   char *code;
  98   assoc assoc;
  99   uniqstr uniqstr;
 100   unsigned char character;
 101 };
 102
 103 /* Define the tokens together with their human representation.  */
 104 %token GRAM_EOF 0 "end of file"
 105 %token STRING     "string"
 106 %token INT        "integer"
 107
 108 %token PERCENT_TOKEN       "%token"
 109 %token PERCENT_NTERM       "%nterm"
 110
 111 %token PERCENT_TYPE        "%type"
 112 %token PERCENT_DESTRUCTOR  "%destructor"
 113 %token PERCENT_PRINTER     "%printer"
 114
 115 %token PERCENT_LEFT        "%left"
 116 %token PERCENT_RIGHT       "%right"
 117 %token PERCENT_NONASSOC    "%nonassoc"
 118 %token PERCENT_PRECEDENCE  "%precedence"
 119
 120 %token PERCENT_PREC          "%prec"
 121 %token PERCENT_DPREC         "%dprec"
 122 %token PERCENT_MERGE         "%merge"
 123
 124
 125 /*----------------------.
 126 | Global Declarations.  |
 127 `----------------------*/
 128
 129 %token
 130   PERCENT_CODE            "%code"
 131   PERCENT_DEFAULT_PREC    "%default-prec"
 132   PERCENT_DEFINE          "%define"
 133   PERCENT_DEFINES         "%defines"
 134   PERCENT_ERROR_VERBOSE   "%error-verbose"
 135   PERCENT_EXPECT          "%expect"
 136   PERCENT_EXPECT_RR       "%expect-rr"
 137   PERCENT_FLAG            "%<flag>"
 138   PERCENT_FILE_PREFIX     "%file-prefix"
 139   PERCENT_GLR_PARSER      "%glr-parser"
 140   PERCENT_INITIAL_ACTION  "%initial-action"
 141   PERCENT_LANGUAGE        "%language"
 142   PERCENT_LEX_PARAM       "%lex-param"
 143   PERCENT_LOCATIONS       "%locations"
 144   PERCENT_NAME_PREFIX     "%name-prefix"
 145   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 146   PERCENT_NO_LINES        "%no-lines"
 147   PERCENT_NONDETERMINISTIC_PARSER
 148                           "%nondeterministic-parser"
 149   PERCENT_OUTPUT          "%output"
 150   PERCENT_PARSE_PARAM     "%parse-param"
 151   PERCENT_PURE_PARSER     "%pure-parser"
 152   PERCENT_REQUIRE         "%require"
 153   PERCENT_SKELETON        "%skeleton"
 154   PERCENT_START           "%start"
 155   PERCENT_TOKEN_TABLE     "%token-table"
 156   PERCENT_VERBOSE         "%verbose"
 157   PERCENT_YACC            "%yacc"
 158 ;
 159
 160 %token BRACED_CODE     "{...}"
 161 %token CHAR            "char"
 162 %token EPILOGUE        "epilogue"
 163 %token EQUAL           "="
 164 %token ID              "identifier"
 165 %token ID_COLON        "identifier:"
 166 %token PERCENT_PERCENT "%%"
 167 %token PIPE            "|"
 168 %token PROLOGUE        "%{...%}"
 169 %token SEMICOLON       ";"
 170 %token TAG             "<tag>"
 171 %token TAG_ANY         "<*>"
 172 %token TAG_NONE        "<>"
 173
 174 %type <character> CHAR
 175 %printer { fputs (char_name ($$), stderr); } CHAR
 176
 177 /* braceless is not to be used for rule or symbol actions, as it
 178    calls code_props_plain_init.  */
 179 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 180 %type <code> "{...}"
 181 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 182          STRING
 183 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 184          braceless content.opt "{...}" "%{...%}" EPILOGUE
 185
 186 %type <uniqstr> TAG ID ID_COLON PERCENT_FLAG variable
 187 %printer { fputs ($$, stderr); } ID variable
 188 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 189 %printer { fprintf (stderr, "%%%s", $$); } PERCENT_FLAG
 190 %printer { fprintf (stderr, "<%s>", $$); } TAG
 191
 192 %type <integer> INT
 193 %printer { fprintf (stderr, "%d", $$); } INT
 194
 195 %type <symbol> id id_colon symbol symbol.prec string_as_id
 196 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 197 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 198
 199 %type <assoc> precedence_declarator
 200 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 201 %%
 202
 203 input:
 204   prologue_declarations "%%" grammar epilogue.opt
 205 ;
 206
 207
 208         /*------------------------------------.
 209         | Declarations: before the first %%.  |
 210         `------------------------------------*/
 211
 212 prologue_declarations:
 213   /* Nothing */
 214 | prologue_declarations prologue_declaration
 215 ;
 216
 217 prologue_declaration:
 218   grammar_declaration
 219 | "%{...%}"
 220     {
 221       code_props plain_code;
 222       code_props_plain_init (&plain_code, $1, @1);
 223       code_props_translate_code (&plain_code);
 224       gram_scanner_last_string_free ();
 225       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 226                         plain_code.code, @1);
 227       code_scanner_last_string_free ();
 228     }
 229 | "%<flag>"
 230     {
 231       muscle_percent_define_insert ($1, @1, "");
 232     }
 233 | "%define" variable content.opt
 234     {
 235       muscle_percent_define_insert ($2, @2, $3);
 236     }
 237 | "%defines"                       { defines_flag = true; }
 238 | "%defines" STRING
 239     {
 240       defines_flag = true;
 241       spec_defines_file = xstrdup ($2);
 242     }
 243 | "%expect" INT                    { expected_sr_conflicts = $2; }
 244 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 245 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 246 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 247 | "%glr-parser"
 248     {
 249       nondeterministic_parser = true;
 250       glr_parser = true;
 251     }
 252 | "%initial-action" "{...}"
 253     {
 254       code_props action;
 255       code_props_symbol_action_init (&action, $2, @2);
 256       code_props_translate_code (&action);
 257       gram_scanner_last_string_free ();
 258       muscle_code_grow ("initial_action", action.code, @2);
 259       code_scanner_last_string_free ();
 260     }
 261 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 262 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 263 | "%locations"                  { locations_flag = true; }
 264 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 265 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 266 | "%no-lines"                   { no_lines_flag = true; }
 267 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 268 | "%output" STRING              { spec_outfile = $2; }
 269 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 270 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 271 | "%pure-parser"
 272     {
 273       /* %pure-parser is deprecated in favor of `%define api.pure', so use
 274          `%define api.pure' in a backward-compatible manner here.  First, don't
 275          complain if %pure-parser is specified multiple times.  */
 276       if (!muscle_find_const ("percent_define(api.pure)"))
 277         muscle_percent_define_insert ("api.pure", @1, "");
 278       /* In all cases, use api.pure now so that the backend doesn't complain if
 279          the skeleton ignores api.pure, but do warn now if there's a previous
 280          conflicting definition from an actual %define.  */
 281       if (!muscle_percent_define_flag_if ("api.pure"))
 282         muscle_percent_define_insert ("api.pure", @1, "");
 283     }
 284 | "%require" STRING             { version_check (&@2, $2); }
 285 | "%skeleton" STRING
 286     {
 287       char const *skeleton_user = $2;
 288       if (strchr (skeleton_user, '/'))
 289         {
 290           size_t dir_length = strlen (current_file);
 291           char *skeleton_build;
 292           while (dir_length && current_file[dir_length - 1] != '/')
 293             --dir_length;
 294           while (dir_length && current_file[dir_length - 1] == '/')
 295             --dir_length;
 296           skeleton_build =
 297             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 298           if (dir_length > 0)
 299             {
 300               strncpy (skeleton_build, current_file, dir_length);
 301               skeleton_build[dir_length++] = '/';
 302             }
 303           strcpy (skeleton_build + dir_length, skeleton_user);
 304           skeleton_user = uniqstr_new (skeleton_build);
 305           free (skeleton_build);
 306         }
 307       skeleton_arg (skeleton_user, grammar_prio, @1);
 308     }
 309 | "%token-table"                { token_table_flag = true; }
 310 | "%verbose"                    { report_flag |= report_states; }
 311 | "%yacc"                       { yacc_flag = true; }
 312 | /*FIXME: Err?  What is this horror doing here? */ ";"
 313 ;
 314
 315 grammar_declaration:
 316   precedence_declaration
 317 | symbol_declaration
 318 | "%start" symbol
 319     {
 320       grammar_start_symbol_set ($2, @2);
 321     }
 322 | "%destructor" "{...}" generic_symlist
 323     {
 324       symbol_list *list;
 325       for (list = $3; list; list = list->next)
 326         symbol_list_destructor_set (list, $2, @2);
 327       symbol_list_free ($3);
 328     }
 329 | "%printer" "{...}" generic_symlist
 330     {
 331       symbol_list *list;
 332       for (list = $3; list; list = list->next)
 333         symbol_list_printer_set (list, $2, @2);
 334       symbol_list_free ($3);
 335     }
 336 | "%default-prec"
 337     {
 338       default_prec = true;
 339     }
 340 | "%no-default-prec"
 341     {
 342       default_prec = false;
 343     }
 344 | "%code" braceless
 345     {
 346       /* Do not invoke muscle_percent_code_grow here since it invokes
 347          muscle_user_name_list_grow.  */
 348       muscle_code_grow ("percent_code()", $2, @2);
 349       code_scanner_last_string_free ();
 350     }
 351 | "%code" ID braceless
 352     {
 353       muscle_percent_code_grow ($2, @2, $3, @3);
 354       code_scanner_last_string_free ();
 355     }
 356 ;
 357
 358
 359 /*---------.
 360 | %union.  |
 361 `---------*/
 362
 363 %token PERCENT_UNION "%union";
 364
 365 union_name:
 366   /* Nothing. */ {}
 367 | ID             { muscle_code_grow ("union_name", $1, @1); }
 368 ;
 369
 370 grammar_declaration:
 371   "%union" union_name braceless
 372     {
 373       union_seen = true;
 374       muscle_code_grow ("stype", $3, @3);
 375       code_scanner_last_string_free ();
 376     }
 377 ;
 378
 379
 380
 381
 382 symbol_declaration:
 383   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 384     {
 385       current_class = unknown_sym;
 386       current_type = NULL;
 387     }
 388 | "%token" { current_class = token_sym; } symbol_defs.1
 389     {
 390       current_class = unknown_sym;
 391       current_type = NULL;
 392     }
 393 | "%type" TAG symbols.1
 394     {
 395       symbol_list *list;
 396       tag_seen = true;
 397       for (list = $3; list; list = list->next)
 398         symbol_type_set (list->content.sym, $2, @2);
 399       symbol_list_free ($3);
 400     }
 401 ;
 402
 403 precedence_declaration:
 404   precedence_declarator tag.opt symbols.prec
 405     {
 406       symbol_list *list;
 407       ++current_prec;
 408       for (list = $3; list; list = list->next)
 409         {
 410           symbol_type_set (list->content.sym, current_type, @2);
 411           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 412         }
 413       symbol_list_free ($3);
 414       current_type = NULL;
 415     }
 416 ;
 417
 418 precedence_declarator:
 419   "%left"       { $$ = left_assoc; }
 420 | "%right"      { $$ = right_assoc; }
 421 | "%nonassoc"   { $$ = non_assoc; }
 422 | "%precedence" { $$ = precedence_assoc; }
 423 ;
 424
 425 tag.opt:
 426   /* Nothing. */ { current_type = NULL; }
 427 | TAG            { current_type = $1; tag_seen = true; }
 428 ;
 429
 430 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 431 symbols.prec:
 432   symbol.prec
 433     { $$ = symbol_list_sym_new ($1, @1); }
 434 | symbols.prec symbol.prec
 435     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 436 ;
 437
 438 symbol.prec:
 439     symbol { $$ = $1; }
 440   | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 441   ;
 442
 443 /* One or more symbols to be %typed. */
 444 symbols.1:
 445   symbol
 446     { $$ = symbol_list_sym_new ($1, @1); }
 447 | symbols.1 symbol
 448     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 449 ;
 450
 451 generic_symlist:
 452   generic_symlist_item { $$ = $1; }
 453 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 454 ;
 455
 456 generic_symlist_item:
 457   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 458 | TAG       { $$ = symbol_list_type_new ($1, @1); }
 459 | "<*>"     { $$ = symbol_list_default_tagged_new (@1); }
 460 | "<>"      { $$ = symbol_list_default_tagless_new (@1); }
 461 ;
 462
 463 /* One token definition.  */
 464 symbol_def:
 465   TAG
 466      {
 467        current_type = $1;
 468        tag_seen = true;
 469      }
 470 | id
 471      {
 472        symbol_class_set ($1, current_class, @1, true);
 473        symbol_type_set ($1, current_type, @1);
 474      }
 475 | id INT
 476     {
 477       symbol_class_set ($1, current_class, @1, true);
 478       symbol_type_set ($1, current_type, @1);
 479       symbol_user_token_number_set ($1, $2, @2);
 480     }
 481 | id string_as_id
 482     {
 483       symbol_class_set ($1, current_class, @1, true);
 484       symbol_type_set ($1, current_type, @1);
 485       symbol_make_alias ($1, $2, @$);
 486     }
 487 | id INT string_as_id
 488     {
 489       symbol_class_set ($1, current_class, @1, true);
 490       symbol_type_set ($1, current_type, @1);
 491       symbol_user_token_number_set ($1, $2, @2);
 492       symbol_make_alias ($1, $3, @$);
 493     }
 494 ;
 495
 496 /* One or more symbol definitions. */
 497 symbol_defs.1:
 498   symbol_def
 499 | symbol_defs.1 symbol_def
 500 ;
 501
 502
 503         /*------------------------------------------.
 504         | The grammar section: between the two %%.  |
 505         `------------------------------------------*/
 506
 507 grammar:
 508   rules_or_grammar_declaration
 509 | grammar rules_or_grammar_declaration
 510 ;
 511
 512 /* As a Bison extension, one can use the grammar declarations in the
 513    body of the grammar.  */
 514 rules_or_grammar_declaration:
 515   rules
 516 | grammar_declaration ";"
 517 | error ";"
 518     {
 519       yyerrok;
 520     }
 521 ;
 522
 523 rules:
 524   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 525 ;
 526
 527 rhses.1:
 528   rhs                { grammar_current_rule_end (@1); }
 529 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 530 | rhses.1 ";"
 531 ;
 532
 533 rhs:
 534   /* Nothing.  */
 535     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 536 | rhs symbol
 537     { grammar_current_rule_symbol_append ($2, @2); }
 538 | rhs "{...}"
 539     { grammar_current_rule_action_append ($2, @2); }
 540 | rhs "%prec" symbol
 541     { grammar_current_rule_prec_set ($3, @3); }
 542 | rhs "%dprec" INT
 543     { grammar_current_rule_dprec_set ($3, @3); }
 544 | rhs "%merge" TAG
 545     { grammar_current_rule_merge_set ($3, @3); }
 546 ;
 547
 548
 549 /*---------------------------.
 550 | variable and content.opt.  |
 551 `---------------------------*/
 552
 553 variable:
 554   ID
 555 | STRING { $$ = uniqstr_new ($1); } /* deprecated and not M4-friendly */
 556 ;
 557
 558 /* Some content or empty by default. */
 559 content.opt:
 560   /* Nothing. */
 561     {
 562       $$ = "";
 563     }
 564 | STRING
 565 ;
 566
 567
 568 /*------------.
 569 | braceless.  |
 570 `------------*/
 571
 572 braceless:
 573   "{...}"
 574     {
 575       code_props plain_code;
 576       $1[strlen ($1) - 1] = '\n';
 577       code_props_plain_init (&plain_code, $1+1, @1);
 578       code_props_translate_code (&plain_code);
 579       gram_scanner_last_string_free ();
 580       $$ = plain_code.code;
 581     }
 582 ;
 583
 584
 585 /*--------------.
 586 | Identifiers.  |
 587 `--------------*/
 588
 589 /* Identifiers are returned as uniqstr values by the scanner.
 590    Depending on their use, we may need to make them genuine symbols.  */
 591
 592 id:
 593   ID
 594     { $$ = symbol_from_uniqstr ($1, @1); }
 595 | CHAR
 596     {
 597       $$ = symbol_get (char_name ($1), @1);
 598       symbol_class_set ($$, token_sym, @1, false);
 599       symbol_user_token_number_set ($$, $1, @1);
 600     }
 601 ;
 602
 603 id_colon:
 604   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 605 ;
 606
 607
 608 symbol:
 609   id
 610 | string_as_id
 611 ;
 612
 613 /* A string used as an ID: quote it.  */
 614 string_as_id:
 615   STRING
 616     {
 617       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 618       symbol_class_set ($$, token_sym, @1, false);
 619     }
 620 ;
 621
 622 epilogue.opt:
 623   /* Nothing.  */
 624 | "%%" EPILOGUE
 625     {
 626       code_props plain_code;
 627       code_props_plain_init (&plain_code, $2, @2);
 628       code_props_translate_code (&plain_code);
 629       gram_scanner_last_string_free ();
 630       muscle_code_grow ("epilogue", plain_code.code, @2);
 631       code_scanner_last_string_free ();
 632     }
 633 ;
 634
 635 %%
 636
 637
 638 /* Return the location of the left-hand side of a rule whose
 639    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 640    the right-hand side, and return an empty location equal to the end
 641    boundary of RHS[0] if the right-hand side is empty.  */
 642
 643 static YYLTYPE
 644 lloc_default (YYLTYPE const *rhs, int n)
 645 {
 646   int i;
 647   YYLTYPE loc;
 648
 649   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 650      The bug is fixed in 7.4.2m, but play it safe for now.  */
 651   loc.start = rhs[n].end;
 652   loc.end = rhs[n].end;
 653
 654   /* Ignore empty nonterminals the start of the the right-hand side.
 655      Do not bother to ignore them at the end of the right-hand side,
 656      since empty nonterminals have the same end as their predecessors.  */
 657   for (i = 1; i <= n; i++)
 658     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 659       {
 660         loc.start = rhs[i].start;
 661         break;
 662       }
 663
 664   return loc;
 665 }
 666
 667
 668 /* Add a lex-param or a parse-param (depending on TYPE) with
 669    declaration DECL and location LOC.  */
 670
 671 static void
 672 add_param (char const *type, char *decl, location loc)
 673 {
 674   static char const alphanum[26 + 26 + 1 + 10] =
 675     "abcdefghijklmnopqrstuvwxyz"
 676     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 677     "_"
 678     "0123456789";
 679   char const *name_start = NULL;
 680   char *p;
 681
 682   /* Stop on last actual character.  */
 683   for (p = decl; p[1]; p++)
 684     if ((p == decl
 685          || ! memchr (alphanum, p[-1], sizeof alphanum))
 686         && memchr (alphanum, p[0], sizeof alphanum - 10))
 687       name_start = p;
 688
 689   /* Strip the surrounding '{' and '}', and any blanks just inside
 690      the braces.  */
 691   while (*--p == ' ' || *p == '\t')
 692     continue;
 693   p[1] = '\0';
 694   while (*++decl == ' ' || *decl == '\t')
 695     continue;
 696
 697   if (! name_start)
 698     complain_at (loc, _("missing identifier in parameter declaration"));
 699   else
 700     {
 701       char *name;
 702       size_t name_len;
 703
 704       for (name_len = 1;
 705            memchr (alphanum, name_start[name_len], sizeof alphanum);
 706            name_len++)
 707         continue;
 708
 709       name = xmalloc (name_len + 1);
 710       memcpy (name, name_start, name_len);
 711       name[name_len] = '\0';
 712       muscle_pair_list_grow (type, decl, name);
 713       free (name);
 714     }
 715
 716   gram_scanner_last_string_free ();
 717 }
 718
 719
 720 static void
 721 version_check (location const *loc, char const *version)
 722 {
 723   if (strverscmp (version, PACKAGE_VERSION) > 0)
 724     {
 725       complain_at (*loc, "require bison %s, but have %s",
 726                    version, PACKAGE_VERSION);
 727       exit (63);
 728     }
 729 }
 730
 731 static void
 732 gram_error (location const *loc, char const *msg)
 733 {
 734   complain_at (*loc, "%s", msg);
 735 }
 736
 737 char const *
 738 token_name (int type)
 739 {
 740   return yytname[YYTRANSLATE (type)];
 741 }
 742
 743 static char const *
 744 char_name (char c)
 745 {
 746   if (c == '\'')
 747     return "'\\''";
 748   else
 749     {
 750       char buf[4];
 751       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 752       return quotearg_style (escape_quoting_style, buf);
 753     }
 754 }