+AFMINSTALL=
+
+if test "$wxUSE_GUI" = "yes"; then
+ USE_GUI=1
+
+ TOOLKIT=
+ TOOLKIT_INCLUDE=
+
+ GUI_TK_LIBRARY=
+ GUI_TK_LINK=
+
+ WXGTK12=
+ WXGTK127=
+ WXGTK20=
+
+ WXWINE=
+
+ if test "$wxUSE_CYGWIN" = 1 || test "$wxUSE_MINGW" = 1 ; then
+ AC_CHECK_HEADER(windows.h, [],
+ [
+ AC_MSG_ERROR(please set CFLAGS to contain the location of windows.h)
+ ])
+
+ INCLUDE_SUBDIRS="$INCLUDE_SUBDIRS msw"
+
+ dnl --- Quick & Dirty ; link against most/all libraries
+ dnl --- This will bloat the executable, but it'll work for now...
+ LIBS="$LIBS -lkernel32 -luser32 -lgdi32 -lcomdlg32 -lwinspool -lwinmm -lshell32 -lcomctl32 -lctl3d32 -ladvapi32 -lwsock32"
+
+ dnl add extra odbc libs if we have compiled in odbc
+ if test "$wxUSE_ODBC" = "yes" ; then
+ LIBS="$LIBS -lodbc32 -lole32 -loleaut32"
+ fi
+
+ dnl -mwindows is needed to avoid that spawning of a console window
+ if test "$wxUSE_MINGW" = 1; then
+ LDFLAGS="$LDFLAGS -mwindows"
+ fi
+
+ TOOLKIT=MSW
+ GUIDIST=MSW_DIST
+
+ dnl we should calculate these
+ RCINCSWITCH="--include-dir"
+ RCDEFSWITCH="--define"
+ RCPREPROCESSOR="--preprocessor \"\$(CC) -c -E -xc-header -DRC_INVOKED\""
+ RCINPUTSWITCH="-i"
+ RCOUTPUTSWITCH="-o"
+ RESFLAGS="$RCPREPROCESSOR $RCINCSWITCH \$(top_srcdir)/include $RCINCSWITCH \$(top_srcdir)/\$(program_dir) $RCDEFSWITCH __WIN32__ $RCDEFSWITCH __WIN95__ $RCDEFSWITCH __GNUWIN32__"
+
+ dnl set optinal RES_PROGRAM_OPT to RES_PROGRAM
+ RESPROGRAM="\$(RES_PROGRAM)"
+ fi
+
+ if test "$wxUSE_GTK" = 1; then
+ AC_MSG_CHECKING([for GTK+ version])
+
+ gtk_version_cached=1
+ AC_CACHE_VAL(wx_cv_lib_gtk,
+ [
+ dnl stupid GTK+ AM macros produce their own messages, so we
+ dnl have to pass to the next line
+ gtk_version_cached=0
+ AC_MSG_RESULT("")
+
+ wx_cv_lib_gtk=
+ if test "x$wxUSE_GTK2" = "xyes"; then
+ AM_PATH_GTK_2_0(1.3.1, wx_cv_lib_gtk=2.0, gthread)
+ fi
+
+ if test -z "$wx_cv_lib_gtk"; then
+ AM_PATH_GTK(1.2.7, wx_cv_lib_gtk=1.2.7)
+ fi
+
+ if test -z "$wx_cv_lib_gtk"; then
+ AM_PATH_GTK(1.2.3, wx_cv_lib_gtk=1.2.3)
+ fi
+
+ if test -z "$wx_cv_lib_gtk"; then
+ dnl looks better in AC_MSG_RESULT
+ wx_cv_lib_gtk=none
+ else
+ dnl we need to cache GTK_CFLAGS and GTK_LIBS for the
+ dnl subsequent runs
+ wx_cv_cflags_gtk=$GTK_CFLAGS
+ wx_cv_libs_gtk=$GTK_LIBS
+ fi
+ ]
+ )
+
+ dnl if it wasn't cached, the messages from AM_PATH_GTK() above are
+ dnl enough
+ if test "$gtk_version_cached" = 1; then
+ AC_MSG_RESULT($wx_cv_lib_gtk)
+ fi
+
+ case "$wx_cv_lib_gtk" in
+ 2.0) WXGTK20=1
+ ;;
+ 1.2.7) WXGTK127=1
+ WXGTK12=1
+ ;;
+ 1.2.3) WXGTK12=1
+ ;;
+ *) AC_MSG_ERROR([
+Please check that gtk-config is in path, the directory
+where GTK+ libraries are installed (returned by
+'gtk-config --libs' command) is in LD_LIBRARY_PATH or
+equivalent variable and GTK+ is version 1.2.3 or above.
+ ])
+ ;;
+ esac
+
+ TOOLKIT_INCLUDE="$wx_cv_cflags_gtk"
+ GUI_TK_LIBRARY="$wx_cv_libs_gtk"
+
+ AFMINSTALL=afminstall
+ TOOLKIT=GTK
+ GUIDIST=GTK_DIST
+
+ dnl test for XIM support in libgdk
+ AC_CHECK_LIB(gdk, gdk_im_open, AC_DEFINE(HAVE_XIM))
+ fi
+
+ if test "$wxUSE_MGL" = 1; then
+ dnl FIXME_MGL - test for MGL's variants for freebsd etc.
+
+ AC_MSG_CHECKING(for SciTech MGL library)
+ if test "x$MGL_ROOT" = x ; then
+ AC_MSG_RESULT(not found)
+ AC_MSG_ERROR([Cannot find MGL library. Make sure MGL_ROOT is set.])
+ else
+ AC_MSG_RESULT($MGL_ROOT)
+ fi
+
+ MGL_OS=linux/gcc/glibc
+ MGL_LIB_TYPE=""
+
+ if test "$wxUSE_DEBUG_FLAG" = yes ; then
+ if test -f $MGL_ROOT/lib/debug/$MGL_OS/libmgl.a ; then
+ MGL_LIB_TYPE=debug
+ fi
+ fi
+ if test "x$MGL_LIB_TYPE" = x ; then
+ if test -f $MGL_ROOT/lib/release/$MGL_OS/libmgl.a ; then
+ MGL_LIB_TYPE=release
+ else
+ AC_MSG_ERROR([Cannot find MGL libraries, make sure they are compiled.])
+ fi
+ fi
+
+ TOOLKIT_INCLUDE="-I$MGL_ROOT/include"
+ GUI_TK_LIBRARY="-L$MGL_ROOT/lib/$MGL_LIB_TYPE/$MGL_OS -lmgl -lmglcpp -lpm"
+
+ AFMINSTALL=afminstall
+ TOOLKIT=MGL
+ GUIDIST=MGL_DIST
+ fi
+
+ if test "$wxUSE_WINE" = 1; then
+ AC_MSG_CHECKING(for WINE includes)
+ WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, windows.h)
+ if test "$ac_find_includes" != "" ; then
+ AC_MSG_RESULT(found $ac_find_includes)
+ TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE -I$ac_find_includes"
+ else
+ AC_MSG_RESULT(no)
+ AC_MSG_ERROR(please set CFLAGS to contain the location of windows.h)
+ fi
+
+ XPM_LINK=""
+ AC_MSG_CHECKING(for Xpm library)
+ WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
+ if test "$ac_find_libraries" != "" ; then
+ GUI_TK_LIBRARY="-L$ac_find_libraries"
+ XPM_LINK="-lXpm"
+ AC_DEFINE(wxHAVE_LIB_XPM)
+ AC_MSG_RESULT(found at $ac_find_libraries)
+ else
+ AC_MSG_RESULT(no)
+ AC_MSG_WARN(library will be compiled without support for images in XPM format)
+ fi
+
+ MESA_LINK=""
+ AC_MSG_CHECKING(for Mesa library)
+ WX_PATH_FIND_LIBRARIES($SEARCH_LIB,MesaGL)
+ if test "$ac_find_libraries" != "" ; then
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY -L$ac_find_libraries"
+ MESA_LINK="-lMesaGL"
+ AC_MSG_RESULT(found at $ac_find_libraries)
+ else
+ AC_MSG_ERROR(no)
+ fi
+
+ GUI_TK_LINK="-lwine $MESA_LINK $XPM_LINK -lXxf86dga -lXxf86vm -lSM -lICE -lXext -lXmu -lX11 -lncurses"
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY $GUI_TK_LINK"
+ WXWINE=1
+ TOOLKIT=MSW
+ GUIDIST=MSW_DIST
+ fi
+
+ dnl use standard macros to check for X headers/libs, this brings support
+ dnl for the standard configure options --x-includes and --x-libraries;
+ dnl the path to the X headers/libs is not only needed for motif, but also
+ dnl by the OpenGL and XKBlib.h checks further down
+
+ AC_PATH_XTRA
+ CPPFLAGS="$CPPFLAGS $X_CFLAGS"
+ LDFLAGS="$LDFLAGS $X_LIBS"
+
+ if test "$wxUSE_MOTIF" = 1; then
+ if test "$no_x" = "yes"; then
+ AC_MSG_ERROR(X11 not found, please use --x-includes and/or --x-libraries options)
+ fi
+
+ GUI_TK_LIBRARY="$X_LIBS"
+ TOOLKIT_INCLUDE="$X_CFLAGS"
+
+ AFMINSTALL=afminstall
+
+ dnl manual check for X11 headers/libs
+ dnl
+ dnl AC_MSG_CHECKING(for X11 headers)
+ dnl WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, X11/Intrinsic.h)
+ dnl if test "$ac_find_includes" != "" ; then
+ dnl AC_MSG_RESULT(found $ac_find_includes)
+ dnl else
+ dnl AC_MSG_RESULT(no)
+ dnl AC_MSG_ERROR(please set CFLAGS to contain the location of X11/Intrinsic.h)
+ dnl fi
+ dnl
+ dnl AC_MSG_CHECKING(for X11 libraries)
+ dnl WX_PATH_FIND_LIBRARIES($SEARCH_LIB, X11)
+ dnl if test "$ac_find_libraries" != "" ; then
+ dnl WX_INCLUDE_PATH_EXIST($ac_find_includes, $TOOLKIT_INCLUDE)
+ dnl WX_LINK_PATH_EXIST($ac_find_libraries, $GUI_TK_LIBRARY)
+ dnl
+ dnl GUI_TK_LIBRARY="$GUI_TK_LIBRARY $ac_path_to_link"
+ dnl TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE $ac_path_to_include"
+ dnl AC_MSG_RESULT(found at $ac_find_libraries)
+ dnl else
+ dnl AC_MSG_RESULT(no)
+ dnl AC_MSG_ERROR(please set LDFLAGS to contain the location of libX11)
+ dnl fi
+
+ COMPILED_X_PROGRAM=0
+
+ AC_MSG_CHECKING(for Motif/Lesstif headers)
+ WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, Xm/Xm.h)
+ if test "$ac_find_includes" != "" ; then
+ AC_MSG_RESULT(found $ac_find_includes)
+ else
+ AC_TRY_COMPILE(
+ [
+ #include <Xm/Xm.h>
+ ],
+ [
+ int version;
+
+ version = xmUseVersion;
+ ],
+ [
+ AC_MSG_RESULT(found in default search path)
+ COMPILED_X_PROGRAM=1
+ ],
+ [
+ AC_MSG_RESULT(no)
+ AC_MSG_ERROR(please set CFLAGS to contain the location of Xm/Xm.h)
+ ]
+ )
+ fi
+
+ if test "$COMPILED_X_PROGRAM" = 0; then
+ AC_MSG_CHECKING(for Motif/Lesstif library)
+ WX_PATH_FIND_LIBRARIES($SEARCH_LIB, Xm)
+ if test "$ac_find_libraries" != "" ; then
+ WX_INCLUDE_PATH_EXIST($ac_find_includes, $TOOLKIT_INCLUDE)
+ WX_LINK_PATH_EXIST($ac_find_libraries, $GUI_TK_LIBRARY)
+
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY $ac_path_to_link"
+ TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE $ac_path_to_include"
+ AC_MSG_RESULT(found at $ac_find_libraries)
+ else
+ dnl it might happen that we found headers in one of the standard
+ dnl paths but the libs are elsewhere - we do need to try to
+ dnl compile a sample program then here
+ AC_TRY_COMPILE(
+ [
+ #include <Xm/Xm.h>
+ ],
+ [
+ int version;
+
+ version = xmUseVersion;
+ ],
+ [
+ AC_MSG_RESULT(found in default search path)
+ COMPILED_X_PROGRAM=1
+ ],
+ [
+ AC_MSG_RESULT(no)
+ AC_MSG_ERROR(please set LDFLAGS to contain the location of libXm)
+ ]
+ )
+ fi
+ fi
+
+ dnl we don't need this as we used AC_PATH_XTRA above which does it for us
+ dnl
+ dnl dnl if we already compiled a sample program, X libs are surely there
+ dnl if test "$COMPILED_X_PROGRAM" = 0; then
+ dnl AC_MSG_CHECKING(for Xt library)
+ dnl WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xt)
+ dnl if test "$ac_find_libraries" != "" ; then
+ dnl WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
+ dnl GUI_TK_LIBRARY="$GUI_TK_LIBRARY $ac_path_to_link"
+ dnl AC_MSG_RESULT(found at $ac_find_libraries)
+ dnl else
+ dnl AC_TRY_COMPILE
+ dnl (
+ dnl [
+ dnl #include <X11/Intrinsic.h>
+ dnl ],
+ dnl [
+ dnl char *p;
+ dnl p = XtMalloc(5);
+ dnl ],
+ dnl [
+ dnl AC_MSG_RESULT(found in default search path)
+ dnl COMPILED_X_PROGRAM=1
+ dnl ],
+ dnl [
+ dnl AC_MSG_RESULT(no)
+ dnl AC_MSG_ERROR(please set LDFLAGS to contain the location of libXt)
+ dnl ]
+ dnl )
+ dnl fi
+ dnl fi
+
+ XPM_LINK=""
+ AC_MSG_CHECKING(for Xpm library)
+ WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
+ if test "$ac_find_libraries" != "" ; then
+ WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY $ac_path_to_link"
+ XPM_LINK="-lXpm "
+ AC_DEFINE(wxHAVE_LIB_XPM)
+ AC_MSG_RESULT(found at $ac_find_libraries)
+ else
+ AC_TRY_COMPILE(
+ [
+ #include <X11/xpm.h>
+ ],
+ [
+ int version;
+
+ version = XpmLibraryVersion();
+ ],
+ [
+ XPM_LINK="-lXpm "
+ AC_DEFINE(wxHAVE_LIB_XPM)
+ AC_MSG_RESULT(found in default search path)
+ COMPILED_X_PROGRAM=0
+ ],
+ [
+ AC_MSG_RESULT(no)
+ AC_MSG_WARN(library will be compiled without support for images in XPM format)
+ ]
+ )
+ fi
+
+ GUI_TK_LINK="-lXm $XPM_LINK -lXmu -lXext -lXt -lX11"
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY $GUI_TK_LINK"
+ TOOLKIT=MOTIF
+ GUIDIST=MOTIF_DIST
+ fi
+
+ if test "$wxUSE_MAC" = 1; then
+ TOOLKIT=MAC
+ dnl we can't call this MAC_DIST or autoconf thinks its a macro
+ GUIDIST=MACX_DIST
+ fi
+
+ if test "$wxUSE_PM" = 1; then
+ TOOLKIT=PM
+ GUIDIST=GTK_DIST
+ fi
+
+ dnl the name of the directory where the files for this toolkit live
+ if test "$TOOLKIT" != "PM" ; then
+ TOOLKIT_DIR=`echo ${TOOLKIT} | tr "[[A-Z]]" "[[a-z]]"`
+ else
+ TOOLKIT_DIR="os2"
+ fi
+
+ dnl the (base) name of the library and support files for this toolkit
+ TOOLKIT_NAME="${TOOLKIT_DIR}"
+
+ dnl the list of paths containing the files for this toolkit
+ TOOLKIT_VPATH="\${top_srcdir}/src/${TOOLKIT_DIR}"
+
+ dnl need to add an extra dir for wxMotif
+ if test "$TOOLKIT_NAME" = "motif"; then
+ TOOLKIT_VPATH="${TOOLKIT_VPATH}${PATH_IFS}\${top_srcdir}/src/motif/xmcombo"
+ fi
+
+ dnl are we using the generic version with this low level toolkit?
+ if test "$wxUSE_UNIVERSAL" = "yes"; then
+ TOOLKIT_NAME="${TOOLKIT_NAME}univ"
+ UNIV_VPATH="\${top_srcdir}/src/univ${PATH_IFS}\${top_srcdir}/src/univ/themes"
+ TOOLKIT_VPATH="${UNIV_VPATH}${PATH_IFS}${TOOLKIT_VPATH}"
+ SETUPH_DIR="univ"
+ else
+ SETUPH_DIR="${TOOLKIT_DIR}"
+ fi
+
+ dnl append 'd' to the debug library name
+ if test "$wxUSE_DEBUG_FLAG" = "yes"; then
+ TOOLKIT_NAME="${TOOLKIT_NAME}d"
+ fi
+
+ dnl the symbol which allows conditional compilation for the given toolkit
+ TOOLKIT_DEF="-D__WX${TOOLKIT}__"
+ if test "$wxUSE_UNIVERSAL" = "yes"; then
+ TOOLKIT_DEF="${TOOLKIT_DEF} -D__WXUNIVERSAL__"
+ fi
+
+ dnl the name of the (libtool) library
+ WX_LIBRARY="wx_${TOOLKIT_NAME}"
+
+ dnl collect together all the object files for this port
+ if test "$wxUSE_UNIVERSAL" = "yes"; then
+ ALL_OBJECTS="\$(GUI_LOWLEVEL_OBJS) \${UNIVOBJS}"
+ else
+ ALL_OBJECTS="\$(GUIOBJS)"
+ fi
+
+ ALL_OBJECTS="${ALL_OBJECTS} \$(COMMONOBJS) \$(GENERICOBJS)"
+
+ if test "$TOOLKIT" != "MSW"; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(UNIXOBJS)"
+ fi
+
+ if test "$wxUSE_HTML" = "yes"; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(HTMLOBJS)"
+ fi
+
+ dnl ODBC objects are Unix only
+ if test "$TOOLKIT" != "MSW"; then
+ if test "$wxUSE_ODBC" = "yes" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(IODBCOBJS)"
+ fi
+ fi
+
+ dnl REGEX_INCLUDE is only set if we want regex support and if we use our
+ dnl own sources and not the system library
+ if test "x$REGEX_INCLUDE" != "x" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(REGEXOBJS)"
+ fi
+
+ if test "$wxUSE_LIBJPEG" = "yes" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(JPEGOBJS)"
+ fi
+ if test "$wxUSE_LIBTIFF" = "yes" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(TIFFOBJS)"
+ fi
+ if test "$wxUSE_LIBPNG" = "yes" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(PNGOBJS)"
+ fi
+ if test "$wxUSE_ZLIB" = "yes" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(ZLIBOBJS)"
+ fi
+ if test "$wxUSE_FREETYPE" = "yes" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(FREETYPEOBJS)"
+ fi
+
+ dnl collect all .d files together as well
+ if test "$wxUSE_UNIVERSAL" = "yes"; then
+ ALL_DEPFILES="\$(GUI_LOWLEVEL_DEPS) \$(UNIVDEPS)"
+ else
+ ALL_DEPFILES="\$(GUIDEPS)"
+ fi
+
+ ALL_DEPFILES="${ALL_DEPFILES} \$(COMMONDEPS) \$(GENERICDEPS)"
+
+ if test "$TOOLKIT" != "MSW"; then
+ ALL_DEPFILES="${ALL_DEPFILES} \$(UNIXDEPS)"
+ fi
+
+ if test "$wxUSE_HTML" = "yes"; then
+ ALL_DEPFILES="${ALL_DEPFILES} \$(HTMLDEPS)"
+ fi
+
+ dnl misc other files depending on the port
+ PORT_FILES="\${top_srcdir}/src/\$(TOOLKITDIR)/files.lst"
+ if test "$wxUSE_UNIVERSAL" = "yes"; then
+ PORT_FILES="${PORT_FILES} \${top_srcdir}/src/univ/files.lst"
+ fi
+ RPM_FILES="src/\$(TOOLKITDIR)/rpmfiles.lst"
+ RPM_SPEC="wx\$(TOOLKIT).spec"
+
+ dnl distribute samples/demos/utils with GUI versions
+ GUIDIST="${GUIDIST} SAMPLES_DIST DEMOS_DIST UTILS_DIST MISC_DIST"
+ DISTDIR="wx\$(TOOLKIT)"
+else
+ USE_GUI=0
+
+ dnl this may be (almost) unneccesary for wxBase now we use TOOLKIT_NAME
+ TOOLKIT_DIR="base"
+
+ dnl well, we have to set it to something...
+ TOOLKIT_VPATH="."
+
+ dnl the base name of the library and wxXXX-config files
+ if test "$wxUSE_DEBUG_FLAG" = "yes"; then
+ TOOLKIT_NAME="${TOOLKIT_DIR}d"
+ else
+ TOOLKIT_NAME="${TOOLKIT_DIR}"
+ fi
+
+ TOOLKIT_DEF="-D__WXBASE__"
+
+ dnl the sources, their dependenices and the headers
+ ALL_OBJECTS="\$(BASE_OBJS) \$(BASE_UNIX_OBJS)"
+ ALL_DEPFILES="\$(BASE_DEPS) \$(BASE_UNIX_DEPS)"
+
+ dnl REGEX_INCLUDE is only set if we want regex support and if we use our
+ dnl own sources and not the system library
+ if test "x$REGEX_INCLUDE" != "x" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(REGEXOBJS)"
+ fi
+
+ if test "$wxUSE_ZLIB" = "yes" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(ZLIBOBJS)"
+ fi
+
+ dnl building wxBase only
+ WX_LIBRARY="wx_${TOOLKIT_NAME}"
+
+ PORT_FILES="\${top_srcdir}/src/files.lst"
+ RPM_FILES="src/rpmfiles.lst"
+ RPM_SPEC="wxBase.spec"
+
+ dnl distribute only wxBase sources/headers
+ GUIDIST="BASE_DIST"
+ DISTDIR="wxBase"
+fi
+
+dnl the name of the (libtool) library
+WX_LIBRARY_NAME="lib${WX_LIBRARY}.la"
+WX_LIBRARY_NAME_GL="lib${WX_LIBRARY}_gl.la"
+
+dnl the name of the static library
+WX_LIBRARY_NAME_STATIC="lib${WX_LIBRARY}.a"
+WX_LIBRARY_NAME_STATIC_GL="lib${WX_LIBRARY}_gl.a"
+
+dnl the name of the shared library
+WX_LIBRARY_NAME_SHARED="lib${WX_LIBRARY}-${WX_RELEASE}.so.${WX_CURRENT}.${WX_REVISION}.${WX_AGE}"
+WX_LIBRARY_NAME_SHARED_GL="lib${WX_LIBRARY}_gl-${WX_RELEASE}.so.${WX_CURRENT}.${WX_REVISION}.${WX_AGE}"
+
+dnl the name of the links to the shared library
+WX_LIBRARY_LINK1="lib${WX_LIBRARY}-${WX_RELEASE}.so.${WX_CURRENT}"
+WX_LIBRARY_LINK2="lib${WX_LIBRARY}-${WX_RELEASE}.so"
+WX_LIBRARY_LINK3="lib${WX_LIBRARY}.so"
+WX_LIBRARY_LINK1_GL="lib${WX_LIBRARY}_gl-${WX_RELEASE}.so.${WX_CURRENT}"
+WX_LIBRARY_LINK2_GL="lib${WX_LIBRARY}_gl-${WX_RELEASE}.so"
+WX_LIBRARY_LINK3_GL="lib${WX_LIBRARY}_gl.so"
+
+dnl shared library settings
+SHARED_LD=
+PIC_FLAG=
+WX_ALL=
+WX_ALL_INSTALLED=
+BURNT_LIBRARY_NAME=
+WX_TARGET_LIBRARY_SONAME=
+
+dnl --- the marker for quick search, leave it here: SHARED_LIB_SETUP ---
+
+if test "$wxUSE_SHARED" = "yes"; then
+ case "${host}" in
+ *-hp-hpux* )
+ if test "$GCC" = yes ; then
+ SHARED_LD="${CC} -shared -fPIC -o"
+ PIC_FLAG="-fPIC"
+ else
+ dnl no idea why it wants it, but it does
+ LDFLAGS="-L/usr/lib"
+
+ SHARED_LD="${CXX} -b -o"
+ PIC_FLAG="+Z"
+ fi
+ WX_LIBRARY_NAME_SHARED="libwx_${TOOLKIT_NAME}.sl"
+ WX_LIBRARY_NAME_SHARED_GL="libwx_${TOOLKIT_NAME}_gl.sl"
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="preinstall_gl"
+ WX_ALL="${WX_LIBRARY_NAME_SHARED} ${WX_LIBRARY_NAME_SHARED_GL}"
+ else
+ WX_ALL="${WX_LIBRARY_NAME_SHARED}"
+ fi
+ ;;
+
+ dnl in fact, these settings are for any platform using gcc
+ *-*-linux* )
+ SHARED_LD="${CC} -shared -o"
+ PIC_FLAG="-fPIC"
+ if test "$wxUSE_BURNT_NAME" = "yes" ; then
+ BURNT_LIBRARY_NAME="-Wl,-soname,${WX_LIBRARY_LINK1}"
+ BURNT_LIBRARY_NAME_GL="-Wl,-soname,${WX_LIBRARY_LINK1_GL}"
+ dnl substitute this in makelib.env for the contrib libs
+ WX_TARGET_LIBRARY_SONAME="-Wl,-soname,\$(TARGETLIB_LINK1)"
+ fi
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS CREATE_INSTALLED_LINKS_GL"
+ WX_ALL="CREATE_LINKS CREATE_LINKS_GL"
+ else
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ fi
+ ;;
+ *-*-irix5* | *-*-irix6* )
+ if test "$GCC" = yes ; then
+ SHARED_LD="${CC} -shared -o"
+ PIC_FLAG="-fPIC"
+ else
+ SHARED_LD="${CXX} -shared -o"
+ fi
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS CREATE_INSTALLED_LINKS_GL"
+ WX_ALL="CREATE_LINKS CREATE_LINKS_GL"
+ else
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ fi
+ ;;
+ *-*-solaris2* )
+ if test "$GCC" = yes ; then
+ SHARED_LD="${CC} -shared -o"
+ PIC_FLAG="-fPIC"
+
+ dnl newer versions of gcc need -isystem to compile X headers on
+ dnl Solaris (which use old style C syntax)
+ CPPFLAGS="$CPPFLAGS -isystem /usr/openwin/include"
+ else
+ SHARED_LD="${CXX} -G -o"
+ PIC_FLAG="-KPIC"
+ fi
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS CREATE_INSTALLED_LINKS_GL"
+ WX_ALL="CREATE_LINKS CREATE_LINKS_GL"
+ else
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ fi
+ ;;
+ *-*-sunos4* )
+ SHARED_LD="${CC} -shared -o"
+ PIC_FLAG="-fPIC"
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ ;;
+ *-*-freebsd* | *-*-openbsd* | *-*-netbsd* )
+ SHARED_LD="${CC} -shared -o"
+ PIC_FLAG="-fPIC"
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS CREATE_INSTALLED_LINKS_GL"
+ WX_ALL="CREATE_LINKS CREATE_LINKS_GL"
+ else
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ fi
+ ;;
+ *-*-darwin* )
+ TOOLKIT_DEF="${TOOLKIT_DEF} -D__UNIX__ -D__DARWIN__ -D__POWERPC__"
+ CFLAGS="${CFLAGS} -fno-common"
+ CPPFLAGS="${CPPFLAGS} -fno-common"
+ SHARED_LD="${CXX} -dynamiclib -o"
+ PIC_FLAG="-dynamic -fPIC"
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS CREATE_INSTALLED_LINKS_GL"
+ WX_ALL="CREATE_LINKS CREATE_LINKS_GL"
+ else
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ fi
+ dnl add the resources target for wxMac
+ if test "$wxUSE_MAC" = 1 ; then
+ WX_ALL="${WX_ALL} ./lib/lib${WX_LIBRARY}-${WX_RELEASE}.r"
+ fi
+ dnl the name of the shared library
+ WX_LIBRARY_NAME_SHARED="lib${WX_LIBRARY}-${WX_RELEASE}.dylib.${WX_CURRENT}.${WX_REVISION}.${WX_AGE}"
+ WX_LIBRARY_NAME_SHARED_GL="lib${WX_LIBRARY}_gl-${WX_RELEASE}.dylib.${WX_CURRENT}.${WX_REVISION}.${WX_AGE}"
+ dnl the name of the links to the shared library
+ WX_LIBRARY_LINK1="lib${WX_LIBRARY}-${WX_RELEASE}.dylib.${WX_CURRENT}"
+ WX_LIBRARY_LINK2="lib${WX_LIBRARY}-${WX_RELEASE}.dylib"
+ WX_LIBRARY_LINK3="lib${WX_LIBRARY}.dylib"
+ WX_LIBRARY_LINK1_GL="lib${WX_LIBRARY}_gl-${WX_RELEASE}.dylib.${WX_CURRENT}"
+ WX_LIBRARY_LINK2_GL="lib${WX_LIBRARY}_gl-${WX_RELEASE}.dylib"
+ WX_LIBRARY_LINK3_GL="lib${WX_LIBRARY}_gl.dylib"
+ ;;
+ *-*-osf* )
+ SHARED_LD="${CXX} -shared -o"
+ PIC_FLAG="-fPIC"
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ ;;
+ *-*-dgux5* )
+ SHARED_LD="${CXX} -shared -o"
+ PIC_FLAG="-fPIC"
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ ;;
+ *-*-sysv5* )
+ SHARED_LD="${CC} -shared -o"
+ PIC_FLAG="-fPIC"
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ ;;
+ *-*-aix* )
+ SHARED_LD="/usr/lpp/xlC/bin/makeC++SharedLib -p 0 -o"
+ WX_ALL=${WX_LIBRARY_NAME_SHARED}
+ ;;
+ *-*-cygwin* )
+ dnl only static for now
+ WX_TARGET_LIBRARY="${WX_LIBRARY_NAME_STATIC}"
+ WX_TARGET_LIBRARY_GL="${WX_LIBRARY_NAME_STATIC_GL}"
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="preinstall_gl"
+ WX_ALL="${WX_LIBRARY_NAME_STATIC} ${WX_LIBRARY_NAME_STATIC_GL}"
+ else
+ WX_ALL="${WX_LIBRARY_NAME_STATIC}"
+ fi
+ ;;
+ *-*-mingw32* )
+ dnl only static for now
+ WX_TARGET_LIBRARY="${WX_LIBRARY_NAME_STATIC}"
+ WX_TARGET_LIBRARY_GL="${WX_LIBRARY_NAME_STATIC_GL}"
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="preinstall_gl"
+ WX_ALL="${WX_LIBRARY_NAME_STATIC} ${WX_LIBRARY_NAME_STATIC_GL}"
+ else
+ WX_ALL="${WX_LIBRARY_NAME_STATIC}"
+ fi
+ ;;
+ *-pc-os2_emx )
+ dnl only static for now
+ WX_TARGET_LIBRARY="${WX_LIBRARY_NAME_STATIC}"
+ WX_ALL="${WX_LIBRARY_NAME_STATIC}"
+ ;;
+ *-*-beos* )
+ dnl can't use gcc under BeOS for shared library creation because it
+ dnl complains about missing 'main'
+ SHARED_LD="${LD} -shared -o"
+ PIC_FLAG="-fPIC"
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="CREATE_LINKS"
+ ;;
+ *)
+ AC_MSG_ERROR(unknown system type ${host}.)
+ esac
+
+ dnl set target to shared if not explicitly chose static before
+ if test "x$WX_TARGET_LIBRARY" = "x"; then
+ WX_TARGET_LIBRARY="${WX_LIBRARY_NAME_SHARED}"
+ WX_TARGET_LIBRARY_GL="${WX_LIBRARY_NAME_SHARED_GL}"
+ fi
+ dnl do not alter the LIBRARY_TYPE strings "so" and "a", they are magic
+ WX_TARGET_LIBRARY_TYPE="so"
+else
+ dnl set target to static
+ WX_TARGET_LIBRARY="${WX_LIBRARY_NAME_STATIC}"
+ WX_TARGET_LIBRARY_GL="${WX_LIBRARY_NAME_STATIC_GL}"
+
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="preinstall_gl"
+ WX_ALL="${WX_LIBRARY_NAME_STATIC} ${WX_LIBRARY_NAME_STATIC_GL}"
+ else
+ WX_ALL="${WX_LIBRARY_NAME_STATIC}"
+ fi
+
+ dnl give static wxBase build a working install target
+ if test "$wxUSE_GUI" = "no"; then
+ dnl we're here because WX_ALL_INSTALLED is empty, but play safe anyway
+ WX_ALL_INSTALLED="${WX_ALL_INSTALLED} preinstall"
+ fi
+
+ WX_TARGET_LIBRARY_TYPE="a"
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for headers
+dnl ------------------------------------------------------------------------
+
+dnl defines HAVE_STRINGS_H (where some string functions live on AIX for example)
+AC_CHECK_HEADERS(strings.h)
+dnl defines HAVE_STDLIB_H
+AC_CHECK_HEADERS(stdlib.h)
+dnl defines HAVE_UNISTD_H
+AC_CHECK_HEADERS(unistd.h)
+dnl defines HAVE_WCHAR_H
+AC_CHECK_HEADERS(wchar.h)
+dnl defines HAVE_WCSTR_H
+AC_CHECK_HEADERS(wcstr.h)
+dnl defines HAVE_FNMATCH_H
+AC_CHECK_HEADERS(fnmatch.h)
+dnl defines HAVE_ICONV_H (Unix98 encoding conversion routines)
+AC_CHECK_HEADERS(iconv.h)
+dnl defines HAVE_LANGINFO_H (GNU libc locale parameters)
+AC_CHECK_HEADERS(langinfo.h)
+
+if test "$wxUSE_GUI" = "yes"; then
+ if test "$wxUSE_UNIX" = "yes"; then
+ dnl defines HAVE_X11_XKBLIB_H
+ AC_CHECK_HEADERS(X11/XKBlib.h)
+ fi
+fi
+
+if test "$USE_WIN32" = 1; then
+ AC_CHECK_HEADERS(w32api.h)
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl Checks for typedefs
+dnl ---------------------------------------------------------------------------
+
+dnl defines mode_t if not already defined
+AC_TYPE_MODE_T
+dnl defines off_t if not already defined
+AC_TYPE_OFF_T
+dnl defines pid_t if not already defined
+AC_TYPE_PID_T
+dnl defines size_t if not already defined
+AC_TYPE_SIZE_T
+dnl defines uid_t and gid_t if not already defined
+AC_TYPE_UID_T
+
+dnl check for wchar_t
+AC_CACHE_CHECK([for wchar_t], wx_cv_type_wchar_t,
+[
+ AC_TRY_COMPILE([#include <wchar.h>],
+ [
+ wchar_t wc, *ws;
+ wc = L'a';
+ ws = L"Hello, world!";
+ ],
+ wx_cv_type_wchar_t=yes,
+ AC_TRY_COMPILE([#include <stdlib.h>],
+ [
+ wchar_t wc, *ws;
+ wc = L'a';
+ ws = L"Hello, world!";
+ ],
+ wx_cv_type_wchar_t=yes,
+ wx_cv_type_wchar_t=no)
+ )
+])
+
+if test "$wx_cv_type_wchar_t" = "yes"; then
+ AC_DEFINE(wxUSE_WCHAR_T)
+fi
+
+dnl check what exactly size_t is on this machine - this is necessary to avoid
+dnl ambiguos overloads in several places, notably wx/string.h and wx/array.h
+AC_LANG_SAVE
+AC_LANG_CPLUSPLUS
+AC_CACHE_CHECK([if size_t is unsigned int],
+ wx_cv_size_t_is_uint,
+ dnl an obvious check like AC_TRY_COMPILE[struct Foo { ... };] doesn't work
+ dnl with egcs (at least) up to 1.1.1 as it allows you to compile duplicate
+ dnl methods in a local class (i.e. class inside a function) declaration
+ dnl without any objections!!
+ dnl
+ dnl hence the hack below: we must have Foo at global scope!
+ AC_TRY_COMPILE([#include <stddef.h>],
+ [
+ return 0; }
+
+ struct Foo { void foo(size_t); void foo(unsigned int); };
+
+ int bar() {
+ ],
+ wx_cv_size_t_is_uint=no,
+ wx_cv_size_t_is_uint=yes
+ )
+)
+
+if test "$wx_cv_size_t_is_uint" = "yes"; then
+ AC_DEFINE(wxSIZE_T_IS_UINT)
+else
+ AC_CACHE_CHECK([if size_t is unsigned long],
+ wx_cv_size_t_is_ulong,
+ AC_TRY_COMPILE([#include <stddef.h>],
+ [
+ return 0; }
+
+ struct Foo { void foo(size_t); void foo(unsigned long); };
+
+ int bar() {
+ ],
+ wx_cv_size_t_is_ulong=no,
+ wx_cv_size_t_is_ulong=yes
+ )
+ )
+
+ if test "$wx_cv_size_t_is_ulong" = "yes"; then
+ AC_DEFINE(wxSIZE_T_IS_ULONG)
+ fi
+fi
+
+AC_LANG_RESTORE
+
+dnl ---------------------------------------------------------------------------
+dnl Checks for structures
+dnl ---------------------------------------------------------------------------
+
+dnl does passwd struct has the pw_gecos field?
+AC_CACHE_CHECK([for pw_gecos in struct passwd], wx_cv_struct_pw_gecos,
+ [
+ AC_TRY_COMPILE([#include <pwd.h>],
+ [
+ char *p;
+ struct passwd *pw;
+ p = pw->pw_gecos;
+ ],
+ [
+ wx_cv_struct_pw_gecos=yes
+ ],
+ [
+ wx_cv_struct_pw_gecos=no
+ ]
+ )
+ ]
+)
+
+if test "$wx_cv_struct_pw_gecos" = "yes"; then
+ AC_DEFINE(HAVE_PW_GECOS)
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl Checks for compiler characteristics
+dnl ---------------------------------------------------------------------------
+
+dnl defines const to be empty if c-compiler does not support const fully
+AC_C_CONST
+dnl defines inline to a sensible value for the c-compiler
+AC_C_INLINE
+
+dnl check the sizes of integral types (give some reasonable default values for
+dnl cross-compiling)
+dnl defines the size of certain types of variables in SIZEOF_<TYPE>
+AC_CHECK_SIZEOF(char, 1)
+AC_CHECK_SIZEOF(short, 2)
+AC_CHECK_SIZEOF(int *, 4)
+AC_CHECK_SIZEOF(int, 4)
+AC_CHECK_SIZEOF(long, 4)
+AC_CHECK_SIZEOF(long long, 0)
+
+dnl we have to do it ourselves because SGI/Irix's stdio.h does not include
+dnl wchar_t an AC_CHECK_SIZEOF only includes stdio.h
+dnl Mac OS X does not provide wchar.h and wchar_t is defined by stdlib.h (GD)
+AC_CACHE_CHECK([size of wchar_t], wx_cv_sizeof_wchar_t,
+[
+ AC_TRY_RUN(
+ [
+ #ifdef HAVE_WCHAR_H
+ # include <wchar.h>
+ #endif
+ #ifdef HAVE_STDLIB_H
+ # include <stdlib.h>
+ #endif
+ #include <stdio.h>
+ int main()
+ {
+ FILE *f=fopen("conftestval", "w");
+ if (!f) exit(1);
+ fprintf(f, "%i", sizeof(wchar_t));
+ exit(0);
+ }
+ ],
+ wx_cv_sizeof_wchar_t=`cat conftestval`,
+ wx_cv_sizeof_wchar_t=0,
+ wx_cv_sizeof_wchar_t=4
+ )
+])
+
+AC_DEFINE_UNQUOTED(SIZEOF_WCHAR_T, $wx_cv_sizeof_wchar_t)
+
+dnl for bytesex stuff (don't use AC_C_BIGENDIAN to allow cross-compiling)
+WX_C_BIGENDIAN
+
+dnl check for iostream (as opposed to iostream.h) standard header
+WX_CPP_NEW_HEADERS(, AC_DEFINE(wxUSE_IOSTREAMH))
+
+dnl check whether C++ compiler supports bool built-in type
+WX_CPP_BOOL
+
+dnl ---------------------------------------------------------------------------
+dnl Check for functions
+dnl ---------------------------------------------------------------------------
+
+dnl check for wcslen
+AC_CHECK_LIB(c, wcslen, [
+ AC_DEFINE(HAVE_WCSLEN)
+ WCHAR_LINK=""
+ ], [
+ AC_CHECK_LIB(w, wcslen, [
+ AC_DEFINE(HAVE_WCSLEN)
+ WCHAR_LINK="-lw"
+ ])
+ ])
+
+dnl check for vprintf/vsprintf() which are GNU extensions
+AC_FUNC_VPRINTF
+
+
+dnl check for vsscanf() and vsnprintf() - on some platforms (Linux, glibc
+dnl 2.1.1 for the first one, HP-UX for the second) it's available in the
+dnl library but the prototype is missing, so we can't use AC_CHECK_FUNCS here,
+dnl do it manually
+
+dnl we use AC_TRY_COMPILE() here instead of AC_TRY_RUN() to make the checks
+dnl work for cross-compilation, but AC_TRY_COMPILE() normally only compiles
+dnl one function while we need at least 2 - hence the ugly hack below. To
+dnl understand why it works, remember that AC_TRY_COMPILE() just prepends
+dnl "int main() {" in the beginning of the code and "; return 0; }" at the
+dnl end...
+
+dnl if we fail to find vsnprintf, also try for _vsnprintf as that is what
+dnl we'll find under MSW if it exists.
+
+dnl final note: AC_TRY_COMPILE will only be executed if there is nothing in
+dnl the cache so we have to do AC_DEFINE(HAVE_VSNPRINTF) below and not inside
+dnl it or the symbol wouldn't be defined for the 2nd and subsequent configure
+dnl runs
+
+dnl check for vsnprintf() - a safe version of vsprintf()
+AC_CACHE_CHECK([for vsnprintf], wx_cv_func_vsnprintf,
+[
+ AC_TRY_COMPILE([
+ #include <stdio.h>
+ #include <stdarg.h>
+ ], [
+ int wx_test_vsnprintf(const char *, ...);
+
+ wx_test_vsnprintf("%s");
+ return 0;
+ }
+
+ int wx_test_vsnprintf(const char *fmt, ...)
+ {
+ char *s;
+
+ va_list argp;
+ va_start(argp, fmt);
+ vsnprintf(s, 42, fmt, argp);
+ va_end(argp);
+ ], [
+ wx_cv_func_vsnprintf=yes
+ ], [
+ AC_TRY_COMPILE([
+ #include <stdio.h>
+ #include <stdarg.h>
+ ], [
+ int wx_test_vsnprintf(const char *, ...);
+
+ wx_test_vsnprintf("%s");
+ return 0;
+ }
+
+ int wx_test_vsnprintf(const char *fmt, ...)
+ {
+ char *s;
+
+ va_list argp;
+ va_start(argp, fmt);
+ _vsnprintf(s, 42, fmt, argp);
+ va_end(argp);
+ ], [
+ wx_cv_func_vsnprintf=yes
+ ], [
+ wx_cv_func_vsnprintf=no
+ ])
+ ])
+])
+
+if test "$wx_cv_func_vsnprintf" = yes; then
+ AC_DEFINE(HAVE_VSNPRINTF)
+else
+ AC_MSG_WARN(unsafe function sprintf will be used instead of snprintf)
+fi
+
+dnl check for vsscanf()
+AC_CACHE_CHECK([for vsscanf], wx_cv_func_vsscanf,
+[
+ AC_TRY_COMPILE([
+ #include <stdio.h>
+ #include <stdarg.h>
+ ], [
+ int wx_test_vsscanf(const char *, ...);
+
+ wx_test_vsscanf("%d");
+ return 0;
+ }
+
+ int wx_test_vsscanf(const char *fmt, ...)
+ {
+ va_list argp;
+ va_start(argp, fmt);
+ vsscanf("42", fmt, argp);
+ va_end(argp);
+ ], [
+ wx_cv_func_vsscanf=yes
+ ], [
+ wx_cv_func_vsscanf=no
+ ])
+])
+
+if test "$wx_cv_func_vsscanf" = yes; then
+ AC_DEFINE(HAVE_VSSCANF)
+fi
+
+dnl the following tests are for Unix(like) systems only
+if test "$TOOLKIT" != "MSW"; then
+
+dnl check for available version of iconv()
+
+AC_LANG_SAVE
+AC_LANG_CPLUSPLUS
+AC_CACHE_CHECK([if iconv() takes char**], wx_cv_iconv_takes_char,
+[
+ AC_TRY_COMPILE([#include <iconv.h>],
+ [
+ char **inbuf, **outbuf;
+ iconv_t cd;
+ size_t insz, outsz;
+ iconv(cd, inbuf, &insz, outbuf, &outsz);
+ ],
+ wx_cv_iconv_takes_char=yes,
+ wx_cv_iconv_takes_char=no)
+])
+AC_LANG_RESTORE
+if test "$wx_cv_iconv_takes_char" = yes ; then
+ AC_DEFINE(WX_ICONV_TAKES_CHAR)
+fi
+
+
+dnl check for POSIX signals if we need them
+if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes" -a "$wxUSE_UNIX" = "yes"; then
+ AC_CHECK_FUNCS(sigaction)
+
+ if test "$ac_cv_func_sigaction" = "no"; then
+ AC_MSG_WARN([No POSIX signal functions on this system, wxApp::OnFatalException will not be called])
+ wxUSE_ON_FATAL_EXCEPTION=no
+ fi
+
+ if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
+ AC_LANG_SAVE
+ AC_LANG_CPLUSPLUS
+
+ AC_CACHE_CHECK([for sa_handler type], wx_cv_type_sa_handler,
+ [
+ AC_TRY_COMPILE([#include <signal.h>],
+ [
+ extern void testSigHandler(int);
+
+ struct sigaction sa;
+ sa.sa_handler = testSigHandler;
+ ], [
+ wx_cv_type_sa_handler=int
+ ], [
+ wx_cv_type_sa_handler=void
+ ])
+ ])
+
+ AC_LANG_RESTORE
+
+ AC_DEFINE_UNQUOTED(wxTYPE_SA_HANDLER, $wx_cv_type_sa_handler)
+ fi
+fi
+
+dnl check for vfork() (even if it's the same as fork() in modern Unices)
+AC_CHECK_FUNCS(vfork)
+
+dnl check for fcntl() or at least flock() needed by Unix implementation of
+dnl wxSingleInstanceChecker
+if test "$wxUSE_SNGLINST_CHECKER" = "yes"; then
+ AC_CHECK_FUNCS(fcntl flock, break)
+
+ if test "$ac_cv_func_fcntl" != "yes" -a "$ac_cv_func_flock" != "yes"; then
+ AC_MSG_WARN(wxSingleInstanceChecker not available)
+ wxUSE_SNGLINST_CHECKER=no
+ fi
+fi
+
+dnl check for timegm() used by datetime.cpp
+AC_CHECK_FUNCS(timegm)
+
+dnl look for a function to modify the environment
+AC_CHECK_FUNCS(putenv setenv, break)
+
+HAVE_SOME_SLEEP_FUNC=0
+if test "$USE_BEOS" = 1; then
+ dnl BeOS has its own (wonder where did they get it from) sleep() function
+ dnl in unistd.h
+ AC_DEFINE(HAVE_SLEEP)
+ HAVE_SOME_SLEEP_FUNC=1
+fi
+
+if test "$USE_DARWIN" = 1; then
+ dnl Mac OS X has both nanosleep and usleep
+ dnl but only usleep is defined in unistd.h
+ AC_DEFINE(HAVE_USLEEP)
+ HAVE_SOME_SLEEP_FUNC=1
+fi
+
+if test "$HAVE_SOME_SLEEP_FUNC" != 1; then
+ dnl try nanosleep() in libc and libposix4, if this fails - usleep()
+ POSIX4_LINK=
+ AC_CHECK_FUNCS(nanosleep,
+ AC_DEFINE(HAVE_NANOSLEEP),
+ [
+ AC_CHECK_LIB(posix4, nanosleep,
+ [
+ AC_DEFINE(HAVE_NANOSLEEP)
+ POSIX4_LINK="-lposix4"
+ ],
+ [
+ AC_CHECK_FUNCS(usleep,
+ AC_DEFINE(HAVE_USLEEP),
+ AC_MSG_WARN([wxSleep() function will not work])
+ )
+ ]
+ )
+ ]
+ )
+fi
+
+dnl check for uname (POSIX) and gethostname (BSD)
+AC_CHECK_FUNCS(uname gethostname, break)
+
+dnl check for MT-safe version of strtok (on DEC Alpha, it's ok for C compiler
+dnl but not for C++ one - hence change language)
+AC_LANG_SAVE
+AC_LANG_CPLUSPLUS
+
+AC_CHECK_FUNCS(strtok_r)
+
+AC_LANG_RESTORE
+
+dnl check for inet_addr and inet_aton (these may live either in libc, or in
+dnl libnsl or libresolv)
+INET_LINK=
+AC_CHECK_FUNCS(inet_addr,
+ AC_DEFINE(HAVE_INET_ADDR),
+ [
+ AC_CHECK_LIB(nsl, inet_addr,
+ INET_LINK="nsl",
+ AC_CHECK_LIB(resolv, inet_addr,
+ INET_LINK="resolv"
+ )
+ )
+ ]
+)
+
+AC_CHECK_FUNCS(inet_aton,
+ AC_DEFINE(HAVE_INET_ATON),
+ [
+ dnl only check it in the same lib
+ AC_CHECK_LIB($INET_LINK, inet_aton, AC_DEFINE(HAVE_INET_ATON))
+ ])
+
+if test "x$INET_LINK" != "x"; then
+ AC_DEFINE(HAVE_INET_ADDR)
+ INET_LINK="-l$INET_LINK"
+fi
+
+fi
+dnl if !MSW
+
+dnl ===========================================================================
+dnl Now we have all the info we need - use it!
+dnl ===========================================================================
+
+dnl flush the cache
+AC_CACHE_SAVE
+
+dnl ---------------------------------------------------------------------------
+dnl thread support for Unix (always available under Win32)
+dnl ---------------------------------------------------------------------------
+
+dnl under MSW we always have thread support
+if test "$TOOLKIT" != "MSW"; then
+
+dnl the code below:
+dnl defines THREADS_OBJ which contains the object files to build
+dnl defines THREADS_LINK which contains the thread library to link with
+dnl defines wxUSE_THREADS=1 if thread support is activated
+
+THREADS_LINK=""
+THREADS_OBJ=""
+
+if test "$wxUSE_THREADS" = "yes" ; then
+ if test "$wxUSE_WINE" = 1 ; then
+ AC_MSG_WARN([Threads are not supported under WINE])
+ wxUSE_THREADS="no"
+ elif test "$USE_BEOS" = 1; then
+ AC_MSG_WARN([BeOS threads are not yet supported])
+ wxUSE_THREADS="no"
+ fi
+fi
+
+if test "$wxUSE_THREADS" = "yes" ; then
+ dnl find if POSIX threads are available
+
+ dnl AIX calls the library libpthreads - thanks IBM!
+ if test "$USE_AIX" = 1; then
+ THREADS_LIB=pthreads
+ else
+ THREADS_LIB=pthread
+ fi
+
+ dnl standard lib name is pthread
+ dnl We no longer test for pthread-0.7 as it breaks compilation on some
+ dnl glibc2 systems, especially for static linkage.
+ AC_CHECK_LIB($THREADS_LIB, pthread_create, [
+ THREADS_OBJ="threadpsx.lo"
+ THREADS_LINK=$THREADS_LIB
+ ], [
+ dnl thread functions are in libc_r under FreeBSD
+ AC_CHECK_LIB(c_r, pthread_create, [
+ THREADS_OBJ="threadpsx.lo"
+ THREADS_LINK="c_r"
+ ], [
+ dnl VZ: SGI threads are not supported currently
+ AC_CHECK_HEADER(sys/prctl.h, [
+ THREADS_OBJ="threadsgi.lo"
+ ])
+ ])
+ ])
+
+ if test -z "$THREADS_OBJ" ; then
+ wxUSE_THREADS=no
+ AC_MSG_WARN(No thread support on this system)
+ fi
+fi
+
+dnl do other tests only if we are using threads
+if test "$wxUSE_THREADS" = "yes" ; then
+ AC_CHECK_FUNCS(thr_setconcurrency)
+
+ dnl define autoconf macro to check for given function in both pthread and
+ dnl posix4 libraries
+ dnl usage: AC_FUNC_THREAD(FUNCTION_NAME)
+ dnl VZ: TODO
+ dnl AC_DEFUN(AC_FUNC_THREAD,
+ dnl [
+ dnl AC_CHECK_LIB($THREADS_LINK, $1,
+ dnl AC_DEFINE(HAVE_`'translit($1, `A-Z', 'a-z'),
+ dnl [AC_CHECK_LIB([posix4], $1,
+ dnl [AC_DEFINE(HAVE_`'translit($1, `A-Z', 'a-z'))
+ dnl POSIX4_LINK="-lposix4"
+ dnl ])
+ dnl ])
+ dnl ])
+
+ AC_CHECK_HEADERS(sched.h)
+
+ AC_CHECK_LIB($THREADS_LINK, sched_yield,
+ AC_DEFINE(HAVE_SCHED_YIELD),
+ [AC_CHECK_LIB([posix4], sched_yield,
+ [AC_DEFINE(HAVE_SCHED_YIELD) POSIX4_LINK="-lposix4"],
+ AC_MSG_WARN(wxThread::Yield will not work properly)
+ )]
+ )
+
+ dnl to be able to set the thread priority, we need to have all of the
+ dnl following functions:
+ dnl 1. pthread_attr_getschedpolicy
+ dnl 2. sched_get_priority_min and sched_get_priority_max
+ dnl (this one can be in either libpthread or libposix4 (under Solaris))
+ dnl 3. pthread_attr_getschedparam and pthread_attr_setschedparam
+ HAVE_PRIOR_FUNCS=0
+ AC_CHECK_LIB($THREADS_LINK, pthread_attr_getschedpolicy,
+ AC_CHECK_LIB($THREADS_LINK, pthread_attr_setschedparam,
+ AC_CHECK_LIB($THREADS_LINK, sched_get_priority_max,
+ HAVE_PRIOR_FUNCS=1,
+ AC_CHECK_LIB([posix4], sched_get_priority_max,
+ [
+ HAVE_PRIOR_FUNCS=1
+ POSIX4_LINK="-lposix4"
+ ],
+ )
+ )
+ )
+ )
+
+ if test "$HAVE_PRIOR_FUNCS" = 1; then
+ AC_DEFINE(HAVE_THREAD_PRIORITY_FUNCTIONS)
+ else
+ AC_MSG_WARN(Setting thread priority will not work)
+ fi
+
+ AC_CHECK_LIB($THREADS_LINK, pthread_cancel,
+ AC_DEFINE(HAVE_PTHREAD_CANCEL),
+ AC_MSG_WARN([wxThread::Kill() will not work properly]))
+
+ AC_CACHE_CHECK([for pthread_cleanup_push/pop], wx_cv_func_pthread_cleanup_push,
+ [
+ AC_TRY_COMPILE([#include <pthread.h>],
+ [
+ pthread_cleanup_push(NULL, NULL);
+ pthread_cleanup_pop(0);
+ ], [
+ wx_cv_func_pthread_cleanup_push=yes
+ ], [
+ wx_cv_func_pthread_cleanup_push=no
+ ])
+ ])
+
+ if test "$wx_cv_func_pthread_cleanup_push" = "yes"; then
+ AC_DEFINE(HAVE_THREAD_CLEANUP_FUNCTIONS)
+ fi
+
+ dnl mutexattr_t initialization is done in quite different ways on different
+ dnl platforms, so check for a few things:
+ dnl
+ dnl HAVE_MUTEX_RECURSIVE means that we can create recursive mutexes
+ dnl HAVE_MUTEXATTR_SETTYPE means that we do it using
+ dnl pthread_mutexattr_settype(PTHREAD_MUTEX_RECURSIVE) and if it is not
+ dnl defined, we do it by directly assigned
+ dnl PTHREAD_MUTEX_RECURSIVE_MUTEX_INITIALIZER_NP to attr
+
+ AC_CACHE_CHECK([for pthread_mutexattr_t], wx_cv_type_pthread_mutexattr_t,
+ [
+ AC_TRY_COMPILE([#include <pthread.h>],
+ [
+ pthread_mutexattr_t attr;
+ pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
+ ], [
+ wx_cv_type_pthread_mutexattr_t=yes
+ ], [
+ wx_cv_type_pthread_mutexattr_t=no
+ ]
+ )
+ ])
+
+ if test "$wx_cv_type_pthread_mutexattr_t" = "yes"; then
+ AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_T)
+ else
+ dnl don't despair, there may be another way to do it
+ AC_CACHE_CHECK([for PTHREAD_RECURSIVE_MUTEX_INITIALIZER],
+ wx_cv_type_pthread_rec_mutex_init,
+ [
+ AC_TRY_COMPILE([#include <pthread.h>],
+ [
+ pthread_mutex_t attr = PTHREAD_RECURSIVE_MUTEX_INITIALIZER_NP;
+ ], [
+ wx_cv_type_pthread_rec_mutex_init=yes
+ ], [
+ wx_cv_type_pthread_rec_mutex_init=no
+ ]
+ )
+ ])
+ if test "$wx_cv_type_pthread_rec_mutex_init" = "yes"; then
+ AC_DEFINE(HAVE_PTHREAD_RECURSIVE_MUTEX_INITIALIZER)
+ else
+ dnl this may break code working elsewhere, so at least warn about it
+ AC_MSG_WARN([wxMutex won't be recursive on this platform])
+ fi
+ fi
+
+ THREADS_LINK="-l$THREADS_LINK"
+
+ dnl building MT programs under Solaris with the native compiler requires -mt
+ dnl switch
+ if test "$USE_SOLARIS" = "yes" -a "$GCC" != "yes"; then
+ CFLAGS="${CFLAGS} -mt"
+ CXXFLAGS="${CXXFLAGS} -mt"
+ LDFLAGS="${LDFLAGS} -mt"
+ fi
+fi
+
+dnl from if !MSW
+fi
+
+if test "$wxUSE_THREADS" = "yes"; then
+ AC_DEFINE(wxUSE_THREADS)
+
+ dnl must define _REENTRANT for multithreaded code except for Darwin/Mac OS X
+ if test "$USE_DARWIN" != 1; then
+ CFLAGS="${CFLAGS} -D_REENTRANT"
+ CXXFLAGS="${CXXFLAGS} -D_REENTRANT"
+ fi
+
+ SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS thread"
+else
+ dnl on some systems, _REENTRANT should be defined if we want to use any _r()
+ dnl functions - add tests for other functions here as well
+ if test "$ac_cv_func_strtok_r" = "yes"; then
+ AC_MSG_CHECKING(if -D_REENTRANT is needed)
+ if test "$NEEDS_D_REENTRANT_FOR_R_FUNCS" = 1; then
+ CFLAGS="${CFLAGS} -D_REENTRANT"
+ CXXFLAGS="${CXXFLAGS} -D_REENTRANT"
+ AC_MSG_RESULT(yes)
+ else
+ AC_MSG_RESULT(no)
+ fi
+ fi
+fi
+
+if test "$WXGTK20" = 1 ; then
+ AC_DEFINE_UNQUOTED(__WXGTK20__,$WXGTK20)
+ WXGTK12=1
+fi
+
+if test "$WXGTK12" = 1 ; then
+ AC_DEFINE_UNQUOTED(__WXGTK12__,$WXGTK12)
+fi
+
+if test "$WXGTK127" = 1 ; then
+ AC_DEFINE_UNQUOTED(__WXGTK127__,$WXGTK127)
+fi
+
+if test "$WXWINE" = 1 ; then
+ TOOLKIT_DEF="${TOOLKIT_DEF} -D__WXWINE__"
+fi
+
+if test "$wxUSE_MAC" = 1 ; then
+ TOOLKIT_DEF="${TOOLKIT_DEF} -DTARGET_CARBON"
+ CFLAGS="${CFLAGS} -fpascal-strings"
+ CPPFLAGS="${CPPFLAGS} -cpp-precomp -fpascal-strings"
+ AC_CHECK_PROG(REZ, Rez, Rez, /Developer/Tools/Rez)
+ AC_CHECK_PROG(DEREZ, Derez, Derez, /Developer/Tools/Derez)
+ RESCOMP=${REZ}
+ REZFLAGS="-d __UNIX__ -useDF"
+ DEREZFLAGS="Carbon.r -useDF"
+ RESFLAGS="Carbon.r -t APPL"
+ LIBWXMACRES="\$(LIBWX_MACRES)"
+ LIBWXMACRESCOMP="\$(LIBWX_MACRESCOMP)"
+fi
+
+if test "$wxUSE_CYGWIN" = 1 ; then
+ TOOLKIT_DEF="${TOOLKIT_DEF} -D__WIN95__"
+fi
+
+WXDEBUG=
+
+if test "$wxUSE_DEBUG_INFO" = "yes" ; then
+ WXDEBUG="-g"
+ wxUSE_OPTIMISE=no
+fi
+
+if test "$wxUSE_DEBUG_GDB" = "yes" ; then
+ wxUSE_DEBUG_INFO=yes
+ WXDEBUG="-ggdb"
+fi
+
+if test "$wxUSE_DEBUG_FLAG" = "yes" ; then
+ AC_DEFINE(WXDEBUG)
+ WXDEBUG_DEFINE="-D__WXDEBUG__"
+else
+ if test "$wxUSE_GTK" = 1 ; then
+ WXDEBUG_DEFINE="-DGTK_NO_CHECK_CASTS"
+ fi
+fi
+
+if test "$wxUSE_MEM_TRACING" = "yes" ; then
+ AC_DEFINE(wxUSE_MEMORY_TRACING)
+ AC_DEFINE(wxUSE_GLOBAL_MEMORY_OPERATORS)
+ AC_DEFINE(wxUSE_DEBUG_NEW_ALWAYS)
+ SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS memcheck"
+fi
+
+if test "$wxUSE_DMALLOC" = "yes" ; then
+ DMALLOC_LINK="-ldmalloc"
+fi
+
+PROFILE=
+if test "$wxUSE_PROFILE" = "yes" ; then
+ PROFILE="-pg"
+fi
+
+DEP_INFO_FLAGS=
+CODE_GEN_FLAGS=
+CODE_GEN_FLAGS_CXX=
+if test "$GCC" = yes ; then
+ if test "$wxUSE_NO_RTTI" = "yes" ; then
+ CODE_GEN_FLAGS_CXX="$CODE_GEN_FLAGS -fno-rtti"
+ fi
+ if test "$wxUSE_NO_EXCEPTIONS" = "yes" ; then
+ CODE_GEN_FLAGS_CXX="$CODE_GEN_FLAGS -fno-exceptions"
+ fi
+ if test "$wxUSE_PERMISSIVE" = "yes" ; then
+ CODE_GEN_FLAGS="$CODE_GEN_FLAGS -fpermissive"
+ fi
+ if test "$wxUSE_NO_DEPS" = "no" ; then
+ DEP_INFO_FLAGS="-MMD"
+ fi
+fi
+
+
+CXXFLAGS=`echo "${CXXFLAGS}" | sed "s/\-O.//g" `
+CFLAGS=`echo "${CFLAGS}" | sed "s/\-O.//g" `
+if test "$wxUSE_OPTIMISE" = "no" ; then
+ OPTIMISE=
+else
+ if test "$GCC" = yes ; then
+ OPTIMISE="-O2"
+ case "${host}" in
+ i586-*-*|i686-*-* )
+ OPTIMISE="${OPTIMISE} "
+ ;;
+ esac
+ else
+ OPTIMISE="-O"
+ fi
+fi
+
+if test "$WXWIN_COMPATIBILITY_2" = "yes"; then
+ AC_DEFINE(WXWIN_COMPATIBILITY_2)
+
+ WXWIN_COMPATIBILITY_2_2="yes"
+fi
+
+if test "$WXWIN_COMPATIBILITY_2_2" = "yes"; then
+ AC_DEFINE(WXWIN_COMPATIBILITY_2_2)
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl Optional libraries
+dnl ---------------------------------------------------------------------------
+
+REGEX_INCLUDE=
+if test "$wxUSE_REGEX" != "no"; then
+ dnl according to Unix 98 specs, regcomp() is in libc but I believe that
+ dnl on some old systems it may be in libregex - check for it too?
+ AC_CHECK_HEADER(regex.h, AC_CHECK_FUNCS(regcomp))
+
+ if test "x$ac_cv_func_regcomp" != "xyes"; then
+ dnl we were asked to use the system version of regex lib only but it
+ dnl is not available
+ if test "$wxUSE_REGEX" = "sys"; then
+ AC_MSG_ERROR([system regex library not found! Use --with-regex to use the built-in regex library.])
+ fi
+
+ dnl fallback to the built in code
+ REGEX_INCLUDE="-I\${top_srcdir}/src/regex"
+ fi
+
+ AC_DEFINE(wxUSE_REGEX)
+fi
+
+ZLIB_INCLUDE=
+if test "$wxUSE_ZLIB" = "yes" -o "$wxUSE_ZLIB" = "sys" ; then
+ AC_DEFINE(wxUSE_ZLIB)
+ if test "$wxUSE_ZLIB" = "yes" ; then
+ ZLIB_INCLUDE="-I\${top_srcdir}/src/zlib"
+ else
+ ZLIB_LINK=
+ AC_CHECK_HEADER(zlib.h, AC_CHECK_LIB(z, deflate, ZLIB_LINK="-lz"))
+ if test "x$ZLIB_LINK" = "x" ; then
+ AC_MSG_ERROR(system zlib compression library not found! Use --with-zlib=yes to use built-in zlib)
+ fi
+ fi
+fi
+
+PNG_INCLUDE=
+if test "$wxUSE_LIBPNG" = "yes" -o "$wxUSE_LIBPNG" = "sys" ; then
+ AC_DEFINE(wxUSE_LIBPNG)
+ dnl for the check below to have a chance to succeed, we must already have
+ dnl libz somewhere
+ if test "$wxUSE_LIBPNG" = "sys" -a "$wxUSE_ZLIB" != "sys" ; then
+ AC_MSG_WARN([--with-libpng=sys doesn't work without --with-zlib=sys, will compile the built-in libpng instead])
+ wxUSE_LIBPNG=yes
+ fi
+
+ if test "$wxUSE_LIBPNG" = "yes" ; then
+ PNG_INCLUDE="-I\${top_srcdir}/src/png"
+ else
+ PNG_LINK=
+ AC_CHECK_HEADER(png.h,
+ AC_CHECK_LIB(png, png_check_sig,
+ PNG_LINK="-lpng",
+ ,
+ [-lz -lm])
+ )
+ if test "x$PNG_LINK" = "x" ; then
+ AC_MSG_ERROR(system png library not found! Use --with-libpng=yes to use the built-in libpng)
+ fi
+ fi
+
+ SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS png"
+fi
+
+JPEG_INCLUDE=
+if test "$wxUSE_LIBJPEG" = "yes" -o "$wxUSE_LIBJPEG" = "sys" ; then
+ AC_DEFINE(wxUSE_LIBJPEG)
+ if test "$wxUSE_LIBJPEG" = "yes" ; then
+ JPEG_INCLUDE="-I\${top_srcdir}/src/jpeg"
+ else
+ JPEG_LINK=
+ dnl can't use AC_CHECK_HEADER as jconfig.h defines things like
+ dnl HAVE_STDLIB_H which are already defined and this provokes
+ dnl a compiler warning which configure considers as an error...
+ AC_MSG_CHECKING(for jpeglib.h)
+ AC_CACHE_VAL(ac_cv_header_jpeglib_h,
+ AC_TRY_COMPILE(
+ [
+ #undef HAVE_STDLIB_H
+ #include <stdio.h>
+ #include <jpeglib.h>
+ ],
+ [
+ ],
+ ac_cv_header_jpeglib_h=yes,
+ ac_cv_header_jpeglib_h=no
+ )
+ )
+ AC_MSG_RESULT($ac_cv_header_jpeglib_h)
+
+ if test "$ac_cv_header_jpeglib_h" = "yes"; then
+ AC_CHECK_LIB(jpeg, jpeg_read_header, JPEG_LINK="-ljpeg")
+ fi
+
+ if test "x$JPEG_LINK" = "x" ; then
+ AC_MSG_ERROR(system jpeg library not found! Use --with-libjpeg=yes to use the built-in one)
+ fi
+ fi
+fi
+
+TIFF_INCLUDE=
+if test "$wxUSE_LIBTIFF" = "yes" -o "$wxUSE_LIBTIFF" = "sys" ; then
+ AC_DEFINE(wxUSE_LIBTIFF)
+ if test "$wxUSE_LIBTIFF" = "yes" ; then
+ TIFF_INCLUDE="-I\${top_srcdir}/src/tiff"
+ else
+ TIFF_LINK=
+ AC_CHECK_HEADER(tiffio.h, AC_CHECK_LIB(tiff, TIFFError,
+ TIFF_LINK="-ltiff",
+ ,
+ -lm))
+ if test "x$TIFF_LINK" = "x" ; then
+ AC_MSG_ERROR(system tiff library not found! Use --with-libtiff=yes to use the built-in one)
+ fi
+ fi
+fi
+
+FREETYPE_INCLUDE=
+if test "$wxUSE_FREETYPE" = "yes" -o "$wxUSE_FREETYPE" = "sys" ; then
+ AC_DEFINE(wxUSE_FREETYPE)
+ if test "$wxUSE_FREETYPE" = "yes" ; then
+ FREETYPE_INCLUDE="-I\${top_srcdir}/src/freetype"
+ else
+ FREETYPE_LINK=
+ AC_CHECK_HEADER(freetype.h,
+ AC_CHECK_LIB(freetype, FT_Render_Glyph,
+ FREETYPE_LINK="-lfreetype",
+ ,
+ [-lm])
+ )
+ if test "x$FREETYPE_LINK" = "x" ; then
+ AC_MSG_ERROR(system freetype library not found! Use --with-freetype=yes to use the built-in freetype)
+ fi
+ fi
+fi
+
+if test "$wxUSE_OPENGL" = "yes"; then
+ if test "$wxUSE_MAC" = 1; then
+ AC_DEFINE(wxUSE_OPENGL)
+ AC_DEFINE(wxUSE_GLCANVAS)
+ OPENGL_LINK="-framework OpenGL -framework AGL"
+ SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS opengl"
+ else
+ AC_CHECK_HEADER(GL/gl.h, [
+ AC_DEFINE(wxUSE_OPENGL)
+ AC_DEFINE(wxUSE_GLCANVAS)
+ SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS opengl"
+ AC_CHECK_LIB(GL, glFlush, [
+ OPENGL_LINK="-lGL -lGLU"
+ ],[
+ AC_CHECK_LIB(MesaGL, glFlush, [
+ OPENGL_LINK="-lMesaGL -lMesaGLU"
+ ],)
+ ],)
+ ],wxUSE_OPENGL=0)
+ fi
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl the library may be built without GUI classes at all
+dnl ---------------------------------------------------------------------------
+
+if test "$wxUSE_GUI" = "yes"; then
+ AC_DEFINE(wxUSE_GUI)
+
+ dnl the things we always pull in the GUI version of the library:
+ dnl 1. basic things like wxApp, wxWindow, wxControl, wxFrame, wxDialog (the
+ dnl library really can't be built without those)
+ dnl 2. basic controls: wxButton, wxStaticText, wxTextCtrl (these are used in
+ dnl almost any program and the first 2 are needed to show a message box
+ dnl which want to be always able to do)
+ dnl 3. GDI stuff: icon, cursors and all that. Although it would be very nice
+ dnl to compile without them (if the app doesn't do any drawing, it doesn't
+ dnl need the dcs, pens, brushes, ...), this just can't be done now
+ dnl 4. menu stuff: wxMenu, wxMenuBar, wxMenuItem
+ dnl 5. misc stuff: timers, settings, message box
+else
+ AC_DEFINE(wxUSE_NOGUI)
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl Unix/Windows
+dnl ---------------------------------------------------------------------------
+
+if test "$wxUSE_UNIX" = "yes"; then
+ AC_DEFINE(wxUSE_UNIX)
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl Register non-GUI class options for makefiles and setup.h
+dnl ---------------------------------------------------------------------------
+
+if test "$wxUSE_APPLE_IEEE" = "yes"; then
+ AC_DEFINE(wxUSE_APPLE_IEEE)
+fi
+
+if test "$wxUSE_TIMER" = "yes"; then
+ AC_DEFINE(wxUSE_TIMER)
+fi
+
+if test "$wxUSE_WAVE" = "yes"; then
+ AC_DEFINE(wxUSE_WAVE)
+fi
+
+if test "$wxUSE_CMDLINE_PARSER" = "yes"; then
+ AC_DEFINE(wxUSE_CMDLINE_PARSER)
+fi
+
+if test "$wxUSE_STOPWATCH" = "yes"; then
+ AC_DEFINE(wxUSE_STOPWATCH)
+fi
+
+if test "$wxUSE_DATETIME" = "yes"; then
+ AC_DEFINE(wxUSE_DATETIME)
+fi
projects / wxWidgets.git / blobdiff