src/parse-gram.y

   1 /* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307  USA
  21 */
  22
  23
  24 %debug
  25 %defines
  26 %locations
  27 %pure-parser
  28 %error-verbose
  29 %defines
  30 %name-prefix="gram_"
  31
  32 %{
  33 #include "system.h"
  34
  35 #include "complain.h"
  36 #include "conflicts.h"
  37 #include "files.h"
  38 #include "getargs.h"
  39 #include "gram.h"
  40 #include "muscle_tab.h"
  41 #include "output.h"
  42 #include "reader.h"
  43 #include "symlist.h"
  44
  45 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  46 static YYLTYPE lloc_default (YYLTYPE const *, int);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 #define YYPRINT(File, Type, Value) \
  56         print_token_value (File, Type, &Value)
  57 static void print_token_value (FILE *, int, YYSTYPE const *);
  58
  59 static void add_param (char const *, char *, location);
  60
  61 symbol_class current_class = unknown_sym;
  62 uniqstr current_type = 0;
  63 symbol *current_lhs;
  64 location current_lhs_location;
  65 assoc current_assoc;
  66 int current_prec = 0;
  67 %}
  68
  69 %initial-action
  70 {
  71   /* Bison's grammar can initial empty locations, hence a default
  72      location is needed. */
  73   @$.start.file   = @$.end.file   = current_file;
  74   @$.start.line   = @$.end.line   = 1;
  75   @$.start.column = @$.end.column = 0;
  76 }
  77
  78 /* Only NUMBERS have a value.  */
  79 %union
  80 {
  81   symbol *symbol;
  82   symbol_list *list;
  83   int integer;
  84   char *chars;
  85   assoc assoc;
  86   uniqstr uniqstr;
  87 };
  88
  89 /* Define the tokens together with their human representation.  */
  90 %token GRAM_EOF 0 "end of file"
  91 %token STRING     "string"
  92 %token INT        "integer"
  93
  94 %token PERCENT_TOKEN       "%token"
  95 %token PERCENT_NTERM       "%nterm"
  96
  97 %token PERCENT_TYPE        "%type"
  98 %token PERCENT_DESTRUCTOR  "%destructor {...}"
  99 %token PERCENT_PRINTER     "%printer {...}"
 100
 101 %token PERCENT_UNION       "%union {...}"
 102
 103 %token PERCENT_LEFT        "%left"
 104 %token PERCENT_RIGHT       "%right"
 105 %token PERCENT_NONASSOC    "%nonassoc"
 106
 107 %token PERCENT_PREC          "%prec"
 108 %token PERCENT_DPREC         "%dprec"
 109 %token PERCENT_MERGE         "%merge"
 110
 111
 112 /*----------------------.
 113 | Global Declarations.  |
 114 `----------------------*/
 115
 116 %token
 117   PERCENT_DEBUG           "%debug"
 118   PERCENT_DEFAULT_PREC    "%default-prec"
 119   PERCENT_DEFINE          "%define"
 120   PERCENT_DEFINES         "%defines"
 121   PERCENT_ERROR_VERBOSE   "%error-verbose"
 122   PERCENT_EXPECT          "%expect"
 123   PERCENT_FILE_PREFIX     "%file-prefix"
 124   PERCENT_GLR_PARSER      "%glr-parser"
 125   PERCENT_INITIAL_ACTION  "%initial-action {...}"
 126   PERCENT_LEX_PARAM       "%lex-param {...}"
 127   PERCENT_LOCATIONS       "%locations"
 128   PERCENT_NAME_PREFIX     "%name-prefix"
 129   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 130   PERCENT_NO_LINES        "%no-lines"
 131   PERCENT_NONDETERMINISTIC_PARSER
 132                           "%nondeterministic-parser"
 133   PERCENT_OUTPUT          "%output"
 134   PERCENT_PARSE_PARAM     "%parse-param {...}"
 135   PERCENT_PURE_PARSER     "%pure-parser"
 136   PERCENT_SKELETON        "%skeleton"
 137   PERCENT_START           "%start"
 138   PERCENT_TOKEN_TABLE     "%token-table"
 139   PERCENT_VERBOSE         "%verbose"
 140   PERCENT_YACC            "%yacc"
 141 ;
 142
 143 %token TYPE            "type"
 144 %token EQUAL           "="
 145 %token SEMICOLON       ";"
 146 %token PIPE            "|"
 147 %token ID              "identifier"
 148 %token ID_COLON        "identifier:"
 149 %token PERCENT_PERCENT "%%"
 150 %token PROLOGUE        "%{...%}"
 151 %token EPILOGUE        "epilogue"
 152 %token BRACED_CODE     "{...}"
 153
 154
 155 %type <chars> STRING string_content
 156               "%destructor {...}"
 157               "%initial-action {...}"
 158               "%lex-param {...}"
 159               "%parse-param {...}"
 160               "%printer {...}"
 161               "%union {...}"
 162               BRACED_CODE action
 163               PROLOGUE EPILOGUE
 164 %type <uniqstr> TYPE
 165 %type <integer> INT
 166 %type <symbol> ID ID_COLON symbol string_as_id
 167 %type <assoc> precedence_declarator
 168 %type <list>  symbols.1
 169 %%
 170
 171 input:
 172   declarations "%%" grammar epilogue.opt
 173 ;
 174
 175
 176         /*------------------------------------.
 177         | Declarations: before the first %%.  |
 178         `------------------------------------*/
 179
 180 declarations:
 181   /* Nothing */
 182 | declarations declaration
 183 ;
 184
 185 declaration:
 186   grammar_declaration
 187 | PROLOGUE                                 { prologue_augment ($1, @1); }
 188 | "%debug"                                 { debug_flag = true; }
 189 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 190 | "%defines"                               { defines_flag = true; }
 191 | "%error-verbose"                         { error_verbose = true; }
 192 | "%expect" INT                            { expected_conflicts = $2; }
 193 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 194 | "%glr-parser"
 195   {
 196     nondeterministic_parser = true;
 197     glr_parser = true;
 198   }
 199 | "%initial-action {...}"
 200   {
 201     muscle_code_grow ("initial_action", $1, @1);
 202   }
 203 | "%lex-param {...}"                       { add_param ("lex_param", $1, @1); }
 204 | "%locations"                             { locations_flag = true; }
 205 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 206 | "%no-lines"                              { no_lines_flag = true; }
 207 | "%nondeterministic-parser"               { nondeterministic_parser = true; }
 208 | "%output" "=" string_content             { spec_outfile = $3; }
 209 | "%parse-param {...}"                     { add_param ("parse_param", $1, @1); }
 210 | "%pure-parser"                           { pure_parser = true; }
 211 | "%skeleton" string_content               { skeleton = $2; }
 212 | "%token-table"                           { token_table_flag = true; }
 213 | "%verbose"                               { report_flag = report_states; }
 214 | "%yacc"                                  { yacc_flag = true; }
 215 | /*FIXME: Err?  What is this horror doing here? */ ";"
 216 ;
 217
 218 grammar_declaration:
 219   precedence_declaration
 220 | symbol_declaration
 221 | "%start" symbol
 222     {
 223       grammar_start_symbol_set ($2, @2);
 224     }
 225 | "%union {...}"
 226     {
 227       typed = true;
 228       MUSCLE_INSERT_INT ("stype_line", @1.start.line);
 229       muscle_insert ("stype", $1);
 230     }
 231 | "%destructor {...}" symbols.1
 232     {
 233       symbol_list *list;
 234       for (list = $2; list; list = list->next)
 235         symbol_destructor_set (list->sym, $1, @1);
 236       symbol_list_free ($2);
 237     }
 238 | "%printer {...}" symbols.1
 239     {
 240       symbol_list *list;
 241       for (list = $2; list; list = list->next)
 242         symbol_printer_set (list->sym, $1, list->location);
 243       symbol_list_free ($2);
 244     }
 245 | "%default-prec"
 246     {
 247       default_prec = true;
 248     }
 249 | "%no-default-prec"
 250     {
 251       default_prec = false;
 252     }
 253 ;
 254
 255 symbol_declaration:
 256   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 257     {
 258       current_class = unknown_sym;
 259       current_type = NULL;
 260     }
 261 | "%token" { current_class = token_sym; } symbol_defs.1
 262     {
 263       current_class = unknown_sym;
 264       current_type = NULL;
 265     }
 266 | "%type" TYPE symbols.1
 267     {
 268       symbol_list *list;
 269       for (list = $3; list; list = list->next)
 270         symbol_type_set (list->sym, $2, @2);
 271       symbol_list_free ($3);
 272     }
 273 ;
 274
 275 precedence_declaration:
 276   precedence_declarator type.opt symbols.1
 277     {
 278       symbol_list *list;
 279       ++current_prec;
 280       for (list = $3; list; list = list->next)
 281         {
 282           symbol_type_set (list->sym, current_type, @2);
 283           symbol_precedence_set (list->sym, current_prec, $1, @1);
 284         }
 285       symbol_list_free ($3);
 286       current_type = NULL;
 287     }
 288 ;
 289
 290 precedence_declarator:
 291   "%left"     { $$ = left_assoc; }
 292 | "%right"    { $$ = right_assoc; }
 293 | "%nonassoc" { $$ = non_assoc; }
 294 ;
 295
 296 type.opt:
 297   /* Nothing. */ { current_type = NULL; }
 298 | TYPE           { current_type = $1; }
 299 ;
 300
 301 /* One or more nonterminals to be %typed. */
 302
 303 symbols.1:
 304   symbol            { $$ = symbol_list_new ($1, @1); }
 305 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 306 ;
 307
 308 /* One token definition.  */
 309 symbol_def:
 310   TYPE
 311      {
 312        current_type = $1;
 313      }
 314 | ID
 315      {
 316        symbol_class_set ($1, current_class, @1);
 317        symbol_type_set ($1, current_type, @1);
 318      }
 319 | ID INT
 320     {
 321       symbol_class_set ($1, current_class, @1);
 322       symbol_type_set ($1, current_type, @1);
 323       symbol_user_token_number_set ($1, $2, @2);
 324     }
 325 | ID string_as_id
 326     {
 327       symbol_class_set ($1, current_class, @1);
 328       symbol_type_set ($1, current_type, @1);
 329       symbol_make_alias ($1, $2, @$);
 330     }
 331 | ID INT string_as_id
 332     {
 333       symbol_class_set ($1, current_class, @1);
 334       symbol_type_set ($1, current_type, @1);
 335       symbol_user_token_number_set ($1, $2, @2);
 336       symbol_make_alias ($1, $3, @$);
 337     }
 338 ;
 339
 340 /* One or more symbol definitions. */
 341 symbol_defs.1:
 342   symbol_def
 343 | symbol_defs.1 symbol_def
 344 ;
 345
 346
 347         /*------------------------------------------.
 348         | The grammar section: between the two %%.  |
 349         `------------------------------------------*/
 350
 351 grammar:
 352   rules_or_grammar_declaration
 353 | grammar rules_or_grammar_declaration
 354 ;
 355
 356 /* As a Bison extension, one can use the grammar declarations in the
 357    body of the grammar.  */
 358 rules_or_grammar_declaration:
 359   rules
 360 | grammar_declaration ";"
 361     {
 362       if (yacc_flag)
 363         complain_at (@$, _("POSIX forbids declarations in the grammar"));
 364     }
 365 | error ";"
 366     {
 367       yyerrok;
 368     }
 369 ;
 370
 371 rules:
 372   ID_COLON { current_lhs = $1; current_lhs_location = @1; } rhses.1
 373 ;
 374
 375 rhses.1:
 376   rhs                { grammar_rule_end (@1); }
 377 | rhses.1 "|" rhs    { grammar_rule_end (@3); }
 378 | rhses.1 ";"
 379 ;
 380
 381 rhs:
 382   /* Nothing.  */
 383     { grammar_rule_begin (current_lhs, current_lhs_location); }
 384 | rhs symbol
 385     { grammar_current_rule_symbol_append ($2, @2); }
 386 | rhs action
 387     { grammar_current_rule_action_append ($2, @2); }
 388 | rhs "%prec" symbol
 389     { grammar_current_rule_prec_set ($3, @3); }
 390 | rhs "%dprec" INT
 391     { grammar_current_rule_dprec_set ($3, @3); }
 392 | rhs "%merge" TYPE
 393     { grammar_current_rule_merge_set ($3, @3); }
 394 ;
 395
 396 symbol:
 397   ID              { $$ = $1; }
 398 | string_as_id    { $$ = $1; }
 399 ;
 400
 401 action:
 402   BRACED_CODE
 403    { $$ = $1; }
 404 ;
 405
 406 /* A string used as an ID: we have to keep the quotes. */
 407 string_as_id:
 408   STRING
 409     {
 410       $$ = symbol_get ($1, @1);
 411       symbol_class_set ($$, token_sym, @1);
 412     }
 413 ;
 414
 415 /* A string used for its contents.  Strip the quotes. */
 416 string_content:
 417   STRING
 418     {
 419       $$ = $1 + 1;
 420       $$[strlen ($$) - 1] = '\0';
 421     };
 422
 423
 424 epilogue.opt:
 425   /* Nothing.  */
 426 | "%%" EPILOGUE
 427     {
 428       muscle_code_grow ("epilogue", $2, @2);
 429       scanner_last_string_free ();
 430     }
 431 ;
 432
 433 %%
 434
 435
 436 /* Return the location of the left-hand side of a rule whose
 437    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 438    the right-hand side, and return an empty location equal to the end
 439    boundary of RHS[0] if the right-hand side is empty.  */
 440
 441 static YYLTYPE
 442 lloc_default (YYLTYPE const *rhs, int n)
 443 {
 444   int i;
 445   YYLTYPE loc;
 446   loc.start = loc.end = rhs[n].end;
 447
 448   /* Ignore empty nonterminals the start of the the right-hand side.
 449      Do not bother to ignore them at the end of the right-hand side,
 450      since empty nonterminals have the same end as their predecessors.  */
 451   for (i = 1; i <= n; i++)
 452     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 453       {
 454         loc.start = rhs[i].start;
 455         break;
 456       }
 457
 458   return loc;
 459 }
 460
 461
 462 /* Add a lex-param or a parse-param (depending on TYPE) with
 463    declaration DECL and location LOC.  */
 464
 465 static void
 466 add_param (char const *type, char *decl, location loc)
 467 {
 468   static char const alphanum[] =
 469     "0123456789"
 470     "abcdefghijklmnopqrstuvwxyz"
 471     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 472     "_";
 473   char const *alpha = alphanum + 10;
 474   char const *name_start = NULL;
 475   char *p;
 476
 477   for (p = decl; *p; p++)
 478     if ((p == decl || ! strchr (alphanum, p[-1])) && strchr (alpha, p[0]))
 479       name_start = p;
 480
 481   /* Strip the surrounding '{' and '}'.  */
 482   decl++;
 483   p[-1] = '\0';
 484
 485   if (! name_start)
 486     complain_at (loc, _("missing identifier in parameter declaration"));
 487   else
 488     {
 489       char *name;
 490       size_t name_len;
 491
 492       for (name_len = 1;
 493            name_start[name_len] && strchr (alphanum, name_start[name_len]);
 494            name_len++)
 495         continue;
 496
 497       name = xmalloc (name_len + 1);
 498       memcpy (name, name_start, name_len);
 499       name[name_len] = '\0';
 500       muscle_pair_list_grow (type, decl, name);
 501       free (name);
 502     }
 503
 504   scanner_last_string_free ();
 505 }
 506
 507 /*----------------------------------------------------.
 508 | When debugging the parser, display tokens' values.  |
 509 `----------------------------------------------------*/
 510
 511 static void
 512 print_token_value (FILE *file, int type, YYSTYPE const *value)
 513 {
 514   fputc (' ', file);
 515   switch (type)
 516     {
 517     case ID:
 518       fprintf (file, " = %s", value->symbol->tag);
 519       break;
 520
 521     case INT:
 522       fprintf (file, " = %d", value->integer);
 523       break;
 524
 525     case STRING:
 526       fprintf (file, " = \"%s\"", value->chars);
 527       break;
 528
 529     case TYPE:
 530       fprintf (file, " = <%s>", value->uniqstr);
 531       break;
 532
 533     case BRACED_CODE:
 534     case PERCENT_DESTRUCTOR:
 535     case PERCENT_LEX_PARAM:
 536     case PERCENT_PARSE_PARAM:
 537     case PERCENT_PRINTER:
 538     case PERCENT_UNION:
 539     case PROLOGUE:
 540     case EPILOGUE:
 541       fprintf (file, " = {{ %s }}", value->chars);
 542       break;
 543
 544     default:
 545       fprintf (file, "unknown token type");
 546       break;
 547     }
 548 }
 549
 550 static void
 551 gram_error (location const *loc, char const *msg)
 552 {
 553   complain_at (*loc, "%s", msg);
 554 }
 555
 556 char const *
 557 token_name (int type)
 558 {
 559   return yytname[type];
 560 }