+#import <AppKit/NSScrollView.h>
+#import <AppKit/NSScroller.h>
+#import <AppKit/NSColor.h>
+#import <AppKit/NSClipView.h>
+#import <Foundation/NSException.h>
+#import <AppKit/NSApplication.h>
+#import <AppKit/NSWindow.h>
+#import <AppKit/NSScreen.h>
+
+// Turn this on to paint green over the dummy views for debugging
+#undef WXCOCOA_FILL_DUMMY_VIEW
+
+#ifdef WXCOCOA_FILL_DUMMY_VIEW
+#import <AppKit/NSBezierPath.h>
+#endif //def WXCOCOA_FILL_DUMMY_VIEW
+
+// STL list used by wxCocoaMouseMovedEventSynthesizer
+#include <list>
+
+/* NSComparisonResult is typedef'd as an enum pre-Leopard but typedef'd as
+ * NSInteger post-Leopard. Pre-Leopard the Cocoa toolkit expects a function
+ * returning int and not NSComparisonResult. Post-Leopard the Cocoa toolkit
+ * expects a function returning the new non-enum NSComparsionResult.
+ * Hence we create a typedef named CocoaWindowCompareFunctionResult.
+ */
+#if defined(NSINTEGER_DEFINED)
+typedef NSComparisonResult CocoaWindowCompareFunctionResult;
+#else
+typedef int CocoaWindowCompareFunctionResult;
+#endif
+
+// A category for methods that are only present in Panther's SDK
+@interface NSView(wxNSViewPrePantherCompatibility)
+- (void)getRectsBeingDrawn:(const NSRect **)rects count:(int *)count;
+@end
+
+// ========================================================================
+// Helper functions for converting to/from wxWidgets coordinates and a
+// specified NSView's coordinate system.
+// ========================================================================
+NSPoint CocoaTransformNSViewBoundsToWx(NSView *nsview, NSPoint pointBounds)
+{
+ wxCHECK_MSG(nsview, pointBounds, wxT("Need to have a Cocoa view to do translation"));
+ if([nsview isFlipped])
+ return pointBounds;
+ NSRect ourBounds = [nsview bounds];
+ return NSMakePoint
+ ( pointBounds.x
+ , ourBounds.size.height - pointBounds.y
+ );
+}
+
+NSRect CocoaTransformNSViewBoundsToWx(NSView *nsview, NSRect rectBounds)
+{
+ wxCHECK_MSG(nsview, rectBounds, wxT("Need to have a Cocoa view to do translation"));
+ if([nsview isFlipped])
+ return rectBounds;
+ NSRect ourBounds = [nsview bounds];
+ return NSMakeRect
+ ( rectBounds.origin.x
+ , ourBounds.size.height - (rectBounds.origin.y + rectBounds.size.height)
+ , rectBounds.size.width
+ , rectBounds.size.height
+ );
+}
+
+NSPoint CocoaTransformNSViewWxToBounds(NSView *nsview, NSPoint pointWx)
+{
+ wxCHECK_MSG(nsview, pointWx, wxT("Need to have a Cocoa view to do translation"));
+ if([nsview isFlipped])
+ return pointWx;
+ NSRect ourBounds = [nsview bounds];
+ return NSMakePoint
+ ( pointWx.x
+ , ourBounds.size.height - pointWx.y
+ );
+}
+
+NSRect CocoaTransformNSViewWxToBounds(NSView *nsview, NSRect rectWx)
+{
+ wxCHECK_MSG(nsview, rectWx, wxT("Need to have a Cocoa view to do translation"));
+ if([nsview isFlipped])
+ return rectWx;
+ NSRect ourBounds = [nsview bounds];
+ return NSMakeRect
+ ( rectWx.origin.x
+ , ourBounds.size.height - (rectWx.origin.y + rectWx.size.height)
+ , rectWx.size.width
+ , rectWx.size.height
+ );
+}
+
+// ============================================================================
+// Screen coordinate helpers
+// ============================================================================
+
+/*
+General observation about Cocoa screen coordinates:
+It is documented that the first object of the [NSScreen screens] array is the screen with the menubar.
+
+It is not documented (but true as far as I can tell) that (0,0) in Cocoa screen coordinates is always
+the BOTTOM-right corner of this screen. Recall that Cocoa uses cartesian coordinates so y-increase is up.
+
+It isn't clearly documented but visibleFrame returns a rectangle in screen coordinates, not a rectangle
+relative to that screen's frame. The only real way to test this is to configure two screens one atop
+the other such that the menubar screen is on top. The Dock at the bottom of the screen will then
+eat into the visibleFrame of screen 1 by incrementing it's y-origin. Thus if you arrange two
+1920x1200 screens top/bottom then screen 1 (the bottom screen) will have frame origin (0,-1200) and
+visibleFrame origin (0,-1149) which is exactly 51 pixels higher than the full frame origin.
+
+In wxCocoa, we somewhat arbitrarily declare that wx (0,0) is the TOP-left of screen 0's frame (the entire screen).
+However, this isn't entirely arbitrary because the Quartz Display Services (CGDisplay) uses this same scheme.
+This works out nicely because wxCocoa's wxDisplay is implemented using Quartz Display Services instead of NSScreen.
+*/
+
+namespace { // file namespace
+
+class wxCocoaPrivateScreenCoordinateTransformer
+{
+ DECLARE_NO_COPY_CLASS(wxCocoaPrivateScreenCoordinateTransformer)
+public:
+ wxCocoaPrivateScreenCoordinateTransformer();
+ ~wxCocoaPrivateScreenCoordinateTransformer();
+ wxPoint OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates(NSRect windowFrame);
+ NSPoint OriginInCocoaScreenCoordinatesForRectInWxDisplayCoordinates(wxCoord x, wxCoord y, wxCoord width, wxCoord height, bool keepOriginVisible);
+
+protected:
+ NSScreen *m_screenZero;
+ NSRect m_screenZeroFrame;
+};
+
+// NOTE: This is intended to be a short-lived object. A future enhancment might
+// make it a global and reconfigure it upon some notification that the screen layout
+// has changed.
+inline wxCocoaPrivateScreenCoordinateTransformer::wxCocoaPrivateScreenCoordinateTransformer()
+{
+ NSArray *screens = [NSScreen screens];
+
+ [screens retain];
+
+ m_screenZero = nil;
+ if(screens != nil && [screens count] > 0)
+ m_screenZero = [[screens objectAtIndex:0] retain];
+
+ [screens release];
+
+ if(m_screenZero != nil)
+ m_screenZeroFrame = [m_screenZero frame];
+ else
+ {
+ wxLogWarning(wxT("Can't translate to/from wx screen coordinates and Cocoa screen coordinates"));
+ // Just blindly assume 1024x768 so that at least we can sort of flip things around into
+ // Cocoa coordinates.
+ // NOTE: Theoretically this case should never happen anyway.
+ m_screenZeroFrame = NSMakeRect(0,0,1024,768);
+ }
+}
+
+inline wxCocoaPrivateScreenCoordinateTransformer::~wxCocoaPrivateScreenCoordinateTransformer()
+{
+ [m_screenZero release];
+ m_screenZero = nil;
+}
+
+inline wxPoint wxCocoaPrivateScreenCoordinateTransformer::OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates(NSRect windowFrame)
+{
+ // x and y are in wx screen coordinates which we're going to arbitrarily define such that
+ // (0,0) is the TOP-left of screen 0 (the one with the menubar)
+ // NOTE WELL: This means that (0,0) is _NOT_ an appropriate position for a window.
+
+ wxPoint theWxOrigin;
+
+ // Working in Cocoa's screen coordinates we must realize that the x coordinate we want is
+ // the distance between the left side (origin.x) of the window's frame and the left side of
+ // screen zero's frame.
+ theWxOrigin.x = windowFrame.origin.x - m_screenZeroFrame.origin.x;
+
+ // Working in Cocoa's screen coordinates we must realize that the y coordinate we want is
+ // actually the distance between the top-left of the screen zero frame and the top-left
+ // of the window's frame.
+
+ theWxOrigin.y = (m_screenZeroFrame.origin.y + m_screenZeroFrame.size.height) - (windowFrame.origin.y + windowFrame.size.height);
+
+ return theWxOrigin;
+}
+
+inline NSPoint wxCocoaPrivateScreenCoordinateTransformer::OriginInCocoaScreenCoordinatesForRectInWxDisplayCoordinates(wxCoord x, wxCoord y, wxCoord width, wxCoord height, bool keepOriginVisible)
+{
+ NSPoint theCocoaOrigin;
+
+ // The position is in wx screen coordinates which we're going to arbitrarily define such that
+ // (0,0) is the TOP-left of screen 0 (the one with the menubar)
+
+ // NOTE: The usable rectangle is smaller and hence we have the keepOriginVisible flag
+ // which will move the origin downward and/or left as necessary if the origin is
+ // inside the screen0 rectangle (i.e. x/y >= 0 in wx coordinates) and outside the
+ // visible frame (i.e. x/y < the top/left of the screen0 visible frame in wx coordinates)
+ // We don't munge origin coordinates < 0 because it actually is possible that the menubar is on
+ // the top of the bottom screen and thus that origin is completely valid!
+ if(keepOriginVisible && (m_screenZero != nil))
+ {
+ // Do al of this in wx coordinates because it's far simpler since we're dealing with top/left points
+ wxPoint visibleOrigin = OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates([m_screenZero visibleFrame]);
+ if(x >= 0 && x < visibleOrigin.x)
+ x = visibleOrigin.x;
+ if(y >= 0 && y < visibleOrigin.y)
+ y = visibleOrigin.y;
+ }
+
+ // The x coordinate is simple as it's just relative to screen zero's frame
+ theCocoaOrigin.x = m_screenZeroFrame.origin.x + x;
+ // Working in Cocoa's coordinates think to start at the bottom of screen zero's frame and add
+ // the height of that rect which gives us the coordinate for the top of the visible rect. Now realize that
+ // the wx coordinates are flipped so if y is say 10 then we want to be 10 pixels down from that and thus
+ // we subtract y. But then we still need to take into account the size of the window which is h and subtract
+ // that to get the bottom-left origin of the rectangle.
+ theCocoaOrigin.y = m_screenZeroFrame.origin.y + m_screenZeroFrame.size.height - y - height;
+
+ return theCocoaOrigin;
+}
+
+} // namespace
+
+wxPoint wxWindowCocoa::OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates(NSRect windowFrame)
+{
+ wxCocoaPrivateScreenCoordinateTransformer transformer;
+ return transformer.OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates(windowFrame);
+}
+
+NSPoint wxWindowCocoa::OriginInCocoaScreenCoordinatesForRectInWxDisplayCoordinates(wxCoord x, wxCoord y, wxCoord width, wxCoord height, bool keepOriginVisible)
+{
+ wxCocoaPrivateScreenCoordinateTransformer transformer;
+ return transformer.OriginInCocoaScreenCoordinatesForRectInWxDisplayCoordinates(x,y,width,height,keepOriginVisible);
+}
+
+// ========================================================================
+// wxWindowCocoaHider
+// ========================================================================
+class wxWindowCocoaHider: protected wxCocoaNSView
+{
+ DECLARE_NO_COPY_CLASS(wxWindowCocoaHider)
+public:
+ wxWindowCocoaHider(wxWindow *owner);
+ virtual ~wxWindowCocoaHider();
+ inline WX_NSView GetNSView() { return m_dummyNSView; }
+protected:
+ wxWindowCocoa *m_owner;
+ WX_NSView m_dummyNSView;
+ virtual void Cocoa_FrameChanged(void);
+ virtual void Cocoa_synthesizeMouseMoved(void) {}
+#ifdef WXCOCOA_FILL_DUMMY_VIEW
+ virtual bool Cocoa_drawRect(const NSRect& rect);
+#endif //def WXCOCOA_FILL_DUMMY_VIEW
+private:
+ wxWindowCocoaHider();
+};
+
+// ========================================================================
+// wxWindowCocoaScrollView
+// ========================================================================
+class wxWindowCocoaScrollView: protected wxCocoaNSView
+{
+ DECLARE_NO_COPY_CLASS(wxWindowCocoaScrollView)
+public:
+ wxWindowCocoaScrollView(wxWindow *owner);
+ virtual ~wxWindowCocoaScrollView();
+ inline WX_NSScrollView GetNSScrollView() { return m_cocoaNSScrollView; }
+ void ClientSizeToSize(int &width, int &height);
+ void DoGetClientSize(int *x, int *y) const;
+ void Encapsulate();
+ void Unencapsulate();
+
+ // wxWindow calls this to do the work. Note that we don't have the refresh parameter
+ // because wxWindow handles that itself.
+ void SetScrollbar(int orientation, int position, int thumbSize, int range);
+ int GetScrollPos(wxOrientation orient);
+ void SetScrollPos(wxOrientation orient, int position);
+ int GetScrollRange(wxOrientation orient);
+ int GetScrollThumb(wxOrientation orient);
+ void ScrollWindow(int dx, int dy, const wxRect*);
+ void UpdateSizes();
+
+ void _wx_doScroller(NSScroller *sender);
+
+protected:
+ wxWindowCocoa *m_owner;
+ WX_NSScrollView m_cocoaNSScrollView;
+ virtual void Cocoa_FrameChanged(void);
+ virtual void Cocoa_synthesizeMouseMoved(void) {}
+ /*!
+ Flag as to whether we're scrolling for a native view or a custom
+ wxWindow. This controls the scrolling behavior. When providing
+ scrolling for a native view we don't catch scroller action messages
+ and thus don't send scroll events and we don't actually scroll the
+ window when the application calls ScrollWindow.
+
+ When providing scrolling for a custom wxWindow, we make the NSScroller
+ send their action messages to us which we in turn package as wx window
+ scrolling events. At this point, the window will not physically be
+ scrolled. The application will most likely handle the event by calling
+ ScrollWindow which will do the real scrolling. On the other hand,
+ the application may instead not call ScrollWindow until some threshold
+ is reached. This causes the window to only scroll in steps which is
+ what, for instance, wxScrolledWindow does.
+ */
+ bool m_isNativeView;
+ /*!
+ The range as the application code wishes to see it. That is, the
+ range from the last SetScrollbar call for the appropriate dimension.
+ The horizontal dimension is the first [0] element and the vertical
+ dimension the second [1] element.
+
+ In wxMSW, a SCROLLINFO with nMin=0 and nMax=range-1 is used which
+ gives exactly range possible positions so long as nPage (which is
+ the thumb size) is less than or equal to 1.
+ */
+ int m_scrollRange[2];
+ /*!
+ The thumb size is intended to reflect the size of the visible portion
+ of the scrolled document. As the document size increases, the thumb
+ visible thumb size decreases. As document size decreases, the visible
+ thumb size increases. However, the thumb size on wx is defined in
+ terms of scroll units (which are effectively defined by the scroll
+ range) and so increasing the number of scroll units to reflect increased
+ document size will have the effect of decreasing the visible thumb
+ size even though the number doesn't change.
+
+ It's also important to note that subtracting the thumb size from the
+ full range gives you the real range that can be used. Microsoft
+ defines nPos (the current scrolling position) to be within the range
+ from nMin to nMax - max(nPage - 1, 0). We know that wxMSW code always
+ sets nMin = 0 and nMax = range -1. So let's algebraically reduce the
+ definition of the maximum allowed position:
+
+ Begin:
+ = nMax - max(nPage - 1, 0)
+ Substitute (range - 1) for nMax and thumbSize for nPage:
+ = range - 1 - max(thumbSize - 1, 0)
+ Add one inside the max conditional and subtract one outside of it:
+ = range - 1 - (max(thumbSize - 1 + 1, 1) - 1)
+ Reduce some constants:
+ = range - 1 - (max(thumbSize, 1) - 1)
+ Distribute the negative across the parenthesis:
+ = range - 1 - max(thumbSize, 1) + 1
+ Reduce the constants:
+ = range - max(thumbSize, 1)
+
+ Also keep in mind that thumbSize may never be greater than range but
+ can be equal to it. Thus for the smallest possible thumbSize there
+ are exactly range possible scroll positions (numbered from 0 to
+ range - 1) and for the largest possible thumbSize there is exactly
+ one possible scroll position (numbered 0).
+ */
+ int m_scrollThumb[2];
+
+ /*!
+ The origin of the virtual coordinate space expressed in terms of client
+ coordinates. Starts at (0,0) and each call to ScrollWindow accumulates
+ into it. Thus if the user scrolls the window right (thus causing the
+ contents to move left with respect to the client origin, the
+ application code (typically wxScrolledWindow) will be called with
+ dx of -something, for example -20. This is added to m_virtualOrigin
+ and thus m_virtualOrigin will be (-20,0) in this example.
+ */
+ wxPoint m_virtualOrigin;
+private:
+ wxWindowCocoaScrollView();
+};
+
+// ========================================================================
+// wxDummyNSView
+// ========================================================================
+@interface wxDummyNSView : NSView
+- (NSView *)hitTest:(NSPoint)aPoint;
+@end
+WX_DECLARE_GET_OBJC_CLASS(wxDummyNSView,NSView)
+
+@implementation wxDummyNSView : NSView
+- (NSView *)hitTest:(NSPoint)aPoint
+{
+ return nil;
+}
+
+@end
+WX_IMPLEMENT_GET_OBJC_CLASS(wxDummyNSView,NSView)
+
+// ========================================================================
+// wxWindowCocoaHider
+// ========================================================================
+wxWindowCocoaHider::wxWindowCocoaHider(wxWindow *owner)
+: m_owner(owner)
+{
+ wxASSERT(owner);
+ wxASSERT(owner->GetNSViewForHiding());
+ m_dummyNSView = [[WX_GET_OBJC_CLASS(wxDummyNSView) alloc]
+ initWithFrame:[owner->GetNSViewForHiding() frame]];
+ [m_dummyNSView setAutoresizingMask: [owner->GetNSViewForHiding() autoresizingMask]];
+ AssociateNSView(m_dummyNSView);
+}
+
+wxWindowCocoaHider::~wxWindowCocoaHider()
+{
+ DisassociateNSView(m_dummyNSView);
+ [m_dummyNSView release];
+}
+
+void wxWindowCocoaHider::Cocoa_FrameChanged(void)
+{
+ // Keep the real window in synch with the dummy
+ wxASSERT(m_dummyNSView);
+ [m_owner->GetNSViewForHiding() setFrame:[m_dummyNSView frame]];
+}
+
+
+#ifdef WXCOCOA_FILL_DUMMY_VIEW
+bool wxWindowCocoaHider::Cocoa_drawRect(const NSRect& rect)
+{
+ NSBezierPath *bezpath = [NSBezierPath bezierPathWithRect:rect];
+ [[NSColor greenColor] set];
+ [bezpath stroke];
+ [bezpath fill];
+ return true;
+}
+#endif //def WXCOCOA_FILL_DUMMY_VIEW
+
+
+/*! @class WXManualScrollView
+ @abstract An NSScrollView subclass which implements wx scroll behavior
+ @discussion
+ Overrides default behavior of NSScrollView such that this class receives
+ the scroller action messages and allows the wxCocoaScrollView to act
+ on them accordingly. In particular, because the NSScrollView will not
+ receive action messages from the scroller, it will not adjust the
+ document view. This must be done manually using the ScrollWindow
+ method of wxWindow.
+ */
+@interface WXManualScrollView : NSScrollView
+{
+ /*! @field m_wxCocoaScrollView
+ */
+ wxWindowCocoaScrollView *m_wxCocoaScrollView;
+}
+
+// Override these to set up the target/action correctly
+- (void)setHorizontalScroller:(NSScroller *)aScroller;
+- (void)setVerticalScroller:(NSScroller *)aScroller;
+- (void)setHasHorizontalScroller:(BOOL)flag;
+- (void)setHasVerticalScroller:(BOOL)flag;
+
+// NOTE: _wx_ prefix means "private" method like _ that Apple (and only Apple) uses.
+- (wxWindowCocoaScrollView*)_wx_wxCocoaScrollView;
+- (void)_wx_setWxCocoaScrollView:(wxWindowCocoaScrollView*)theWxScrollView;
+
+/*! @method _wx_doScroller
+ @abstract Handles action messages from the scrollers
+ @discussion
+ Similar to Apple's _doScroller: method which is private and not documented.
+ We do not, however, call that method. Instead, we effectively override
+ it entirely. We don't override it by naming ourself the same thing because
+ the base class code may or may not call that method for other reasons we
+ simply cannot know about.
+ */
+- (void)_wx_doScroller:(id)sender;
+
+@end
+
+
+@implementation WXManualScrollView : NSScrollView
+
+static inline void WXManualScrollView_DoSetScrollerTargetAction(WXManualScrollView *self, NSScroller *aScroller)
+{
+ if(aScroller != NULL && [self _wx_wxCocoaScrollView] != NULL)
+ {
+ [aScroller setTarget:self];
+ [aScroller setAction:@selector(_wx_doScroller:)];
+ }
+}
+
+- (void)setHorizontalScroller:(NSScroller *)aScroller
+{
+ [super setHorizontalScroller:aScroller];
+ WXManualScrollView_DoSetScrollerTargetAction(self, aScroller);
+}
+
+- (void)setVerticalScroller:(NSScroller *)aScroller
+{
+ [super setVerticalScroller:aScroller];
+ WXManualScrollView_DoSetScrollerTargetAction(self, aScroller);
+}
+
+- (void)setHasHorizontalScroller:(BOOL)flag
+{
+ [super setHasHorizontalScroller:flag];
+ WXManualScrollView_DoSetScrollerTargetAction(self, [self horizontalScroller]);
+}
+
+- (void)setHasVerticalScroller:(BOOL)flag
+{
+ [super setHasVerticalScroller:flag];
+ WXManualScrollView_DoSetScrollerTargetAction(self, [self verticalScroller]);
+}
+
+- (wxWindowCocoaScrollView*)_wx_wxCocoaScrollView
+{ return m_wxCocoaScrollView; }
+
+- (void)_wx_setWxCocoaScrollView:(wxWindowCocoaScrollView*)theWxScrollView
+{
+ m_wxCocoaScrollView = theWxScrollView;
+ [self setHorizontalScroller:[self horizontalScroller]];
+ [self setVerticalScroller:[self verticalScroller]];
+}
+
+- (void)_wx_doScroller:(id)sender
+{
+ if(m_wxCocoaScrollView != NULL)
+ m_wxCocoaScrollView->_wx_doScroller(sender);
+ else
+ wxLogError(wxT("Unexpected action message received from NSScroller"));
+}
+
+- (void)reflectScrolledClipView:(NSClipView *)aClipView
+{
+ struct _ScrollerBackup
+ {
+ _ScrollerBackup(NSScroller *aScroller)
+ : m_scroller(aScroller)
+ , m_floatValue(aScroller!=nil?[aScroller floatValue]:0.0)
+ , m_knobProportion(aScroller!=nil?[aScroller knobProportion]:1.0)
+ , m_isEnabled(aScroller!=nil?[aScroller isEnabled]:false)
+ {
+ }
+ NSScroller *m_scroller;
+ CGFloat m_floatValue;
+ CGFloat m_knobProportion;
+ BOOL m_isEnabled;
+ ~_ScrollerBackup()
+ {
+ if(m_scroller != nil)
+ {
+ [m_scroller setFloatValue:m_floatValue knobProportion:m_knobProportion];
+ [m_scroller setEnabled:m_isEnabled];
+ }
+ }
+ private:
+ _ScrollerBackup();
+ _ScrollerBackup(_ScrollerBackup const&);
+ _ScrollerBackup& operator=(_ScrollerBackup const&);
+ };
+ _ScrollerBackup _horizontalBackup([self horizontalScroller]);
+ _ScrollerBackup _verticalBackup([self verticalScroller]);
+ // We MUST call super's implementation or else nothing seems to work right at all.
+ // However, we need our scrollers not to change values due to the document window
+ // moving so we cheat and save/restore their values across this call.
+ [super reflectScrolledClipView: aClipView];
+}
+
+@end
+WX_IMPLEMENT_GET_OBJC_CLASS(WXManualScrollView,NSScrollView)
+
+// ========================================================================
+// wxFlippedNSClipView
+// ========================================================================
+@interface wxFlippedNSClipView : NSClipView
+- (BOOL)isFlipped;
+@end
+WX_DECLARE_GET_OBJC_CLASS(wxFlippedNSClipView,NSClipView)
+
+@implementation wxFlippedNSClipView : NSClipView
+- (BOOL)isFlipped
+{
+ return YES;
+}
+
+@end
+WX_IMPLEMENT_GET_OBJC_CLASS(wxFlippedNSClipView,NSClipView)
+
+// ========================================================================
+// wxWindowCocoaScrollView
+// ========================================================================
+wxWindowCocoaScrollView::wxWindowCocoaScrollView(wxWindow *owner)
+: m_owner(owner)
+, m_cocoaNSScrollView() // nil
+, m_scrollRange() // {0,0}
+, m_scrollThumb() // {0,0}
+, m_virtualOrigin(0,0)
+{
+ wxAutoNSAutoreleasePool pool;
+ wxASSERT(owner);
+ wxASSERT(owner->GetNSView());
+ m_isNativeView = ![owner->GetNSView() isKindOfClass:[WX_GET_OBJC_CLASS(WXNSView) class]];
+ m_cocoaNSScrollView = [(m_isNativeView?[NSScrollView alloc]:[WXManualScrollView alloc])
+ initWithFrame:[owner->GetNSView() frame]];
+ AssociateNSView(m_cocoaNSScrollView);
+ if(m_isNativeView)
+ {
+ /* Set a bezel border around the entire thing because it looks funny without it.
+ TODO: Be sure to undo any borders on the real view (if any) and apply them
+ to this view if necessary. Right now, there is no border support in wxCocoa
+ so this isn't an issue.
+ */
+ [m_cocoaNSScrollView setBorderType:NSBezelBorder];
+ }
+ else
+ {
+ [(WXManualScrollView*)m_cocoaNSScrollView _wx_setWxCocoaScrollView: this];
+ // Don't set a bezel because we might be creating a scroll view due to being
+ // the "target window" of a wxScrolledWindow. That is to say that the user
+ // has absolutely no intention of scrolling the clip view used by this
+ // NSScrollView.
+ }
+
+ /* Replace the default NSClipView with a flipped one. This ensures
+ scrolling is "pinned" to the top-left instead of bottom-right. */
+ NSClipView *flippedClip = [[WX_GET_OBJC_CLASS(wxFlippedNSClipView) alloc]
+ initWithFrame: [[m_cocoaNSScrollView contentView] frame]];
+ [m_cocoaNSScrollView setContentView:flippedClip];
+ [flippedClip release];
+
+ // In all cases we must encapsulate the real NSView properly
+ Encapsulate();
+}
projects / wxWidgets.git / blobdiff