configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl The ONLY thing this is used for is to configure for different
   3 dnl linux architectures and configurations, it is not used to make the
   4 dnl code more portable
   5
   6 dnl You MUST have an environment that has all the POSIX functions and
   7 dnl some of the more populare bsd/sysv ones (like select). You'll also
   8 dnl need a C++ compiler that is semi-standard conformant, exceptions are
   9 dnl not used but STL is.
  10
  11 AC_INIT(configure.in)
  12 AC_CONFIG_AUX_DIR(buildlib)
  13 AC_CONFIG_HEADER(include/config.h:buildlib/config.h.in)
  14
  15 dnl Tom's host stuff
  16 tl_CHECK_TOOL_PREFIX    dnl Initial guess
  17
  18 dnl Check our C compiler
  19 tl_PROG_CC
  20 AC_ISC_POSIX
  21
  22 dnl Check the host arch (build+target not needed... yet)
  23 tl_CANONICAL_HOST
  24 tl_CHECK_TOOL_PREFIX    dnl recheck, in case the initial guess was wrong
  25
  26 dnl Check for other programs
  27 tl_PROG_CXX
  28 AC_LANG_CPLUSPLUS
  29
  30 dnl Checks for X11
  31 AC_PATH_X
  32 AC_PATH_XTRA
  33 AC_SUBST(X11LIB)
  34 X11LIB=
  35 if test "$no_x" != "yes"; then
  36   X11LIB="-lX11"
  37   AC_DEFINE(HAVE_X11)
  38   dnl Checks for Slang
  39   AC_CHECK_LIB(Xpm, XpmLibraryVersion,[AC_DEFINE(HAVE_LIBXPM) XPMLIB="-lXpm"],,$X_LIBS $X_PRE_LIBS $X11LIB $X_EXTRA_LIBS)
  40   AC_SUBST(XPMLIB)
  41   if test "$XPMLIB" != "-lXpm"; then
  42      AC_MSG_ERROR(failed: I need xpm if you are building for X)
  43   fi
  44 fi
  45
  46 dnl Checks for Slang
  47 AC_CHECK_LIB(slang, init_SLang,[AC_DEFINE(HAVE_LIBSLANG) SLANGLIB="-lslang"])
  48 AC_SUBST(SLANGLIB)
  49
  50 dnl Checks for GPM
  51 AC_ARG_WITH(gpm,[  --without-gpm                  do not use GPM mouse support])
  52 if test "$with_gpm" != "no"; then
  53   AC_CHECK_LIB(gpm, Gpm_Open,[AC_DEFINE(HAVE_LIBGPM) GPMLIB="-lgpm"])
  54   AC_SUBST(GPMLIB)
  55 fi
  56
  57 dnl Converts the ARCH to be the same as dpkg
  58 AC_MSG_CHECKING(system architecture)
  59 archset="`awk '$1 == "'$host_cpu'" { print $2 }' $srcdir/buildlib/archtable`"
  60 if test "x$archset" = "x"; then
  61   AC_MSG_ERROR(failed: use --host=)
  62 fi
  63 AC_MSG_RESULT($archset)
  64 AC_DEFINE_UNQUOTED(PKG_DEB_ARCH,"$archset")
  65
  66 dnl Check the sizes etc. of the architecture
  67 changequote(,)
  68 if archline="`sed -ne 's/^'$archset':[  ]\+\(.*\)/\1/gp' $srcdir/buildlib/sizetable`"; then
  69 changequote([,])
  70   set $archline
  71   if test "$1" = "little"; then
  72     ac_cv_c_bigendian=no
  73   else
  74     ac_cv_c_bigendian=yes
  75   fi
  76   size_char=$2
  77   size_int=$3
  78   size_short=$4
  79   size_long=$5
  80 fi
  81 if test "$cross_compiling" = "yes" -a "$archline" = ""; then
  82   AC_MSG_ERROR(When cross compiling, architecture must be present in sizetable)
  83 fi
  84 AC_C_BIGENDIAN
  85 AC_CHECK_SIZEOF(char,$size_char)
  86 AC_CHECK_SIZEOF(int,$size_int)
  87 AC_CHECK_SIZEOF(short,$size_short)
  88 AC_CHECK_SIZEOF(long,$size_long)
  89
  90 dnl Check for debiandoc
  91 AC_CHECK_PROG(DEBIANDOC_HTML,debiandoc2html,"yes","")
  92 AC_CHECK_PROG(DEBIANDOC_TEXT,debiandoc2text,"yes","")
  93
  94 AC_OUTPUT(environment.mak:buildlib/environment.mak.in makefile:buildlib/makefile.in,make dirs)