data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4
   5 # Copyright (C) 2002, 2004-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, YEARS)
  26 # --------------------------
  27 m4_define([b4_copyright],
  28 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  29
  30 b4_comment([$1
  31
  32 m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [   ])
  33
  34 This program is free software: you can redistribute it and/or modify
  35 it under the terms of the GNU General Public License as published by
  36 the Free Software Foundation, either version 3 of the License, or
  37 (at your option) any later version.
  38
  39 This program is distributed in the hope that it will be useful,
  40 but WITHOUT ANY WARRANTY; without even the implied warranty of
  41 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  42 GNU General Public License for more details.
  43
  44 You should have received a copy of the GNU General Public License
  45 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  46
  47 b4_comment([As a special exception, you may create a larger work that contains
  48 part or all of the Bison parser skeleton and distribute that work
  49 under terms of your choice, so long as that work isn't itself a
  50 parser generator using the skeleton or a modified version thereof
  51 as a parser skeleton.  Alternatively, if you modify or redistribute
  52 the parser skeleton itself, you may (at your option) remove this
  53 special exception, which will cause the skeleton and the resulting
  54 Bison output files to be licensed under the GNU General Public
  55 License without this special exception.
  56
  57 This special exception was added by the Free Software Foundation in
  58 version 2.2 of Bison.])])
  59
  60
  61 ## ---------------- ##
  62 ## Error handling.  ##
  63 ## ---------------- ##
  64
  65 # The following error handling macros print error directives that should not
  66 # become arguments of other macro invocations since they would likely then be
  67 # mangled.  Thus, they print to stdout directly.
  68
  69 # b4_cat(TEXT)
  70 # ------------
  71 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  72 # escaped.  For example:
  73 #
  74 #   b4_cat([[@complain(invalid input@)]])
  75 m4_define([b4_cat],
  76 [m4_syscmd([cat <<'_m4eof'
  77 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  78 _m4eof
  79 ])dnl
  80 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  81
  82 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  83 # -------------------------------------------
  84 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  85 #
  86 # For example:
  87 #
  88 #   b4_error([[warn]], [[invalid value for '%s': %s]], [[foo]], [[3]])
  89 m4_define([b4_error],
  90 [b4_cat([[@]$1[(]$2[]]dnl
  91 [m4_if([$#], [2], [],
  92        [m4_foreach([b4_arg],
  93                    m4_dquote(m4_shift(m4_shift($@))),
  94                    [[@,]b4_arg])])[@)]])])
  95
  96 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
  97 # ----------------------------------------------------------
  98 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
  99 #
 100 # For example:
 101 #
 102 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 103 #               [[invalid %s]], [[foo]])
 104 m4_define([b4_error_at],
 105 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 106 [m4_if([$#], [4], [],
 107        [m4_foreach([b4_arg],
 108                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 109                    [[@,]b4_arg])])[@)]])])
 110
 111 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 112 # ------------------------------------
 113 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 114 #
 115 # For example:
 116 #
 117 #   b4_warn([[invalid value for '%s': %s]], [[foo]], [[3]])
 118 #
 119 # As a simple test suite, this:
 120 #
 121 #   m4_divert(-1)
 122 #   m4_define([asdf], [ASDF])
 123 #   m4_define([fsa], [FSA])
 124 #   m4_define([fdsa], [FDSA])
 125 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 126 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 127 #   b4_warn()
 128 #   b4_warn(1)
 129 #   b4_warn(1, 2)
 130 #
 131 # Should produce this without newlines:
 132 #
 133 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 134 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 135 #   @warn(@)
 136 #   @warn(1@)
 137 #   @warn(1@,2@)
 138 m4_define([b4_warn],
 139 [b4_error([[warn]], $@)])
 140
 141 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 142 # ---------------------------------------------------
 143 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 144 #
 145 # For example:
 146 #
 147 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 148 m4_define([b4_warn_at],
 149 [b4_error_at([[warn]], $@)])
 150
 151 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 152 # ----------------------------------------
 153 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 154 #
 155 # See b4_warn example.
 156 m4_define([b4_complain],
 157 [b4_error([[complain]], $@)])
 158
 159 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 160 # -------------------------------------------------------
 161 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 162 #
 163 # See b4_warn_at example.
 164 m4_define([b4_complain_at],
 165 [b4_error_at([[complain]], $@)])
 166
 167 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 168 # -------------------------------------
 169 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 170 #
 171 # See b4_warn example.
 172 m4_define([b4_fatal],
 173 [b4_error([[fatal]], $@)dnl
 174 m4_exit(1)])
 175
 176 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 177 # ----------------------------------------------------
 178 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 179 #
 180 # See b4_warn_at example.
 181 m4_define([b4_fatal_at],
 182 [b4_error_at([[fatal]], $@)dnl
 183 m4_exit(1)])
 184
 185
 186 ## ---------------- ##
 187 ## Default values.  ##
 188 ## ---------------- ##
 189
 190 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 191 m4_define_default([b4_pre_prologue], [])
 192 m4_define_default([b4_post_prologue], [])
 193 m4_define_default([b4_epilogue], [])
 194 m4_define_default([b4_parse_param], [])
 195
 196 # The initial column and line.
 197 m4_define_default([b4_location_initial_column], [1])
 198 m4_define_default([b4_location_initial_line],   [1])
 199
 200
 201 ## ------------ ##
 202 ## Data Types.  ##
 203 ## ------------ ##
 204
 205 # b4_ints_in(INT1, INT2, LOW, HIGH)
 206 # ---------------------------------
 207 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 208 m4_define([b4_ints_in],
 209 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 210
 211
 212
 213 ## ------------------ ##
 214 ## Decoding options.  ##
 215 ## ------------------ ##
 216
 217 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 218 # -----------------------------------
 219 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 220 m4_define([b4_flag_if],
 221 [m4_case(b4_$1_flag,
 222          [0], [$3],
 223          [1], [$2],
 224          [m4_fatal([invalid $1 value: ]$1)])])
 225
 226
 227 # b4_define_flag_if(FLAG)
 228 # -----------------------
 229 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 230 # value of the Boolean FLAG.
 231 m4_define([b4_define_flag_if],
 232 [_b4_define_flag_if($[1], $[2], [$1])])
 233
 234 # _b4_define_flag_if($1, $2, FLAG)
 235 # --------------------------------
 236 # Work around the impossibility to define macros inside macros,
 237 # because issuing `[$1]' is not possible in M4.  GNU M4 should provide
 238 # $$1 a la M5/TeX.
 239 m4_define([_b4_define_flag_if],
 240 [m4_if([$1$2], $[1]$[2], [],
 241        [m4_fatal([$0: Invalid arguments: $@])])dnl
 242 m4_define([b4_$3_if],
 243           [b4_flag_if([$3], [$1], [$2])])])
 244
 245
 246 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 247 # -----------------------------
 248 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 249 b4_define_flag_if([defines])            # Whether headers are requested.
 250 b4_define_flag_if([error_verbose])      # Whether error are verbose.
 251 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 252 b4_define_flag_if([locations])          # Whether locations are tracked.
 253 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 254 b4_define_flag_if([token_table])        # Whether yytoken_table is demanded.
 255 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 256
 257 # yytoken_table is needed to support verbose errors.
 258 b4_error_verbose_if([m4_define([b4_token_table_flag], [1])])
 259
 260
 261 ## ------------------------- ##
 262 ## Assigning token numbers.  ##
 263 ## ------------------------- ##
 264
 265
 266 ## ----------- ##
 267 ## Synclines.  ##
 268 ## ----------- ##
 269
 270 # b4_basename(NAME)
 271 # -----------------
 272 # Similar to POSIX basename; the differences don't matter here.
 273 # Beware that NAME is not evaluated.
 274 m4_define([b4_basename],
 275 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 276
 277
 278 # b4_syncline(LINE, FILE)
 279 # -----------------------
 280 m4_define([b4_syncline],
 281 [b4_flag_if([synclines], [
 282 b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 283 b4_sync_start([$1], [$2])])])
 284
 285 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 286 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 287
 288 # b4_user_code(USER-CODE)
 289 # -----------------------
 290 # Emit code from the user, ending it with synclines.
 291 m4_define([b4_user_code],
 292 [$1
 293 b4_syncline([@oline@], [@ofile@])])
 294
 295
 296 # b4_define_user_code(MACRO)
 297 # --------------------------
 298 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 299 m4_define([b4_define_user_code],
 300 [m4_define([b4_user_$1],
 301 [b4_user_code([b4_$1])])])
 302
 303
 304 # b4_user_actions
 305 # b4_user_initial_action
 306 # b4_user_post_prologue
 307 # b4_user_pre_prologue
 308 # b4_user_stype
 309 # ----------------------
 310 # Macros that issue user code, ending with synclines.
 311 b4_define_user_code([actions])
 312 b4_define_user_code([initial_action])
 313 b4_define_user_code([post_prologue])
 314 b4_define_user_code([pre_prologue])
 315 b4_define_user_code([stype])
 316
 317
 318 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 319 # -----------------------------------------------------
 320 # Complain if any name of type WHAT is used by the user (as recorded in
 321 # USER-LIST) but is not used by Bison (as recorded by macros in the
 322 # namespace BISON-NAMESPACE).
 323 #
 324 # USER-LIST must expand to a list specifying all user occurrences of all names
 325 # of type WHAT.   Each item in the list must be a triplet specifying one
 326 # occurrence: name, start boundary, and end boundary.  Empty string names are
 327 # fine.  An empty list is fine.
 328 #
 329 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 330 # name occurrences and with correct quoting:
 331 #
 332 #   m4_define([b4_foo_user_names],
 333 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 334 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 335 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 336 #
 337 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 338 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 339 # are fine, but it would be ugly for Bison to actually use one.
 340 #
 341 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 342 # the names bar and baz are used by Bison:
 343 #
 344 #   m4_define([b4_foo_bison_names(bar)])
 345 #   m4_define([b4_foo_bison_names(baz)])
 346 #
 347 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 348 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 349 # quoting:
 350 #
 351 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 352 #                       [[b4_foo_bison_names]])
 353 m4_define([b4_check_user_names],
 354 [m4_foreach([b4_occurrence], $2,
 355 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 356 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 357 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 358 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 359 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 360           [b4_complain_at([b4_start], [b4_end],
 361                           [[%s '%s' is not used]],
 362                           [$1], [b4_user_name])])[]dnl
 363 m4_popdef([b4_occurrence])dnl
 364 m4_popdef([b4_user_name])dnl
 365 m4_popdef([b4_start])dnl
 366 m4_popdef([b4_end])dnl
 367 ])])
 368
 369
 370
 371
 372 ## --------------------- ##
 373 ## b4_percent_define_*.  ##
 374 ## --------------------- ##
 375
 376
 377 # b4_percent_define_use(VARIABLE)
 378 # -------------------------------
 379 # Declare that VARIABLE was used.
 380 m4_define([b4_percent_define_use],
 381 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 382 ])
 383
 384 # b4_percent_define_get(VARIABLE, [DEFAULT])
 385 # ------------------------------------------
 386 # Mimic muscle_percent_define_get in ../src/muscle-tab.h.  That is, if
 387 # the %define variable VARIABLE is defined, emit its value.  Contrary
 388 # to its C counterpart, return DEFAULT otherwise.  Also, record
 389 # Bison's usage of VARIABLE by defining
 390 # b4_percent_define_bison_variables(VARIABLE).
 391 #
 392 # For example:
 393 #
 394 #   b4_percent_define_get([[foo]])
 395 m4_define([b4_percent_define_get],
 396 [b4_percent_define_use([$1])dnl
 397 m4_ifdef([b4_percent_define(]$1[)],
 398          [m4_indir([b4_percent_define(]$1[)])],
 399          [$2])])
 400
 401
 402 # b4_percent_define_get_loc(VARIABLE)
 403 # -----------------------------------
 404 # Mimic muscle_percent_define_get_loc in ../src/muscle-tab.h exactly.  That is,
 405 # if the %define variable VARIABLE is undefined, complain fatally since that's
 406 # a Bison or skeleton error.  Otherwise, return its definition location in a
 407 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 408 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 409 # reason to suspect that the user-supplied value has yet influenced the output.
 410 #
 411 # For example:
 412 #
 413 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 414 m4_define([b4_percent_define_get_loc],
 415 [m4_ifdef([b4_percent_define_loc(]$1[)],
 416           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 417 b4_loc[]dnl
 418 m4_popdef([b4_loc])],
 419           [b4_fatal([[b4_percent_define_get_loc: undefined %%define variable '%s']], [$1])])])
 420
 421 # b4_percent_define_get_syncline(VARIABLE)
 422 # ----------------------------------------
 423 # Mimic muscle_percent_define_get_syncline in ../src/muscle-tab.h exactly.
 424 # That is, if the %define variable VARIABLE is undefined, complain fatally
 425 # since that's a Bison or skeleton error.  Otherwise, return its definition
 426 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 427 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 428 # influenced the output.
 429 #
 430 # For example:
 431 #
 432 #   b4_percent_define_get_syncline([[foo]])
 433 m4_define([b4_percent_define_get_syncline],
 434 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 435           [m4_indir([b4_percent_define_syncline(]$1[)])],
 436           [b4_fatal([[b4_percent_define_get_syncline: undefined %%define variable '%s']], [$1])])])
 437
 438 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 439 # ------------------------------------------------------
 440 # Mimic muscle_percent_define_ifdef in ../src/muscle-tab.h exactly.  That is,
 441 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 442 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 443 # b4_percent_define_bison_variables(VARIABLE).
 444 #
 445 # For example:
 446 #
 447 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 448 m4_define([b4_percent_define_ifdef],
 449 [m4_ifdef([b4_percent_define(]$1[)],
 450           [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
 451           [$3])])
 452
 453 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 454 # --------------------------------------------------------
 455 # Mimic muscle_percent_define_flag_if in ../src/muscle-tab.h exactly.  That is,
 456 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 457 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 458 # (a Bison or skeleton error since the default value should have been set
 459 # already) or defined to any other value (possibly a user error).  Also, record
 460 # Bison's usage of VARIABLE by defining
 461 # b4_percent_define_bison_variables(VARIABLE).
 462 #
 463 # For example:
 464 #
 465 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 466 m4_define([b4_percent_define_flag_if],
 467 [b4_percent_define_ifdef([$1],
 468   [m4_case(b4_percent_define_get([$1]),
 469            [], [$2], [true], [$2], [false], [$3],
 470            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 471                                            [[invalid value for %%define Boolean variable '%s']],
 472                                            [$1])],
 473                            [[b4_percent_define_flag_if($1)]])])],
 474   [b4_fatal([[b4_percent_define_flag_if: undefined %%define variable '%s']], [$1])])])
 475
 476 # b4_percent_define_default(VARIABLE, DEFAULT)
 477 # --------------------------------------------
 478 # Mimic muscle_percent_define_default in ../src/muscle-tab.h exactly.  That is,
 479 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 480 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 481 # suspect that the value has yet influenced the output.
 482 #
 483 # For example:
 484 #
 485 #   b4_percent_define_default([[foo]], [[default value]])
 486 m4_define([b4_percent_define_default],
 487 [m4_ifndef([b4_percent_define(]$1[)],
 488            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 489             m4_define([b4_percent_define_loc(]$1[)],
 490                       [[[[<skeleton default value>:-1.-1]],
 491                         [[<skeleton default value>:-1.-1]]]])dnl
 492             m4_define([b4_percent_define_syncline(]$1[)], [[]])])])
 493
 494 # b4_percent_define_check_values(VALUES)
 495 # --------------------------------------
 496 # Mimic muscle_percent_define_check_values in ../src/muscle-tab.h exactly
 497 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 498 # is a list of sublists of strings.  For each sublist, the first string is the
 499 # name of a %define variable, and all remaining strings in that sublist are the
 500 # valid values for that variable.  Complain if such a variable is undefined (a
 501 # Bison error since the default value should have been set already) or defined
 502 # to any other value (possibly a user error).  Don't record this as a Bison
 503 # usage of the variable as there's no reason to suspect that the value has yet
 504 # influenced the output.
 505 #
 506 # For example:
 507 #
 508 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 509 #                                  [[[[bar]], [[bar-value1]]]])
 510 m4_define([b4_percent_define_check_values],
 511 [m4_foreach([b4_sublist], m4_quote($@),
 512             [_b4_percent_define_check_values(b4_sublist)])])
 513
 514 m4_define([_b4_percent_define_check_values],
 515 [m4_ifdef([b4_percent_define(]$1[)],
 516   [m4_pushdef([b4_good_value], [0])dnl
 517    m4_if($#, 1, [],
 518          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 519                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 520                             [m4_define([b4_good_value], [1])])])])dnl
 521    m4_if(b4_good_value, [0],
 522          [b4_complain_at(b4_percent_define_get_loc([$1]),
 523                          [[invalid value for %%define variable '%s': '%s']],
 524                          [$1],
 525                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))
 526           m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 527                      [b4_complain_at(b4_percent_define_get_loc([$1]),
 528                                      [[accepted value: '%s']],
 529                                      m4_dquote(b4_value))])])dnl
 530    m4_popdef([b4_good_value])],
 531   [b4_fatal([[b4_percent_define_check_values: undefined %%define variable '%s']], [$1])])])
 532
 533 # b4_percent_code_get([QUALIFIER])
 534 # --------------------------------
 535 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 536 # comment and ending with synclines and a newline.  If QUALIFIER is not
 537 # specified or empty, do this for the unqualified %code blocks.  Also, record
 538 # Bison's usage of QUALIFIER (if specified) by defining
 539 # b4_percent_code_bison_qualifiers(QUALIFIER).
 540 #
 541 # For example, to emit any unqualified %code blocks followed by any %code
 542 # blocks for the qualifier foo:
 543 #
 544 #   b4_percent_code_get
 545 #   b4_percent_code_get([[foo]])
 546 m4_define([b4_percent_code_get],
 547 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 548 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 549 m4_ifdef(b4_macro_name,
 550 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 551                    [["%code ]$1["]])[ blocks.]])
 552 b4_user_code([m4_indir(b4_macro_name)])
 553 ])dnl
 554 m4_popdef([b4_macro_name])])
 555
 556 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 557 # -----------------------------------------------------
 558 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 559 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 560 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 561 # b4_percent_code_bison_qualifiers(QUALIFIER).
 562 m4_define([b4_percent_code_ifdef],
 563 [m4_ifdef([b4_percent_code(]$1[)],
 564           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 565           [$3])])
 566
 567
 568 ## ----------------------------------------------------------- ##
 569 ## After processing the skeletons, check that all the user's   ##
 570 ## %define variables and %code qualifiers were used by Bison.  ##
 571 ## ----------------------------------------------------------- ##
 572
 573 m4_define([b4_check_user_names_wrap],
 574 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 575           [b4_check_user_names([[%]$1 $2],
 576                                [b4_percent_]$1[_user_]$2[s],
 577                                [[b4_percent_]$1[_bison_]$2[s]])])])
 578
 579 m4_wrap_lifo([
 580 b4_check_user_names_wrap([[define]], [[variable]])
 581 b4_check_user_names_wrap([[code]], [[qualifier]])
 582 ])