djgpp/config.sed

   1 # DJGPP specific configuration file.
   2 # Sed script for additional DJGPP specific editing
   3 # of the configure script generated by autoconf 2.57.
   4
   5
   6 # Copyright (C) 2005, 2006 Free Software Foundation, Inc.
   7
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software Foundation,
  20 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  21
  22 # Additional editing of Makefiles
  23 /(echo[  ]*':t/ a\
  24 # DJGPP specific Makefile changes.\
  25   /^aliaspath * *=/s,:,";",g;t t\
  26   /TEXINPUTS=/s,:,";",g;t t\
  27   /PATH=/s,:,";",g;t t\
  28   s,\\.deps,_deps,g;t t\
  29   s,\\.new\\.,_new.,g;t t\
  30   s,\\.old\\.,_old.,g;t t\
  31   s,c++\\.at,cxx.at,g;t t\
  32   s,c++\\.m4,cxx.m4,g;t t\
  33   s,calc++,calcxx,g;t t\
  34   s,scan-gram-c,c-scan-gram,g;t t\
  35   s,scan-skel-c,c-scan-skel,g;t t\
  36   s,Makefile\\.in\\.in,Makefile.in-in,g;t t\
  37   s,Makefile\\.am\\.in,Makefile.am-in,g;t t\
  38   s,(MAKEINFOFLAGS),& --no-split,\
  39   /^install-info-am:/,/^$/ {\
  40     /@list=/ s,\\\$(INFO_DEPS),& bison.i,\
  41     /@for *file/ s,\\\$(INFO_DEPS),& bison.i,\
  42     s,file-\\[0-9\\]\\[0-9\\],& \\$\\$file[0-9] \\$\\$file[0-9][0-9],\
  43   }\
  44   /^\\.y\\.c:/,/^$/ {\
  45     /\\\$(YACCCOMPILE)/ {\
  46       a\\\
  47         -@test -f y.tab.c && mv -f y.tab.c y_tab.c\\\
  48         -@test -f y.tab.h && mv -f y.tab.h y_tab.h\
  49     }\
  50   }\
  51 /^libbison.a:/ i\\\
  52 \\$(top_srcdir)/djgpp/subpipe.c: \\$(top_srcdir)/djgpp/subpipe.h\\\
  53 subpipe.o: \\$(top_srcdir)/djgpp/subpipe.c \\$(top_srcdir)/djgpp/subpipe.h\\\
  54         \\$(COMPILE) -c \\$<\
  55 /^yacc:/ i\\\
  56 yacc.bat:\\\
  57         echo "bison\\$(EXEEXT) -y %1 %2 %3 %4 %5 %6 %7 %8 %9" >\\$@\
  58 /^bin_SCRIPTS =/s/$/ yacc.bat/\
  59 /^MOSTLYCLEANFILES = yacc/s/$/ yacc.bat/
  60
  61
  62 # Makefile.in.in is renamed to Makefile.in-in.
  63 /ac_config_files=/,/_ACEOF/ {
  64   s|po/Makefile\.in|&:po/Makefile.in-in|
  65 }
  66 /CONFIG_FILES=/ s|po/Makefile\.in|&:po/Makefile.in-in|2
  67
  68 # We always use _deps and _libs instead of .deps and .libs, because
  69 # the latter is an invalid name on 8+3 MS-DOS file system.  This makes
  70 # the generated Makefiles good for every DJGPP installation, not only
  71 # the one where the package was configured (which could happen to be
  72 # a Windows box, where leading dots in file names are allowed).
  73 s,\.deps,_deps,g
  74 s,\.libs,_libs,g
  75 /^rmdir[         ]*\.tst/ i\
  76 am__leading_dot=_
  77
  78 # Replace (command) > /dev/null with `command > /dev/null`, since
  79 # parenthesized commands always return zero status in the ported Bash,
  80 # even if the named command doesn't exist
  81 /if ([^|;`]*null/{
  82   s,(,`,
  83   s,),,
  84   /null[         ]*2>&1/ s,2>&1,&`,
  85   /null.*null/ s,null.*null,&`,
  86   /null.*null/ !{
  87     /null[       ]*2>&1/ !s,null,&`,
  88   }
  89 }
  90
  91 # DOS-style absolute file names should be supported as well
  92 /\*) top_srcdir=/s,/\*,[\\\\/]* | ?:[\\\\/]*,
  93
  94 # Prevent the spliting of subs.sed.
  95 # The sed script: subs.sed is split into 48 lines long files.
  96 # This will produce sed scripts called subs-$ac_sed_frag.sed, where
  97 # $ac_sed_frag is some unique number. This will not work if the splited
  98 # sed script contains a multiple line sed command at line #48. In this
  99 # case the first part of the multiple line sed command will be written
 100 # at the end of one particular subs-$ac_sed_frag.sed and the rest of the
 101 # sed command will be written at the begining of the next subs-$ac_sed_frag.sed
 102 # making both sed script useless.
 103 # This matches the configure script produced by Autoconf 2.57
 104 /ac_max_sed_lines=[0-9]/ s,=.*$,=`sed -n "$=" $tmp/subs.sed`,
 105
 106 # The following two items are changes needed for configuring
 107 # and compiling across partitions.
 108 # 1) The given srcdir value is always translated from the
 109 #    "x:" syntax into "/dev/x" syntax while we run configure.
 110 /^[      ]*-srcdir=\*.*$/ a\
 111     ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
 112 /set X `ls -Lt \$srcdir/ i\
 113    if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
 114      srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
 115    fi
 116
 117 # Autoconf 2.52e generated configure scripts
 118 # write absolute paths into Makefiles and bison.in
 119 # making them useless for DJGPP installations for
 120 # which the package has not been configured for.
 121 /MISSING=/,/^$/ {
 122   /^fi$/ a\
 123 am_missing_run=`echo "$am_missing_run" | sed 's%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*%${top_srcdir}%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*%${top_srcdir}%'`
 124 }
 125 /^install_sh=/a\
 126 install_sh=`echo "$install_sh" | sed 's%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*%${top_srcdir}%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*%${top_srcdir}%'`
 127
 128 # This will only work if the assumption that the
 129 # testsuite is ran from the following path:
 130 #   ${top_srcdir}/tests/testsuite.dir
 131 # holds. The explicit names are of no importance.
 132 #   ../../. == ${top_srcdir}
 133 /\.)[    ]*ac_abs_builddir=/,/^esac$/ {
 134  /^esac$/ a\
 135 ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../.%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../.%"`
 136 }
 137 /\.)[    ]*ac_abs_top_builddir=/,/^esac$/ {
 138  /^esac$/ a\
 139 ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../../%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../../%"`
 140 }
 141 /\.)[    ]*ac_abs_srcdir=/,/^esac$/ {
 142  /^esac$/ a\
 143 ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../.%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../.%"`
 144 }
 145 /\.)[    ]*ac_abs_top_srcdir=/,/^esac$/ {
 146  /^esac$/ a\
 147 ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%/dev.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../../%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-z]*/[^/]*%../../../%"`
 148 }
 149
 150 # Add DJGPP version information.
 151 /^#define VERSION/ s/\$VERSION/&  (DJGPP port (r1))/
 152
 153 # We need makeinfo to make the html formated docs.
 154 /\$am_missing_run[       ]*makeinfo/ s,\$am_missing_run,,
 155
 156 # The path to the FORTRAN compiler and libraries
 157 # shall contain no absolute path reference so it
 158 # will be good for all djgpp installations.
 159 /^FLIBS="\$ac_cv_flibs"/ i\
 160 ac_djgpp_path=`echo "$DJDIR" | sed 's%\\\\\\%/%g' | tr $as_cr_LETTERS $as_cr_letters`\
 161 ac_cv_flibs=`echo "$ac_cv_flibs" | sed "s%-L$ac_djgpp_path%-L/dev/env/DJDIR%g"`
 162
 163 # The following is not a valid DOS file name
 164 s/calc++/calcxx/g