configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2012])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz nostdinc
  49                  color-tests parallel-tests
  50                  silent-rules]
  51                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  52                            [gnu], [gnits]))
  53 AM_SILENT_RULES([yes])
  54 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  55
  56 # Checks for the compiler.
  57 AC_PROG_CC_STDC
  58
  59 # Gnulib (early checks).
  60 gl_EARLY
  61
  62 AC_ARG_ENABLE([gcc-warnings],
  63 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  64 [case $enable_gcc_warnings in
  65    yes|no) ;;
  66    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  67  esac],
  68               [enable_gcc_warnings=no])
  69 if test "$enable_gcc_warnings" = yes; then
  70   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  71   AC_SUBST([WERROR_CFLAGS])
  72   gl_WARN_ADD([-Wall])
  73   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  74   gl_WARN_ADD([-Wcast-align])
  75   gl_WARN_ADD([-Wcast-qual])
  76   gl_WARN_ADD([-Wformat])
  77   gl_WARN_ADD([-Wpointer-arith])
  78   gl_WARN_ADD([-Wwrite-strings])
  79   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  80   # The following warnings are not suitable for C++.
  81   gl_WARN_ADD([-Wbad-function-cast])
  82   gl_WARN_ADD([-Wmissing-declarations])
  83   gl_WARN_ADD([-Wmissing-prototypes])
  84   gl_WARN_ADD([-Wshadow])
  85   gl_WARN_ADD([-Wstrict-prototypes])
  86   AC_SUBST([WARN_CFLAGS])
  87   # Warnings for the test suite only.
  88   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  89   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
  90   AC_SUBST([WARN_CXXFLAGS_TEST], ["$WARN_CXXFLAGS $WARN_CFLAGS_TEST"])
  91   AC_SUBST([WARN_CFLAGS_TEST], ["$WARN_CFLAGS $WARN_CFLAGS_TEST"])
  92 fi
  93
  94 BISON_TEST_FOR_WORKING_C_COMPILER
  95
  96 AC_ARG_ENABLE([yacc],
  97   [AC_HELP_STRING([--disable-yacc],
  98      [do not build a yacc command or an -ly library])],
  99   , [enable_yacc=yes])
 100 case $enable_yacc in
 101 yes)
 102   YACC_SCRIPT=src/yacc
 103   YACC_LIBRARY=lib/liby.a;;
 104 *)
 105   YACC_SCRIPT=
 106   YACC_LIBRARY=;;
 107 esac
 108 AC_SUBST([YACC_SCRIPT])
 109 AC_SUBST([YACC_LIBRARY])
 110
 111 # Checks for programs.
 112 AC_PROG_LEX
 113 AC_PROG_YACC
 114 AC_PROG_RANLIB
 115 AC_PROG_GNU_M4
 116 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 117 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 118 supports -g, otherwise to "".])
 119 AM_MISSING_PROG([HELP2MAN], [help2man])
 120 AC_PATH_PROG([XSLTPROC], [xsltproc])
 121 AC_SUBST([XSLTPROC])
 122
 123 # Checks for header files.
 124 AC_CHECK_HEADERS_ONCE([locale.h])
 125
 126 # Checks for compiler characteristics.
 127 AC_C_INLINE
 128
 129 # Gnulib (later checks).  Putting them here rather than right after
 130 # gl_EARLY avoids some redundant checks.
 131 gl_INIT
 132
 133 # Checks for library functions.
 134 AC_CHECK_FUNCS_ONCE([setlocale])
 135 AM_WITH_DMALLOC
 136 BISON_PREREQ_SUBPIPE
 137 BISON_PREREQ_TIMEVAR
 138
 139 # Gettext.
 140 # We use gnulib, which is only guaranteed to work properly with the
 141 # latest Gettext.
 142 AM_GNU_GETTEXT([external], [need-ngettext])
 143 AM_GNU_GETTEXT_VERSION([0.18])
 144 BISON_I18N
 145
 146 # Internationalized parsers.
 147 AC_CONFIG_FILES([runtime-po/Makefile.in])
 148 # Autoconf macros for packages using internationalized parsers.
 149 aclocaldir='${datadir}/aclocal'
 150 AC_SUBST([aclocaldir])
 151
 152 # Create the benchmark script.
 153 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 154
 155 # Initialize the test suite.
 156 AC_CONFIG_TESTDIR(tests)
 157 AC_CONFIG_FILES([tests/atlocal])
 158 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 159 AC_CHECK_PROGS([VALGRIND], [valgrind])
 160 AC_PROG_CXX
 161 BISON_TEST_FOR_WORKING_CXX_COMPILER
 162 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 163 # Needed by tests/atlocal.in.
 164 AC_SUBST([GCC])
 165 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 166 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 167
 168 gt_JAVACOMP([1.3], [1.4])
 169 gt_JAVAEXEC
 170
 171 # We use gnulib, but from lib/local.mk instead of lib/Makefile.am.
 172 # So prefix paths with lib/.  See also etc/prefix-gnulib-mk.
 173 gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, , lib/,g'`
 174 # Listing the names of the variables to prefix is error-prone.
 175 # Rather, adjust all the AC_SUBST variables whose name ends in '_H',
 176 # and whose content ends in '.h'.
 177 for ac_var in $ac_subst_vars
 178 do
 179   eval "ac_val=\$$ac_var"
 180   case $ac_var=$ac_val in
 181     (*_H=*.h) eval "$ac_var=lib/\$$ac_var";;
 182   esac
 183 done
 184 AC_CONFIG_FILES([Makefile
 185                  po/Makefile.in
 186                  doc/yacc.1])
 187 AC_OUTPUT