tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   6 # Software Foundation, Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # We want a recent Autotest.
  22 m4_version_prereq([2.58])
  23
  24
  25 ## ------------------------------- ##
  26 ## Macros decoding Bison options.  ##
  27 ## ------------------------------- ##
  28
  29
  30 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  31 # -----------------------------------------
  32 m4_define([AT_BISON_OPTION_PUSHDEFS],
  33 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  34
  35
  36 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  37 # --------------------------------------------------
  38 # This macro works around the impossibility to define macros
  39 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  40 # This sucks hard, GNU M4 should really provide M5 like $$1.
  41 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  42 [m4_if([$1$2], $[1]$[2], [],
  43        [m4_fatal([$0: Invalid arguments: $@])])dnl
  44 m4_pushdef([AT_DEFINES_IF],
  45 [m4_bmatch([$3], [%defines], [$1], [$2])])
  46 m4_pushdef([AT_SKEL_CC_IF],
  47 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  48 m4_pushdef([AT_GLR_IF],
  49 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  50 m4_pushdef([AT_LALR1_CC_IF],
  51 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  52 m4_pushdef([AT_GLR_CC_IF],
  53 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  54 # Using yacc.c?
  55 m4_pushdef([AT_YACC_IF],
  56 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  57 m4_pushdef([AT_LEXPARAM_IF],
  58 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  59 m4_pushdef([AT_PARAM_IF],
  60 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  61 m4_pushdef([AT_LOCATION_IF],
  62 [m4_bmatch([$3], [%locations], [$1], [$2])])
  63 m4_pushdef([AT_PURE_IF],
  64 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  65            [m4_bmatch([$3], [%define  *api\.pure *"false"], [$2], [$1])],
  66            [$2])])
  67 m4_pushdef([AT_PURE_AND_LOC_IF],
  68 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  69 m4_pushdef([AT_GLR_OR_PARAM_IF],
  70 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  71 m4_pushdef([AT_NAME_PREFIX],
  72 [m4_bmatch([$3], [%name-prefix ".*"],
  73            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  74            [yy])])
  75 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  76 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  77 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  78                     [$2])])
  79 # yyerror always sees the locations (when activated), except if
  80 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  81 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  82 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  83                                         [$1])],
  84                             [$1])],
  85                 [$2])])
  86
  87 # The interface is pure: either because %define api.pure, or because we
  88 # are using the C++ parsers.
  89 m4_pushdef([AT_PURE_LEX_IF],
  90 [AT_PURE_IF([$1],
  91             [AT_SKEL_CC_IF([$1], [$2])])])
  92
  93 AT_PURE_LEX_IF(
  94 [m4_pushdef([AT_LOC], [(*llocp)])
  95  m4_pushdef([AT_VAL], [(*lvalp)])
  96  m4_pushdef([AT_LEX_FORMALS],
  97             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
  98  m4_pushdef([AT_LEX_ARGS],
  99             [lvalp[]AT_LOCATION_IF([, llocp])])
 100  m4_pushdef([AT_USE_LEX_ARGS],
 101             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 102  m4_pushdef([AT_LEX_PRE_FORMALS],
 103             [AT_LEX_FORMALS, ])
 104  m4_pushdef([AT_LEX_PRE_ARGS],
 105             [AT_LEX_ARGS, ])
 106 ],
 107 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 108  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 109  m4_pushdef([AT_LEX_FORMALS],     [void])
 110  m4_pushdef([AT_LEX_ARGS],        [])
 111  m4_pushdef([AT_USE_LEX_ARGS],    [])
 112  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 113  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 114 ])
 115 ])# _AT_BISON_OPTION_PUSHDEFS
 116
 117
 118 # AT_BISON_OPTION_POPDEFS
 119 # -----------------------
 120 m4_define([AT_BISON_OPTION_POPDEFS],
 121 [m4_popdef([AT_LEX_PRE_ARGS])
 122 m4_popdef([AT_LEX_PRE_FORMALS])
 123 m4_popdef([AT_USE_LEX_ARGS])
 124 m4_popdef([AT_LEX_ARGS])
 125 m4_popdef([AT_LEX_FORMALS])
 126 m4_popdef([AT_VAL])
 127 m4_popdef([AT_LOC])
 128 m4_popdef([AT_PURE_LEX_IF])
 129 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 130 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 131 m4_popdef([AT_NAME_PREFIX])
 132 m4_popdef([AT_GLR_OR_PARAM_IF])
 133 m4_popdef([AT_PURE_AND_LOC_IF])
 134 m4_popdef([AT_LOCATION_IF])
 135 m4_popdef([AT_PARAM_IF])
 136 m4_popdef([AT_LEXPARAM_IF])
 137 m4_popdef([AT_YACC_IF])
 138 m4_popdef([AT_GLR_IF])
 139 m4_popdef([AT_SKEL_CC_IF])
 140 m4_popdef([AT_GLR_CC_IF])
 141 m4_popdef([AT_LALR1_CC_IF])
 142 m4_popdef([AT_DEFINES_IF])
 143 ])# AT_BISON_OPTION_POPDEFS
 144
 145
 146
 147 ## -------------------------- ##
 148 ## Generating Grammar Files.  ##
 149 ## -------------------------- ##
 150
 151 # AT_DATA_SOURCE_PROLOGUE
 152 # ------------------------
 153 # The prologue that should be included in any source code that is
 154 # meant to be compiled.
 155 m4_define([AT_DATA_SOURCE_PROLOGUE],
 156 [[#include <config.h>
 157 /* We don't need perfect functions for these tests. */
 158 #undef malloc
 159 #undef memcmp
 160 #undef realloc
 161 ]])
 162
 163 # AT_DATA_GRAMMAR_PROLOGUE
 164 # ------------------------
 165 # The prologue that should be included in any grammar which parser is
 166 # meant to be compiled.
 167 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 168 [[%code top {
 169 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 170 [}
 171 ]])
 172
 173 # AT_DATA_SOURCE(NAME, CONTENT)
 174 # -----------------------------
 175 # Generate the file NAME, which CONTENT is preceded by
 176 # AT_DATA_SOURCE_PROLOGUE.
 177 m4_define([AT_DATA_SOURCE],
 178 [AT_DATA([$1],
 179 [AT_DATA_SOURCE_PROLOGUE
 180 $2])
 181 ])
 182
 183 # AT_DATA_GRAMMAR(NAME, CONTENT)
 184 # ------------------------------
 185 # Generate the file NAME, which CONTENT is preceded by
 186 # AT_DATA_GRAMMAR_PROLOGUE.
 187 m4_define([AT_DATA_GRAMMAR],
 188 [AT_DATA([$1],
 189 [AT_DATA_GRAMMAR_PROLOGUE
 190 $2])
 191 ])
 192
 193 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 194 # -------------------------------------------------
 195 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 196 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 197 #
 198 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 199 # Bison in the test suite.  For now it ensures that:
 200 #
 201 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 202 #      a non-zero exit status since Bison doesn't always try to free all memory
 203 #      in that case.
 204 #
 205 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 206 #      --graph and --report=all output for every working grammar.
 207 m4_define([AT_BISON_CHECK],
 208 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 209        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 210 AT_BISON_CHECK_NO_XML($@)])
 211
 212 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 213 # --------------------------------------------------------
 214 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 215 # when a tortured grammar's XML is known to be too large for xsltproc to
 216 # handle.
 217 m4_define([AT_BISON_CHECK_NO_XML],
 218 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 219                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 220
 221 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 222 # -----------------------------------------------------
 223 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 224 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 225 # have a non-zero exit status.
 226 m4_define([AT_BISON_CHECK_XML],
 227 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 228   mkdir xml-tests]
 229   m4_pushdef([AT_BISON_ARGS],
 230              [m4_bpatsubsts([[$1]],
 231                             [--report(-file)?=[^][ ]*], [],
 232                             [--graph=[^][ ]*], [],
 233                             [--xml=[^][ ]*], [])])dnl
 234   # Don't combine these Bison invocations since we want to be sure that
 235   # --report=all isn't required to get the full XML file.
 236   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 237              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 238            [[0]], [ignore], [ignore])
 239   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 240            [[0]], [ignore], [ignore])
 241   m4_popdef([AT_BISON_ARGS])dnl
 242   [cp xml-tests/test.output expout]
 243   AT_CHECK([[$XSLTPROC \
 244              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 245              xml-tests/test.xml]], [[0]], [expout])
 246   [cp xml-tests/test.dot expout]
 247   AT_CHECK([[$XSLTPROC \
 248              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 249              xml-tests/test.xml]], [[0]], [expout])
 250   [rm -rf xml-tests expout
 251 fi]])
 252
 253 # AT_QUELL_VALGRIND
 254 # -----------------
 255 # Put this before a Bison invocation to keep Valgrind from complaining about
 256 # reachable memory.
 257 #
 258 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 259 # The triple quoting below will cause test cases to fail if you do.  If you do
 260 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 261 # will then fail to shell-escape its contents when attempting to print them.
 262 # The testsuite verbose output, at least, will be incorrect, but nothing may
 263 # fail to make sure you notice.
 264 m4_define([AT_QUELL_VALGRIND],
 265 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 266
 267 ## ------------------------ ##
 268 ## Compiling C, C++ Files.  ##
 269 ## ------------------------ ##
 270
 271
 272 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 273 # ----------------------------------------
 274 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 275 # assume that we are linking too; this is a hack.
 276 m4_define([AT_COMPILE],
 277 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 278            0, [ignore], [ignore])])
 279
 280 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 281 # --------------------------------------------
 282 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 283 # assume that we are linking too; this is a hack.
 284 # If the C++ compiler does not work, ignore the test.
 285 m4_define([AT_COMPILE_CXX],
 286 [AT_KEYWORDS(c++)
 287 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 288 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 289          0, [ignore], [ignore])])
 290
 291
 292 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 293 # --------------------------------
 294 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 295 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 296 # along with it.
 297 # Relies on AT_SKEL_CC_IF.
 298 m4_define([AT_FULL_COMPILE],
 299 [AT_SKEL_CC_IF(
 300   [AT_BISON_CHECK([-o $1.cc $1.y])
 301    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 302   [AT_BISON_CHECK([-o $1.c $1.y])
 303    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 304 ])
 305
 306
 307 ## ---------------------------- ##
 308 ## Running a generated parser.  ##
 309 ## ---------------------------- ##
 310
 311 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 312 # ------------------------------------------------------------
 313 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 314 m4_define([AT_PARSER_CHECK],
 315 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 316
 317
 318
 319
 320 ## ----------------------- ##
 321 ## Launch the test suite.  ##
 322 ## ----------------------- ##
 323
 324 AT_INIT
 325
 326 AT_TESTED([bison])