src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include "complain.h"
  27 #include "conflicts.h"
  28 #include "files.h"
  29 #include "getargs.h"
  30 #include "gram.h"
  31 #include "muscle_tab.h"
  32 #include "quotearg.h"
  33 #include "reader.h"
  34 #include "symlist.h"
  35 #include "scan-gram.h"
  36 #include "scan-code.h"
  37 #include "strverscmp.h"
  38
  39 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  40 static YYLTYPE lloc_default (YYLTYPE const *, int);
  41
  42 #define YY_LOCATION_PRINT(File, Loc) \
  43           location_print (File, Loc)
  44
  45 static void version_check (location const *loc, char const *version);
  46
  47 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  48    FIXME: depends on the undocumented availability of YYLLOC.  */
  49 #undef  yyerror
  50 #define yyerror(Msg) \
  51         gram_error (&yylloc, Msg)
  52 static void gram_error (location const *, char const *);
  53
  54 static char const *char_name (char);
  55
  56 static void add_param (char const *, char *, location);
  57
  58 static symbol_class current_class = unknown_sym;
  59 static uniqstr current_type = 0;
  60 static symbol *current_lhs;
  61 static location current_lhs_location;
  62 static int current_prec = 0;
  63
  64 #ifdef UINT_FAST8_MAX
  65 # define YYTYPE_UINT8 uint_fast8_t
  66 #endif
  67 #ifdef INT_FAST8_MAX
  68 # define YYTYPE_INT8 int_fast8_t
  69 #endif
  70 #ifdef UINT_FAST16_MAX
  71 # define YYTYPE_UINT16 uint_fast16_t
  72 #endif
  73 #ifdef INT_FAST16_MAX
  74 # define YYTYPE_INT16 int_fast16_t
  75 #endif
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86
  87 %initial-action
  88 {
  89   /* Bison's grammar can initial empty locations, hence a default
  90      location is needed. */
  91   boundary_set (&@$.start, current_file, 1, 0);
  92   boundary_set (&@$.end, current_file, 1, 0);
  93 }
  94
  95 /* Only NUMBERS have a value.  */
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char *chars;
 102   assoc assoc;
 103   uniqstr uniqstr;
 104   unsigned char character;
 105 };
 106
 107 /* Define the tokens together with their human representation.  */
 108 %token GRAM_EOF 0 "end of file"
 109 %token STRING     "string"
 110 %token INT        "integer"
 111
 112 %token PERCENT_TOKEN       "%token"
 113 %token PERCENT_NTERM       "%nterm"
 114
 115 %token PERCENT_TYPE        "%type"
 116 %token PERCENT_DESTRUCTOR  "%destructor"
 117 %token PERCENT_PRINTER     "%printer"
 118
 119 %token PERCENT_LEFT        "%left"
 120 %token PERCENT_RIGHT       "%right"
 121 %token PERCENT_NONASSOC    "%nonassoc"
 122
 123 %token PERCENT_PREC          "%prec"
 124 %token PERCENT_DPREC         "%dprec"
 125 %token PERCENT_MERGE         "%merge"
 126
 127
 128 /*----------------------.
 129 | Global Declarations.  |
 130 `----------------------*/
 131
 132 %token
 133   PERCENT_DEBUG           "%debug"
 134   PERCENT_DEFAULT_PREC    "%default-prec"
 135   PERCENT_DEFINE          "%define"
 136   PERCENT_DEFINES         "%defines"
 137   PERCENT_ERROR_VERBOSE   "%error-verbose"
 138   PERCENT_EXPECT          "%expect"
 139   PERCENT_EXPECT_RR       "%expect-rr"
 140   PERCENT_FILE_PREFIX     "%file-prefix"
 141   PERCENT_GLR_PARSER      "%glr-parser"
 142   PERCENT_INITIAL_ACTION  "%initial-action"
 143   PERCENT_LEX_PARAM       "%lex-param"
 144   PERCENT_LOCATIONS       "%locations"
 145   PERCENT_NAME_PREFIX     "%name-prefix"
 146   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 147   PERCENT_NO_LINES        "%no-lines"
 148   PERCENT_NONDETERMINISTIC_PARSER
 149                           "%nondeterministic-parser"
 150   PERCENT_OUTPUT          "%output"
 151   PERCENT_PARSE_PARAM     "%parse-param"
 152   PERCENT_PURE_PARSER     "%pure-parser"
 153   PERCENT_REQUIRE         "%require"
 154   PERCENT_SKELETON        "%skeleton"
 155   PERCENT_START           "%start"
 156   PERCENT_TOKEN_TABLE     "%token-table"
 157   PERCENT_VERBOSE         "%verbose"
 158   PERCENT_YACC            "%yacc"
 159 ;
 160
 161 %token BRACED_CODE     "{...}"
 162 %token CHAR            "char"
 163 %token EPILOGUE        "epilogue"
 164 %token EQUAL           "="
 165 %token ID              "identifier"
 166 %token ID_COLON        "identifier:"
 167 %token PERCENT_PERCENT "%%"
 168 %token PIPE            "|"
 169 %token PROLOGUE        "%{...%}"
 170 %token SEMICOLON       ";"
 171 %token TYPE            "type"
 172
 173 %type <character> CHAR
 174 %printer { fputs (char_name ($$), stderr); } CHAR
 175
 176 %type <chars> STRING string_content "{...}" PROLOGUE EPILOGUE
 177 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 178          STRING string_content
 179 %printer { fprintf (stderr, "{\n%s\n}", $$); } "{...}" PROLOGUE EPILOGUE
 180
 181 %type <uniqstr> TYPE ID ID_COLON
 182 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 183 %printer { fputs ($$, stderr); } ID
 184 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 185
 186 %type <integer> INT
 187 %printer { fprintf (stderr, "%d", $$); } INT
 188
 189 %type <symbol> id id_colon symbol string_as_id
 190 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 191 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 192
 193 %type <assoc> precedence_declarator
 194 %type <list>  symbols.1
 195 %%
 196
 197 input:
 198   declarations "%%" grammar epilogue.opt
 199 ;
 200
 201
 202         /*------------------------------------.
 203         | Declarations: before the first %%.  |
 204         `------------------------------------*/
 205
 206 declarations:
 207   /* Nothing */
 208 | declarations declaration
 209 ;
 210
 211 declaration:
 212   grammar_declaration
 213 | PROLOGUE                         { prologue_augment (translate_code ($1, @1),
 214                                                        @1); }
 215 | "%debug"                                 { debug_flag = true; }
 216 | "%define" string_content
 217     {
 218       static char one[] = "1";
 219       muscle_insert ($2, one);
 220     }
 221 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 222 | "%defines"                               { defines_flag = true; }
 223 | "%error-verbose"                         { error_verbose = true; }
 224 | "%expect" INT                            { expected_sr_conflicts = $2; }
 225 | "%expect-rr" INT                         { expected_rr_conflicts = $2; }
 226 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 227 | "%glr-parser"
 228     {
 229       nondeterministic_parser = true;
 230       glr_parser = true;
 231     }
 232 | "%initial-action" "{...}"
 233     {
 234       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 235     }
 236 | "%lex-param" "{...}"                     { add_param ("lex_param", $2, @2); }
 237 | "%locations"                             { locations_flag = true; }
 238 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 239 | "%no-lines"                              { no_lines_flag = true; }
 240 | "%nondeterministic-parser"               { nondeterministic_parser = true; }
 241 | "%output" "=" string_content             { spec_outfile = $3; }
 242 | "%parse-param" "{...}"                   { add_param ("parse_param", $2, @2); }
 243 | "%pure-parser"                           { pure_parser = true; }
 244 | "%require" string_content                { version_check (&@2, $2); }
 245 | "%skeleton" string_content               { skeleton = $2; }
 246 | "%token-table"                           { token_table_flag = true; }
 247 | "%verbose"                               { report_flag = report_states; }
 248 | "%yacc"                                  { yacc_flag = true; }
 249 | /*FIXME: Err?  What is this horror doing here? */ ";"
 250 ;
 251
 252 grammar_declaration:
 253   precedence_declaration
 254 | symbol_declaration
 255 | "%start" symbol
 256     {
 257       grammar_start_symbol_set ($2, @2);
 258     }
 259 | "%destructor" "{...}" symbols.1
 260     {
 261       symbol_list *list;
 262       const char *action = translate_symbol_action ($2, @2);
 263       for (list = $3; list; list = list->next)
 264         symbol_destructor_set (list->sym, action, @2);
 265       symbol_list_free ($3);
 266     }
 267 | "%printer" "{...}" symbols.1
 268     {
 269       symbol_list *list;
 270       const char *action = translate_symbol_action ($2, @2);
 271       for (list = $3; list; list = list->next)
 272         symbol_printer_set (list->sym, action, @2);
 273       symbol_list_free ($3);
 274     }
 275 | "%default-prec"
 276     {
 277       default_prec = true;
 278     }
 279 | "%no-default-prec"
 280     {
 281       default_prec = false;
 282     }
 283 ;
 284
 285
 286 /*----------*
 287  | %union.  |
 288  *----------*/
 289
 290 %token PERCENT_UNION "%union";
 291
 292 union_name:
 293   /* Nothing. */ {}
 294 | ID             { muscle_code_grow ("union_name", $1, @1); }
 295 ;
 296
 297 grammar_declaration:
 298   "%union" union_name "{...}"
 299     {
 300       char const *body = $3;
 301
 302       if (typed)
 303         {
 304           /* Concatenate the union bodies, turning the first one's
 305              trailing '}' into '\n', and omitting the second one's '{'.  */
 306           char *code = muscle_find ("stype");
 307           code[strlen (code) - 1] = '\n';
 308           body++;
 309         }
 310
 311       typed = true;
 312       muscle_code_grow ("stype", body, @3);
 313     }
 314 ;
 315
 316
 317
 318
 319 symbol_declaration:
 320   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 321     {
 322       current_class = unknown_sym;
 323       current_type = NULL;
 324     }
 325 | "%token" { current_class = token_sym; } symbol_defs.1
 326     {
 327       current_class = unknown_sym;
 328       current_type = NULL;
 329     }
 330 | "%type" TYPE symbols.1
 331     {
 332       symbol_list *list;
 333       for (list = $3; list; list = list->next)
 334         symbol_type_set (list->sym, $2, @2);
 335       symbol_list_free ($3);
 336     }
 337 ;
 338
 339 precedence_declaration:
 340   precedence_declarator type.opt symbols.1
 341     {
 342       symbol_list *list;
 343       ++current_prec;
 344       for (list = $3; list; list = list->next)
 345         {
 346           symbol_type_set (list->sym, current_type, @2);
 347           symbol_precedence_set (list->sym, current_prec, $1, @1);
 348         }
 349       symbol_list_free ($3);
 350       current_type = NULL;
 351     }
 352 ;
 353
 354 precedence_declarator:
 355   "%left"     { $$ = left_assoc; }
 356 | "%right"    { $$ = right_assoc; }
 357 | "%nonassoc" { $$ = non_assoc; }
 358 ;
 359
 360 type.opt:
 361   /* Nothing. */ { current_type = NULL; }
 362 | TYPE           { current_type = $1; }
 363 ;
 364
 365 /* One or more nonterminals to be %typed. */
 366 symbols.1:
 367   symbol            { $$ = symbol_list_new ($1, @1); }
 368 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 369 ;
 370
 371 /* One token definition.  */
 372 symbol_def:
 373   TYPE
 374      {
 375        current_type = $1;
 376      }
 377 | id
 378      {
 379        symbol_class_set ($1, current_class, @1, true);
 380        symbol_type_set ($1, current_type, @1);
 381      }
 382 | id INT
 383     {
 384       symbol_class_set ($1, current_class, @1, true);
 385       symbol_type_set ($1, current_type, @1);
 386       symbol_user_token_number_set ($1, $2, @2);
 387     }
 388 | id string_as_id
 389     {
 390       symbol_class_set ($1, current_class, @1, true);
 391       symbol_type_set ($1, current_type, @1);
 392       symbol_make_alias ($1, $2, @$);
 393     }
 394 | id INT string_as_id
 395     {
 396       symbol_class_set ($1, current_class, @1, true);
 397       symbol_type_set ($1, current_type, @1);
 398       symbol_user_token_number_set ($1, $2, @2);
 399       symbol_make_alias ($1, $3, @$);
 400     }
 401 ;
 402
 403 /* One or more symbol definitions. */
 404 symbol_defs.1:
 405   symbol_def
 406 | symbol_defs.1 symbol_def
 407 ;
 408
 409
 410         /*------------------------------------------.
 411         | The grammar section: between the two %%.  |
 412         `------------------------------------------*/
 413
 414 grammar:
 415   rules_or_grammar_declaration
 416 | grammar rules_or_grammar_declaration
 417 ;
 418
 419 /* As a Bison extension, one can use the grammar declarations in the
 420    body of the grammar.  */
 421 rules_or_grammar_declaration:
 422   rules
 423 | grammar_declaration ";"
 424 | error ";"
 425     {
 426       yyerrok;
 427     }
 428 ;
 429
 430 rules:
 431   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 432 ;
 433
 434 rhses.1:
 435   rhs                { grammar_current_rule_end (@1); }
 436 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 437 | rhses.1 ";"
 438 ;
 439
 440 rhs:
 441   /* Nothing.  */
 442     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 443 | rhs symbol
 444     { grammar_current_rule_symbol_append ($2, @2); }
 445 | rhs "{...}"
 446     { grammar_current_rule_action_append (gram_last_string,
 447                                           gram_last_braced_code_loc); }
 448 | rhs "%prec" symbol
 449     { grammar_current_rule_prec_set ($3, @3); }
 450 | rhs "%dprec" INT
 451     { grammar_current_rule_dprec_set ($3, @3); }
 452 | rhs "%merge" TYPE
 453     { grammar_current_rule_merge_set ($3, @3); }
 454 ;
 455
 456
 457 /*---------------*
 458  | Identifiers.  |
 459  *---------------*/
 460
 461 /* Identifiers are returned as uniqstr values by the scanner.
 462    Depending on their use, we may need to make them genuine symbols.  */
 463
 464 id:
 465   ID
 466     { $$ = symbol_get ($1, @1); }
 467 | CHAR
 468     {
 469       $$ = symbol_get (char_name ($1), @1);
 470       symbol_class_set ($$, token_sym, @1, false);
 471       symbol_user_token_number_set ($$, $1, @1);
 472     }
 473 ;
 474
 475 id_colon:
 476   ID_COLON { $$ = symbol_get ($1, @1); }
 477 ;
 478
 479
 480 symbol:
 481   id
 482 | string_as_id
 483 ;
 484
 485 /* A string used as an ID: quote it.  */
 486 string_as_id:
 487   STRING
 488     {
 489       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 490       symbol_class_set ($$, token_sym, @1, false);
 491     }
 492 ;
 493
 494 /* A string used for its contents.  Don't quote it.  */
 495 string_content:
 496   STRING
 497     { $$ = $1; }
 498 ;
 499
 500
 501 epilogue.opt:
 502   /* Nothing.  */
 503 | "%%" EPILOGUE
 504     {
 505       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 506       gram_scanner_last_string_free ();
 507     }
 508 ;
 509
 510 %%
 511
 512
 513 /* Return the location of the left-hand side of a rule whose
 514    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 515    the right-hand side, and return an empty location equal to the end
 516    boundary of RHS[0] if the right-hand side is empty.  */
 517
 518 static YYLTYPE
 519 lloc_default (YYLTYPE const *rhs, int n)
 520 {
 521   int i;
 522   YYLTYPE loc;
 523
 524   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 525      The bug is fixed in 7.4.2m, but play it safe for now.  */
 526   loc.start = rhs[n].end;
 527   loc.end = rhs[n].end;
 528
 529   /* Ignore empty nonterminals the start of the the right-hand side.
 530      Do not bother to ignore them at the end of the right-hand side,
 531      since empty nonterminals have the same end as their predecessors.  */
 532   for (i = 1; i <= n; i++)
 533     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 534       {
 535         loc.start = rhs[i].start;
 536         break;
 537       }
 538
 539   return loc;
 540 }
 541
 542
 543 /* Add a lex-param or a parse-param (depending on TYPE) with
 544    declaration DECL and location LOC.  */
 545
 546 static void
 547 add_param (char const *type, char *decl, location loc)
 548 {
 549   static char const alphanum[26 + 26 + 1 + 10] =
 550     "abcdefghijklmnopqrstuvwxyz"
 551     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 552     "_"
 553     "0123456789";
 554   char const *name_start = NULL;
 555   char *p;
 556
 557   /* Stop on last actual character.  */
 558   for (p = decl; p[1]; p++)
 559     if ((p == decl
 560          || ! memchr (alphanum, p[-1], sizeof alphanum))
 561         && memchr (alphanum, p[0], sizeof alphanum - 10))
 562       name_start = p;
 563
 564   /* Strip the surrounding '{' and '}', and any blanks just inside
 565      the braces.  */
 566   while (*--p == ' ' || *p == '\t')
 567     continue;
 568   p[1] = '\0';
 569   while (*++decl == ' ' || *decl == '\t')
 570     continue;
 571
 572   if (! name_start)
 573     complain_at (loc, _("missing identifier in parameter declaration"));
 574   else
 575     {
 576       char *name;
 577       size_t name_len;
 578
 579       for (name_len = 1;
 580            memchr (alphanum, name_start[name_len], sizeof alphanum);
 581            name_len++)
 582         continue;
 583
 584       name = xmalloc (name_len + 1);
 585       memcpy (name, name_start, name_len);
 586       name[name_len] = '\0';
 587       muscle_pair_list_grow (type, decl, name);
 588       free (name);
 589     }
 590
 591   gram_scanner_last_string_free ();
 592 }
 593
 594 static void
 595 version_check (location const *loc, char const *version)
 596 {
 597   if (strverscmp (version, PACKAGE_VERSION) > 0)
 598     {
 599       complain_at (*loc, "require bison %s, but have %s",
 600                    version, PACKAGE_VERSION);
 601       exit (63);
 602     }
 603 }
 604
 605 static void
 606 gram_error (location const *loc, char const *msg)
 607 {
 608   complain_at (*loc, "%s", msg);
 609 }
 610
 611 char const *
 612 token_name (int type)
 613 {
 614   return yytname[YYTRANSLATE (type)];
 615 }
 616
 617 static char const *
 618 char_name (char c)
 619 {
 620   if (c == '\'')
 621     return "'\\''";
 622   else
 623     {
 624       char buf[4];
 625       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 626       return quotearg_style (escape_quoting_style, buf);
 627     }
 628 }