configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2012])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz nostdinc
  49                  color-tests parallel-tests
  50                  silent-rules]
  51                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  52                            [gnu], [gnits]))
  53 AM_SILENT_RULES([yes])
  54 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  55
  56 # Checks for the compiler.
  57 AC_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 # Gnulib (early checks).
  61 gl_EARLY
  62
  63 AC_ARG_ENABLE([gcc-warnings],
  64 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  65 [case $enable_gcc_warnings in
  66    yes|no) ;;
  67    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  68  esac],
  69               [enable_gcc_warnings=no])
  70 if test "$enable_gcc_warnings" = yes; then
  71   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  72     -Wcast-qual -Wformat -Wpointer-arith -Wwrite-strings'
  73   warn_c='-Wbad-function-cast -Wmissing-declarations -Wmissing-prototypes
  74     -Wshadow -Wstrict-prototypes'
  75   warn_cxx='-Wnoexcept'
  76
  77   AC_LANG_PUSH([C])
  78   # Clang supports many of GCC's -W options, but only issues warnings
  79   # on the ones it does not recognize.  In that case, gl_WARN_ADD
  80   # thinks the option is supported, and unknown options are then added
  81   # to CFLAGS.  But then, when -Werror is added in the test suite for
  82   # instance, the warning about the unknown option turns into an
  83   # error.
  84   #
  85   # This should be addressed by gnulib's gl_WARN_ADD, but in the
  86   # meanwhile, turn warnings about unknown options into errors in
  87   # CFLAGS, and restore CFLAGS after the tests.
  88   save_CFLAGS=$CFLAGS
  89   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
  90   for i in $warn_common $warn_c;
  91   do
  92     gl_WARN_ADD([$i], [WARN_CFLAGS])
  93   done
  94   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  95   # Warnings for the test suite only.
  96   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  97   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
  98   CFLAGS=$save_CFLAGS
  99   AC_LANG_POP([C])
 100
 101   AC_LANG_PUSH([C++])
 102   save_CXXFLAGS=$CXXFLAGS
 103   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 104   for i in $warn_common $warn_cxx;
 105   do
 106     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 107   done
 108   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 109               [AC_LANG_PROGRAM([], [nullptr])])
 110   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 111   # Warnings for the test suite only.
 112   gl_WARN_ADD([-Wundef], [WARN_CXXFLAGS_TEST])
 113   gl_WARN_ADD([-pedantic], [WARN_CXXFLAGS_TEST])
 114   CXXFLAGS=$save_CXXFLAGS
 115   AC_LANG_POP([C++])
 116 fi
 117
 118 BISON_TEST_FOR_WORKING_C_COMPILER
 119 BISON_TEST_FOR_WORKING_CXX_COMPILER
 120
 121 AC_ARG_ENABLE([yacc],
 122   [AC_HELP_STRING([--disable-yacc],
 123      [do not build a yacc command or an -ly library])],
 124   , [enable_yacc=yes])
 125 case $enable_yacc in
 126 yes)
 127   YACC_SCRIPT=src/yacc
 128   YACC_LIBRARY=lib/liby.a;;
 129 *)
 130   YACC_SCRIPT=
 131   YACC_LIBRARY=;;
 132 esac
 133 AC_SUBST([YACC_SCRIPT])
 134 AC_SUBST([YACC_LIBRARY])
 135
 136 # Checks for programs.
 137 AM_MISSING_PROG([DOT], [dot])
 138 AC_PROG_LEX
 139 $LEX_IS_FLEX || AC_MSG_ERROR([Flex is required])
 140 AC_PROG_YACC
 141 AC_PROG_RANLIB
 142 AC_PROG_GNU_M4
 143 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 144 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 145 supports -g, otherwise to "".])
 146 AC_PATH_PROG([PERL], [perl])
 147 if test -z "$PERL"; then
 148    AC_MSG_ERROR([perl not found])
 149 fi
 150 AM_MISSING_PROG([HELP2MAN], [help2man])
 151 AC_PATH_PROG([XSLTPROC], [xsltproc])
 152 AC_SUBST([XSLTPROC])
 153
 154 # Checks for header files.
 155 AC_CHECK_HEADERS_ONCE([locale.h])
 156
 157 # Checks for compiler characteristics.
 158 AC_C_INLINE
 159
 160 # Gnulib (later checks).  Putting them here rather than right after
 161 # gl_EARLY avoids some redundant checks.
 162 gl_INIT
 163
 164 # Checks for library functions.
 165 AC_CHECK_FUNCS_ONCE([setlocale])
 166 AM_WITH_DMALLOC
 167 BISON_PREREQ_TIMEVAR
 168
 169 # Gettext.
 170 # We use gnulib, which is only guaranteed to work properly with the
 171 # latest Gettext.
 172 AM_GNU_GETTEXT([external], [need-ngettext])
 173 AM_GNU_GETTEXT_VERSION([0.18])
 174 BISON_I18N
 175
 176 # Internationalized parsers.
 177 AC_CONFIG_FILES([runtime-po/Makefile.in])
 178 # Autoconf macros for packages using internationalized parsers.
 179 aclocaldir='${datadir}/aclocal'
 180 AC_SUBST([aclocaldir])
 181
 182 # Create the benchmark script.
 183 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 184
 185 # Initialize the test suite.
 186 AC_CONFIG_TESTDIR(tests)
 187 AC_CONFIG_FILES([tests/atlocal])
 188 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 189 AC_CHECK_PROGS([VALGRIND], [valgrind])
 190 case $VALGRIND:$host_os in
 191   '':*) ;;
 192   *:darwin*)
 193     # See README-hacking.
 194     # VALGRIND+=' --suppressions=$(abs_top_srcdir)/build-aux/darwin11.4.0.valgrind'
 195     VALGRIND=;;
 196   *:*)
 197     AC_SUBST([VALGRIND_PREBISON], ["$VALGRIND -q"]);;
 198 esac
 199
 200 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 201 # Needed by tests/atlocal.in.
 202 AC_SUBST([GCC])
 203
 204 gt_JAVACOMP([1.3], [1.4])
 205 gt_JAVAEXEC
 206
 207 AC_CONFIG_FILES([Makefile
 208                  po/Makefile.in
 209                  doc/yacc.1])
 210 AC_OUTPUT