tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   6 # Software Foundation, Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # We want a recent Autotest.
  22 m4_version_prereq([2.58])
  23
  24
  25 ## ------------- ##
  26 ## Basic tests.  ##
  27 ## ------------- ##
  28
  29 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  30 # ------------------------------------------
  31 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  32 # taken in "slurp" mode, i.e., one can match end-of-lines.
  33 m4_define([AT_MATCHES_CHECK],
  34 [AT_CHECK([perl -0777 -ne '
  35 my $count = 0;
  36 s{$2}{ ++$count; "" }gem;
  37 printf "$count\n";' $1], [0], [$3
  38 ])])
  39
  40
  41 ## ------------------------------- ##
  42 ## Macros decoding Bison options.  ##
  43 ## ------------------------------- ##
  44
  45 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  46 # ----------------------------------------------------------------
  47 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  48 m4_define([AT_LOC_PUSHDEF],
  49 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  50 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  51 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  52 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  53
  54 # AT_LOC_POPDEF
  55 # -------------
  56 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  57 m4_define([AT_LOC_POPDEF],
  58 [m4_popdef([AT_LOC_FIRST_LINE])
  59 m4_popdef([AT_LOC_FIRST_COLUMN])
  60 m4_popdef([AT_LOC_LAST_LINE])
  61 m4_popdef([AT_LOC_LAST_COLUMN])])
  62
  63
  64
  65 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  66 # -----------------------------------------
  67 m4_define([AT_BISON_OPTION_PUSHDEFS],
  68 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  69
  70
  71 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  72 # --------------------------------------------------
  73 # This macro works around the impossibility to define macros
  74 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  75 # This sucks hard, GNU M4 should really provide M5-like $$1.
  76 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  77 [m4_if([$1$2], $[1]$[2], [],
  78        [m4_fatal([$0: Invalid arguments: $@])])dnl
  79 m4_pushdef([AT_DEFINES_IF],
  80 [m4_bmatch([$3], [%defines], [$1], [$2])])
  81 m4_pushdef([AT_SKEL_CC_IF],
  82 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  83 m4_pushdef([AT_SKEL_JAVA_IF],
  84 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
  85 m4_pushdef([AT_GLR_IF],
  86 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  87 m4_pushdef([AT_LALR1_CC_IF],
  88 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  89 m4_pushdef([AT_GLR_CC_IF],
  90 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  91 # Using yacc.c?
  92 m4_pushdef([AT_YACC_IF],
  93 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  94 m4_pushdef([AT_LEXPARAM_IF],
  95 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  96 m4_pushdef([AT_LOCATION_IF],
  97 [m4_bmatch([$3], [%locations], [$1], [$2])])
  98 m4_pushdef([AT_LOCATION_TYPE_IF],
  99 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 100 m4_pushdef([AT_PARAM_IF],
 101 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 102 m4_pushdef([AT_PURE_IF],
 103 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 104            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 105            [$2])])
 106 m4_pushdef([AT_PURE_AND_LOC_IF],
 107 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 108 m4_pushdef([AT_GLR_OR_PARAM_IF],
 109 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 110 m4_pushdef([AT_NAME_PREFIX],
 111 [m4_bmatch([$3], [%name-prefix ".*"],
 112            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 113            [yy])])
 114 m4_pushdef([AT_TOKEN_PREFIX],
 115 [m4_bmatch([$3], [%define api.tokens.prefix ".*"],
 116            [m4_bregexp([$3], [%define api.tokens.prefix "\(.*\)"], [\1])])])
 117 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 118 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 119 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 120                     [$2])])
 121 # yyerror always sees the locations (when activated), except if
 122 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 123 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 124 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 125                                         [$1])],
 126                             [$1])],
 127                 [$2])])
 128
 129 # The interface is pure: either because %define api.pure, or because we
 130 # are using the C++ parsers.
 131 m4_pushdef([AT_PURE_LEX_IF],
 132 [AT_PURE_IF([$1],
 133             [AT_SKEL_CC_IF([$1], [$2])])])
 134
 135 AT_PURE_LEX_IF(
 136 [m4_pushdef([AT_LOC], [(*llocp)])
 137  m4_pushdef([AT_VAL], [(*lvalp)])
 138  m4_pushdef([AT_LEX_FORMALS],
 139             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 140  m4_pushdef([AT_LEX_ARGS],
 141             [lvalp[]AT_LOCATION_IF([, llocp])])
 142  m4_pushdef([AT_USE_LEX_ARGS],
 143             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 144  m4_pushdef([AT_LEX_PRE_FORMALS],
 145             [AT_LEX_FORMALS, ])
 146  m4_pushdef([AT_LEX_PRE_ARGS],
 147             [AT_LEX_ARGS, ])
 148 ],
 149 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 150  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 151  m4_pushdef([AT_LEX_FORMALS],     [void])
 152  m4_pushdef([AT_LEX_ARGS],        [])
 153  m4_pushdef([AT_USE_LEX_ARGS],    [])
 154  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 155  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 156 ])
 157
 158 # Handle the different types of location components.
 159
 160 AT_SKEL_CC_IF(
 161   [AT_LOCATION_TYPE_IF(
 162     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 163     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 164   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 165
 166
 167 AT_GLR_IF([AT_KEYWORDS([glr])])
 168 ])# _AT_BISON_OPTION_PUSHDEFS
 169
 170
 171 # AT_BISON_OPTION_POPDEFS
 172 # -----------------------
 173 m4_define([AT_BISON_OPTION_POPDEFS],
 174 [m4_popdef([AT_LEX_PRE_ARGS])
 175 m4_popdef([AT_LEX_PRE_FORMALS])
 176 m4_popdef([AT_USE_LEX_ARGS])
 177 m4_popdef([AT_LEX_ARGS])
 178 m4_popdef([AT_LEX_FORMALS])
 179 m4_popdef([AT_VAL])
 180 m4_popdef([AT_LOC])
 181 m4_popdef([AT_PURE_LEX_IF])
 182 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 183 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 184 m4_popdef([AT_NAME_PREFIX])
 185 m4_popdef([AT_GLR_OR_PARAM_IF])
 186 m4_popdef([AT_PURE_AND_LOC_IF])
 187 m4_popdef([AT_LOCATION_TYPE_IF])
 188 m4_popdef([AT_LOCATION_IF])
 189 m4_popdef([AT_PARAM_IF])
 190 m4_popdef([AT_LEXPARAM_IF])
 191 m4_popdef([AT_YACC_IF])
 192 m4_popdef([AT_GLR_IF])
 193 m4_popdef([AT_SKEL_CC_IF])
 194 m4_popdef([AT_SKEL_JAVA_IF])
 195 m4_popdef([AT_GLR_CC_IF])
 196 m4_popdef([AT_LALR1_CC_IF])
 197 m4_popdef([AT_DEFINES_IF])
 198 AT_LOC_POPDEF
 199 ])# AT_BISON_OPTION_POPDEFS
 200
 201
 202
 203 ## -------------------------- ##
 204 ## Generating Grammar Files.  ##
 205 ## -------------------------- ##
 206
 207 # AT_DATA_SOURCE_PROLOGUE
 208 # ------------------------
 209 # The prologue that should be included in any source code that is
 210 # meant to be compiled.
 211 m4_define([AT_DATA_SOURCE_PROLOGUE],
 212 [[#include <config.h>
 213 /* We don't need perfect functions for these tests. */
 214 #undef malloc
 215 #undef memcmp
 216 #undef realloc
 217 ]])
 218
 219 # AT_DATA_GRAMMAR_PROLOGUE
 220 # ------------------------
 221 # The prologue that should be included in any grammar which parser is
 222 # meant to be compiled.
 223 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 224 [[%code top {
 225 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 226 [}
 227 ]])
 228
 229 # AT_DATA_SOURCE(NAME, CONTENT)
 230 # -----------------------------
 231 # Generate the file NAME, which CONTENT is preceded by
 232 # AT_DATA_SOURCE_PROLOGUE.
 233 m4_define([AT_DATA_SOURCE],
 234 [AT_DATA([$1],
 235 [AT_DATA_SOURCE_PROLOGUE
 236 $2])
 237 ])
 238
 239 # AT_DATA_GRAMMAR(NAME, CONTENT)
 240 # ------------------------------
 241 # Generate the file NAME, which CONTENT is preceded by
 242 # AT_DATA_GRAMMAR_PROLOGUE.
 243 m4_define([AT_DATA_GRAMMAR],
 244 [AT_DATA([$1],
 245 [AT_DATA_GRAMMAR_PROLOGUE
 246 $2])
 247 ])
 248
 249 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 250 # -------------------------------------------------
 251 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 252 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 253 #
 254 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 255 # Bison in the test suite.  For now it ensures that:
 256 #
 257 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 258 #      a non-zero exit status since Bison doesn't always try to free all memory
 259 #      in that case.
 260 #
 261 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 262 #      --graph and --report=all output for every working grammar.
 263 #
 264 #   3. If stderr contains a warning, -Werror and --warnings=error
 265 #      convert the warning to an error.
 266 m4_define([AT_BISON_CHECK],
 267 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 268        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 269 AT_BISON_CHECK_NO_XML($@)])
 270
 271 m4_define([AT_BISON_WERROR_MSG],
 272           [[bison: warnings being treated as errors]])
 273
 274 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 275 # --------------------------------------------------------
 276 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 277 # when a tortured grammar's XML is known to be too large for xsltproc to
 278 # handle.
 279 m4_define([AT_BISON_CHECK_NO_XML],
 280 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 281                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 282 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 283       [m4_if(m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0],
 284              [[# Don't interfere with caller's files.
 285               if test -f stderr; then
 286                 mv stderr at-bison-check-stderr.bak
 287               fi
 288               if test -f experr; then
 289                 mv experr at-bison-check-experr.bak
 290               fi
 291
 292               # Run with -Werror.
 293               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison -Werror ]$1],
 294                         [[1]], [$3], [stderr])[
 295
 296               # Build expected stderr up to and including the "warnings
 297               # being treated as errors" message.
 298               ]AT_DATA([[at-bison-check-warnings]], [$4])[
 299               at_bison_check_first="` \
 300                 sed -n '/: warning: /=' at-bison-check-warnings \
 301                 | sed -n 1p \
 302               `"
 303               if test $at_bison_check_first -gt 1; then
 304                 sed -n "1,`expr $at_bison_check_first - 1`"p \
 305                   at-bison-check-warnings > experr
 306               fi
 307               echo ']AT_BISON_WERROR_MSG[' >> experr
 308
 309               # Finish building expected stderr and check.  Unlike
 310               # warnings, complaints cause bison to exit early.  Thus,
 311               # with -Werror, bison does not necessarily report all
 312               # warnings that it does without -Werror, but it at least
 313               # reports one.
 314               at_bison_check_last="`sed -n '$=' stderr`"
 315               if test x"$at_bison_check_last" = x; then
 316                 at_bison_check_last=1
 317               fi
 318               at_bison_check_last="`expr $at_bison_check_last - 1`"
 319               sed -n "$at_bison_check_first,$at_bison_check_last"p \
 320                 at-bison-check-warnings >> experr
 321               ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 322                           stderr 1>&2]], [[0]], [[]], [experr])[
 323
 324               # Now check --warnings=error.
 325               cp stderr experr
 326               ]AT_CHECK(AT_QUELL_VALGRIND[[ bison --warnings=error ]$1],
 327                         [[1]], [$3], [experr])[
 328
 329               # Restore caller's files.
 330               if test -f at-bison-check-experr.bak; then
 331                 mv at-bison-check-experr.bak experr
 332               fi
 333               if test -f at-bison-check-stderr.bak; then
 334                 mv at-bison-check-stderr.bak stderr
 335               fi
 336              ]])
 337       ])
 338 ])
 339
 340 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 341 # -----------------------------------------------------
 342 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 343 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 344 # have a non-zero exit status.
 345 m4_define([AT_BISON_CHECK_XML],
 346 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 347   mkdir xml-tests]
 348   m4_pushdef([AT_BISON_ARGS],
 349              [m4_bpatsubsts([[$1]],
 350                             [--report(-file)?=[^][ ]*], [],
 351                             [--graph=[^][ ]*], [],
 352                             [--xml=[^][ ]*], [])])dnl
 353   # Don't combine these Bison invocations since we want to be sure that
 354   # --report=all isn't required to get the full XML file.
 355   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 356              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 357            [[0]], [ignore], [ignore])
 358   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 359            [[0]], [ignore], [ignore])
 360   m4_popdef([AT_BISON_ARGS])dnl
 361   [cp xml-tests/test.output expout]
 362   AT_CHECK([[$XSLTPROC \
 363              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 364              xml-tests/test.xml]], [[0]], [expout])
 365   [cp xml-tests/test.dot expout]
 366   AT_CHECK([[$XSLTPROC \
 367              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 368              xml-tests/test.xml]], [[0]], [expout])
 369   [rm -rf xml-tests expout
 370 fi]])
 371
 372 # AT_QUELL_VALGRIND
 373 # -----------------
 374 # Put this before a Bison invocation to keep Valgrind from complaining about
 375 # reachable memory.
 376 #
 377 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 378 # The triple quoting below will cause test cases to fail if you do.  If you do
 379 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 380 # will then fail to shell-escape its contents when attempting to print them.
 381 # The testsuite verbose output, at least, will be incorrect, but nothing may
 382 # fail to make sure you notice.
 383 m4_define([AT_QUELL_VALGRIND],
 384 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 385
 386 ## ------------------------ ##
 387 ## Compiling C, C++ Files.  ##
 388 ## ------------------------ ##
 389
 390
 391 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 392 # ----------------------------------------
 393 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 394 # assume that we are linking too; this is a hack.
 395 m4_define([AT_COMPILE],
 396 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 397            0, [ignore], [ignore])])
 398
 399 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 400 # --------------------------------------------
 401 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 402 # assume that we are linking too; this is a hack.
 403 # If the C++ compiler does not work, ignore the test.
 404 m4_define([AT_COMPILE_CXX],
 405 [AT_KEYWORDS(c++)
 406 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 407 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 408          0, [ignore], [ignore])])
 409
 410 # AT_JAVA_COMPILE(SOURCES)
 411 # ------------------------
 412 # Compile SOURCES into Java class files.  Skip the test if java or javac
 413 # is not installed.
 414 m4_define([AT_JAVA_COMPILE],
 415 [AT_KEYWORDS(java)
 416 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 417            test -n "$CONF_JAVAC" || exit 77]])
 418 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 419          [[0]], [ignore], [ignore])])
 420
 421 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 422 # --------------------------------
 423 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 424 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 425 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 426 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 427 # AT_SKEL_JAVA_IF.
 428 m4_define([AT_FULL_COMPILE], [
 429   AT_SKEL_JAVA_IF([
 430     AT_BISON_CHECK([[-o ]$1[.java ]$1[.y]])
 431     AT_JAVA_COMPILE([$1[.java]]m4_ifval($2,
 432                                         [[$1[.java ]$1[-]$2[.java]]]))
 433   ], [
 434     AT_SKEL_CC_IF([
 435       AT_BISON_CHECK([[-o ]$1[.cc ]$1[.y]])
 436       AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1[.cc ]$1[-]$2[.cc]]]))
 437     ], [
 438       AT_BISON_CHECK([[-o ]$1[.c ]$1[.y]])
 439       AT_COMPILE([$1]m4_ifval($2, [, [$1[.c ]$1[-]$2[.c]]]))
 440     ])
 441   ])
 442 ])
 443
 444
 445 ## ---------------------------- ##
 446 ## Running a generated parser.  ##
 447 ## ---------------------------- ##
 448
 449 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 450 # ------------------------------------------------------------
 451 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 452 m4_define([AT_PARSER_CHECK],
 453 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 454
 455 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 456 # -----------------------------------------------------------------
 457 m4_define([AT_JAVA_PARSER_CHECK],
 458 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 459
 460 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 461 #                          DECLS, GRAMMAR, INPUT,
 462 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 463 #                          [OTHER-CHECKS],
 464 #                          [PARSER-EXIT-VALUE],
 465 #                          [PARSER-STDOUT], [PARSER-STDERR])
 466 # -------------------------------------------------------------
 467 # Using TITLE as the test group title, check the generated parser tables
 468 # and parser for a specified grammar file under a condition labeled by
 469 # COND-VALUE.
 470 #
 471 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 472 # recognized attribute is described below where it is relevant.
 473 #
 474 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 475 # the grammar file.  Insert basic yyerror, yylex, and main function
 476 # definitions as well.  Hardcode yylex to return the (possibly empty)
 477 # comma-delimited series of tokens in INPUT followed by token 0.
 478 #
 479 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 480 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 481 # On the bison command-line, specify `--report=all --defines'.  Check
 482 # that Bison exits with value 0, has no stdout, and has stderr
 483 # BISON-STDERR.
 484 #
 485 # If TEST-SPEC contains the attribute `last-state', check that the value
 486 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 487 # the grammar; in other words, check the number of states (minus one).
 488 # Otherwise, check that everything in the `.output' file starting with
 489 # the definition of state 0 is the same as the entire value of
 490 # TABLES-OR-LAST-STATE.
 491 #
 492 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 493 # `.output' file, which is named `input.output', and/or grammar file,
 494 # which is named `input.y'.
 495 #
 496 # Finally, compile the generated parser and then run it using
 497 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 498 # PARSER-STDERR as the 2nd-4th arguments.
 499 #
 500 # As a precondition, you must properly double-quote all arguments that
 501 # are to be interpreted as strings.
 502 #
 503 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 504 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 505 # first argument.  This is useful, for example, when wrapping multiple
 506 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 507 # condition, in another macro.
 508 #
 509 # For example:
 510 #
 511 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 512 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 513 #   # ---------------------------------------------------------------------
 514 #   m4_define([AT_TEST_SYNTAX_ERROR],
 515 #   [
 516 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 517 #                              [[last-state]],
 518 #                              [[%error-verbose ]$2], [$3], [$4],
 519 #                              [[]], [$5], [], [$6], [$7], [$8])
 520 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 521 #                              [[last-state]],
 522 #                              [$2], [$3], [$4],
 523 #                              [[]], [$5], [], [$6], [$7], [$8])
 524 #   ])
 525 #
 526 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 527 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 528 #                        [[3]],
 529 #                        [[1]], [[]],
 530 #                        [AT_COND_CASE([[no verbose]],
 531 #                                      [[syntax error
 532 #   ]],
 533 #                                      [[syntax error, unexpected 'b', expecting $end
 534 #   ]])])
 535 m4_define([AT_TEST_TABLES_AND_PARSE],
 536 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 537
 538 AT_SETUP([$1])
 539
 540 AT_DATA_GRAMMAR([[input.y]],
 541 [[%code {
 542   #include <stdio.h>
 543   static void yyerror (char const *msg);
 544   static int yylex (void);
 545 }
 546
 547 ]$4[
 548
 549 %%
 550
 551 ]$5[
 552
 553 %%
 554
 555 static void
 556 yyerror (char const *msg)
 557 {
 558   fprintf (stderr, "%s\n", msg);
 559 }
 560
 561 static int
 562 yylex (void)
 563 {
 564   static int const input[] = {
 565     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 566   };
 567   static int const *inputp = input;
 568   return *inputp++;
 569 }
 570
 571 int
 572 main (void)
 573 {
 574   return yyparse ();
 575 }
 576 ]])
 577
 578 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 579 # expanding macros, so it corrupts some special characters in the
 580 # macros.  To avoid this, expand now and pass it the result with proper
 581 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 582 # strings.
 583
 584 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 585       [AT_BISON_CHECK],
 586       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 587                                [0], [], m4_dquote($7))
 588
 589 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 590       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 591                 m4_dquote($8))],
 592       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 593                 m4_dquote($8)[[
 594 ]])])
 595
 596 $9
 597
 598 AT_COMPILE([[input]])
 599
 600 AT_PARSER_CHECK([[./input]],
 601                 m4_ifval([$10], [m4_dquote($10)]),
 602                 m4_ifval([$11], [m4_dquote($11)]),
 603                 m4_ifval([$12], [m4_dquote($12)]))
 604
 605 AT_CLEANUP
 606
 607 m4_popdef([AT_COND_CASE])])
 608
 609
 610
 611 ## ----------------------- ##
 612 ## Launch the test suite.  ##
 613 ## ----------------------- ##
 614
 615 AT_INIT
 616
 617 AT_TESTED([bison])