tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 # We want a recent Autotest.
  22 m4_version_prereq([2.58])
  23
  24
  25 ## ------------------------------- ##
  26 ## Macros decoding Bison options.  ##
  27 ## ------------------------------- ##
  28
  29
  30 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  31 # -----------------------------------------
  32 m4_define([AT_BISON_OPTION_PUSHDEFS],
  33 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  34
  35
  36 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  37 # --------------------------------------------------
  38 # This macro works around the impossibility to define macros
  39 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  40 # This sucks hard, GNU M4 should really provide M5 like $$1.
  41 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  42 [m4_if([$1$2], $[1]$[2], [],
  43        [m4_fatal([$0: Invalid arguments: $@])])dnl
  44 m4_pushdef([AT_LALR1_CC_IF],
  45 [m4_bmatch([$3], ["lalr1.cc"], [$1], [$2])])
  46 m4_pushdef([AT_GLR_IF],
  47 [m4_bmatch([$3], [%glr-parser], [$1], [$2])])
  48 # Using yacc.c?
  49 m4_pushdef([AT_YACC_IF],
  50 [m4_bmatch([$3], [%glr-parser\|%skeleton], [$2], [$1])])
  51 m4_pushdef([AT_PARAM_IF],
  52 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  53 m4_pushdef([AT_LOCATION_IF],
  54 [m4_bmatch([$3], [%locations], [$1], [$2])])
  55 m4_pushdef([AT_PURE_IF],
  56 [m4_bmatch([$3], [%pure-parser], [$1], [$2])])
  57 m4_pushdef([AT_PURE_AND_LOC_IF],
  58 [m4_bmatch([$3], [%locations.*%pure-parser\|%pure-parser.*%locations],
  59            [$1], [$2])])
  60 m4_pushdef([AT_GLR_OR_PARAM_IF],
  61 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  62
  63 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  64 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  65 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  66                     [$2])])
  67 # yyerror always sees the locations (when activated), except if
  68 # yacc & pure & !param.
  69 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  70 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
  71                                         [$1])],
  72                             [$1])],
  73                 [$2])])
  74
  75 # The interface is pure: either because %pure-parser, or because we
  76 # are using the C++ parsers.
  77 m4_pushdef([AT_PURE_LEX_IF],
  78 [AT_PURE_IF([$1],
  79             [AT_LALR1_CC_IF([$1], [$2])])])
  80
  81 AT_PURE_LEX_IF(
  82 [m4_pushdef([AT_LOC], [(*yylloc)])
  83  m4_pushdef([AT_VAL], [(*yylval)])
  84  m4_pushdef([AT_LEX_FORMALS],
  85             [YYSTYPE *yylval[]AT_LOCATION_IF([, YYLTYPE *yylloc])])
  86  m4_pushdef([AT_LEX_ARGS],
  87             [yylval[]AT_LOCATION_IF([, yylloc])])
  88  m4_pushdef([AT_USE_LEX_ARGS],
  89             [(void) yylval;AT_LOCATION_IF([(void) yylloc])])
  90  m4_pushdef([AT_LEX_PRE_FORMALS],
  91             [AT_LEX_FORMALS, ])
  92  m4_pushdef([AT_LEX_PRE_ARGS],
  93             [AT_LEX_ARGS, ])
  94 ],
  95 [m4_pushdef([AT_LOC], [(yylloc)])
  96  m4_pushdef([AT_VAL], [(yylval)])
  97  m4_pushdef([AT_LEX_FORMALS],     [void])
  98  m4_pushdef([AT_LEX_ARGS],        [])
  99  m4_pushdef([AT_USE_LEX_ARGS],    [])
 100  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 101  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 102 ])
 103 ])# _AT_BISON_OPTION_PUSHDEFS
 104
 105
 106 # AT_BISON_OPTION_POPDEFS
 107 # -----------------------
 108 m4_define([AT_BISON_OPTION_POPDEFS],
 109 [m4_popdef([AT_LEX_PRE_ARGS])
 110 m4_popdef([AT_LEX_PRE_FORMALS])
 111 m4_popdef([AT_USE_LEX_ARGS])
 112 m4_popdef([AT_LEX_ARGS])
 113 m4_popdef([AT_LEX_FORMALS])
 114 m4_popdef([AT_VAL])
 115 m4_popdef([AT_LOC])
 116 m4_popdef([AT_PURE_LEX_IF])
 117 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 118 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 119 m4_popdef([AT_GLR_OR_PARAM_IF])
 120 m4_popdef([AT_PURE_AND_LOC_IF])
 121 m4_popdef([AT_LOCATION_IF])
 122 m4_popdef([AT_PARAM_IF])
 123 m4_popdef([AT_YACC_IF])
 124 m4_popdef([AT_GLR_IF])
 125 m4_popdef([AT_LALR1_CC_IF])
 126 ])# AT_BISON_OPTION_POPDEFS
 127
 128
 129
 130 ## -------------------------- ##
 131 ## Generating Grammar Files.  ##
 132 ## -------------------------- ##
 133
 134
 135 # AT_DATA_GRAMMAR_PROLOGUE
 136 # ------------------------
 137 # The prologue that should be included in any grammar which parser is
 138 # meant to be compiled.
 139 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 140 [[%{
 141 #if HAVE_CONFIG_H
 142 # include <config.h>
 143   /* We don't need perfect functions for these tests. */
 144 # undef malloc
 145 # undef memcmp
 146 # undef realloc
 147 #endif
 148 %}]
 149 ])
 150
 151
 152 # AT_DATA_GRAMMAR(NAME, CONTENT)
 153 # ------------------------------
 154 # Generate the file NAME, which CONTENT is preceded by
 155 # AT_DATA_GRAMMAR_PROLOGUE.
 156 m4_define([AT_DATA_GRAMMAR],
 157 [AT_DATA([$1],
 158 [AT_DATA_GRAMMAR_PROLOGUE
 159 $2])
 160 ])
 161
 162
 163 ## ------------------------ ##
 164 ## Compiling C, C++ Files.  ##
 165 ## ------------------------ ##
 166
 167
 168 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 169 # ----------------------------------------
 170 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 171 # assume that we are linking too; this is a hack.
 172 m4_define([AT_COMPILE],
 173 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])m4_default([$2], [$1.c]) m4_bmatch([$1], [[.]], [], [$LIBS ])-o $1],
 174            0, [ignore], [ignore])])
 175
 176 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.c])
 177 # --------------------------------------------
 178 # If the C++ compiler is not defined, ignore the test.
 179 m4_define([AT_COMPILE_CXX],
 180 [AT_KEYWORDS(c++)
 181 AT_CHECK([$CXX --version || exit 77], 0, ignore, ignore)
 182 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_default([$2], [$1.c]) -o $1],
 183          0, [ignore], [ignore])])
 184
 185
 186
 187 ## ---------------------------- ##
 188 ## Running a generated parser.  ##
 189 ## ---------------------------- ##
 190
 191 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR)
 192 # -----------------------------------------------------
 193 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 194 m4_define([AT_PARSER_CHECK],
 195 [AT_CHECK([$PREPARSER $1], [$2], [$3], [$4])])
 196
 197
 198
 199
 200 ## ----------------------- ##
 201 ## Launch the test suite.  ##
 202 ## ----------------------- ##
 203
 204 AT_INIT
 205
 206 AT_TESTED([bison])