tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 # AT_SETUP_STRIP(TITLE)
  33 # ---------------------
  34 # Abbreviate the TITLE to be passed to AT_SETUP.
  35 m4_define([AT_SETUP_STRIP],
  36 [m4_bpatsubsts([$1],
  37       [%\(language\|skeleton\) "?\([^\" ]*\)"?],
  38         [\2],
  39       [%define "?\([-A-Za-z0-9_.]+\)"? \("\([^\" ]+\)"\|\([-A-Za-z0-9_.]+\)\)],
  40         [\1=\3\4],
  41       [%define "?\([-A-Za-z0-9_.]+\)"?],
  42         [\1])dnl
  43 ])
  44
  45
  46 ## ------------- ##
  47 ## Basic tests.  ##
  48 ## ------------- ##
  49
  50 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  51 # ------------------------------------------
  52 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  53 # taken in "slurp" mode, i.e., one can match end-of-lines.
  54 m4_define([AT_MATCHES_CHECK],
  55 [AT_CHECK([$PERL -0777 -ne '
  56 my $count = 0;
  57 s{$2}{ ++$count; "" }gem;
  58 printf "$count\n";' $1], [0], [$3
  59 ])])
  60
  61
  62 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  63 # ------------------------------------------------
  64 # Don't interfere with caller's files.
  65 m4_divert_text([PREPARE_TESTS],
  66 [at_save_special_files ()
  67 {
  68   for at_save_file in stderr experr expout
  69   do
  70     test ! -f at-bison-check-$at_save_file.bak ||
  71       as_fn_error 1 "fatal error: back-up on top of a back-up"
  72     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  73   done
  74 }
  75
  76 at_restore_special_files ()
  77 {
  78   for at_save_file in stderr experr expout
  79   do
  80     test ! -f at-bison-check-$at_save_file.bak ||
  81       mv at-bison-check-$at_save_file.bak $at_save_file
  82   done
  83 }
  84 ])
  85
  86 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  87 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  88
  89
  90
  91 ## ------------------------------- ##
  92 ## Macros decoding Bison options.  ##
  93 ## ------------------------------- ##
  94
  95 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  96 # ----------------------------------------------------------------
  97 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  98 m4_define([AT_LOC_PUSHDEF],
  99 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
 100 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
 101 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
 102 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
 103
 104 # AT_LOC_POPDEF
 105 # -------------
 106 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
 107 m4_define([AT_LOC_POPDEF],
 108 [m4_popdef([AT_LOC_FIRST_LINE])
 109 m4_popdef([AT_LOC_FIRST_COLUMN])
 110 m4_popdef([AT_LOC_LAST_LINE])
 111 m4_popdef([AT_LOC_LAST_COLUMN])])
 112
 113
 114
 115 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 116 # -----------------------------------------
 117 m4_define([AT_BISON_OPTION_PUSHDEFS],
 118 [m4_divert_text([KILL],
 119                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 120
 121
 122 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 123 # --------------------------------------------------
 124 # This macro works around the impossibility to define macros
 125 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 126 # This sucks hard, GNU M4 should really provide M5-like $$1.
 127 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 128 [m4_if([$1$2], $[1]$[2], [],
 129        [m4_fatal([$0: Invalid arguments: $@])])dnl
 130 m4_pushdef([AT_DEFINES_IF],
 131 [m4_bmatch([$3], [%defines], [$1], [$2])])
 132 m4_pushdef([AT_SKEL_CC_IF],
 133 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 134 m4_pushdef([AT_SKEL_JAVA_IF],
 135 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 136 # The target language: "c", "c++", or "java".
 137 m4_pushdef([AT_LANG],
 138 [AT_SKEL_JAVA_IF([java],
 139                  [AT_SKEL_CC_IF([c++],
 140                                 [c])])])
 141 m4_pushdef([AT_GLR_IF],
 142 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 143 m4_pushdef([AT_LALR1_CC_IF],
 144 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 145 m4_pushdef([AT_GLR_CC_IF],
 146 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 147 # Using yacc.c?
 148 m4_pushdef([AT_YACC_IF],
 149 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 150 m4_pushdef([AT_LEXPARAM_IF],
 151 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 152 m4_pushdef([AT_LOCATION_IF],
 153 [m4_bmatch([$3], [%locations], [$1], [$2])])
 154 m4_pushdef([AT_LOCATION_TYPE_IF],
 155 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 156 m4_pushdef([AT_PARAM_IF],
 157 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 158 # Comma-terminated list of formals parse-parameters.
 159 # E.g., %parse-param { int x } %parse-param {int y} -> "int x, int y, ".
 160 # FIXME: Support grouped parse-param.
 161 m4_pushdef([AT_PARSE_PARAMS])
 162 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 163              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 164
 165 m4_pushdef([AT_PURE_IF],
 166 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 167            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 168            [$2])])
 169 m4_pushdef([AT_NAME_PREFIX],
 170 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 171            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 172            [yy])])
 173 m4_pushdef([AT_TOKEN_CTOR_IF],
 174 [m4_bmatch([$3], [%define api.token.constructor], [$1], [$2])])
 175 m4_pushdef([AT_TOKEN_PREFIX],
 176 [m4_bmatch([$3], [%define api.token.prefix ".*"],
 177            [m4_bregexp([$3], [%define api.token.prefix "\(.*\)"], [\1])])])
 178 m4_pushdef([AT_API_prefix],
 179 [m4_bmatch([$3], [%define api\.prefix ".*"],
 180            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 181            [yy])])
 182 m4_pushdef([AT_API_PREFIX],
 183 [m4_toupper(AT_API_prefix)])
 184 # yyerror receives the location if %location, and if the parser is pure. For
 185 # historical reasons, with the "yacc.c" skeleton, the location is not passed
 186 # unless an additional "%parse-param" is present, or if the purity is defined
 187 # as "full".
 188 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 189 [AT_LOCATION_IF([AT_PURE_IF([m4_bmatch([$3],
 190                                        m4_quote(m4_join([\|],
 191                                                         [%define api.pure "?full"?],
 192                                                         [%glr-parser],
 193                                                         [%parse-param],
 194                                                         [%skeleton "?glr.c"?])),
 195                                        [$1], [$2])],
 196                             [$2])],
 197                     [$2])])
 198
 199 # yyerror always sees the locations (when activated) if the parser is impure.
 200 # When the parser is pure, yyerror sees the location if it is received as an
 201 # argument.
 202 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 203 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_YYERROR_ARG_LOC_IF([$1], [$2])],
 204                                         [$1])],
 205                             [$1])],
 206                 [$2])])
 207
 208 # The interface is pure: either because %define api.pure, or because we
 209 # are using the C++ parsers.
 210 m4_pushdef([AT_PURE_LEX_IF],
 211 [AT_PURE_IF([$1],
 212             [AT_SKEL_CC_IF([$1], [$2])])])
 213
 214 m4_pushdef([AT_YYSTYPE],
 215 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 216                [AT_API_PREFIX[STYPE]])])
 217 m4_pushdef([AT_YYLTYPE],
 218 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 219                [AT_API_PREFIX[LTYPE]])])
 220
 221
 222 AT_PURE_LEX_IF(
 223 [m4_pushdef([AT_LOC], [(*llocp)])
 224  m4_pushdef([AT_VAL], [(*lvalp)])
 225  m4_pushdef([AT_YYLEX_FORMALS],
 226             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 227  m4_pushdef([AT_YYLEX_ARGS],
 228             [lvalp[]AT_LOCATION_IF([, llocp])])
 229  m4_pushdef([AT_USE_LEX_ARGS],
 230             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 231  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 232             [AT_YYLEX_FORMALS, ])
 233  m4_pushdef([AT_YYLEX_PRE_ARGS],
 234             [AT_YYLEX_ARGS, ])
 235 ],
 236 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 237  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 238  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 239  m4_pushdef([AT_YYLEX_ARGS],        [])
 240  m4_pushdef([AT_USE_LEX_ARGS],    [])
 241  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 242  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 243 ])
 244
 245 # Handle the different types of location components.
 246
 247 AT_SKEL_CC_IF(
 248   [AT_LOCATION_TYPE_IF(
 249     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 250     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 251   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 252
 253
 254 AT_GLR_IF([AT_KEYWORDS([glr])])
 255 ])# _AT_BISON_OPTION_PUSHDEFS
 256
 257
 258 # AT_BISON_OPTION_POPDEFS
 259 # -----------------------
 260 m4_define([AT_BISON_OPTION_POPDEFS],
 261 [m4_divert_text([KILL],
 262 [m4_popdef([AT_YYLEX_PRE_ARGS])
 263 m4_popdef([AT_YYLEX_PRE_FORMALS])
 264 m4_popdef([AT_USE_LEX_ARGS])
 265 m4_popdef([AT_YYLEX_ARGS])
 266 m4_popdef([AT_YYLEX_FORMALS])
 267 m4_popdef([AT_YYLTYPE])
 268 m4_popdef([AT_YYSTYPE])
 269 m4_popdef([AT_VAL])
 270 m4_popdef([AT_LOC])
 271 m4_popdef([AT_PURE_LEX_IF])
 272 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 273 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 274 m4_popdef([AT_API_PREFIX])
 275 m4_popdef([AT_API_prefix])
 276 m4_popdef([AT_TOKEN_PREFIX])
 277 m4_popdef([AT_TOKEN_CTOR_IF])
 278 m4_popdef([AT_NAME_PREFIX])
 279 m4_popdef([AT_LOCATION_TYPE_IF])
 280 m4_popdef([AT_LOCATION_IF])
 281 m4_popdef([AT_PARSE_PARAMS])
 282 m4_popdef([AT_PARAM_IF])
 283 m4_popdef([AT_LEXPARAM_IF])
 284 m4_popdef([AT_YACC_IF])
 285 m4_popdef([AT_GLR_IF])
 286 m4_popdef([AT_SKEL_CC_IF])
 287 m4_popdef([AT_LANG])
 288 m4_popdef([AT_SKEL_JAVA_IF])
 289 m4_popdef([AT_GLR_CC_IF])
 290 m4_popdef([AT_LALR1_CC_IF])
 291 m4_popdef([AT_DEFINES_IF])
 292 AT_LOC_POPDEF])dnl
 293 ])# AT_BISON_OPTION_POPDEFS
 294
 295
 296
 297 ## -------------------------- ##
 298 ## Generating Grammar Files.  ##
 299 ## -------------------------- ##
 300
 301 # AT_DATA_SOURCE_PROLOGUE
 302 # ------------------------
 303 # The prologue that should be included in any source code that is
 304 # meant to be compiled.
 305 m4_define([AT_DATA_SOURCE_PROLOGUE],
 306 [[#include <config.h>
 307 /* We don't need perfect functions for these tests. */
 308 #undef malloc
 309 #undef memcmp
 310 #undef realloc
 311 ]])
 312
 313 # AT_DATA_GRAMMAR_PROLOGUE
 314 # ------------------------
 315 # The prologue that should be included in any grammar which parser is
 316 # meant to be compiled.
 317 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 318 [[%code top {
 319 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 320 [}
 321 ]])
 322
 323 # AT_DATA_SOURCE(NAME, CONTENT)
 324 # -----------------------------
 325 # Generate the file NAME, which CONTENT is preceded by
 326 # AT_DATA_SOURCE_PROLOGUE.
 327 m4_define([AT_DATA_SOURCE],
 328 [AT_DATA([$1],
 329 [AT_DATA_SOURCE_PROLOGUE
 330 $2])
 331 ])
 332
 333 # AT_DATA_GRAMMAR(NAME, CONTENT)
 334 # ------------------------------
 335 # Generate the file NAME, which CONTENT is preceded by
 336 # AT_DATA_GRAMMAR_PROLOGUE.
 337 m4_define([AT_DATA_GRAMMAR],
 338 [AT_DATA([$1],
 339 [AT_DATA_GRAMMAR_PROLOGUE
 340 $2])
 341 ])
 342
 343 # AT_YYLEX_PROTOTYPE
 344 # AT_YYLEX_DECLARE_EXTERN
 345 # AT_YYLEX_DECLARE
 346 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 347 # ----------------------------------
 348 # INPUT can be empty, or in double quotes, or a list (in braces).
 349 # ACTION may compute yylval for instance, using "res" as token type,
 350 # and "toknum" as the number of calls to yylex (starting at 0).
 351 m4_define([AT_YYLEX_PROTOTYPE],
 352 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 353 ])
 354
 355 m4_define([AT_YYLEX_DECLARE_EXTERN],
 356 [AT_YYLEX_PROTOTYPE;dnl
 357 ])
 358
 359 m4_define([AT_YYLEX_DECLARE],
 360 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 361 ])
 362
 363 m4_define([AT_YYLEX_DEFINE],
 364 [[#include <assert.h>
 365 static
 366 ]AT_YYLEX_PROTOTYPE[
 367 {
 368   ]m4_bmatch([$1], [^\(".*"\)?$],
 369              [[static char const input[] = ]m4_default([$1], [""])],
 370              [[static int const input[] = ]$1])[;
 371   static size_t toknum = 0;
 372   int res;
 373   ]AT_USE_LEX_ARGS[;
 374   assert (toknum < sizeof input / sizeof input[0]);
 375   res = input[toknum++];
 376   ]$2[;]AT_LOCATION_IF([[
 377   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 378   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 379   return res;
 380 }]dnl
 381 ])
 382
 383 # AT_YYERROR_FORMALS
 384 # AT_YYERROR_PROTOTYPE
 385 # AT_YYERROR_DECLARE_EXTERN
 386 # AT_YYERROR_DECLARE
 387 # AT_YYERROR_DEFINE
 388 # -------------------------
 389 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 390 m4_define([AT_YYERROR_FORMALS],
 391 [m4_case(AT_LANG,
 392 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE const * const llocp, ])AT_PARSE_PARAMS [const char *msg]])[]dnl
 393 ])
 394
 395 m4_define([AT_YYERROR_PROTOTYPE],
 396 [m4_case(AT_LANG,
 397 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 398 ])
 399
 400 m4_define([AT_YYERROR_DECLARE_EXTERN],
 401 [m4_case(AT_LANG,
 402 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 403 ])
 404
 405 m4_define([AT_YYERROR_DECLARE],
 406 [m4_case(AT_LANG,
 407 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 408 ])
 409
 410 m4_define([AT_YYERROR_DEFINE],
 411 [m4_case(AT_LANG,
 412 [c], [[#include <stdio.h>
 413 /* A C error reporting function.  */
 414 static
 415 ]AT_YYERROR_PROTOTYPE[
 416 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 417               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 418   YYUSE(\1);])dnl
 419 AT_YYERROR_SEES_LOC_IF([[
 420   YY_LOCATION_PRINT (stderr, ]AT_LOC[);
 421   fprintf (stderr, ": ");]])[
 422   fprintf (stderr, "%s\n", msg);
 423 }]],
 424 [c++], [[/* A C++ error reporting function.  */
 425 void
 426 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 427 {  std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 428 }]],
 429 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 430 {
 431     if (l == null)
 432       System.err.println (s);
 433     else
 434       System.err.println (l + ": " + s);
 435   }
 436 ]], [[
 437   public void yyerror (String s)
 438   {
 439     System.err.println (s);
 440   }]])],
 441 [m4_fatal([$0: invalid language: ]AT_LANG)])dnl
 442 ])
 443
 444
 445 ## --------------- ##
 446 ## Running Bison.  ##
 447 ## --------------- ##
 448
 449 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 450 # -------------------------------------------------
 451 # High-level routine that may call bison several times, under different
 452 # conditions.
 453 #
 454 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 455 # shell constructs (such as redirection or pipes) that would prevent
 456 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 457 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 458 #
 459 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 460 # Bison in the test suite.  For now it ensures that:
 461 #
 462 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 463 #      a non-zero exit status since Bison doesn't always try to free all memory
 464 #      in that case.
 465 #
 466 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 467 #      --graph and --report=all output for every working grammar.
 468 #
 469 #   3. If stderr contains a warning, -Werror and --warnings=error
 470 #      convert the warning to an error.
 471 #
 472 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 473 m4_define([AT_BISON_CHECK],
 474 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 475 AT_BISON_CHECK_NO_XML($@)])
 476
 477 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 478 # --------------------------------------------------
 479 # Low-level macro to run bison once.
 480 m4_define([AT_BISON_CHECK_],
 481 [AT_CHECK(AT_QUELL_VALGRIND[[ bison ]]$@)])
 482
 483
 484 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 485 # ----------------------------------------------------------
 486 # Check that warnings (if some are expected) are correctly
 487 # turned into errors with -Werror, etc.
 488 m4_define([AT_BISON_CHECK_WARNINGS],
 489 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 490       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 491
 492 m4_define([AT_BISON_CHECK_WARNINGS_],
 493 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 494 # added after the grammar file name, so skip these checks in that
 495 # case.
 496 if test "$POSIXLY_CORRECT_IS_EXPORTED" = false; then
 497           ]AT_SAVE_SPECIAL_FILES[
 498
 499   # To avoid expanding it repeatedly, store specified stdout.
 500   ]AT_DATA([expout], [$3])[
 501
 502   # Run with -Werror.
 503   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 504
 505   # Build expected stderr up to and including the "warnings being
 506   # treated as errors" message.
 507   ]AT_DATA([[experr]], [$4])[
 508   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 509                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 510   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 511
 512   # Now check --warnings=error.
 513   cp stderr experr
 514   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 515
 516   # Now check -Wnone and --warnings=none by making sure that
 517   # -Werror doesn't change the exit status when -Wnone or
 518   # --warnings=none is specified.
 519   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 520   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 521
 522   ]AT_RESTORE_SPECIAL_FILES[
 523 fi]dnl
 524 ])
 525
 526 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 527 # --------------------------------------------------------
 528 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 529 # when a tortured grammar's XML is known to be too large for xsltproc to
 530 # handle.
 531 m4_define([AT_BISON_CHECK_NO_XML],
 532 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison ]]$@)
 533 AT_BISON_CHECK_WARNINGS($@)])
 534
 535 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 536 # -----------------------------------------------------
 537 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 538 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 539 # have a non-zero exit status.
 540 m4_define([AT_BISON_CHECK_XML],
 541 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 542   AT_SAVE_SPECIAL_FILES
 543   [mkdir xml-tests]
 544   m4_pushdef([AT_BISON_ARGS],
 545              [m4_bpatsubsts([[$1]],
 546                             [--report(-file)?=[^][ ]*], [],
 547                             [--graph=[^][ ]*], [],
 548                             [--xml=[^][ ]*], [])])dnl
 549   # Don't combine these Bison invocations since we want to be sure that
 550   # --report=all isn't required to get the full XML file.
 551   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 552              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 553            [[0]], [ignore], [ignore])
 554   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 555            [[0]], [ignore], [ignore])
 556   m4_popdef([AT_BISON_ARGS])dnl
 557   [cp xml-tests/test.output expout]
 558   AT_CHECK([[$XSLTPROC \
 559              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 560              xml-tests/test.xml]], [[0]], [expout])
 561   [sort xml-tests/test.dot > expout]
 562   AT_CHECK([[$XSLTPROC \
 563              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 564              xml-tests/test.xml | sort]], [[0]], [expout])
 565   [rm -rf xml-tests expout]
 566   AT_RESTORE_SPECIAL_FILES
 567 [fi]])
 568
 569 # AT_QUELL_VALGRIND
 570 # -----------------
 571 # Put this before a Bison invocation to keep Valgrind from complaining about
 572 # reachable memory.
 573 #
 574 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 575 # The triple quoting below will cause test cases to fail if you do.  If you do
 576 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 577 # will then fail to shell-escape its contents when attempting to print them.
 578 # The testsuite verbose output, at least, will be incorrect, but nothing may
 579 # fail to make sure you notice.
 580 m4_define([AT_QUELL_VALGRIND],
 581 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 582
 583
 584
 585 ## ------------------------ ##
 586 ## Compiling C, C++ Files.  ##
 587 ## ------------------------ ##
 588
 589
 590 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 591 # ----------------------------------------
 592 # Compile SOURCES into OUTPUT.
 593 #
 594 # If OUTPUT does not contain '.', assume that we are linking too,
 595 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 596 # with trailing .o removed, and ".c" appended.
 597 m4_define([AT_COMPILE],
 598 [AT_CHECK([$BISON_C_WORKS], 0, ignore, ignore)
 599 AT_CHECK(m4_join([ ],
 600                   [$CC $CFLAGS $CPPFLAGS],
 601                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 602                   [-o $1],
 603                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 604                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 605            0, [ignore], [ignore])])
 606
 607 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 608 # ---------------------------------------------
 609 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 610 # ignore the test.
 611 #
 612 # If OUTPUT does not contain '.', assume that we are linking too,
 613 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 614 # with trailing .o removed, and ".cc" appended.
 615 m4_define([AT_COMPILE_CXX],
 616 [AT_KEYWORDS(c++)
 617 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 618 AT_CHECK(m4_join([ ],
 619                  [$CXX $CXXFLAGS $CPPFLAGS],
 620                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 621                  [-o $1],
 622                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 623                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 624          0, [ignore], [ignore])])
 625
 626 # AT_JAVA_COMPILE(SOURCES)
 627 # ------------------------
 628 # Compile SOURCES into Java class files.  Skip the test if java or javac
 629 # is not installed.
 630 m4_define([AT_JAVA_COMPILE],
 631 [AT_KEYWORDS(java)
 632 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 633 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 634 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 635          [[0]], [ignore], [ignore])])
 636
 637 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 638 # --------------------------------------------
 639 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 640 #
 641 # If OUTPUT does not contain '.', assume that we are linking too,
 642 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 643 # with trailing .o removed, and ".c"/".cc" appended.
 644 m4_define([AT_LANG_COMPILE],
 645 [m4_case(AT_LANG,
 646 [c],    [AT_COMPILE([$1], [$2])],
 647 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 648 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 649         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 650 ])
 651
 652 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 653 # -------------------------------------------
 654 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 655 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 656 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 657 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 658 # AT_SKEL_JAVA_IF.
 659 m4_define([AT_FULL_COMPILE],
 660 [m4_case(AT_LANG,
 661 [java],
 662   [AT_BISON_CHECK([-o $1.java $1.y])
 663    AT_LANG_COMPILE([$1],
 664                     m4_join([ ],
 665                             [$1.java],
 666                             m4_ifval($2, [[$1-$2.java]]),
 667                            m4_ifval($3, [[$1-$3.java]])))],
 668 [c++],
 669   [AT_BISON_CHECK([-o $1.cc $1.y])
 670    AT_LANG_COMPILE([$1],
 671                      m4_join([ ],
 672                              [$1.cc],
 673                              m4_ifval($2, [[$1-$2.cc]]),
 674                            m4_ifval($3, [[$1-$3.cc]])))],
 675 [c],
 676   [AT_BISON_CHECK([-o $1.c $1.y])
 677    AT_LANG_COMPILE([$1],
 678                   m4_join([ ],
 679                           [$1.c],
 680                           m4_ifval($2, [[$1-$2.c]]),
 681                            m4_ifval($3, [[$1-$3.c]])))])
 682 ])
 683
 684
 685
 686 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 687 # --------------------------------
 688 # Check that we can link together C and C++ objects.
 689 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 690 [AT_DATA([c-and-cxx.h],
 691 [[#ifdef __cplusplus
 692 extern "C"
 693 {
 694 #endif
 695   int fortytwo (void);
 696 #ifdef __cplusplus
 697 }
 698 #endif
 699 ]])
 700 AT_DATA([c-only.c],
 701 [[#include "c-and-cxx.h"
 702 int
 703 main (void)
 704 {
 705   return fortytwo () == 42 ? 0 : 1;
 706 }
 707 ]])
 708 AT_DATA([cxx-only.cc],
 709 [[#include "c-and-cxx.h"
 710 int fortytwo ()
 711 {
 712   return 42;
 713 }
 714 ]])
 715 AT_COMPILE([c-only.o], [c-only.c])
 716 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 717 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 718           exit 77], [ignore], [ignore])
 719 AT_PARSER_CHECK([./c-and-cxx])
 720 ])
 721
 722
 723 ## ---------------------------- ##
 724 ## Running a generated parser.  ##
 725 ## ---------------------------- ##
 726
 727
 728 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 729 # ------------------------------------------------------------
 730 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 731 #
 732 # Get rid of spurious messages when compiled with --coverage:
 733 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 734 m4_define([AT_PARSER_CHECK],
 735 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 736 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 737          [0], [], [$4])
 738 ])
 739
 740
 741 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 742 # -----------------------------------------------------------------
 743 m4_define([AT_JAVA_PARSER_CHECK],
 744 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 745
 746
 747 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 748 #                          DECLS, GRAMMAR, INPUT,
 749 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 750 #                          [OTHER-CHECKS],
 751 #                          [PARSER-EXIT-VALUE],
 752 #                          [PARSER-STDOUT], [PARSER-STDERR])
 753 # -------------------------------------------------------------
 754 # Using TITLE as the test group title, check the generated parser tables
 755 # and parser for a specified grammar file under a condition labeled by
 756 # COND-VALUE.
 757 #
 758 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 759 # recognized attribute is described below where it is relevant.
 760 #
 761 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 762 # the grammar file.  Insert basic yyerror, yylex, and main function
 763 # definitions as well.  Hardcode yylex to return the (possibly empty)
 764 # comma-delimited series of tokens in INPUT followed by token 0.
 765 #
 766 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 767 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 768 # On the bison command-line, specify `--report=all --defines'.  Check
 769 # that Bison exits with value 0, has no stdout, and has stderr
 770 # BISON-STDERR.
 771 #
 772 # If TEST-SPEC contains the attribute `last-state', check that the value
 773 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 774 # the grammar; in other words, check the number of states (minus one).
 775 # Otherwise, check that everything in the `.output' file starting with
 776 # the definition of state 0 is the same as the entire value of
 777 # TABLES-OR-LAST-STATE.
 778 #
 779 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 780 # `.output' file, which is named `input.output', and/or grammar file,
 781 # which is named `input.y'.
 782 #
 783 # Finally, compile the generated parser and then run it using
 784 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 785 # PARSER-STDERR as the 2nd-4th arguments.
 786 #
 787 # As a precondition, you must properly double-quote all arguments that
 788 # are to be interpreted as strings.
 789 #
 790 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 791 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 792 # first argument.  This is useful, for example, when wrapping multiple
 793 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 794 # condition, in another macro.
 795 #
 796 # For example:
 797 #
 798 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 799 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 800 #   # ---------------------------------------------------------------------
 801 #   m4_define([AT_TEST_SYNTAX_ERROR],
 802 #   [
 803 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 804 #                              [[last-state]],
 805 #                              [[%error-verbose ]$2], [$3], [$4],
 806 #                              [[]], [$5], [], [$6], [$7], [$8])
 807 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 808 #                              [[last-state]],
 809 #                              [$2], [$3], [$4],
 810 #                              [[]], [$5], [], [$6], [$7], [$8])
 811 #   ])
 812 #
 813 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 814 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 815 #                        [[3]],
 816 #                        [[1]], [[]],
 817 #                        [AT_COND_CASE([[no verbose]],
 818 #                                      [[syntax error
 819 #   ]],
 820 #                                      [[syntax error, unexpected 'b', expecting $end
 821 #   ]])])
 822 m4_define([AT_TEST_TABLES_AND_PARSE],
 823 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 824
 825 AT_SETUP([$1])
 826 AT_BISON_OPTION_PUSHDEFS([$4])
 827 AT_DATA_GRAMMAR([[input.y]],
 828 [[%code {
 829   #include <stdio.h>
 830   ]AT_YYERROR_DECLARE[
 831   ]AT_YYLEX_DECLARE[
 832 }
 833
 834 ]$4[
 835
 836 %%
 837
 838 ]$5[
 839
 840 %%
 841 ]AT_YYERROR_DEFINE[
 842 static int
 843 yylex (void)
 844 {
 845   static int const input[] = {
 846     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 847   };
 848   static int const *inputp = input;
 849   return *inputp++;
 850 }
 851
 852 int
 853 main (void)
 854 {
 855   return yyparse ();
 856 }
 857 ]])
 858
 859 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 860 # expanding macros, so it corrupts some special characters in the
 861 # macros.  To avoid this, expand now and pass it the result with proper
 862 # string quotation.  Assume args 7 through 12 expand to properly quoted
 863 # strings.
 864
 865 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 866       [AT_BISON_CHECK],
 867       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 868                                [0], [], m4_dquote($7))
 869
 870 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 871       [AT_CHECK([[sed -n '/^State 0$/,$p' input.output]], [[0]],
 872                 m4_dquote($8))],
 873       [AT_CHECK([[sed -n 's/^State //p' input.output | tail -1]], [[0]],
 874                 m4_dquote($8)[[
 875 ]])])
 876
 877 $9
 878
 879 # Canonical LR generates very large tables, resulting in very long
 880 # files with #line directives that may overflow what the standards
 881 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 882 # will issue an error.
 883 #
 884 # There is no "" around `wc` since some indent the result.
 885 m4_bmatch([$4], [%define lr.type canonical-lr],
 886 [if test 32767 -lt `wc -l < input.c`; then
 887   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 888   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 889 fi])
 890 AT_COMPILE([[input]])
 891
 892 AT_PARSER_CHECK([[./input]],
 893                 m4_ifval([$10], [m4_dquote($10)]),
 894                 m4_ifval([$11], [m4_dquote($11)]),
 895                 m4_ifval([$12], [m4_dquote($12)]))
 896
 897 AT_BISON_OPTION_POPDEFS
 898 AT_CLEANUP
 899
 900 m4_popdef([AT_COND_CASE])])
 901
 902
 903
 904
 905 ## ----------------------- ##
 906 ## Launch the test suite.  ##
 907 ## ----------------------- ##
 908
 909 AT_INIT
 910
 911 # AT_SETUP([TITLE])
 912 # -----------------
 913 # Redefine AT_SETUP to be more concise.  Must be done after AT_INIT.
 914 m4_copy_force([AT_SETUP], [B4_SETUP])
 915 m4_define([AT_SETUP],
 916 [B4_SETUP(m4_expand([AT_SETUP_STRIP([[$1]])]))])
 917
 918 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 919 # options are processed, so we don't know the value of CXX and
 920 # CXXFLAGS yet.
 921 #
 922 # Note that it also means that command line values for CXX and
 923 # CXXFLAGS will not be propagated to CC and CFLAGS.
 924 AT_ARG_OPTION([compile-c-with-cxx],
 925               [compile C parsers with the C++ compiler])
 926
 927 AT_COLOR_TESTS
 928
 929 AT_TESTED([bison])