+// ========================================================================
+// wxCocoaMouseMovedEventSynthesizer
+// ========================================================================
+
+#define wxTRACE_COCOA_MouseMovedSynthesizer wxT("COCOA_MouseMovedSynthesizer")
+
+/* This class registers one run loop observer to cover all windows registered with it.
+ * It will register the observer when the first view is registerd and unregister the
+ * observer when the last view is unregistered.
+ * It is instantiated as a static s_mouseMovedSynthesizer in this file although there
+ * is no reason it couldn't be instantiated multiple times.
+ */
+class wxCocoaMouseMovedEventSynthesizer
+{
+ wxDECLARE_NO_COPY_CLASS(wxCocoaMouseMovedEventSynthesizer);
+public:
+ wxCocoaMouseMovedEventSynthesizer()
+ { m_lastScreenMouseLocation = NSZeroPoint;
+ }
+ ~wxCocoaMouseMovedEventSynthesizer();
+ void RegisterWxCocoaView(wxCocoaNSView *aView);
+ void UnregisterWxCocoaView(wxCocoaNSView *aView);
+ void SynthesizeMouseMovedEvent();
+
+protected:
+ void AddRunLoopObserver();
+ void RemoveRunLoopObserver();
+ wxCFRef<CFRunLoopObserverRef> m_runLoopObserver;
+ std::list<wxCocoaNSView*> m_registeredViews;
+ NSPoint m_lastScreenMouseLocation;
+ static void SynthesizeMouseMovedEvent(CFRunLoopObserverRef observer, CFRunLoopActivity activity, void *info);
+};
+
+void wxCocoaMouseMovedEventSynthesizer::RegisterWxCocoaView(wxCocoaNSView *aView)
+{
+ m_registeredViews.push_back(aView);
+ wxLogTrace(wxTRACE_COCOA_MouseMovedSynthesizer, wxT("Registered wxCocoaNSView=%p"), aView);
+
+ if(!m_registeredViews.empty() && m_runLoopObserver == NULL)
+ {
+ AddRunLoopObserver();
+ }
+}
+
+void wxCocoaMouseMovedEventSynthesizer::UnregisterWxCocoaView(wxCocoaNSView *aView)
+{
+ m_registeredViews.remove(aView);
+ wxLogTrace(wxTRACE_COCOA_MouseMovedSynthesizer, wxT("Unregistered wxCocoaNSView=%p"), aView);
+ if(m_registeredViews.empty() && m_runLoopObserver != NULL)
+ {
+ RemoveRunLoopObserver();
+ }
+}
+
+wxCocoaMouseMovedEventSynthesizer::~wxCocoaMouseMovedEventSynthesizer()
+{
+ if(!m_registeredViews.empty())
+ {
+ // This means failure to clean up so we report on it as a debug message.
+ wxLogDebug(wxT("There are still %d wxCocoaNSView registered to receive mouse moved events at static destruction time"), m_registeredViews.size());
+ m_registeredViews.clear();
+ }
+ if(m_runLoopObserver != NULL)
+ {
+ // This should not occur unless m_registeredViews was not empty since the last object unregistered should have done this.
+ wxLogDebug(wxT("Removing run loop observer during static destruction time."));
+ RemoveRunLoopObserver();
+ }
+}
+
+void wxCocoaMouseMovedEventSynthesizer::SynthesizeMouseMovedEvent(CFRunLoopObserverRef observer, CFRunLoopActivity activity, void *info)
+{
+ reinterpret_cast<wxCocoaMouseMovedEventSynthesizer*>(info)->SynthesizeMouseMovedEvent();
+}
+
+void wxCocoaMouseMovedEventSynthesizer::AddRunLoopObserver()
+{
+ CFRunLoopObserverContext observerContext =
+ { 0
+ , this
+ , NULL
+ , NULL
+ , NULL
+ };
+
+ // The kCFRunLoopExit observation point is used such that we hook the run loop after it has already decided that
+ // it is going to exit which is generally for the purpose of letting the event loop process the next Cocoa event.
+
+ // Executing our procedure within the run loop (e.g. kCFRunLoopBeforeWaiting which was used before) results
+ // in our observer procedure being called before the run loop has decided that it is going to return control to
+ // the Cocoa event loop. One major problem is uncovered by the wxGenericHyperlinkCtrl (consider this to be "user
+ // code") which changes the window's cursor and thus causes the cursor rectangle's to be invalidated.
+
+ // Cocoa implements this invalidation using a delayed notification scheme whereby the resetCursorRects method
+ // won't be called until the CFRunLoop gets around to it. If the CFRunLoop has not yet exited then it will get
+ // around to it before letting the event loop do its work. This has some very odd effects on the way the
+ // newly created tracking rects function. In particular, we will often miss the mouseExited: message if the
+ // user flicks the mouse quickly enough such that the mouse is already outside of the tracking rect by the
+ // time the new one is built.
+
+ // Observing from the kCFRunLoopExit point gives Cocoa's event loop an opportunity to chew some events before it cedes
+ // control back to the CFRunLoop, thus causing the delayed notifications to fire at an appropriate time and
+ // the mouseExited: message to be sent properly.
+
+ m_runLoopObserver.reset(CFRunLoopObserverCreate(kCFAllocatorDefault, kCFRunLoopExit, TRUE, 0, SynthesizeMouseMovedEvent, &observerContext));
+ CFRunLoopAddObserver([[NSRunLoop currentRunLoop] getCFRunLoop], m_runLoopObserver, kCFRunLoopCommonModes);
+ wxLogTrace(wxTRACE_COCOA_TrackingRect, wxT("Added tracking rect run loop observer"));
+}
+
+void wxCocoaMouseMovedEventSynthesizer::RemoveRunLoopObserver()
+{
+ CFRunLoopRemoveObserver([[NSRunLoop currentRunLoop] getCFRunLoop], m_runLoopObserver, kCFRunLoopCommonModes);
+ m_runLoopObserver.reset();
+ wxLogTrace(wxTRACE_COCOA_TrackingRect, wxT("Removed tracking rect run loop observer"));
+}
+
+void wxCocoaMouseMovedEventSynthesizer::SynthesizeMouseMovedEvent()
+{
+ NSPoint screenMouseLocation = [NSEvent mouseLocation];
+ // Checking the last mouse location is done for a few reasons:
+ // 1. We are observing every iteration of the event loop so we'd be sending out a lot of extraneous events
+ // telling the app the mouse moved when the user hit a key for instance.
+ // 2. When handling the mouse moved event, user code can do something to the view which will cause Cocoa to
+ // call resetCursorRects. Cocoa does this by using a delayed notification which means the event loop gets
+ // pumped once which would mean that if we didn't check the mouse location we'd get into a never-ending
+ // loop causing the tracking rectangles to constantly be reset.
+ if(screenMouseLocation.x != m_lastScreenMouseLocation.x || screenMouseLocation.y != m_lastScreenMouseLocation.y)
+ {
+ m_lastScreenMouseLocation = screenMouseLocation;
+ wxLogTrace(wxTRACE_COCOA_TrackingRect, wxT("Synthesizing mouse moved at screen (%f,%f)"), screenMouseLocation.x, screenMouseLocation.y);
+ for(std::list<wxCocoaNSView*>::iterator i = m_registeredViews.begin(); i != m_registeredViews.end(); ++i)
+ {
+ (*i)->Cocoa_synthesizeMouseMoved();
+ }
+ }
+}
+
+// Singleton used for all views:
+static wxCocoaMouseMovedEventSynthesizer s_mouseMovedSynthesizer;
+
+// ========================================================================
+// wxCocoaTrackingRectManager
+// ========================================================================
+
+wxCocoaTrackingRectManager::wxCocoaTrackingRectManager(wxWindow *window)
+: m_window(window)
+{
+ m_isTrackingRectActive = false;
+ BuildTrackingRect();
+}
+
+void wxCocoaTrackingRectManager::ClearTrackingRect()
+{
+ if(m_isTrackingRectActive)
+ {
+ [m_window->GetNSView() removeTrackingRect:m_trackingRectTag];
+ m_isTrackingRectActive = false;
+ wxLogTrace(wxTRACE_COCOA_TrackingRect, wxT("%s@%p: Removed tracking rect #%d"), m_window->GetClassInfo()->GetClassName(), m_window, m_trackingRectTag);
+ }
+ // If we were doing periodic events we need to clear those too
+ StopSynthesizingEvents();
+}
+
+void wxCocoaTrackingRectManager::StopSynthesizingEvents()
+{
+ s_mouseMovedSynthesizer.UnregisterWxCocoaView(m_window);
+}
+
+void wxCocoaTrackingRectManager::BuildTrackingRect()
+{
+ // Pool here due to lack of one during wx init phase
+ wxAutoNSAutoreleasePool pool;
+
+ wxASSERT_MSG(!m_isTrackingRectActive, wxT("Tracking rect was not cleared"));
+
+ NSView *theView = m_window->GetNSView();
+
+ if([theView window] != nil)
+ {
+ NSRect visibleRect = [theView visibleRect];
+
+ m_trackingRectTag = [theView addTrackingRect:visibleRect owner:theView userData:NULL assumeInside:NO];
+ m_trackingRectInWindowCoordinates = [theView convertRect:visibleRect toView:nil];
+ m_isTrackingRectActive = true;
+
+ wxLogTrace(wxTRACE_COCOA_TrackingRect, wxT("%s@%p: Added tracking rect #%d"), m_window->GetClassInfo()->GetClassName(), m_window, m_trackingRectTag);
+ }
+}
+
+void wxCocoaTrackingRectManager::BeginSynthesizingEvents()
+{
+ s_mouseMovedSynthesizer.RegisterWxCocoaView(m_window);
+}
+
+void wxCocoaTrackingRectManager::RebuildTrackingRectIfNeeded()
+{
+ if(m_isTrackingRectActive)
+ {
+ NSView *theView = m_window->GetNSView();
+ NSRect currentRect = [theView convertRect:[theView visibleRect] toView:nil];
+ if(NSEqualRects(m_trackingRectInWindowCoordinates,currentRect))
+ {
+ wxLogTrace(wxTRACE_COCOA_TrackingRect, wxT("Ignored request to rebuild TR#%d"), m_trackingRectTag);
+ return;
+ }
+ }
+ RebuildTrackingRect();
+}
+
+void wxCocoaTrackingRectManager::RebuildTrackingRect()
+{
+ ClearTrackingRect();
+ BuildTrackingRect();
+}
+
+wxCocoaTrackingRectManager::~wxCocoaTrackingRectManager()
+{
+ ClearTrackingRect();
+}
+
+bool wxCocoaTrackingRectManager::IsOwnerOfEvent(NSEvent *anEvent)
+{
+ return m_isTrackingRectActive && (m_trackingRectTag == [anEvent trackingNumber]);
+}
+
projects / wxWidgets.git / blobdiff