+
+#ifdef WXCOCOA_FILL_DUMMY_VIEW
+bool wxWindowCocoaHider::Cocoa_drawRect(const NSRect& rect)
+{
+ NSBezierPath *bezpath = [NSBezierPath bezierPathWithRect:rect];
+ [[NSColor greenColor] set];
+ [bezpath stroke];
+ [bezpath fill];
+ return true;
+}
+#endif //def WXCOCOA_FILL_DUMMY_VIEW
+
+
+/*! @class WXManualScrollView
+ @abstract An NSScrollView subclass which implements wx scroll behaviour
+ @discussion
+ Overrides default behaviour of NSScrollView such that this class receives
+ the scroller action messages and allows the wxCocoaScrollView to act
+ on them accordingly. In particular, because the NSScrollView will not
+ receive action messages from the scroller, it will not adjust the
+ document view. This must be done manually using the ScrollWindow
+ method of wxWindow.
+ */
+@interface WXManualScrollView : NSScrollView
+{
+ /*! @field m_wxCocoaScrollView
+ */
+ wxWindowCocoaScrollView *m_wxCocoaScrollView;
+}
+
+// Override these to set up the target/action correctly
+- (void)setHorizontalScroller:(NSScroller *)aScroller;
+- (void)setVerticalScroller:(NSScroller *)aScroller;
+- (void)setHasHorizontalScroller:(BOOL)flag;
+- (void)setHasVerticalScroller:(BOOL)flag;
+
+// NOTE: _wx_ prefix means "private" method like _ that Apple (and only Apple) uses.
+- (wxWindowCocoaScrollView*)_wx_wxCocoaScrollView;
+- (void)_wx_setWxCocoaScrollView:(wxWindowCocoaScrollView*)theWxScrollView;
+
+/*! @method _wx_doScroller
+ @abstract Handles action messages from the scrollers
+ @discussion
+ Similar to Apple's _doScroller: method which is private and not documented.
+ We do not, however, call that method. Instead, we effectively override
+ it entirely. We don't override it by naming ourself the same thing because
+ the base class code may or may not call that method for other reasons we
+ simply cannot know about.
+ */
+- (void)_wx_doScroller:(id)sender;
+
+@end
+
+
+@implementation WXManualScrollView : NSScrollView
+
+static inline void WXManualScrollView_DoSetScrollerTargetAction(WXManualScrollView *self, NSScroller *aScroller)
+{
+ if(aScroller != NULL && [self _wx_wxCocoaScrollView] != NULL)
+ {
+ [aScroller setTarget:self];
+ [aScroller setAction:@selector(_wx_doScroller:)];
+ }
+}
+
+- (void)setHorizontalScroller:(NSScroller *)aScroller
+{
+ [super setHorizontalScroller:aScroller];
+ WXManualScrollView_DoSetScrollerTargetAction(self, aScroller);
+}
+
+- (void)setVerticalScroller:(NSScroller *)aScroller
+{
+ [super setVerticalScroller:aScroller];
+ WXManualScrollView_DoSetScrollerTargetAction(self, aScroller);
+}
+
+- (void)setHasHorizontalScroller:(BOOL)flag
+{
+ [super setHasHorizontalScroller:flag];
+ WXManualScrollView_DoSetScrollerTargetAction(self, [self horizontalScroller]);
+}
+
+- (void)setHasVerticalScroller:(BOOL)flag
+{
+ [super setHasVerticalScroller:flag];
+ WXManualScrollView_DoSetScrollerTargetAction(self, [self verticalScroller]);
+}
+
+- (wxWindowCocoaScrollView*)_wx_wxCocoaScrollView
+{ return m_wxCocoaScrollView; }
+
+- (void)_wx_setWxCocoaScrollView:(wxWindowCocoaScrollView*)theWxScrollView
+{
+ m_wxCocoaScrollView = theWxScrollView;
+ [self setHorizontalScroller:[self horizontalScroller]];
+ [self setVerticalScroller:[self verticalScroller]];
+}
+
+- (void)_wx_doScroller:(id)sender
+{
+ if(m_wxCocoaScrollView != NULL)
+ m_wxCocoaScrollView->_wx_doScroller(sender);
+ else
+ wxLogError(wxT("Unexpected action message received from NSScroller"));
+}
+
+- (void)reflectScrolledClipView:(NSClipView *)aClipView
+{
+ struct _ScrollerBackup
+ {
+ _ScrollerBackup(NSScroller *aScroller)
+ : m_scroller(aScroller)
+ , m_floatValue(aScroller!=nil?[aScroller floatValue]:0.0)
+ , m_knobProportion(aScroller!=nil?[aScroller knobProportion]:1.0)
+ , m_isEnabled(aScroller!=nil?[aScroller isEnabled]:false)
+ {
+ }
+ NSScroller *m_scroller;
+ CGFloat m_floatValue;
+ CGFloat m_knobProportion;
+ BOOL m_isEnabled;
+ ~_ScrollerBackup()
+ {
+ if(m_scroller != nil)
+ {
+ [m_scroller setFloatValue:m_floatValue knobProportion:m_knobProportion];
+ [m_scroller setEnabled:m_isEnabled];
+ }
+ }
+ private:
+ _ScrollerBackup();
+ _ScrollerBackup(_ScrollerBackup const&);
+ _ScrollerBackup& operator=(_ScrollerBackup const&);
+ };
+ _ScrollerBackup _horizontalBackup([self horizontalScroller]);
+ _ScrollerBackup _verticalBackup([self verticalScroller]);
+ // We MUST call super's implementation or else nothing seems to work right at all.
+ // However, we need our scrollers not to change values due to the document window
+ // moving so we cheat and save/restore their values across this call.
+ [super reflectScrolledClipView: aClipView];
+}
+
+@end
+WX_IMPLEMENT_GET_OBJC_CLASS(WXManualScrollView,NSScrollView)
+
+// ========================================================================
+// wxFlippedNSClipView
+// ========================================================================
+@interface wxFlippedNSClipView : NSClipView
+- (BOOL)isFlipped;
+@end
+WX_DECLARE_GET_OBJC_CLASS(wxFlippedNSClipView,NSClipView)
+
+@implementation wxFlippedNSClipView : NSClipView
+- (BOOL)isFlipped
+{
+ return YES;
+}
+
+@end
+WX_IMPLEMENT_GET_OBJC_CLASS(wxFlippedNSClipView,NSClipView)
+
+// ========================================================================
+// wxWindowCocoaScrollView
+// ========================================================================
+wxWindowCocoaScrollView::wxWindowCocoaScrollView(wxWindow *owner)
+: m_owner(owner)
+, m_cocoaNSScrollView() // nil
+, m_scrollRange() // {0,0}
+, m_scrollThumb() // {0,0}
+, m_virtualOrigin(0,0)
+{
+ wxAutoNSAutoreleasePool pool;
+ wxASSERT(owner);
+ wxASSERT(owner->GetNSView());
+ m_isNativeView = ![owner->GetNSView() isKindOfClass:[WX_GET_OBJC_CLASS(WXNSView) class]];
+ m_cocoaNSScrollView = [(m_isNativeView?[NSScrollView alloc]:[WXManualScrollView alloc])
+ initWithFrame:[owner->GetNSView() frame]];
+ AssociateNSView(m_cocoaNSScrollView);
+ if(m_isNativeView)
+ {
+ /* Set a bezel border around the entire thing because it looks funny without it.
+ TODO: Be sure to undo any borders on the real view (if any) and apply them
+ to this view if necessary. Right now, there is no border support in wxCocoa
+ so this isn't an issue.
+ */
+ [m_cocoaNSScrollView setBorderType:NSBezelBorder];
+ }
+ else
+ {
+ [(WXManualScrollView*)m_cocoaNSScrollView _wx_setWxCocoaScrollView: this];
+ // Don't set a bezel because we might be creating a scroll view due to being
+ // the "target window" of a wxScrolledWindow. That is to say that the user
+ // has absolutely no intention of scrolling the clip view used by this
+ // NSScrollView.
+ }
+
+ /* Replace the default NSClipView with a flipped one. This ensures
+ scrolling is "pinned" to the top-left instead of bottom-right. */
+ NSClipView *flippedClip = [[WX_GET_OBJC_CLASS(wxFlippedNSClipView) alloc]
+ initWithFrame: [[m_cocoaNSScrollView contentView] frame]];
+ [m_cocoaNSScrollView setContentView:flippedClip];
+ [flippedClip release];
+
+ // In all cases we must encapsulate the real NSView properly
+ Encapsulate();
+}
+
+void wxWindowCocoaScrollView::Encapsulate()
+{
+ // Set the scroll view autoresizingMask to match the current NSView
+ [m_cocoaNSScrollView setAutoresizingMask: [m_owner->GetNSView() autoresizingMask]];
+ [m_owner->GetNSView() setAutoresizingMask: NSViewNotSizable];
+ // NOTE: replaceSubView will cause m_cocaNSView to be released
+ // except when it hasn't been added into an NSView hierarchy in which
+ // case it doesn't need to be and this should work out to a no-op
+ m_owner->CocoaReplaceView(m_owner->GetNSView(), m_cocoaNSScrollView);
+ // The NSView is still retained by owner
+ [m_cocoaNSScrollView setDocumentView: m_owner->GetNSView()];
+ // Now it's also retained by the NSScrollView
+}
+
+void wxWindowCocoaScrollView::Unencapsulate()
+{
+ [m_cocoaNSScrollView setDocumentView: nil];
+ m_owner->CocoaReplaceView(m_cocoaNSScrollView, m_owner->GetNSView());
+ if(![[m_owner->GetNSView() superview] isFlipped])
+ [m_owner->GetNSView() setAutoresizingMask: NSViewMinYMargin];
+}
+
+wxWindowCocoaScrollView::~wxWindowCocoaScrollView()
+{
+ DisassociateNSView(m_cocoaNSScrollView);
+ if(!m_isNativeView)
+ {
+ [(WXManualScrollView*)m_cocoaNSScrollView _wx_setWxCocoaScrollView:NULL];
+ }
+ [m_cocoaNSScrollView release];
+}
+
+void wxWindowCocoaScrollView::ClientSizeToSize(int &width, int &height)
+{
+ NSSize frameSize = [NSScrollView
+ frameSizeForContentSize: NSMakeSize(width,height)
+ hasHorizontalScroller: [m_cocoaNSScrollView hasHorizontalScroller]
+ hasVerticalScroller: [m_cocoaNSScrollView hasVerticalScroller]
+ borderType: [m_cocoaNSScrollView borderType]];
+ width = (int)frameSize.width;
+ height = (int)frameSize.height;
+}
+
+void wxWindowCocoaScrollView::DoGetClientSize(int *x, int *y) const
+{
+ NSSize nssize = [m_cocoaNSScrollView contentSize];
+ if(x)
+ *x = (int)nssize.width;
+ if(y)
+ *y = (int)nssize.height;
+}
+
+static inline void SetCocoaScroller(NSScroller *aScroller, int WXUNUSED(orientation), int position, int thumbSize, int range)
+{
+ wxCHECK_RET(aScroller != nil, wxT("Expected the NSScrollView to have a scroller"));
+
+ // NOTE: thumbSize is already ensured to be >= 1 and <= range by our caller
+ // unless range = 0 in which case we shouldn't have been be called.
+ wxCHECK_RET(range > 0, wxT("Internal wxCocoa bug: shouldn't have been called with 0 range"));
+
+ // Range of valid position values is from 0 to effectiveRange
+ // NOTE: if thumbSize == range then effectiveRange is 0.
+ // thumbSize is at least 1 which gives range from 0 to range - 1 inclusive
+ // which is exactly what we want.
+ int effectiveRange = range - thumbSize;
+
+ // knobProportion is hopefully easy to understand
+ // Note that thumbSize is already guaranteed >= 1 by our caller.
+ CGFloat const knobProportion = CGFloat(thumbSize)/CGFloat(range);
+
+ // NOTE: When effectiveRange is zero there really is no valid position
+ // We arbitrarily pick 0.0 which is the same as a scroller in the home position.
+ CGFloat const floatValue = (effectiveRange != 0)?CGFloat(position)/CGFloat(effectiveRange):0.0;
+
+ [aScroller setFloatValue:floatValue knobProportion: knobProportion];
+ // Make sure it's visibly working
+ [aScroller setEnabled:YES];
+}
+
+void wxWindowCocoaScrollView::SetScrollPos(wxOrientation orientation, int position)
+{
+ // NOTE: Rather than using only setFloatValue: (which we could do) we instead
+ // simply share the SetCocoaScroller call because all but the knobProportion
+ // calculations have to be done anyway.
+ if(orientation & wxHORIZONTAL)
+ {
+ NSScroller *aScroller = [m_cocoaNSScrollView horizontalScroller];
+ if(aScroller != nil)
+ SetCocoaScroller(aScroller, orientation, position, m_scrollThumb[0], m_scrollRange[0]);
+ }
+ if(orientation & wxVERTICAL)
+ {
+ NSScroller *aScroller = [m_cocoaNSScrollView verticalScroller];
+ if(aScroller != nil)
+ SetCocoaScroller(aScroller, orientation, position, m_scrollThumb[1], m_scrollRange[1]);
+ }
+}
+
+void wxWindowCocoaScrollView::SetScrollbar(int orientation, int position, int thumbSize, int range)
+{
+ // FIXME: API assumptions:
+ // 1. If the user wants to remove a scroller he gives range 0.
+ // 2. If the user wants to disable a scroller he sets thumbSize == range
+ // in which case it is logically impossible to scroll.
+ // The scroller shall still be displayed.
+
+ // Ensure that range is >= 0.
+ wxASSERT(range >= 0);
+ if(range < 0)
+ range = 0;
+
+ // Ensure that thumbSize <= range
+ wxASSERT(thumbSize <= range);
+ // Also ensure thumbSize >= 1 but don't complain if it isn't
+ if(thumbSize < 1)
+ thumbSize = 1;
+ // Now make sure it's really less than range, even if we just set it to 1
+ if(thumbSize > range)
+ thumbSize = range;
+
+ bool needScroller = (range != 0);
+
+ // Can potentially set both horizontal and vertical at the same time although this is
+ // probably not very useful.
+ if(orientation & wxHORIZONTAL)
+ {
+ m_scrollRange[0] = range;
+ m_scrollThumb[0] = thumbSize;
+ if(!m_isNativeView)
+ {
+ [m_cocoaNSScrollView setHasHorizontalScroller:needScroller];
+ if(needScroller)
+ SetCocoaScroller([m_cocoaNSScrollView horizontalScroller], orientation, position, thumbSize, range);
+ }
+ }
+
+ if(orientation & wxVERTICAL)
+ {
+ m_scrollRange[1] = range;
+ m_scrollThumb[1] = thumbSize;
+ if(!m_isNativeView)
+ {
+ [m_cocoaNSScrollView setHasVerticalScroller:needScroller];
+ if(needScroller)
+ SetCocoaScroller([m_cocoaNSScrollView verticalScroller], orientation, position, thumbSize, range);
+ }
+ }
+}
+
+int wxWindowCocoaScrollView::GetScrollPos(wxOrientation orient)
+{
+ if((orient & wxBOTH) == wxBOTH)
+ {
+ wxLogError(wxT("GetScrollPos called for wxHORIZONTAL and wxVERTICAL together which makes no sense"));
+ return 0;
+ }
+ int effectiveScrollRange;
+ NSScroller *cocoaScroller;
+ if(orient & wxHORIZONTAL)
+ {
+ effectiveScrollRange = m_scrollRange[0] - m_scrollThumb[0];
+ cocoaScroller = [m_cocoaNSScrollView horizontalScroller];
+ }
+ else if(orient & wxVERTICAL)
+ {
+ effectiveScrollRange = m_scrollRange[1] - m_scrollThumb[1];
+ cocoaScroller = [m_cocoaNSScrollView verticalScroller];
+ }
+ else
+ {
+ wxLogError(wxT("GetScrollPos called without an orientation which makes no sense"));
+ return 0;
+ }
+ if(cocoaScroller == nil)
+ { // Document is not scrolled
+ return 0;
+ }
+ /*
+ The effective range of a scroll bar as defined by wxWidgets is from 0 to (range - thumbSize).
+ That is a scroller at the left/top position is at 0 and a scroller at the bottom/right
+ position is at range-thumbsize.
+
+ The range of an NSScroller is 0.0 to 1.0. Much easier! NOTE: Apple doesn't really specify
+ but GNUStep docs do say that 0.0 is top/left and 1.0 is bottom/right. This is actually
+ in contrast to NSSlider which generally has 1.0 at the TOP when it's done vertically.
+ */
+ CGFloat cocoaScrollPos = [cocoaScroller floatValue];
+ return effectiveScrollRange * cocoaScrollPos;
+}
+
+int wxWindowCocoaScrollView::GetScrollRange(wxOrientation orient)
+{
+ if((orient & wxBOTH) == wxBOTH)
+ {
+ wxLogError(wxT("GetScrollRange called for wxHORIZONTAL and wxVERTICAL together which makes no sense"));
+ return 0;
+ }
+ if(orient & wxHORIZONTAL)
+ {
+ return m_scrollRange[0];
+ }
+ else if(orient & wxVERTICAL)
+ {
+ return m_scrollRange[1];
+ }
+ else
+ {
+ wxLogError(wxT("GetScrollPos called without an orientation which makes no sense"));
+ return 0;
+ }
+}
+
+int wxWindowCocoaScrollView::GetScrollThumb(wxOrientation orient)
+{
+ if((orient & wxBOTH) == wxBOTH)
+ {
+ wxLogError(wxT("GetScrollThumb called for wxHORIZONTAL and wxVERTICAL together which makes no sense"));
+ return 0;
+ }
+ if(orient & wxHORIZONTAL)
+ {
+ return m_scrollThumb[0];
+ }
+ else if(orient & wxVERTICAL)
+ {
+ return m_scrollThumb[1];
+ }
+ else
+ {
+ wxLogError(wxT("GetScrollThumb called without an orientation which makes no sense"));
+ return 0;
+ }
+}
+
+/*!
+ Moves the contents (all existing drawing as well as all all child wxWindow) by the specified
+ amount expressed in the wxWindow's own coordinate system. This is used to implement scrolling
+ but the usage is rather interesting. When scrolling right (e.g. increasing the value of
+ the scroller) you must give a negative delta x (e.g. moving the contents LEFT). Likewise,
+ when scrolling the window down, increasing the value of the scroller, you give a negative
+ delta y which moves the contents up.
+
+ wxCocoa notes: To accomplish this trick in Cocoa we basically do what NSScrollView would
+ have done and that is adjust the content view's bounds origin. The content view is somewhat
+ confusingly the NSClipView which is more or less sort of the pImpl for NSScrollView
+ The real NSView with the user's content (e.g. the "virtual area" in wxWidgets parlance)
+ is called the document view in NSScrollView parlance.
+
+ The bounds origin is basically the exact opposite concept. Whereas in Windows the client
+ coordinate system remains constant and the content must shift left/up for increases
+ of scrolling, in Cocoa the coordinate system is actually the virtual one. So we must
+ instead shift the bounds rectangle right/down to get the effect of the content moving
+ left/up. Basically, it's a higher level interface than that provided by wxWidgets
+ so essentially we're implementing the low-level move content interface in terms of
+ the high-level move the viewport (the bounds) over top that content (the document
+ view which is the virtual area to wx).
+
+ For all intents and purposes that basically just means that we subtract the deltas
+ from the bounds origin and thus a negative delta actually increases the bounds origin
+ and a positive delta actually decreases it. This is absolutely true for the horizontal
+ axis but there's a catch in the vertical axis. If the content view (the clip view) is
+ flipped (and we do this by default) then it works exactly like the horizontal axis.
+ If it is not flipped (i.e. it is in postscript coordinates which are opposite to
+ wxWidgets) then the sense needs to be reversed.
+
+ However, this plays hell with window positions. The frame rects of any child views
+ do not change origin and this is actually important because if they did, the views
+ would send frame changed notifications, not to mention that Cocoa just doesn't really
+ do scrolling that way, it does it the way we do it here.
+
+ To fix this we implement GetPosition for child windows to not merely consult its
+ superview at the Cocoa level in order to do proper Cocoa->wx coordinate transform
+ but to actually consult is parent wxWindow because it makes a big difference if
+ the parent is scrolled. Argh. (FIXME: This isn't actually implemented yet)
+ */
+void wxWindowCocoaScrollView::ScrollWindow(int dx, int dy, const wxRect*)
+{
+ // Update our internal origin so we know how much the application code
+ // expects us to have been scrolled.
+ m_virtualOrigin.x += dx;
+ m_virtualOrigin.y += dy;
+
+ // Scroll the window using the standard Cocoa method of adjusting the
+ // clip view's bounds in the opposite fashion.
+ NSClipView *contentView = [m_cocoaNSScrollView contentView];
+ NSRect clipViewBoundsRect = [contentView bounds];
+ clipViewBoundsRect.origin.x -= dx;
+ if([contentView isFlipped])
+ clipViewBoundsRect.origin.y -= dy;
+ else
+ clipViewBoundsRect.origin.y += dy;
+ [contentView scrollToPoint:clipViewBoundsRect.origin];
+}
+
+void wxWindowCocoaScrollView::_wx_doScroller(NSScroller *sender)
+{
+ wxOrientation orientation;
+ if(sender == [m_cocoaNSScrollView horizontalScroller])
+ orientation = wxHORIZONTAL;
+ else if(sender == [m_cocoaNSScrollView verticalScroller])
+ orientation = wxVERTICAL;
+ else
+ {
+ wxLogDebug(wxT("Received action message from unexpected NSScroller"));
+ return;
+ }
+ // NOTE: Cocoa does not move the scroller for page up/down or line
+ // up/down events. That means the value will be the old value.
+ // For thumbtrack events, the value is the new value.
+ int scrollpos = GetScrollPos(orientation);
+ int commandType;
+ switch([sender hitPart])
+ {
+ default:
+ case NSScrollerNoPart:
+ case NSScrollerKnob: // Drag of knob
+ case NSScrollerKnobSlot: // Jump directly to position
+ commandType = wxEVT_SCROLLWIN_THUMBTRACK;
+ break;
+ case NSScrollerDecrementPage:
+ commandType = wxEVT_SCROLLWIN_PAGEUP;
+ break;
+ case NSScrollerIncrementPage:
+ commandType = wxEVT_SCROLLWIN_PAGEDOWN;
+ break;
+ case NSScrollerDecrementLine:
+ commandType = wxEVT_SCROLLWIN_LINEUP;
+ break;
+ case NSScrollerIncrementLine:
+ commandType = wxEVT_SCROLLWIN_LINEDOWN;
+ break;
+ }
+ wxScrollWinEvent event(commandType, scrollpos, orientation);
+ event.SetEventObject(m_owner);
+ m_owner->HandleWindowEvent(event);
+}
+
+void wxWindowCocoaScrollView::UpdateSizes()
+{
+ // Using the virtual size, figure out what the document frame size should be
+ // NOTE: Assume that the passed in virtualSize is already >= the client size
+ wxSize virtualSize = m_owner->GetVirtualSize();
+
+ // Get the document's current frame
+ NSRect documentViewFrame = [m_owner->GetNSView() frame];
+ NSRect newFrame = documentViewFrame;
+ newFrame.size = NSMakeSize(virtualSize.x, virtualSize.y);
+
+ if(!NSEqualRects(newFrame, documentViewFrame))
+ {
+ [m_owner->GetNSView() setFrame:newFrame];
+ }
+}
+
+void wxWindowCocoaScrollView::Cocoa_FrameChanged(void)
+{
+ wxLogTrace(wxTRACE_COCOA,wxT("wxWindowCocoaScrollView=%p::Cocoa_FrameChanged for wxWindow %p"), this, m_owner);
+ wxSizeEvent event(m_owner->GetSize(), m_owner->GetId());
+ event.SetEventObject(m_owner);
+ m_owner->HandleWindowEvent(event);
+
+ /* If the view is not a native one then it's being managed by wx. In this case the control
+ may decide to change its virtual size and we must update the document view's size to
+ match. For native views the virtual size will never have been set so we do not want
+ to use it at all.
+ */
+ if(!m_isNativeView)
+ UpdateSizes();
+}
+
projects / wxWidgets.git / blobdiff