src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include <strverscmp.h>
  27
  28 #include "complain.h"
  29 #include "conflicts.h"
  30 #include "files.h"
  31 #include "getargs.h"
  32 #include "gram.h"
  33 #include "muscle_tab.h"
  34 #include "quotearg.h"
  35 #include "reader.h"
  36 #include "symlist.h"
  37 #include "scan-gram.h"
  38 #include "scan-code.h"
  39
  40 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  41 static YYLTYPE lloc_default (YYLTYPE const *, int);
  42
  43 #define YY_LOCATION_PRINT(File, Loc) \
  44           location_print (File, Loc)
  45
  46 static void version_check (location const *loc, char const *version);
  47
  48 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  49    FIXME: depends on the undocumented availability of YYLLOC.  */
  50 #undef  yyerror
  51 #define yyerror(Msg) \
  52         gram_error (&yylloc, Msg)
  53 static void gram_error (location const *, char const *);
  54
  55 static char const *char_name (char);
  56
  57 /** Add a lex-param or a parse-param.
  58  *
  59  * \param type  \a lex_param or \a parse_param
  60  * \param decl  the formal argument
  61  * \param loc   the location in the source.
  62  */
  63 static void add_param (char const *type, char *decl, location loc);
  64
  65
  66 static symbol_class current_class = unknown_sym;
  67 static uniqstr current_type = NULL;
  68 static symbol *current_lhs;
  69 static location current_lhs_location;
  70 static int current_prec = 0;
  71
  72 #define YYTYPE_INT16 int_fast16_t
  73 #define YYTYPE_INT8 int_fast8_t
  74 #define YYTYPE_UINT16 uint_fast16_t
  75 #define YYTYPE_UINT8 uint_fast8_t
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86 %expect 0
  87
  88 %initial-action
  89 {
  90   /* Bison's grammar can initial empty locations, hence a default
  91      location is needed. */
  92   boundary_set (&@$.start, current_file, 1, 1);
  93   boundary_set (&@$.end, current_file, 1, 1);
  94 }
  95
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char const *chars;
 102   char *code;
 103   assoc assoc;
 104   uniqstr uniqstr;
 105   unsigned char character;
 106 };
 107
 108 /* Define the tokens together with their human representation.  */
 109 %token GRAM_EOF 0 "end of file"
 110 %token STRING     "string"
 111 %token INT        "integer"
 112
 113 %token PERCENT_TOKEN       "%token"
 114 %token PERCENT_NTERM       "%nterm"
 115
 116 %token PERCENT_TYPE        "%type"
 117 %token PERCENT_DESTRUCTOR  "%destructor"
 118 %token PERCENT_PRINTER     "%printer"
 119
 120 %token PERCENT_LEFT        "%left"
 121 %token PERCENT_RIGHT       "%right"
 122 %token PERCENT_NONASSOC    "%nonassoc"
 123
 124 %token PERCENT_PREC          "%prec"
 125 %token PERCENT_DPREC         "%dprec"
 126 %token PERCENT_MERGE         "%merge"
 127
 128
 129 /*----------------------.
 130 | Global Declarations.  |
 131 `----------------------*/
 132
 133 %token
 134   PERCENT_CODE            "%code"
 135   PERCENT_CODE_TOP        "%code-top"
 136   PERCENT_DEBUG           "%debug"
 137   PERCENT_DEFAULT_PREC    "%default-prec"
 138   PERCENT_DEFINE          "%define"
 139   PERCENT_DEFINES         "%defines"
 140   PERCENT_ERROR_VERBOSE   "%error-verbose"
 141   PERCENT_EXPECT          "%expect"
 142   PERCENT_EXPECT_RR       "%expect-rr"
 143   PERCENT_FILE_PREFIX     "%file-prefix"
 144   PERCENT_GLR_PARSER      "%glr-parser"
 145   PERCENT_INITIAL_ACTION  "%initial-action"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PROVIDES        "%provides"
 156   PERCENT_PURE_PARSER     "%pure-parser"
 157   PERCENT_PUSH_PARSER     "%push-parser"
 158   PERCENT_REQUIRE         "%require"
 159   PERCENT_REQUIRES        "%requires"
 160   PERCENT_SKELETON        "%skeleton"
 161   PERCENT_START           "%start"
 162   PERCENT_TOKEN_TABLE     "%token-table"
 163   PERCENT_VERBOSE         "%verbose"
 164   PERCENT_YACC            "%yacc"
 165 ;
 166
 167 %token BRACED_CODE     "{...}"
 168 %token CHAR            "char"
 169 %token EPILOGUE        "epilogue"
 170 %token EQUAL           "="
 171 %token ID              "identifier"
 172 %token ID_COLON        "identifier:"
 173 %token PERCENT_PERCENT "%%"
 174 %token PIPE            "|"
 175 %token PROLOGUE        "%{...%}"
 176 %token SEMICOLON       ";"
 177 %token TYPE            "type"
 178 %token TYPE_TAG_ANY    "<*>"
 179 %token TYPE_TAG_NONE   "<>"
 180
 181 %type <character> CHAR
 182 %printer { fputs (char_name ($$), stderr); } CHAR
 183
 184 /* braceless is not to be used for rule or symbol actions, as it
 185    calls translate_code. */
 186 %type <chars> STRING "%{...%}" EPILOGUE braceless content content.opt
 187 %type <code> "{...}"
 188 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 189          STRING
 190 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 191          braceless content content.opt "{...}" "%{...%}" EPILOGUE
 192
 193 %type <uniqstr> TYPE ID ID_COLON
 194 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 195 %printer { fputs ($$, stderr); } ID
 196 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 197
 198 %type <integer> INT
 199 %printer { fprintf (stderr, "%d", $$); } INT
 200
 201 %type <symbol> id id_colon symbol string_as_id
 202 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 203 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 204
 205 %type <assoc> precedence_declarator
 206 %type <list>  symbols.1 generic_symlist generic_symlist_item
 207 %%
 208
 209 input:
 210   prologue_declarations "%%" grammar epilogue.opt
 211 ;
 212
 213
 214         /*------------------------------------.
 215         | Declarations: before the first %%.  |
 216         `------------------------------------*/
 217
 218 prologue_declarations:
 219   /* Nothing */
 220 | prologue_declarations prologue_declaration
 221 ;
 222
 223 prologue_declaration:
 224   grammar_declaration
 225 | "%{...%}"     { prologue_augment (translate_code ($1, @1), @1, union_seen); }
 226 | "%debug"                         { debug_flag = true; }
 227 | "%define" STRING content.opt     { muscle_insert ($2, $3); }
 228 | "%defines"                       { defines_flag = true; }
 229 | "%defines" STRING
 230     {
 231       defines_flag = true;
 232       spec_defines_file = xstrdup ($2);
 233     }
 234 | "%error-verbose"                 { error_verbose = true; }
 235 | "%expect" INT                    { expected_sr_conflicts = $2; }
 236 | "%expect-rr" INT                 { expected_rr_conflicts = $2; }
 237 | "%file-prefix" STRING            { spec_file_prefix = $2; }
 238 | "%file-prefix" "=" STRING        { spec_file_prefix = $3; } /* deprecated */
 239 | "%glr-parser"
 240     {
 241       nondeterministic_parser = true;
 242       glr_parser = true;
 243     }
 244 | "%initial-action" "{...}"
 245     {
 246       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 247     }
 248 | "%lex-param" "{...}"          { add_param ("lex_param", $2, @2); }
 249 | "%locations"                  { locations_flag = true; }
 250 | "%name-prefix" STRING         { spec_name_prefix = $2; }
 251 | "%name-prefix" "=" STRING     { spec_name_prefix = $3; } /* deprecated */
 252 | "%no-lines"                   { no_lines_flag = true; }
 253 | "%nondeterministic-parser"    { nondeterministic_parser = true; }
 254 | "%output" STRING              { spec_outfile = $2; }
 255 | "%output" "=" STRING          { spec_outfile = $3; }  /* deprecated */
 256 | "%parse-param" "{...}"        { add_param ("parse_param", $2, @2); }
 257 | "%pure-parser"                { pure_parser = true; }
 258 | "%push-parser"                { push_parser = true; }
 259 | "%require" STRING             { version_check (&@2, $2); }
 260 | "%skeleton" STRING            { skeleton = $2; }
 261 | "%token-table"                { token_table_flag = true; }
 262 | "%verbose"                    { report_flag = report_states; }
 263 | "%yacc"                       { yacc_flag = true; }
 264 | /*FIXME: Err?  What is this horror doing here? */ ";"
 265 ;
 266
 267 grammar_declaration:
 268   precedence_declaration
 269 | symbol_declaration
 270 | "%start" symbol
 271     {
 272       grammar_start_symbol_set ($2, @2);
 273     }
 274 | "%destructor" "{...}" generic_symlist
 275     {
 276       symbol_list *list;
 277       const char *action = translate_symbol_action ($2, @2);
 278       for (list = $3; list; list = list->next)
 279         symbol_list_destructor_set (list, action, @2);
 280       symbol_list_free ($3);
 281     }
 282 | "%printer" "{...}" generic_symlist
 283     {
 284       symbol_list *list;
 285       const char *action = translate_symbol_action ($2, @2);
 286       for (list = $3; list; list = list->next)
 287         symbol_list_printer_set (list, action, @2);
 288       symbol_list_free ($3);
 289     }
 290 | "%default-prec"
 291     {
 292       default_prec = true;
 293     }
 294 | "%no-default-prec"
 295     {
 296       default_prec = false;
 297     }
 298 | "%code" braceless      { prologue_augment ($2, @2, true); }
 299 | "%code-top" braceless  { prologue_augment ($2, @2, false); }
 300 | "%provides" braceless  { muscle_code_grow ("provides", $2, @2); }
 301 | "%requires" braceless  { muscle_code_grow ("requires", $2, @2); }
 302 ;
 303
 304
 305 /*----------*
 306  | %union.  |
 307  *----------*/
 308
 309 %token PERCENT_UNION "%union";
 310
 311 union_name:
 312   /* Nothing. */ {}
 313 | ID             { muscle_code_grow ("union_name", $1, @1); }
 314 ;
 315
 316 grammar_declaration:
 317   "%union" union_name "{...}"
 318     {
 319       char const *body = $3;
 320
 321       /* Concatenate the %union bodies.  If this is the first %union, make sure
 322          the synchronization line appears after the opening '{' so as not to
 323          confuse Doxygen.  Otherwise, turn the previous %union's trailing '}'
 324          into '\n', and omit the new %union's leading '{'.  */
 325       if (!union_seen)
 326         {
 327           muscle_grow ("stype", "{", "");
 328         }
 329       else
 330         {
 331           char *code = muscle_find ("stype");
 332           code[strlen (code) - 1] = '\n';
 333         }
 334       body++;
 335
 336       union_seen = true;
 337       muscle_code_grow ("stype", body, @3);
 338     }
 339 ;
 340
 341
 342
 343
 344 symbol_declaration:
 345   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 346     {
 347       current_class = unknown_sym;
 348       current_type = NULL;
 349     }
 350 | "%token" { current_class = token_sym; } symbol_defs.1
 351     {
 352       current_class = unknown_sym;
 353       current_type = NULL;
 354     }
 355 | "%type" TYPE symbols.1
 356     {
 357       symbol_list *list;
 358       tag_seen = true;
 359       for (list = $3; list; list = list->next)
 360         symbol_type_set (list->content.sym, $2, @2);
 361       symbol_list_free ($3);
 362     }
 363 ;
 364
 365 precedence_declaration:
 366   precedence_declarator type.opt symbols.1
 367     {
 368       symbol_list *list;
 369       ++current_prec;
 370       for (list = $3; list; list = list->next)
 371         {
 372           symbol_type_set (list->content.sym, current_type, @2);
 373           symbol_precedence_set (list->content.sym, current_prec, $1, @1);
 374         }
 375       symbol_list_free ($3);
 376       current_type = NULL;
 377     }
 378 ;
 379
 380 precedence_declarator:
 381   "%left"     { $$ = left_assoc; }
 382 | "%right"    { $$ = right_assoc; }
 383 | "%nonassoc" { $$ = non_assoc; }
 384 ;
 385
 386 type.opt:
 387   /* Nothing. */ { current_type = NULL; }
 388 | TYPE           { current_type = $1; tag_seen = true; }
 389 ;
 390
 391 /* One or more symbols to be %typed. */
 392 symbols.1:
 393   symbol
 394     { $$ = symbol_list_sym_new ($1, @1); }
 395 | symbols.1 symbol
 396     { $$ = symbol_list_prepend ($1, symbol_list_sym_new ($2, @2)); }
 397 ;
 398
 399 generic_symlist:
 400   generic_symlist_item { $$ = $1; }
 401 | generic_symlist generic_symlist_item { $$ = symbol_list_prepend ($1, $2); }
 402 ;
 403
 404 generic_symlist_item:
 405   symbol            { $$ = symbol_list_sym_new ($1, @1); }
 406 | TYPE              { $$ = symbol_list_type_new ($1, @1); }
 407 | "<*>"             { $$ = symbol_list_default_tagged_new (@1); }
 408 | "<>"             { $$ = symbol_list_default_tagless_new (@1); }
 409 ;
 410
 411 /* One token definition.  */
 412 symbol_def:
 413   TYPE
 414      {
 415        current_type = $1;
 416        tag_seen = true;
 417      }
 418 | id
 419      {
 420        symbol_class_set ($1, current_class, @1, true);
 421        symbol_type_set ($1, current_type, @1);
 422      }
 423 | id INT
 424     {
 425       symbol_class_set ($1, current_class, @1, true);
 426       symbol_type_set ($1, current_type, @1);
 427       symbol_user_token_number_set ($1, $2, @2);
 428     }
 429 | id string_as_id
 430     {
 431       symbol_class_set ($1, current_class, @1, true);
 432       symbol_type_set ($1, current_type, @1);
 433       symbol_make_alias ($1, $2, @$);
 434     }
 435 | id INT string_as_id
 436     {
 437       symbol_class_set ($1, current_class, @1, true);
 438       symbol_type_set ($1, current_type, @1);
 439       symbol_user_token_number_set ($1, $2, @2);
 440       symbol_make_alias ($1, $3, @$);
 441     }
 442 ;
 443
 444 /* One or more symbol definitions. */
 445 symbol_defs.1:
 446   symbol_def
 447 | symbol_defs.1 symbol_def
 448 ;
 449
 450
 451         /*------------------------------------------.
 452         | The grammar section: between the two %%.  |
 453         `------------------------------------------*/
 454
 455 grammar:
 456   rules_or_grammar_declaration
 457 | grammar rules_or_grammar_declaration
 458 ;
 459
 460 /* As a Bison extension, one can use the grammar declarations in the
 461    body of the grammar.  */
 462 rules_or_grammar_declaration:
 463   rules
 464 | grammar_declaration ";"
 465 | error ";"
 466     {
 467       yyerrok;
 468     }
 469 ;
 470
 471 rules:
 472   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 473 ;
 474
 475 rhses.1:
 476   rhs                { grammar_current_rule_end (@1); }
 477 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 478 | rhses.1 ";"
 479 ;
 480
 481 rhs:
 482   /* Nothing.  */
 483     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 484 | rhs symbol
 485     { grammar_current_rule_symbol_append ($2, @2); }
 486 | rhs "{...}"
 487     { grammar_current_rule_action_append ($2, @2); }
 488 | rhs "%prec" symbol
 489     { grammar_current_rule_prec_set ($3, @3); }
 490 | rhs "%dprec" INT
 491     { grammar_current_rule_dprec_set ($3, @3); }
 492 | rhs "%merge" TYPE
 493     { grammar_current_rule_merge_set ($3, @3); }
 494 ;
 495
 496
 497 /*-----------*
 498  | content.  |
 499  *-----------*/
 500
 501 content:
 502   STRING
 503 | braceless
 504 ;
 505
 506 /* Some content or "1" by default. */
 507 content.opt:
 508   /* Nothing. */
 509     {
 510       static char one[] = "1";
 511       $$ = one;
 512     }
 513 | content
 514 ;
 515
 516
 517 braceless:
 518   "{...}"
 519     {
 520       $1[strlen ($1) - 1] = '\n';
 521       $$ = translate_code ($1 + 1, @1);
 522     }
 523 ;
 524
 525
 526 /*---------------*
 527  | Identifiers.  |
 528  *---------------*/
 529
 530 /* Identifiers are returned as uniqstr values by the scanner.
 531    Depending on their use, we may need to make them genuine symbols.  */
 532
 533 id:
 534   ID
 535     { $$ = symbol_from_uniqstr ($1, @1); }
 536 | CHAR
 537     {
 538       $$ = symbol_get (char_name ($1), @1);
 539       symbol_class_set ($$, token_sym, @1, false);
 540       symbol_user_token_number_set ($$, $1, @1);
 541     }
 542 ;
 543
 544 id_colon:
 545   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 546 ;
 547
 548
 549 symbol:
 550   id
 551 | string_as_id
 552 ;
 553
 554 /* A string used as an ID: quote it.  */
 555 string_as_id:
 556   STRING
 557     {
 558       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 559       symbol_class_set ($$, token_sym, @1, false);
 560     }
 561 ;
 562
 563 epilogue.opt:
 564   /* Nothing.  */
 565 | "%%" EPILOGUE
 566     {
 567       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 568       gram_scanner_last_string_free ();
 569     }
 570 ;
 571
 572 %%
 573
 574
 575 /* Return the location of the left-hand side of a rule whose
 576    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 577    the right-hand side, and return an empty location equal to the end
 578    boundary of RHS[0] if the right-hand side is empty.  */
 579
 580 static YYLTYPE
 581 lloc_default (YYLTYPE const *rhs, int n)
 582 {
 583   int i;
 584   YYLTYPE loc;
 585
 586   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 587      The bug is fixed in 7.4.2m, but play it safe for now.  */
 588   loc.start = rhs[n].end;
 589   loc.end = rhs[n].end;
 590
 591   /* Ignore empty nonterminals the start of the the right-hand side.
 592      Do not bother to ignore them at the end of the right-hand side,
 593      since empty nonterminals have the same end as their predecessors.  */
 594   for (i = 1; i <= n; i++)
 595     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 596       {
 597         loc.start = rhs[i].start;
 598         break;
 599       }
 600
 601   return loc;
 602 }
 603
 604
 605 /* Add a lex-param or a parse-param (depending on TYPE) with
 606    declaration DECL and location LOC.  */
 607
 608 static void
 609 add_param (char const *type, char *decl, location loc)
 610 {
 611   static char const alphanum[26 + 26 + 1 + 10] =
 612     "abcdefghijklmnopqrstuvwxyz"
 613     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 614     "_"
 615     "0123456789";
 616   char const *name_start = NULL;
 617   char *p;
 618
 619   /* Stop on last actual character.  */
 620   for (p = decl; p[1]; p++)
 621     if ((p == decl
 622          || ! memchr (alphanum, p[-1], sizeof alphanum))
 623         && memchr (alphanum, p[0], sizeof alphanum - 10))
 624       name_start = p;
 625
 626   /* Strip the surrounding '{' and '}', and any blanks just inside
 627      the braces.  */
 628   while (*--p == ' ' || *p == '\t')
 629     continue;
 630   p[1] = '\0';
 631   while (*++decl == ' ' || *decl == '\t')
 632     continue;
 633
 634   if (! name_start)
 635     complain_at (loc, _("missing identifier in parameter declaration"));
 636   else
 637     {
 638       char *name;
 639       size_t name_len;
 640
 641       for (name_len = 1;
 642            memchr (alphanum, name_start[name_len], sizeof alphanum);
 643            name_len++)
 644         continue;
 645
 646       name = xmalloc (name_len + 1);
 647       memcpy (name, name_start, name_len);
 648       name[name_len] = '\0';
 649       muscle_pair_list_grow (type, decl, name);
 650       free (name);
 651     }
 652
 653   gram_scanner_last_string_free ();
 654 }
 655
 656
 657 static void
 658 version_check (location const *loc, char const *version)
 659 {
 660   if (strverscmp (version, PACKAGE_VERSION) > 0)
 661     {
 662       complain_at (*loc, "require bison %s, but have %s",
 663                    version, PACKAGE_VERSION);
 664       exit (63);
 665     }
 666 }
 667
 668 static void
 669 gram_error (location const *loc, char const *msg)
 670 {
 671   complain_at (*loc, "%s", msg);
 672 }
 673
 674 char const *
 675 token_name (int type)
 676 {
 677   return yytname[YYTRANSLATE (type)];
 678 }
 679
 680 static char const *
 681 char_name (char c)
 682 {
 683   if (c == '\'')
 684     return "'\\''";
 685   else
 686     {
 687       char buf[4];
 688       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 689       return quotearg_style (escape_quoting_style, buf);
 690     }
 691 }