src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 #include <config.h>
  22 #include "system.h"
  23
  24 #include "complain.h"
  25 #include "conflicts.h"
  26 #include "files.h"
  27 #include "getargs.h"
  28 #include "gram.h"
  29 #include "muscle-tab.h"
  30 #include "named-ref.h"
  31 #include "quotearg.h"
  32 #include "reader.h"
  33 #include "symlist.h"
  34 #include "scan-gram.h"
  35 #include "scan-code.h"
  36
  37 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  38 static YYLTYPE lloc_default (YYLTYPE const *, int);
  39
  40 #define YY_LOCATION_PRINT(File, Loc) \
  41           location_print (File, Loc)
  42
  43 static void version_check (location const *loc, char const *version);
  44
  45 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  46    FIXME: depends on the undocumented availability of YYLLOC.  */
  47 #undef  yyerror
  48 #define yyerror(Msg) \
  49         gram_error (&yylloc, Msg)
  50 static void gram_error (location const *, char const *);
  51
  52 static char const *char_name (char);
  53
  54 /** Add a lex-param or a parse-param.
  55  *
  56  * \param type  \a lex_param or \a parse_param
  57  * \param decl  the formal argument
  58  * \param loc   the location in the source.
  59  */
  60 static void add_param (char const *type, char *decl, location loc);
  61
  62
  63 static symbol_class current_class = unknown_sym;
  64 static uniqstr current_type = NULL;
  65 static symbol *current_lhs;
  66 static location current_lhs_location;
  67 static named_ref *current_lhs_named_ref;
  68 static int current_prec = 0;
  69
  70 #define YYTYPE_INT16 int_fast16_t
  71 #define YYTYPE_INT8 int_fast8_t
  72 #define YYTYPE_UINT16 uint_fast16_t
  73 #define YYTYPE_UINT8 uint_fast8_t
  74 %}
  75
  76 %debug
  77 %verbose
  78 %defines
  79 %locations
  80 %pure-parser
  81 %define parse.error "verbose"
  82 %name-prefix="gram_"
  83 %expect 0
  84
  85 %initial-action
  86 {
  87   /* Bison's grammar can initial empty locations, hence a default
  88      location is needed. */
  89   boundary_set (&@$.start, current_file, 1, 1);
  90   boundary_set (&@$.end, current_file, 1, 1);
  91 }
  92
  93 %union
  94 {
  95   symbol *symbol;
  96   symbol_list *list;
  97   int integer;
  98   char const *chars;
  99   char *code;
 100   assoc assoc;
 101   uniqstr uniqstr;
 102   unsigned char character;
 103   named_ref *named_ref;
 104 };
 105
 106 /* Define the tokens together with their human representation.  */
 107 %token GRAM_EOF 0 "end of file"
 108 %token STRING     "string"
 109 %token INT        "integer"
 110
 111 %token PERCENT_TOKEN       "%token"
 112 %token PERCENT_NTERM       "%nterm"
 113
 114 %token PERCENT_TYPE        "%type"
 115 %token PERCENT_DESTRUCTOR  "%destructor"
 116 %token PERCENT_PRINTER     "%printer"
 117
 118 %token PERCENT_LEFT        "%left"
 119 %token PERCENT_RIGHT       "%right"
 120 %token PERCENT_NONASSOC    "%nonassoc"
 121 %token PERCENT_PRECEDENCE  "%precedence"
 122
 123 %token PERCENT_PREC          "%prec"
 124 %token PERCENT_DPREC         "%dprec"
 125 %token PERCENT_MERGE         "%merge"
 126
 127
 128 /*----------------------.
 129 | Global Declarations.  |
 130 `----------------------*/
 131
 132 %token
 133   PERCENT_CODE            "%code"
 134   PERCENT_DEFAULT_PREC    "%default-prec"
 135   PERCENT_DEFINE          "%define"
 136   PERCENT_DEFINES         "%defines"
 137   PERCENT_ERROR_VERBOSE   "%error-verbose"
 138   PERCENT_EXPECT          "%expect"
 139   PERCENT_EXPECT_RR       "%expect-rr"
 140   PERCENT_FLAG            "%<flag>"
 141   PERCENT_FILE_PREFIX     "%file-prefix"
 142   PERCENT_GLR_PARSER      "%glr-parser"
 143   PERCENT_INITIAL_ACTION  "%initial-action"
 144   PERCENT_LANGUAGE        "%language"
 145   PERCENT_LEX_PARAM       "%lex-param"
 146   PERCENT_NAME_PREFIX     "%name-prefix"
 147   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 148   PERCENT_NO_LINES        "%no-lines"
 149   PERCENT_NONDETERMINISTIC_PARSER
 150                           "%nondeterministic-parser"
 151   PERCENT_OUTPUT          "%output"
 152   PERCENT_PARSE_PARAM     "%parse-param"
 153   PERCENT_REQUIRE         "%require"
 154   PERCENT_SKELETON        "%skeleton"
 155   PERCENT_START           "%start"
 156   PERCENT_TOKEN_TABLE     "%token-table"
 157   PERCENT_VERBOSE         "%verbose"
 158   PERCENT_YACC            "%yacc"
 159 ;
 160
 161 %token BRACED_CODE     "{...}"
 162 %token CHAR            "char"
 163 %token EPILOGUE        "epilogue"
 164 %token EQUAL           "="
 165 %token ID              "identifier"
 166 %token ID_COLON        "identifier:"
 167 %token PERCENT_PERCENT "%%"
 168 %token PIPE            "|"
 169 %token PROLOGUE        "%{...%}"
 170 %token SEMICOLON       ";"
 171 %token TAG             "<tag>"
 172 %token TAG_ANY         "<*>"
 173 %token TAG_NONE        "<>"
 174 %token BRACKETED_ID    "[identifier]"
 175
 176 %type <character> CHAR
 177 %printer { fputs (char_name ($$), stderr); } CHAR
 178
 179 /* braceless is not to be used for rule or symbol actions, as it
 180    calls code_props_plain_init.  */
 181 %type <chars> STRING "%{...%}" EPILOGUE braceless content.opt
 182 %type <code> "{...}"
 183 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 184          STRING
 185 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 186          braceless content.opt "{...}" "%{...%}" EPILOGUE
 187
 188 %type <uniqstr> TAG ID ID_COLON BRACKETED_ID PERCENT_FLAG variable
 189 %type <named_ref> named_ref.opt
 190 %printer { fputs ($$, stderr); } ID variable
 191 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 192 %printer { fprintf (stderr, "%%%s", $$); } PERCENT_FLAG
 193 %printer { fprintf (stderr, "<%s>", $$); } TAG
 194
 195 %type <integer> INT
 196 %printer { fprintf (stderr, "%d", $$); } INT
 197
 198 %type <symbol> id id_colon symbol symbol.prec string_as_id
 199 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 200 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 201
 202 %type <assoc> precedence_declarator
 203 %type <list>  symbols.1 symbols.prec generic_symlist generic_symlist_item
 204 %%
 205
 206 input:
 207   prologue_declarations "%%" grammar epilogue.opt
 208 ;
 209
 210
 211         /*------------------------------------.
 212         | Declarations: before the first %%.  |
 213         `------------------------------------*/
 214
 215 prologue_declarations:
 216   /* Nothing */
 217 | prologue_declarations prologue_declaration
 218 ;
 219
 220 prologue_declaration:
 221   grammar_declaration
 222 | "%{...%}"
 223     {
 224       code_props plain_code;
 225       code_props_plain_init (&plain_code, $1, @1);
 226       code_props_translate_code (&plain_code);
 227       gram_scanner_last_string_free ();
 228       muscle_code_grow (union_seen ? "post_prologue" : "pre_prologue",
 229                         plain_code.code, @1);
 230       code_scanner_last_string_free ();
 231     }
 232 | "%<flag>"
 233     {
 234       muscle_percent_define_ensure ($1, @1, true);
 235     }
 236 | "%define" variable content.opt
 237     {
 238       muscle_percent_define_insert ($2, @2, $3,
 239                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 240     }
 241 | "%defines"                       { defines_flag = true; }
 242 | "%defines" STRING
 243     {
 244       defines_flag = true;
 245       spec_defines_file = xstrdup ($2);
 246     }
 247 | "%error-verbose"
 248     {
 249       muscle_percent_define_insert ("parse.error", @1, "verbose",
 250                                     MUSCLE_PERCENT_DEFINE_GRAMMAR_FILE);
 251     }
 252 | "%expect" INT                    { expected_sr_conflicts = $2; }
 253 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 254 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 255 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 256 | "%glr-parser"
 257     {
 258       nondeterministic_parser = true;
 259       glr_parser = true;
 260     }
 261 | "%initial-action" "{...}"
 262     {
 263       code_props action;
 264       code_props_symbol_action_init (&action, $2, @2);
 265       code_props_translate_code (&action);
 266       gram_scanner_last_string_free ();
 267       muscle_code_grow ("initial_action", action.code, @2);
 268       code_scanner_last_string_free ();
 269     }
 270 | "%language" STRING            { language_argmatch ($2, grammar_prio, @1); }
 271 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 272 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 273 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 274 | "%no-lines"                   { no_lines_flag = true; }
 275 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 276 | "%output" STRING              { spec_outfile = $2; }
 277 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 278 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 279 | "%require" STRING             { version_check (&@2, $2); }
 280 | "%skeleton" STRING
 281     {
 282       char const *skeleton_user = $2;
 283       if (strchr (skeleton_user, '/'))
 284         {
 285           size_t dir_length = strlen (current_file);
 286           char *skeleton_build;
 287           while (dir_length && current_file[dir_length - 1] != '/')
 288             --dir_length;
 289           while (dir_length && current_file[dir_length - 1] == '/')
 290             --dir_length;
 291           skeleton_build =
 292             xmalloc (dir_length + 1 + strlen (skeleton_user) + 1);
 293           if (dir_length > 0)
 294             {
 295               strncpy (skeleton_build, current_file, dir_length);
 296               skeleton_build[dir_length++] = '/';
 297             }
 298           strcpy (skeleton_build + dir_length, skeleton_user);
 299           skeleton_user = uniqstr_new (skeleton_build);
 300           free (skeleton_build);
 301         }
 302       skeleton_arg (skeleton_user, grammar_prio, @1);
 303     }
 304 | "%token-table"                { token_table_flag = true; }
 305 | "%verbose"                    { report_flag |= report_states; }
 306 | "%yacc"                       { yacc_flag = true; }
 307 | /*FIXME: Err?  What is this horror doing here? */ ";"
 308 ;
 309
 310 grammar_declaration:
 311   precedence_declaration
 312 | symbol_declaration
 313 | "%start" symbol
 314     {
 315       grammar_start_symbol_set ($2, @2);
 316     }
 317 | "%destructor" "{...}" generic_symlist
 318     {
 319       symbol_list *list;
 320       for (list = $3; list; list = list->next)
 321         symbol_list_destructor_set (list, $2, @2);
 322       symbol_list_free ($3);
 323     }
 324 | "%printer" "{...}" generic_symlist
 325     {
 326       symbol_list *list;
 327       for (list = $3; list; list = list->next)
 328         symbol_list_printer_set (list, $2, @2);
 329       symbol_list_free ($3);
 330     }
 331 | "%default-prec"
 332     {
 333       default_prec = true;
 334     }
 335 | "%no-default-prec"
 336     {
 337       default_prec = false;
 338     }
 339 | "%code" braceless
 340     {
 341       /* Do not invoke muscle_percent_code_grow here since it invokes
 342          muscle_user_name_list_grow.  */
 343       muscle_code_grow ("percent_code()", $2, @2);
 344       code_scanner_last_string_free ();
 345     }
 346 | "%code" ID braceless
 347     {
 348       muscle_percent_code_grow ($2, @2, $3, @3);
 349       code_scanner_last_string_free ();
 350     }
 351 ;
 352
 353
 354 /*---------.
 355 | %union.  |
 356 `---------*/
 357
 358 %token PERCENT_UNION "%union";
 359
 360 union_name:
 361   /* Nothing. */ {}
 362 | ID             { muscle_code_grow ("union_name", $1, @1); }
 363 ;
 364
 365 grammar_declaration:
 366   "%union" union_name braceless
 367     {
 368       union_seen = true;
 369       muscle_code_grow ("stype", $3, @3);
 370       code_scanner_last_string_free ();
 371     }
 372 ;
 373
 374
 375
 376
 377 symbol_declaration:
 378   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 379     {
 380       current_class = unknown_sym;
 381       current_type = NULL;
 382     }
 383 | "%token" { current_class = token_sym; } symbol_defs.1
 384     {
 385       current_class = unknown_sym;
 386       current_type = NULL;
 387     }
 388 | "%type" TAG symbols.1
 389     {
 390       symbol_list *list;
 391       tag_seen = true;
 392       for (list = $3; list; list = list->next)
 393         symbol_type_set (list->content.sym, $2, @2);
 394       symbol_list_free ($3);
 395     }
 396 ;
 397
 398 precedence_declaration:
 399   precedence_declarator tag.opt symbols.prec
 400     {
 401       symbol_list *list;
 402       ++current_prec;
 403       for (list = $3; list; list = list->next)
 404         {
 405           symbol_type_set (list->content.sym, current_type, @2);
 406           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 407         }
 408       symbol_list_free ($3);
 409       current_type = NULL;
 410     }
 411 ;
 412
 413 precedence_declarator:
 414   "%left"       { $$ = left_assoc; }
 415 | "%right"      { $$ = right_assoc; }
 416 | "%nonassoc"   { $$ = non_assoc; }
 417 | "%precedence" { $$ = precedence_assoc; }
 418 ;
 419
 420 tag.opt:
 421   /* Nothing. */ { current_type = NULL; }
 422 | TAG            { current_type = $1; tag_seen = true; }
 423 ;
 424
 425 /* Just like symbols.1 but accept INT for the sake of POSIX.  */
 426 symbols.prec:
 427   symbol.prec
 428     { $$ = symbol_list_sym_new ($1, @1); }
 429 | symbols.prec symbol.prec
 430     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 431 ;
 432
 433 symbol.prec:
 434     symbol { $$ = $1; }
 435   | symbol INT { $$ = $1; symbol_user_token_number_set ($1, $2, @2); }
 436   ;
 437
 438 /* One or more symbols to be %typed. */
 439 symbols.1:
 440   symbol
 441     { $$ = symbol_list_sym_new ($1, @1); }
 442 | symbols.1 symbol
 443     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 444 ;
 445
 446 generic_symlist:
 447   generic_symlist_item { $$ = $1; }
 448 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 449 ;
 450
 451 generic_symlist_item:
 452   symbol    { $$ = symbol_list_sym_new ($1, @1); }
 453 | TAG       { $$ = symbol_list_type_new ($1, @1); }
 454 | "<*>"     { $$ = symbol_list_default_tagged_new (@1); }
 455 | "<>"      { $$ = symbol_list_default_tagless_new (@1); }
 456 ;
 457
 458 /* One token definition.  */
 459 symbol_def:
 460   TAG
 461      {
 462        current_type = $1;
 463        tag_seen = true;
 464      }
 465 | id
 466      {
 467        symbol_class_set ($1, current_class, @1, true);
 468        symbol_type_set ($1, current_type, @1);
 469      }
 470 | id INT
 471     {
 472       symbol_class_set ($1, current_class, @1, true);
 473       symbol_type_set ($1, current_type, @1);
 474       symbol_user_token_number_set ($1, $2, @2);
 475     }
 476 | id string_as_id
 477     {
 478       symbol_class_set ($1, current_class, @1, true);
 479       symbol_type_set ($1, current_type, @1);
 480       symbol_make_alias ($1, $2, @$);
 481     }
 482 | id INT string_as_id
 483     {
 484       symbol_class_set ($1, current_class, @1, true);
 485       symbol_type_set ($1, current_type, @1);
 486       symbol_user_token_number_set ($1, $2, @2);
 487       symbol_make_alias ($1, $3, @$);
 488     }
 489 ;
 490
 491 /* One or more symbol definitions. */
 492 symbol_defs.1:
 493   symbol_def
 494 | symbol_defs.1 symbol_def
 495 ;
 496
 497
 498         /*------------------------------------------.
 499         | The grammar section: between the two %%.  |
 500         `------------------------------------------*/
 501
 502 grammar:
 503   rules_or_grammar_declaration
 504 | grammar rules_or_grammar_declaration
 505 ;
 506
 507 /* As a Bison extension, one can use the grammar declarations in the
 508    body of the grammar.  */
 509 rules_or_grammar_declaration:
 510   rules
 511 | grammar_declaration ";"
 512 | error ";"
 513     {
 514       yyerrok;
 515     }
 516 ;
 517
 518 rules:
 519   id_colon named_ref.opt { current_lhs = $1; current_lhs_location = @1;
 520     current_lhs_named_ref = $2; } rhses.1
 521 ;
 522
 523 rhses.1:
 524   rhs                { grammar_current_rule_end (@1); }
 525 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 526 | rhses.1 ";"
 527 ;
 528
 529 rhs:
 530   /* Nothing.  */
 531     { grammar_current_rule_begin (current_lhs, current_lhs_location,
 532                                   current_lhs_named_ref); }
 533 | rhs symbol named_ref.opt
 534     { grammar_current_rule_symbol_append ($2, @2, $3); }
 535 | rhs "{...}" named_ref.opt
 536     { grammar_current_rule_action_append ($2, @2, $3); }
 537 | rhs "%prec" symbol
 538     { grammar_current_rule_prec_set ($3, @3); }
 539 | rhs "%dprec" INT
 540     { grammar_current_rule_dprec_set ($3, @3); }
 541 | rhs "%merge" TAG
 542     { grammar_current_rule_merge_set ($3, @3); }
 543 ;
 544
 545 named_ref.opt:
 546   /* Nothing. */ { $$ = 0; }
 547 |
 548   BRACKETED_ID   { $$ = named_ref_new($1, @1); }
 549 ;
 550
 551
 552 /*---------------------------.
 553 | variable and content.opt.  |
 554 `---------------------------*/
 555
 556 /* The STRING form of variable is deprecated and is not M4-friendly.
 557    For example, M4 fails for `%define "[" "value"'.  */
 558 variable:
 559   ID
 560 | STRING { $$ = uniqstr_new ($1); }
 561 ;
 562
 563 /* Some content or empty by default. */
 564 content.opt:
 565   /* Nothing. */   { $$ = ""; }
 566 | STRING
 567 ;
 568
 569
 570 /*------------.
 571 | braceless.  |
 572 `------------*/
 573
 574 braceless:
 575   "{...}"
 576     {
 577       code_props plain_code;
 578       $1[strlen ($1) - 1] = '\n';
 579       code_props_plain_init (&plain_code, $1+1, @1);
 580       code_props_translate_code (&plain_code);
 581       gram_scanner_last_string_free ();
 582       $$ = plain_code.code;
 583     }
 584 ;
 585
 586
 587 /*--------------.
 588 | Identifiers.  |
 589 `--------------*/
 590
 591 /* Identifiers are returned as uniqstr values by the scanner.
 592    Depending on their use, we may need to make them genuine symbols.  */
 593
 594 id:
 595   ID
 596     { $$ = symbol_from_uniqstr ($1, @1); }
 597 | CHAR
 598     {
 599       $$ = symbol_get (char_name ($1), @1);
 600       symbol_class_set ($$, token_sym, @1, false);
 601       symbol_user_token_number_set ($$, $1, @1);
 602     }
 603 ;
 604
 605 id_colon:
 606   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 607 ;
 608
 609
 610 symbol:
 611   id
 612 | string_as_id
 613 ;
 614
 615 /* A string used as an ID: quote it.  */
 616 string_as_id:
 617   STRING
 618     {
 619       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 620       symbol_class_set ($$, token_sym, @1, false);
 621     }
 622 ;
 623
 624 epilogue.opt:
 625   /* Nothing.  */
 626 | "%%" EPILOGUE
 627     {
 628       code_props plain_code;
 629       code_props_plain_init (&plain_code, $2, @2);
 630       code_props_translate_code (&plain_code);
 631       gram_scanner_last_string_free ();
 632       muscle_code_grow ("epilogue", plain_code.code, @2);
 633       code_scanner_last_string_free ();
 634     }
 635 ;
 636
 637 %%
 638
 639
 640 /* Return the location of the left-hand side of a rule whose
 641    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 642    the right-hand side, and return an empty location equal to the end
 643    boundary of RHS[0] if the right-hand side is empty.  */
 644
 645 static YYLTYPE
 646 lloc_default (YYLTYPE const *rhs, int n)
 647 {
 648   int i;
 649   YYLTYPE loc;
 650
 651   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 652      The bug is fixed in 7.4.2m, but play it safe for now.  */
 653   loc.start = rhs[n].end;
 654   loc.end = rhs[n].end;
 655
 656   /* Ignore empty nonterminals the start of the the right-hand side.
 657      Do not bother to ignore them at the end of the right-hand side,
 658      since empty nonterminals have the same end as their predecessors.  */
 659   for (i = 1; i <= n; i++)
 660     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 661       {
 662         loc.start = rhs[i].start;
 663         break;
 664       }
 665
 666   return loc;
 667 }
 668
 669
 670 /* Add a lex-param or a parse-param (depending on TYPE) with
 671    declaration DECL and location LOC.  */
 672
 673 static void
 674 add_param (char const *type, char *decl, location loc)
 675 {
 676   static char const alphanum[26 + 26 + 1 + 10] =
 677     "abcdefghijklmnopqrstuvwxyz"
 678     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 679     "_"
 680     "0123456789";
 681   char const *name_start = NULL;
 682   char *p;
 683
 684   /* Stop on last actual character.  */
 685   for (p = decl; p[1]; p++)
 686     if ((p == decl
 687          || ! memchr (alphanum, p[-1], sizeof alphanum))
 688         && memchr (alphanum, p[0], sizeof alphanum - 10))
 689       name_start = p;
 690
 691   /* Strip the surrounding '{' and '}', and any blanks just inside
 692      the braces.  */
 693   while (*--p == ' ' || *p == '\t')
 694     continue;
 695   p[1] = '\0';
 696   while (*++decl == ' ' || *decl == '\t')
 697     continue;
 698
 699   if (! name_start)
 700     complain_at (loc, _("missing identifier in parameter declaration"));
 701   else
 702     {
 703       char *name;
 704       size_t name_len;
 705
 706       for (name_len = 1;
 707            memchr (alphanum, name_start[name_len], sizeof alphanum);
 708            name_len++)
 709         continue;
 710
 711       name = xmalloc (name_len + 1);
 712       memcpy (name, name_start, name_len);
 713       name[name_len] = '\0';
 714       muscle_pair_list_grow (type, decl, name);
 715       free (name);
 716     }
 717
 718   gram_scanner_last_string_free ();
 719 }
 720
 721
 722 static void
 723 version_check (location const *loc, char const *version)
 724 {
 725   if (strverscmp (version, PACKAGE_VERSION) > 0)
 726     {
 727       complain_at (*loc, "require bison %s, but have %s",
 728                    version, PACKAGE_VERSION);
 729       exit (63);
 730     }
 731 }
 732
 733 static void
 734 gram_error (location const *loc, char const *msg)
 735 {
 736   complain_at (*loc, "%s", msg);
 737 }
 738
 739 char const *
 740 token_name (int type)
 741 {
 742   return yytname[YYTRANSLATE (type)];
 743 }
 744
 745 static char const *
 746 char_name (char c)
 747 {
 748   if (c == '\'')
 749     return "'\\''";
 750   else
 751     {
 752       char buf[4];
 753       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 754       return quotearg_style (escape_quoting_style, buf);
 755     }
 756 }