configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2012])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz silent-rules]
  49                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  50                            [gnu], [gnits]))
  51 AM_SILENT_RULES([yes])
  52 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  53
  54 # Checks for the compiler.
  55 AC_PROG_CC_STDC
  56 AC_PROG_CXX
  57
  58 # Gnulib (early checks).
  59 gl_EARLY
  60
  61 AC_ARG_ENABLE([gcc-warnings],
  62 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  63 [case $enable_gcc_warnings in
  64    yes|no) ;;
  65    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  66  esac],
  67               [enable_gcc_warnings=no])
  68 if test "$enable_gcc_warnings" = yes; then
  69   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  70     -Wcast-qual -Wformat -Wpointer-arith -Wwrite-strings'
  71   warn_c='-Wbad-function-cast -Wmissing-declarations -Wmissing-prototypes
  72     -Wshadow -Wstrict-prototypes'
  73   warn_cxx='-Wnoexcept -Wzero-as-null-pointer-constant'
  74   AC_LANG_PUSH([C])
  75   for i in $warn_common $warn_c;
  76   do
  77     gl_WARN_ADD([$i], [WARN_CFLAGS])
  78   done
  79   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  80   # Warnings for the test suite only.
  81   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  82   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
  83   AC_LANG_POP([C])
  84
  85   AC_LANG_PUSH([C++])
  86   for i in $warn_common $warn_cxx;
  87   do
  88     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
  89   done
  90   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
  91   # Warnings for the test suite only.
  92   gl_WARN_ADD([-Wundef], [WARN_CXXFLAGS_TEST])
  93   gl_WARN_ADD([-pedantic], [WARN_CXXFLAGS_TEST])
  94   AC_LANG_POP([C++])
  95 fi
  96
  97 BISON_TEST_FOR_WORKING_C_COMPILER
  98 BISON_TEST_FOR_WORKING_CXX_COMPILER
  99
 100 AC_ARG_ENABLE([yacc],
 101   [AC_HELP_STRING([--disable-yacc],
 102      [do not build a yacc command or an -ly library])],
 103   , [enable_yacc=yes])
 104 case $enable_yacc in
 105 yes)
 106   YACC_SCRIPT=yacc
 107   YACC_LIBRARY=liby.a;;
 108 *)
 109   YACC_SCRIPT=
 110   YACC_LIBRARY=;;
 111 esac
 112 AC_SUBST([YACC_SCRIPT])
 113 AC_SUBST([YACC_LIBRARY])
 114
 115 # Checks for programs.
 116 AC_PROG_LEX
 117 AC_PROG_YACC
 118 AC_PROG_RANLIB
 119 AC_PROG_GNU_M4
 120 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 121 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 122 supports -g, otherwise to "".])
 123 AM_MISSING_PROG([HELP2MAN], [help2man])
 124 AC_PATH_PROG([XSLTPROC], [xsltproc])
 125 AC_SUBST([XSLTPROC])
 126
 127 # Checks for header files.
 128 AC_CHECK_HEADERS_ONCE([locale.h])
 129
 130 # Checks for compiler characteristics.
 131 AC_C_INLINE
 132
 133 # Gnulib (later checks).  Putting them here rather than right after
 134 # gl_EARLY avoids some redundant checks.
 135 gl_INIT
 136
 137 # Checks for library functions.
 138 AC_CHECK_FUNCS_ONCE([setlocale])
 139 AM_WITH_DMALLOC
 140 BISON_PREREQ_TIMEVAR
 141
 142 # Gettext.
 143 # We use gnulib, which is only guaranteed to work properly with the
 144 # latest Gettext.
 145 AM_GNU_GETTEXT([external], [need-ngettext])
 146 AM_GNU_GETTEXT_VERSION([0.18])
 147 BISON_I18N
 148
 149 # Internationalized parsers.
 150 AC_CONFIG_FILES([runtime-po/Makefile.in])
 151 # Autoconf macros for packages using internationalized parsers.
 152 aclocaldir='${datadir}/aclocal'
 153 AC_SUBST([aclocaldir])
 154
 155 # Create the benchmark script.
 156 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 157
 158 # Initialize the test suite.
 159 AC_CONFIG_TESTDIR(tests)
 160 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 161 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 162 AC_CHECK_PROGS([VALGRIND], [valgrind])
 163 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 164 # Needed by tests/atlocal.in.
 165 AC_SUBST([GCC])
 166
 167 gt_JAVACOMP([1.3])
 168 gt_JAVAEXEC
 169
 170 AC_CONFIG_FILES([Makefile
 171                  build-aux/Makefile
 172                  po/Makefile.in
 173                  data/Makefile
 174                  etc/Makefile
 175                  examples/Makefile
 176                     examples/calc++/Makefile
 177                  lib/Makefile src/Makefile
 178                  doc/Makefile
 179                    doc/yacc.1])
 180 AC_OUTPUT