+#import <AppKit/NSScrollView.h>
+#import <AppKit/NSScroller.h>
+#import <AppKit/NSColor.h>
+#import <AppKit/NSClipView.h>
+#import <Foundation/NSException.h>
+#import <AppKit/NSApplication.h>
+#import <AppKit/NSWindow.h>
+#import <AppKit/NSScreen.h>
+
+// Turn this on to paint green over the dummy views for debugging
+#undef WXCOCOA_FILL_DUMMY_VIEW
+
+#ifdef WXCOCOA_FILL_DUMMY_VIEW
+#import <AppKit/NSBezierPath.h>
+#endif //def WXCOCOA_FILL_DUMMY_VIEW
+
+// STL list used by wxCocoaMouseMovedEventSynthesizer
+#include <list>
+
+/* NSComparisonResult is typedef'd as an enum pre-Leopard but typedef'd as
+ * NSInteger post-Leopard. Pre-Leopard the Cocoa toolkit expects a function
+ * returning int and not NSComparisonResult. Post-Leopard the Cocoa toolkit
+ * expects a function returning the new non-enum NSComparsionResult.
+ * Hence we create a typedef named CocoaWindowCompareFunctionResult.
+ */
+#if defined(NSINTEGER_DEFINED)
+typedef NSComparisonResult CocoaWindowCompareFunctionResult;
+#else
+typedef int CocoaWindowCompareFunctionResult;
+#endif
+
+// A category for methods that are only present in Panther's SDK
+@interface NSView(wxNSViewPrePantherCompatibility)
+- (void)getRectsBeingDrawn:(const NSRect **)rects count:(int *)count;
+@end
+
+// ========================================================================
+// Helper functions for converting to/from wxWidgets coordinates and a
+// specified NSView's coordinate system.
+// ========================================================================
+NSPoint CocoaTransformNSViewBoundsToWx(NSView *nsview, NSPoint pointBounds)
+{
+ wxCHECK_MSG(nsview, pointBounds, wxT("Need to have a Cocoa view to do translation"));
+ if([nsview isFlipped])
+ return pointBounds;
+ NSRect ourBounds = [nsview bounds];
+ return NSMakePoint
+ ( pointBounds.x
+ , ourBounds.size.height - pointBounds.y
+ );
+}
+
+NSRect CocoaTransformNSViewBoundsToWx(NSView *nsview, NSRect rectBounds)
+{
+ wxCHECK_MSG(nsview, rectBounds, wxT("Need to have a Cocoa view to do translation"));
+ if([nsview isFlipped])
+ return rectBounds;
+ NSRect ourBounds = [nsview bounds];
+ return NSMakeRect
+ ( rectBounds.origin.x
+ , ourBounds.size.height - (rectBounds.origin.y + rectBounds.size.height)
+ , rectBounds.size.width
+ , rectBounds.size.height
+ );
+}
+
+NSPoint CocoaTransformNSViewWxToBounds(NSView *nsview, NSPoint pointWx)
+{
+ wxCHECK_MSG(nsview, pointWx, wxT("Need to have a Cocoa view to do translation"));
+ if([nsview isFlipped])
+ return pointWx;
+ NSRect ourBounds = [nsview bounds];
+ return NSMakePoint
+ ( pointWx.x
+ , ourBounds.size.height - pointWx.y
+ );
+}
+
+NSRect CocoaTransformNSViewWxToBounds(NSView *nsview, NSRect rectWx)
+{
+ wxCHECK_MSG(nsview, rectWx, wxT("Need to have a Cocoa view to do translation"));
+ if([nsview isFlipped])
+ return rectWx;
+ NSRect ourBounds = [nsview bounds];
+ return NSMakeRect
+ ( rectWx.origin.x
+ , ourBounds.size.height - (rectWx.origin.y + rectWx.size.height)
+ , rectWx.size.width
+ , rectWx.size.height
+ );
+}
+
+// ============================================================================
+// Screen coordinate helpers
+// ============================================================================
+
+/*
+General observation about Cocoa screen coordinates:
+It is documented that the first object of the [NSScreen screens] array is the screen with the menubar.
+
+It is not documented (but true as far as I can tell) that (0,0) in Cocoa screen coordinates is always
+the BOTTOM-right corner of this screen. Recall that Cocoa uses cartesian coordinates so y-increase is up.
+
+It isn't clearly documented but visibleFrame returns a rectangle in screen coordinates, not a rectangle
+relative to that screen's frame. The only real way to test this is to configure two screens one atop
+the other such that the menubar screen is on top. The Dock at the bottom of the screen will then
+eat into the visibleFrame of screen 1 by incrementing it's y-origin. Thus if you arrange two
+1920x1200 screens top/bottom then screen 1 (the bottom screen) will have frame origin (0,-1200) and
+visibleFrame origin (0,-1149) which is exactly 51 pixels higher than the full frame origin.
+
+In wxCocoa, we somewhat arbitrarily declare that wx (0,0) is the TOP-left of screen 0's frame (the entire screen).
+However, this isn't entirely arbitrary because the Quartz Display Services (CGDisplay) uses this same scheme.
+This works out nicely because wxCocoa's wxDisplay is implemented using Quartz Display Services instead of NSScreen.
+*/
+
+namespace { // file namespace
+
+class wxCocoaPrivateScreenCoordinateTransformer
+{
+ wxDECLARE_NO_COPY_CLASS(wxCocoaPrivateScreenCoordinateTransformer);
+public:
+ wxCocoaPrivateScreenCoordinateTransformer();
+ ~wxCocoaPrivateScreenCoordinateTransformer();
+ wxPoint OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates(NSRect windowFrame);
+ NSPoint OriginInCocoaScreenCoordinatesForRectInWxDisplayCoordinates(wxCoord x, wxCoord y, wxCoord width, wxCoord height, bool keepOriginVisible);
+
+protected:
+ NSScreen *m_screenZero;
+ NSRect m_screenZeroFrame;
+};
+
+// NOTE: This is intended to be a short-lived object. A future enhancment might
+// make it a global and reconfigure it upon some notification that the screen layout
+// has changed.
+inline wxCocoaPrivateScreenCoordinateTransformer::wxCocoaPrivateScreenCoordinateTransformer()
+{
+ NSArray *screens = [NSScreen screens];
+
+ [screens retain];
+
+ m_screenZero = nil;
+ if(screens != nil && [screens count] > 0)
+ m_screenZero = [[screens objectAtIndex:0] retain];
+
+ [screens release];
+
+ if(m_screenZero != nil)
+ m_screenZeroFrame = [m_screenZero frame];
+ else
+ {
+ wxLogWarning(wxT("Can't translate to/from wx screen coordinates and Cocoa screen coordinates"));
+ // Just blindly assume 1024x768 so that at least we can sort of flip things around into
+ // Cocoa coordinates.
+ // NOTE: Theoretically this case should never happen anyway.
+ m_screenZeroFrame = NSMakeRect(0,0,1024,768);
+ }
+}
+
+inline wxCocoaPrivateScreenCoordinateTransformer::~wxCocoaPrivateScreenCoordinateTransformer()
+{
+ [m_screenZero release];
+ m_screenZero = nil;
+}
+
+inline wxPoint wxCocoaPrivateScreenCoordinateTransformer::OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates(NSRect windowFrame)
+{
+ // x and y are in wx screen coordinates which we're going to arbitrarily define such that
+ // (0,0) is the TOP-left of screen 0 (the one with the menubar)
+ // NOTE WELL: This means that (0,0) is _NOT_ an appropriate position for a window.
+
+ wxPoint theWxOrigin;
+
+ // Working in Cocoa's screen coordinates we must realize that the x coordinate we want is
+ // the distance between the left side (origin.x) of the window's frame and the left side of
+ // screen zero's frame.
+ theWxOrigin.x = windowFrame.origin.x - m_screenZeroFrame.origin.x;
+
+ // Working in Cocoa's screen coordinates we must realize that the y coordinate we want is
+ // actually the distance between the top-left of the screen zero frame and the top-left
+ // of the window's frame.
+
+ theWxOrigin.y = (m_screenZeroFrame.origin.y + m_screenZeroFrame.size.height) - (windowFrame.origin.y + windowFrame.size.height);
+
+ return theWxOrigin;
+}
+
+inline NSPoint wxCocoaPrivateScreenCoordinateTransformer::OriginInCocoaScreenCoordinatesForRectInWxDisplayCoordinates(wxCoord x, wxCoord y, wxCoord width, wxCoord height, bool keepOriginVisible)
+{
+ NSPoint theCocoaOrigin;
+
+ // The position is in wx screen coordinates which we're going to arbitrarily define such that
+ // (0,0) is the TOP-left of screen 0 (the one with the menubar)
+
+ // NOTE: The usable rectangle is smaller and hence we have the keepOriginVisible flag
+ // which will move the origin downward and/or left as necessary if the origin is
+ // inside the screen0 rectangle (i.e. x/y >= 0 in wx coordinates) and outside the
+ // visible frame (i.e. x/y < the top/left of the screen0 visible frame in wx coordinates)
+ // We don't munge origin coordinates < 0 because it actually is possible that the menubar is on
+ // the top of the bottom screen and thus that origin is completely valid!
+ if(keepOriginVisible && (m_screenZero != nil))
+ {
+ // Do al of this in wx coordinates because it's far simpler since we're dealing with top/left points
+ wxPoint visibleOrigin = OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates([m_screenZero visibleFrame]);
+ if(x >= 0 && x < visibleOrigin.x)
+ x = visibleOrigin.x;
+ if(y >= 0 && y < visibleOrigin.y)
+ y = visibleOrigin.y;
+ }
+
+ // The x coordinate is simple as it's just relative to screen zero's frame
+ theCocoaOrigin.x = m_screenZeroFrame.origin.x + x;
+ // Working in Cocoa's coordinates think to start at the bottom of screen zero's frame and add
+ // the height of that rect which gives us the coordinate for the top of the visible rect. Now realize that
+ // the wx coordinates are flipped so if y is say 10 then we want to be 10 pixels down from that and thus
+ // we subtract y. But then we still need to take into account the size of the window which is h and subtract
+ // that to get the bottom-left origin of the rectangle.
+ theCocoaOrigin.y = m_screenZeroFrame.origin.y + m_screenZeroFrame.size.height - y - height;
+
+ return theCocoaOrigin;
+}
+
+} // namespace
+
+wxPoint wxWindowCocoa::OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates(NSRect windowFrame)
+{
+ wxCocoaPrivateScreenCoordinateTransformer transformer;
+ return transformer.OriginInWxDisplayCoordinatesForRectInCocoaScreenCoordinates(windowFrame);
+}
+
+NSPoint wxWindowCocoa::OriginInCocoaScreenCoordinatesForRectInWxDisplayCoordinates(wxCoord x, wxCoord y, wxCoord width, wxCoord height, bool keepOriginVisible)
+{
+ wxCocoaPrivateScreenCoordinateTransformer transformer;
+ return transformer.OriginInCocoaScreenCoordinatesForRectInWxDisplayCoordinates(x,y,width,height,keepOriginVisible);
+}
+
+// ========================================================================
+// wxWindowCocoaHider
+// ========================================================================
+class wxWindowCocoaHider: protected wxCocoaNSView
+{
+ wxDECLARE_NO_COPY_CLASS(wxWindowCocoaHider);
+public:
+ wxWindowCocoaHider(wxWindow *owner);
+ virtual ~wxWindowCocoaHider();
+ inline WX_NSView GetNSView() { return m_dummyNSView; }
+protected:
+ wxWindowCocoa *m_owner;
+ WX_NSView m_dummyNSView;
+ virtual void Cocoa_FrameChanged(void);
+ virtual void Cocoa_synthesizeMouseMoved(void) {}
+#ifdef WXCOCOA_FILL_DUMMY_VIEW
+ virtual bool Cocoa_drawRect(const NSRect& rect);
+#endif //def WXCOCOA_FILL_DUMMY_VIEW
+private:
+ wxWindowCocoaHider();
+};
+
+// ========================================================================
+// wxDummyNSView
+// ========================================================================
+@interface wxDummyNSView : NSView
+- (NSView *)hitTest:(NSPoint)aPoint;
+@end
+WX_DECLARE_GET_OBJC_CLASS(wxDummyNSView,NSView)
+
+@implementation wxDummyNSView : NSView
+- (NSView *)hitTest:(NSPoint)aPoint
+{
+ return nil;
+}
+
+@end
+WX_IMPLEMENT_GET_OBJC_CLASS(wxDummyNSView,NSView)
+
+// ========================================================================
+// wxWindowCocoaHider
+// NOTE: This class and method of hiding predates setHidden: support in
+// the toolkit. The hack used here is to replace the view with a stand-in
+// that will be subject to the usual Cocoa resizing rules.
+// When possible (i.e. when running on 10.3 or higher) we make it hidden
+// mostly as an optimization so Cocoa doesn't have to consider it when
+// drawing or finding key views.
+// ========================================================================
+wxWindowCocoaHider::wxWindowCocoaHider(wxWindow *owner)
+: m_owner(owner)
+{
+ wxASSERT(owner);
+ wxASSERT(owner->GetNSViewForHiding());
+ m_dummyNSView = [[WX_GET_OBJC_CLASS(wxDummyNSView) alloc]
+ initWithFrame:[owner->GetNSViewForHiding() frame]];
+ [m_dummyNSView setAutoresizingMask: [owner->GetNSViewForHiding() autoresizingMask]];
+ AssociateNSView(m_dummyNSView);
+
+ if([m_dummyNSView respondsToSelector:@selector(setHidden:)])
+ [m_dummyNSView setHidden:YES];
+}
+
+wxWindowCocoaHider::~wxWindowCocoaHider()
+{
+ DisassociateNSView(m_dummyNSView);
+ [m_dummyNSView release];
+}
+
+void wxWindowCocoaHider::Cocoa_FrameChanged(void)
+{
+ // Keep the real window in synch with the dummy
+ wxASSERT(m_dummyNSView);
+ [m_owner->GetNSViewForHiding() setFrame:[m_dummyNSView frame]];
+}
+
+
+#ifdef WXCOCOA_FILL_DUMMY_VIEW
+bool wxWindowCocoaHider::Cocoa_drawRect(const NSRect& rect)
+{
+ NSBezierPath *bezpath = [NSBezierPath bezierPathWithRect:rect];
+ [[NSColor greenColor] set];
+ [bezpath stroke];
+ [bezpath fill];
+ return true;
+}
+#endif //def WXCOCOA_FILL_DUMMY_VIEW
+
+
+/*! @class WXManualScrollView
+ @abstract An NSScrollView subclass which implements wx scroll behaviour
+ @discussion
+ Overrides default behaviour of NSScrollView such that this class receives
+ the scroller action messages and allows the wxCocoaScrollView to act
+ on them accordingly. In particular, because the NSScrollView will not
+ receive action messages from the scroller, it will not adjust the
+ document view. This must be done manually using the ScrollWindow
+ method of wxWindow.
+ */
+@interface WXManualScrollView : NSScrollView
+{
+ /*! @field m_wxCocoaScrollView
+ */
+ wxWindowCocoaScrollView *m_wxCocoaScrollView;
+}
+
+// Override these to set up the target/action correctly
+- (void)setHorizontalScroller:(NSScroller *)aScroller;
+- (void)setVerticalScroller:(NSScroller *)aScroller;
+- (void)setHasHorizontalScroller:(BOOL)flag;
+- (void)setHasVerticalScroller:(BOOL)flag;
+
+// NOTE: _wx_ prefix means "private" method like _ that Apple (and only Apple) uses.
+- (wxWindowCocoaScrollView*)_wx_wxCocoaScrollView;
+- (void)_wx_setWxCocoaScrollView:(wxWindowCocoaScrollView*)theWxScrollView;
+
+/*! @method _wx_doScroller
+ @abstract Handles action messages from the scrollers
+ @discussion
+ Similar to Apple's _doScroller: method which is private and not documented.
+ We do not, however, call that method. Instead, we effectively override
+ it entirely. We don't override it by naming ourself the same thing because
+ the base class code may or may not call that method for other reasons we
+ simply cannot know about.
+ */
+- (void)_wx_doScroller:(id)sender;
+
+@end
+
+
+@implementation WXManualScrollView : NSScrollView
+
+static inline void WXManualScrollView_DoSetScrollerTargetAction(WXManualScrollView *self, NSScroller *aScroller)
+{
+ if(aScroller != NULL && [self _wx_wxCocoaScrollView] != NULL)
+ {
+ [aScroller setTarget:self];
+ [aScroller setAction:@selector(_wx_doScroller:)];
+ }
+}
+
+- (void)setHorizontalScroller:(NSScroller *)aScroller
+{
+ [super setHorizontalScroller:aScroller];
+ WXManualScrollView_DoSetScrollerTargetAction(self, aScroller);
+}
+
+- (void)setVerticalScroller:(NSScroller *)aScroller
+{
+ [super setVerticalScroller:aScroller];
+ WXManualScrollView_DoSetScrollerTargetAction(self, aScroller);
+}
+
+- (void)setHasHorizontalScroller:(BOOL)flag
+{
+ [super setHasHorizontalScroller:flag];
+ WXManualScrollView_DoSetScrollerTargetAction(self, [self horizontalScroller]);
+}
+
+- (void)setHasVerticalScroller:(BOOL)flag
+{
+ [super setHasVerticalScroller:flag];
+ WXManualScrollView_DoSetScrollerTargetAction(self, [self verticalScroller]);
+}
+
+- (wxWindowCocoaScrollView*)_wx_wxCocoaScrollView
+{ return m_wxCocoaScrollView; }
+
+- (void)_wx_setWxCocoaScrollView:(wxWindowCocoaScrollView*)theWxScrollView
+{
+ m_wxCocoaScrollView = theWxScrollView;
+ [self setHorizontalScroller:[self horizontalScroller]];
+ [self setVerticalScroller:[self verticalScroller]];
+}
+
+- (void)_wx_doScroller:(id)sender
+{
+ if(m_wxCocoaScrollView != NULL)
+ m_wxCocoaScrollView->_wx_doScroller(sender);
+ else
+ wxLogError(wxT("Unexpected action message received from NSScroller"));
+}
+
+- (void)reflectScrolledClipView:(NSClipView *)aClipView
+{
+ struct _ScrollerBackup
+ {
+ _ScrollerBackup(NSScroller *aScroller)
+ : m_scroller(aScroller)
+ , m_floatValue(aScroller!=nil?[aScroller floatValue]:0.0)
+ , m_knobProportion(aScroller!=nil?[aScroller knobProportion]:1.0)
+ , m_isEnabled(aScroller!=nil?[aScroller isEnabled]:false)
+ {
+ }
+ NSScroller *m_scroller;
+ CGFloat m_floatValue;
+ CGFloat m_knobProportion;
+ BOOL m_isEnabled;
+ ~_ScrollerBackup()
+ {
+ if(m_scroller != nil)
+ {
+ [m_scroller setFloatValue:m_floatValue knobProportion:m_knobProportion];
+ [m_scroller setEnabled:m_isEnabled];
+ }
+ }
+ private:
+ _ScrollerBackup();
+ _ScrollerBackup(_ScrollerBackup const&);
+ _ScrollerBackup& operator=(_ScrollerBackup const&);
+ };
+ _ScrollerBackup _horizontalBackup([self horizontalScroller]);
+ _ScrollerBackup _verticalBackup([self verticalScroller]);
+ // We MUST call super's implementation or else nothing seems to work right at all.
+ // However, we need our scrollers not to change values due to the document window
+ // moving so we cheat and save/restore their values across this call.
+ [super reflectScrolledClipView: aClipView];
+}
+
+@end
+WX_IMPLEMENT_GET_OBJC_CLASS(WXManualScrollView,NSScrollView)
+
+// ========================================================================
+// wxFlippedNSClipView
+// ========================================================================
+@interface wxFlippedNSClipView : NSClipView
+- (BOOL)isFlipped;
+@end
+WX_DECLARE_GET_OBJC_CLASS(wxFlippedNSClipView,NSClipView)
+
+@implementation wxFlippedNSClipView : NSClipView
+- (BOOL)isFlipped
+{
+ return YES;
+}
+
+@end
+WX_IMPLEMENT_GET_OBJC_CLASS(wxFlippedNSClipView,NSClipView)
+
+// ========================================================================
+// wxWindowCocoaScrollView
+// ========================================================================
+wxWindowCocoaScrollView::wxWindowCocoaScrollView(wxWindow *owner)
+: m_owner(owner)
+, m_cocoaNSScrollView() // nil
+, m_scrollRange() // {0,0}
+, m_scrollThumb() // {0,0}
+, m_virtualOrigin(0,0)
+{
+ wxAutoNSAutoreleasePool pool;
+ wxASSERT(owner);
+ wxASSERT(owner->GetNSView());
+ m_isNativeView = ![owner->GetNSView() isKindOfClass:[WX_GET_OBJC_CLASS(WXNSView) class]];
+ m_cocoaNSScrollView = [(m_isNativeView?[NSScrollView alloc]:[WXManualScrollView alloc])
+ initWithFrame:[owner->GetNSView() frame]];
+ AssociateNSView(m_cocoaNSScrollView);
+ if(m_isNativeView)
+ {
+ /* Set a bezel border around the entire thing because it looks funny without it.
+ TODO: Be sure to undo any borders on the real view (if any) and apply them
+ to this view if necessary. Right now, there is no border support in wxCocoa
+ so this isn't an issue.
+ */
+ [m_cocoaNSScrollView setBorderType:NSBezelBorder];
+ }
+ else
+ {
+ [(WXManualScrollView*)m_cocoaNSScrollView _wx_setWxCocoaScrollView: this];
+ // Don't set a bezel because we might be creating a scroll view due to being
+ // the "target window" of a wxScrolledWindow. That is to say that the user
+ // has absolutely no intention of scrolling the clip view used by this
+ // NSScrollView.
+ }
+
+ /* Replace the default NSClipView with a flipped one. This ensures
+ scrolling is "pinned" to the top-left instead of bottom-right. */
+ NSClipView *flippedClip = [[WX_GET_OBJC_CLASS(wxFlippedNSClipView) alloc]
+ initWithFrame: [[m_cocoaNSScrollView contentView] frame]];
+ [m_cocoaNSScrollView setContentView:flippedClip];
+ [flippedClip release];
+
+ // In all cases we must encapsulate the real NSView properly
+ Encapsulate();
+}
+
+void wxWindowCocoaScrollView::Encapsulate()
+{
+ // Set the scroll view autoresizingMask to match the current NSView
+ [m_cocoaNSScrollView setAutoresizingMask: [m_owner->GetNSView() autoresizingMask]];
+ [m_owner->GetNSView() setAutoresizingMask: NSViewNotSizable];
+ // NOTE: replaceSubView will cause m_cocaNSView to be released
+ // except when it hasn't been added into an NSView hierarchy in which
+ // case it doesn't need to be and this should work out to a no-op
+ m_owner->CocoaReplaceView(m_owner->GetNSView(), m_cocoaNSScrollView);
+ // The NSView is still retained by owner
+ [m_cocoaNSScrollView setDocumentView: m_owner->GetNSView()];
+ // Now it's also retained by the NSScrollView
+}
+
+void wxWindowCocoaScrollView::Unencapsulate()
+{
+ [m_cocoaNSScrollView setDocumentView: nil];
+ m_owner->CocoaReplaceView(m_cocoaNSScrollView, m_owner->GetNSView());
+ if(![[m_owner->GetNSView() superview] isFlipped])
+ [m_owner->GetNSView() setAutoresizingMask: NSViewMinYMargin];
+}
+
+wxWindowCocoaScrollView::~wxWindowCocoaScrollView()
+{
+ DisassociateNSView(m_cocoaNSScrollView);
+ if(!m_isNativeView)
+ {
+ [(WXManualScrollView*)m_cocoaNSScrollView _wx_setWxCocoaScrollView:NULL];
+ }
+ [m_cocoaNSScrollView release];
+}
+
+void wxWindowCocoaScrollView::ClientSizeToSize(int &width, int &height)
+{
+ NSSize frameSize = [NSScrollView
+ frameSizeForContentSize: NSMakeSize(width,height)
+ hasHorizontalScroller: [m_cocoaNSScrollView hasHorizontalScroller]
+ hasVerticalScroller: [m_cocoaNSScrollView hasVerticalScroller]
+ borderType: [m_cocoaNSScrollView borderType]];
+ width = (int)frameSize.width;
+ height = (int)frameSize.height;
+}
+
+void wxWindowCocoaScrollView::DoGetClientSize(int *x, int *y) const
+{
+ NSSize nssize = [m_cocoaNSScrollView contentSize];
+ if(x)
+ *x = (int)nssize.width;
+ if(y)
+ *y = (int)nssize.height;
+}
+
+static inline void SetCocoaScroller(NSScroller *aScroller, int WXUNUSED(orientation), int position, int thumbSize, int range)
+{
+ wxCHECK_RET(aScroller != nil, wxT("Expected the NSScrollView to have a scroller"));
+
+ // NOTE: thumbSize is already ensured to be >= 1 and <= range by our caller
+ // unless range = 0 in which case we shouldn't have been be called.
+ wxCHECK_RET(range > 0, wxT("Internal wxCocoa bug: shouldn't have been called with 0 range"));
+
+ // Range of valid position values is from 0 to effectiveRange
+ // NOTE: if thumbSize == range then effectiveRange is 0.
+ // thumbSize is at least 1 which gives range from 0 to range - 1 inclusive
+ // which is exactly what we want.
+ int effectiveRange = range - thumbSize;
+
+ // knobProportion is hopefully easy to understand
+ // Note that thumbSize is already guaranteed >= 1 by our caller.
+ CGFloat const knobProportion = CGFloat(thumbSize)/CGFloat(range);
+
+ // NOTE: When effectiveRange is zero there really is no valid position
+ // We arbitrarily pick 0.0 which is the same as a scroller in the home position.
+ CGFloat const floatValue = (effectiveRange != 0)?CGFloat(position)/CGFloat(effectiveRange):0.0;
+
+ [aScroller setFloatValue:floatValue knobProportion: knobProportion];
+ // Make sure it's visibly working
+ [aScroller setEnabled:YES];
+}
+
+void wxWindowCocoaScrollView::SetScrollPos(wxOrientation orientation, int position)
+{
+ // NOTE: Rather than using only setFloatValue: (which we could do) we instead
+ // simply share the SetCocoaScroller call because all but the knobProportion
+ // calculations have to be done anyway.
+ if(orientation & wxHORIZONTAL)
+ {
+ NSScroller *aScroller = [m_cocoaNSScrollView horizontalScroller];
+ if(aScroller != nil)
+ SetCocoaScroller(aScroller, orientation, position, m_scrollThumb[0], m_scrollRange[0]);
+ }
+ if(orientation & wxVERTICAL)
+ {
+ NSScroller *aScroller = [m_cocoaNSScrollView verticalScroller];
+ if(aScroller != nil)
+ SetCocoaScroller(aScroller, orientation, position, m_scrollThumb[1], m_scrollRange[1]);
+ }
+}
+
+void wxWindowCocoaScrollView::SetScrollbar(int orientation, int position, int thumbSize, int range)
+{
+ // FIXME: API assumptions:
+ // 1. If the user wants to remove a scroller he gives range 0.
+ // 2. If the user wants to disable a scroller he sets thumbSize == range
+ // in which case it is logically impossible to scroll.
+ // The scroller shall still be displayed.
+
+ // Ensure that range is >= 0.
+ wxASSERT(range >= 0);
+ if(range < 0)
+ range = 0;
+
+ // Ensure that thumbSize <= range
+ wxASSERT(thumbSize <= range);
+ // Also ensure thumbSize >= 1 but don't complain if it isn't
+ if(thumbSize < 1)
+ thumbSize = 1;
+ // Now make sure it's really less than range, even if we just set it to 1
+ if(thumbSize > range)
+ thumbSize = range;
+
+ bool needScroller = (range != 0);
+
+ // Can potentially set both horizontal and vertical at the same time although this is
+ // probably not very useful.
+ if(orientation & wxHORIZONTAL)
+ {
+ m_scrollRange[0] = range;
+ m_scrollThumb[0] = thumbSize;
+ if(!m_isNativeView)
+ {
+ [m_cocoaNSScrollView setHasHorizontalScroller:needScroller];
+ if(needScroller)
+ SetCocoaScroller([m_cocoaNSScrollView horizontalScroller], orientation, position, thumbSize, range);
+ }
+ }
+
+ if(orientation & wxVERTICAL)
+ {
+ m_scrollRange[1] = range;
+ m_scrollThumb[1] = thumbSize;
+ if(!m_isNativeView)
+ {
+ [m_cocoaNSScrollView setHasVerticalScroller:needScroller];
+ if(needScroller)
+ SetCocoaScroller([m_cocoaNSScrollView verticalScroller], orientation, position, thumbSize, range);
+ }
+ }
+}
+
+int wxWindowCocoaScrollView::GetScrollPos(wxOrientation orient)
+{
+ if((orient & wxBOTH) == wxBOTH)
+ {
+ wxLogError(wxT("GetScrollPos called for wxHORIZONTAL and wxVERTICAL together which makes no sense"));
+ return 0;
+ }
+ int effectiveScrollRange;
+ NSScroller *cocoaScroller;
+ if(orient & wxHORIZONTAL)
+ {
+ effectiveScrollRange = m_scrollRange[0] - m_scrollThumb[0];
+ cocoaScroller = [m_cocoaNSScrollView horizontalScroller];
+ }
+ else if(orient & wxVERTICAL)
+ {
+ effectiveScrollRange = m_scrollRange[1] - m_scrollThumb[1];
+ cocoaScroller = [m_cocoaNSScrollView verticalScroller];
+ }
+ else
+ {
+ wxLogError(wxT("GetScrollPos called without an orientation which makes no sense"));
+ return 0;
+ }
+ if(cocoaScroller == nil)
+ { // Document is not scrolled
+ return 0;
+ }
+ /*
+ The effective range of a scroll bar as defined by wxWidgets is from 0 to (range - thumbSize).
+ That is a scroller at the left/top position is at 0 and a scroller at the bottom/right
+ position is at range-thumbsize.
+
+ The range of an NSScroller is 0.0 to 1.0. Much easier! NOTE: Apple doesn't really specify
+ but GNUStep docs do say that 0.0 is top/left and 1.0 is bottom/right. This is actually
+ in contrast to NSSlider which generally has 1.0 at the TOP when it's done vertically.
+ */
+ CGFloat cocoaScrollPos = [cocoaScroller floatValue];
+ return effectiveScrollRange * cocoaScrollPos;
+}
+
+int wxWindowCocoaScrollView::GetScrollRange(wxOrientation orient)
+{
+ if((orient & wxBOTH) == wxBOTH)
+ {
+ wxLogError(wxT("GetScrollRange called for wxHORIZONTAL and wxVERTICAL together which makes no sense"));
+ return 0;
+ }
+ if(orient & wxHORIZONTAL)
+ {
+ return m_scrollRange[0];
+ }
+ else if(orient & wxVERTICAL)
+ {
+ return m_scrollRange[1];
+ }
+ else
+ {
+ wxLogError(wxT("GetScrollPos called without an orientation which makes no sense"));
+ return 0;
+ }
+}
projects / wxWidgets.git / blobdiff