tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 ## ------------------------------- ##
  41 ## Macros decoding Bison options.  ##
  42 ## ------------------------------- ##
  43
  44 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  45 # ----------------------------------------------------------------
  46 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  47 m4_define([AT_LOC_PUSHDEF],
  48 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  49 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  50 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  51 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  52
  53 # AT_LOC_POPDEF
  54 # -------------
  55 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  56 m4_define([AT_LOC_POPDEF],
  57 [m4_popdef([AT_LOC_FIRST_LINE])
  58 m4_popdef([AT_LOC_FIRST_COLUMN])
  59 m4_popdef([AT_LOC_LAST_LINE])
  60 m4_popdef([AT_LOC_LAST_COLUMN])])
  61
  62
  63
  64 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  65 # -----------------------------------------
  66 m4_define([AT_BISON_OPTION_PUSHDEFS],
  67 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  68
  69
  70 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  71 # --------------------------------------------------
  72 # This macro works around the impossibility to define macros
  73 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  74 # This sucks hard, GNU M4 should really provide M5 like $$1.
  75 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  76 [m4_if([$1$2], $[1]$[2], [],
  77        [m4_fatal([$0: Invalid arguments: $@])])dnl
  78 m4_pushdef([AT_DEFINES_IF],
  79 [m4_bmatch([$3], [%defines], [$1], [$2])])
  80 m4_pushdef([AT_SKEL_CC_IF],
  81 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  82 m4_pushdef([AT_SKEL_JAVA_IF],
  83 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
  84 m4_pushdef([AT_GLR_IF],
  85 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  86 m4_pushdef([AT_LALR1_CC_IF],
  87 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  88 m4_pushdef([AT_GLR_CC_IF],
  89 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  90 # Using yacc.c?
  91 m4_pushdef([AT_YACC_IF],
  92 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  93 m4_pushdef([AT_LEXPARAM_IF],
  94 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  95 m4_pushdef([AT_LOCATION_IF],
  96 [m4_bmatch([$3], [%locations], [$1], [$2])])
  97 m4_pushdef([AT_LOCATION_TYPE_IF],
  98 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  99 m4_pushdef([AT_PARAM_IF],
 100 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 101 m4_pushdef([AT_PURE_IF],
 102 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 103            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 104            [$2])])
 105 m4_pushdef([AT_PURE_AND_LOC_IF],
 106 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 107 m4_pushdef([AT_GLR_OR_PARAM_IF],
 108 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 109 m4_pushdef([AT_NAME_PREFIX],
 110 [m4_bmatch([$3], [%name-prefix ".*"],
 111            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 112            [yy])])
 113 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 114 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 115 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 116                     [$2])])
 117 # yyerror always sees the locations (when activated), except if
 118 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 119 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 120 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 121                                         [$1])],
 122                             [$1])],
 123                 [$2])])
 124
 125 # The interface is pure: either because %define api.pure, or because we
 126 # are using the C++ parsers.
 127 m4_pushdef([AT_PURE_LEX_IF],
 128 [AT_PURE_IF([$1],
 129             [AT_SKEL_CC_IF([$1], [$2])])])
 130
 131 AT_PURE_LEX_IF(
 132 [m4_pushdef([AT_LOC], [(*llocp)])
 133  m4_pushdef([AT_VAL], [(*lvalp)])
 134  m4_pushdef([AT_LEX_FORMALS],
 135             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 136  m4_pushdef([AT_LEX_ARGS],
 137             [lvalp[]AT_LOCATION_IF([, llocp])])
 138  m4_pushdef([AT_USE_LEX_ARGS],
 139             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 140  m4_pushdef([AT_LEX_PRE_FORMALS],
 141             [AT_LEX_FORMALS, ])
 142  m4_pushdef([AT_LEX_PRE_ARGS],
 143             [AT_LEX_ARGS, ])
 144 ],
 145 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 146  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 147  m4_pushdef([AT_LEX_FORMALS],     [void])
 148  m4_pushdef([AT_LEX_ARGS],        [])
 149  m4_pushdef([AT_USE_LEX_ARGS],    [])
 150  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 151  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 152 ])
 153
 154 # Handle the different types of location components.
 155
 156 AT_SKEL_CC_IF(
 157   [AT_LOCATION_TYPE_IF(
 158     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 159     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 160   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 161
 162 ])# _AT_BISON_OPTION_PUSHDEFS
 163
 164
 165 # AT_BISON_OPTION_POPDEFS
 166 # -----------------------
 167 m4_define([AT_BISON_OPTION_POPDEFS],
 168 [m4_popdef([AT_LEX_PRE_ARGS])
 169 m4_popdef([AT_LEX_PRE_FORMALS])
 170 m4_popdef([AT_USE_LEX_ARGS])
 171 m4_popdef([AT_LEX_ARGS])
 172 m4_popdef([AT_LEX_FORMALS])
 173 m4_popdef([AT_VAL])
 174 m4_popdef([AT_LOC])
 175 m4_popdef([AT_PURE_LEX_IF])
 176 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 177 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 178 m4_popdef([AT_NAME_PREFIX])
 179 m4_popdef([AT_GLR_OR_PARAM_IF])
 180 m4_popdef([AT_PURE_AND_LOC_IF])
 181 m4_popdef([AT_LOCATION_TYPE_IF])
 182 m4_popdef([AT_LOCATION_IF])
 183 m4_popdef([AT_PARAM_IF])
 184 m4_popdef([AT_LEXPARAM_IF])
 185 m4_popdef([AT_YACC_IF])
 186 m4_popdef([AT_GLR_IF])
 187 m4_popdef([AT_SKEL_CC_IF])
 188 m4_popdef([AT_SKEL_JAVA_IF])
 189 m4_popdef([AT_GLR_CC_IF])
 190 m4_popdef([AT_LALR1_CC_IF])
 191 m4_popdef([AT_DEFINES_IF])
 192 AT_LOC_POPDEF
 193 ])# AT_BISON_OPTION_POPDEFS
 194
 195
 196
 197 ## -------------------------- ##
 198 ## Generating Grammar Files.  ##
 199 ## -------------------------- ##
 200
 201 # AT_DATA_SOURCE_PROLOGUE
 202 # ------------------------
 203 # The prologue that should be included in any source code that is
 204 # meant to be compiled.
 205 m4_define([AT_DATA_SOURCE_PROLOGUE],
 206 [[#include <config.h>
 207 /* We don't need perfect functions for these tests. */
 208 #undef malloc
 209 #undef memcmp
 210 #undef realloc
 211 ]])
 212
 213 # AT_DATA_GRAMMAR_PROLOGUE
 214 # ------------------------
 215 # The prologue that should be included in any grammar which parser is
 216 # meant to be compiled.
 217 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 218 [[%code top {
 219 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 220 [}
 221 ]])
 222
 223 # AT_DATA_SOURCE(NAME, CONTENT)
 224 # -----------------------------
 225 # Generate the file NAME, which CONTENT is preceded by
 226 # AT_DATA_SOURCE_PROLOGUE.
 227 m4_define([AT_DATA_SOURCE],
 228 [AT_DATA([$1],
 229 [AT_DATA_SOURCE_PROLOGUE
 230 $2])
 231 ])
 232
 233 # AT_DATA_GRAMMAR(NAME, CONTENT)
 234 # ------------------------------
 235 # Generate the file NAME, which CONTENT is preceded by
 236 # AT_DATA_GRAMMAR_PROLOGUE.
 237 m4_define([AT_DATA_GRAMMAR],
 238 [AT_DATA([$1],
 239 [AT_DATA_GRAMMAR_PROLOGUE
 240 $2])
 241 ])
 242
 243 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 244 # -------------------------------------------------
 245 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 246 # shell constructs (such as redirection or pipes) that would prevent
 247 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 248 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 249 #
 250 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 251 # Bison in the test suite.  For now it ensures that:
 252 #
 253 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 254 #      a non-zero exit status since Bison doesn't always try to free all memory
 255 #      in that case.
 256 #
 257 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 258 #      --graph and --report=all output for every working grammar.
 259 #
 260 #   3. If stderr contains a warning, -Werror and --warnings=error
 261 #      convert the warning to an error.
 262 #
 263 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 264 m4_define([AT_BISON_CHECK],
 265 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 266        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 267 AT_BISON_CHECK_NO_XML($@)])
 268
 269 m4_define([AT_BISON_WERROR_MSG],
 270           [[bison: warnings being treated as errors]])
 271
 272 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 273 # --------------------------------------------------------
 274 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 275 # when a tortured grammar's XML is known to be too large for xsltproc to
 276 # handle.
 277 m4_define([AT_BISON_CHECK_NO_XML],
 278 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 279                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 280 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 281       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 282         # POSIXLY_CORRECT=1 causes bison to complain if options are added
 283         # after the grammar file name, so skip these checks in that case.
 284         if test x"$POSIXLY_CORRECT" != x1; then
 285           # Don't interfere with caller's files.
 286           if test -f stderr; then mv stderr at-bison-check-stderr.bak; fi
 287           if test -f experr; then mv experr at-bison-check-experr.bak; fi
 288           if test -f expout; then mv expout at-bison-check-expout.bak; fi
 289
 290           # To avoid expanding it repeatedly, store specified stdout.
 291           ]AT_DATA([expout], [$3])[
 292
 293           # Run with -Werror.
 294           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 295                     [[1]], [expout], [stderr])[
 296
 297           # Build expected stderr up to and including the "warnings being
 298           # treated as errors" message.
 299           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 300           at_bison_check_first="` \
 301             sed -n '/: warning: /=' at-bison-check-warnings \
 302             | sed -n 1p \
 303           `"
 304           at_bison_check_first_tmp="` \
 305             sed -n '/conflicts: [0-9].*reduce$/=' at-bison-check-warnings \
 306             | sed -n 1p \
 307           `"
 308           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 309             at_bison_check_first=$at_bison_check_first_tmp
 310           fi
 311           if test $at_bison_check_first -gt 1; then
 312             sed -n "1,`expr $at_bison_check_first - 1`"p \
 313               at-bison-check-warnings > experr
 314           fi
 315           echo ']AT_BISON_WERROR_MSG[' >> experr
 316
 317           # Finish building expected stderr and check.  Unlike warnings,
 318           # complaints cause bison to exit early.  Thus, with -Werror, bison
 319           # does not necessarily report all warnings that it does without
 320           # -Werror, but it at least reports one.
 321           at_bison_check_last="`sed -n '$=' stderr`"
 322           if test x"$at_bison_check_last" = x; then
 323             at_bison_check_last=1
 324           fi
 325           at_bison_check_last="`expr $at_bison_check_last - 1`"
 326           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 327             at-bison-check-warnings >> experr
 328           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 329                       stderr 1>&2]], [[0]], [[]], [experr])[
 330
 331           # Now check --warnings=error.
 332           cp stderr experr
 333           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 334                     [[1]], [expout], [experr])[
 335
 336           # Now check -Wnone and --warnings=none by making sure that
 337           # -Werror doesn't change the exit status when -Wnone or
 338           # --warnings=none is specified.
 339           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 340                     [[0]], [expout])[
 341           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 342                     -Werror]], [[0]], [expout])[
 343
 344           # Restore caller's files.
 345           if test -f at-bison-check-expout.bak; then
 346             mv at-bison-check-expout.bak expout
 347           fi
 348           if test -f at-bison-check-experr.bak; then
 349             mv at-bison-check-experr.bak experr
 350           fi
 351           if test -f at-bison-check-stderr.bak; then
 352             mv at-bison-check-stderr.bak stderr
 353           fi
 354         fi
 355       ]])
 356 ])
 357
 358 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 359 # -----------------------------------------------------
 360 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 361 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 362 # have a non-zero exit status.
 363 m4_define([AT_BISON_CHECK_XML],
 364 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 365   mkdir xml-tests]
 366   m4_pushdef([AT_BISON_ARGS],
 367              [m4_bpatsubsts([[$1]],
 368                             [--report(-file)?=[^][ ]*], [],
 369                             [--graph=[^][ ]*], [],
 370                             [--xml=[^][ ]*], [])])dnl
 371   # Don't combine these Bison invocations since we want to be sure that
 372   # --report=all isn't required to get the full XML file.
 373   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 374              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 375            [[0]], [ignore], [ignore])
 376   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 377            [[0]], [ignore], [ignore])
 378   m4_popdef([AT_BISON_ARGS])dnl
 379   [cp xml-tests/test.output expout]
 380   AT_CHECK([[$XSLTPROC \
 381              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 382              xml-tests/test.xml]], [[0]], [expout])
 383   [cp xml-tests/test.dot expout]
 384   AT_CHECK([[$XSLTPROC \
 385              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 386              xml-tests/test.xml]], [[0]], [expout])
 387   [rm -rf xml-tests expout
 388 fi]])
 389
 390 # AT_QUELL_VALGRIND
 391 # -----------------
 392 # Put this before a Bison invocation to keep Valgrind from complaining about
 393 # reachable memory.
 394 #
 395 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 396 # The triple quoting below will cause test cases to fail if you do.  If you do
 397 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 398 # will then fail to shell-escape its contents when attempting to print them.
 399 # The testsuite verbose output, at least, will be incorrect, but nothing may
 400 # fail to make sure you notice.
 401 m4_define([AT_QUELL_VALGRIND],
 402 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 403
 404 ## ------------------------ ##
 405 ## Compiling C, C++ Files.  ##
 406 ## ------------------------ ##
 407
 408
 409 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 410 # ----------------------------------------
 411 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 412 # assume that we are linking too; this is a hack.
 413 m4_define([AT_COMPILE],
 414 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 415            0, [ignore], [ignore])])
 416
 417 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 418 # --------------------------------------------
 419 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 420 # assume that we are linking too; this is a hack.
 421 # If the C++ compiler does not work, ignore the test.
 422 m4_define([AT_COMPILE_CXX],
 423 [AT_KEYWORDS(c++)
 424 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 425 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 426          0, [ignore], [ignore])])
 427
 428 # AT_JAVA_COMPILE(SOURCES)
 429 # ------------------------
 430 # Compile SOURCES into Java class files.  Skip the test if java or javac
 431 # is not installed.
 432 m4_define([AT_JAVA_COMPILE],
 433 [AT_KEYWORDS(java)
 434 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 435            test -n "$CONF_JAVAC" || exit 77]])
 436 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 437          [[0]], [ignore], [ignore])])
 438
 439 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 440 # --------------------------------
 441 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 442 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 443 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 444 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 445 # AT_SKEL_JAVA_IF.
 446 m4_define([AT_FULL_COMPILE], [
 447   AT_SKEL_JAVA_IF([
 448     AT_BISON_CHECK([[-o ]$1[.java ]$1[.y]])
 449     AT_JAVA_COMPILE([$1[.java]]m4_ifval($2,
 450                                         [[$1[.java ]$1[-]$2[.java]]]))
 451   ], [
 452     AT_SKEL_CC_IF([
 453       AT_BISON_CHECK([[-o ]$1[.cc ]$1[.y]])
 454       AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1[.cc ]$1[-]$2[.cc]]]))
 455     ], [
 456       AT_BISON_CHECK([[-o ]$1[.c ]$1[.y]])
 457       AT_COMPILE([$1]m4_ifval($2, [, [$1[.c ]$1[-]$2[.c]]]))
 458     ])
 459   ])
 460 ])
 461
 462
 463 ## ---------------------------- ##
 464 ## Running a generated parser.  ##
 465 ## ---------------------------- ##
 466
 467 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 468 # ------------------------------------------------------------
 469 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 470 m4_define([AT_PARSER_CHECK],
 471 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 472
 473 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 474 # -----------------------------------------------------------------
 475 m4_define([AT_JAVA_PARSER_CHECK],
 476 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 477
 478 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 479 #                          DECLS, GRAMMAR, INPUT,
 480 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 481 #                          [OTHER-CHECKS],
 482 #                          [PARSER-EXIT-VALUE],
 483 #                          [PARSER-STDOUT], [PARSER-STDERR])
 484 # -------------------------------------------------------------
 485 # Using TITLE as the test group title, check the generated parser tables
 486 # and parser for a specified grammar file under a condition labeled by
 487 # COND-VALUE.
 488 #
 489 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 490 # recognized attribute is described below where it is relevant.
 491 #
 492 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 493 # the grammar file.  Insert basic yyerror, yylex, and main function
 494 # definitions as well.  Hardcode yylex to return the (possibly empty)
 495 # comma-delimited series of tokens in INPUT followed by token 0.
 496 #
 497 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 498 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 499 # On the bison command-line, specify `--report=all --defines'.  Check
 500 # that Bison exits with value 0, has no stdout, and has stderr
 501 # BISON-STDERR.
 502 #
 503 # If TEST-SPEC contains the attribute `last-state', check that the value
 504 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 505 # the grammar; in other words, check the number of states (minus one).
 506 # Otherwise, check that everything in the `.output' file starting with
 507 # the definition of state 0 is the same as the entire value of
 508 # TABLES-OR-LAST-STATE.
 509 #
 510 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 511 # `.output' file, which is named `input.output', and/or grammar file,
 512 # which is named `input.y'.
 513 #
 514 # Finally, compile the generated parser and then run it using
 515 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 516 # PARSER-STDERR as the 2nd-4th arguments.
 517 #
 518 # As a precondition, you must properly double-quote all arguments that
 519 # are to be interpreted as strings.
 520 #
 521 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 522 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 523 # first argument.  This is useful, for example, when wrapping multiple
 524 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 525 # condition, in another macro.
 526 #
 527 # For example:
 528 #
 529 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 530 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 531 #   # ---------------------------------------------------------------------
 532 #   m4_define([AT_TEST_SYNTAX_ERROR],
 533 #   [
 534 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 535 #                              [[last-state]],
 536 #                              [[%error-verbose ]$2], [$3], [$4],
 537 #                              [[]], [$5], [], [$6], [$7], [$8])
 538 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 539 #                              [[last-state]],
 540 #                              [$2], [$3], [$4],
 541 #                              [[]], [$5], [], [$6], [$7], [$8])
 542 #   ])
 543 #
 544 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 545 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 546 #                        [[3]],
 547 #                        [[1]], [[]],
 548 #                        [AT_COND_CASE([[no verbose]],
 549 #                                      [[syntax error
 550 #   ]],
 551 #                                      [[syntax error, unexpected 'b', expecting $end
 552 #   ]])])
 553 m4_define([AT_TEST_TABLES_AND_PARSE],
 554 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 555
 556 AT_SETUP([$1])
 557
 558 AT_DATA_GRAMMAR([[input.y]],
 559 [[%code {
 560   #include <stdio.h>
 561   static void yyerror (char const *msg);
 562   static int yylex (void);
 563 }
 564
 565 ]$4[
 566
 567 %%
 568
 569 ]$5[
 570
 571 %%
 572
 573 static void
 574 yyerror (char const *msg)
 575 {
 576   fprintf (stderr, "%s\n", msg);
 577 }
 578
 579 static int
 580 yylex (void)
 581 {
 582   static int const input[] = {
 583     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 584   };
 585   static int const *inputp = input;
 586   return *inputp++;
 587 }
 588
 589 int
 590 main (void)
 591 {
 592   return yyparse ();
 593 }
 594 ]])
 595
 596 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 597 # expanding macros, so it corrupts some special characters in the
 598 # macros.  To avoid this, expand now and pass it the result with proper
 599 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 600 # strings.
 601
 602 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 603       [AT_BISON_CHECK],
 604       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 605                                [0], [], m4_dquote($7))
 606
 607 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 608       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 609                 m4_dquote($8))],
 610       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 611                 m4_dquote($8)[[
 612 ]])])
 613
 614 $9
 615
 616 AT_COMPILE([[input]])
 617
 618 AT_PARSER_CHECK([[./input]],
 619                 m4_ifval([$10], [m4_dquote($10)]),
 620                 m4_ifval([$11], [m4_dquote($11)]),
 621                 m4_ifval([$12], [m4_dquote($12)]))
 622
 623 AT_CLEANUP
 624
 625 m4_popdef([AT_COND_CASE])])
 626
 627
 628
 629 ## ----------------------- ##
 630 ## Launch the test suite.  ##
 631 ## ----------------------- ##
 632
 633 AT_INIT
 634
 635 AT_TESTED([bison])