+ wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
+ BOOL r = superimpl(slf, (SEL)_cmd);
+ if ( r )
+ {
+ DoNotifyFocusEvent( true, otherWindow );
+ }
+
+ return r;
+}
+
+bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
+{
+ wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
+ BOOL r = superimpl(slf, (SEL)_cmd);
+ // get the current focus after running resignFirstResponder
+ // note that this value isn't reliable, it might return the same view that
+ // is resigning
+ NSView* otherView = FindFocus();
+ wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
+ // NSTextViews have an editor as true responder, therefore the might get the
+ // resign notification if their editor takes over, don't trigger any event then
+ if ( r && !m_hasEditor)
+ {
+ DoNotifyFocusEvent( false, otherWindow );
+ }
+ return r;
+}
+
+void wxWidgetCocoaImpl::resetCursorRects(WXWidget slf, void *_cmd)
+{
+ wxWindow* wxpeer = GetWXPeer();
+ if ( wxpeer )
+ {
+ NSCursor *cursor = (NSCursor*)wxpeer->GetCursor().GetHCURSOR();
+ if (cursor == NULL)
+ {
+ wxOSX_ResetCursorRectsHandlerPtr superimpl = (wxOSX_ResetCursorRectsHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
+ superimpl(slf, (SEL)_cmd);
+ }
+ else
+ {
+ [slf addCursorRect: [slf bounds]
+ cursor: cursor];
+ }
+ }
+}
+
+bool wxWidgetCocoaImpl::isFlipped(WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
+{
+ return m_isFlipped;
+}
+
+
+#define OSX_DEBUG_DRAWING 0
+
+void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
+{
+ CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
+ CGContextSaveGState( context );
+
+#if OSX_DEBUG_DRAWING
+ CGContextBeginPath( context );
+ CGContextMoveToPoint(context, 0, 0);
+ NSRect bounds = [self bounds];
+ CGContextAddLineToPoint(context, 10, 0);
+ CGContextMoveToPoint(context, 0, 0);
+ CGContextAddLineToPoint(context, 0, 10);
+ CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
+ CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
+ CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
+ CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
+ CGContextClosePath( context );
+ CGContextStrokePath(context);
+#endif
+
+ if ( !m_isFlipped )
+ {
+ CGContextTranslateCTM( context, 0, [m_osxView bounds].size.height );
+ CGContextScaleCTM( context, 1, -1 );
+ }
+
+ wxRegion updateRgn;
+ const NSRect *rects;
+ NSInteger count;
+
+ [slf getRectsBeingDrawn:&rects count:&count];
+ for ( int i = 0 ; i < count ; ++i )
+ {
+ updateRgn.Union(wxFromNSRect(slf, rects[i]) );
+ }
+
+ wxWindow* wxpeer = GetWXPeer();
+ wxpeer->GetUpdateRegion() = updateRgn;
+ wxpeer->MacSetCGContextRef( context );
+
+ bool handled = wxpeer->MacDoRedraw( 0 );
+
+ CGContextRestoreGState( context );
+
+ CGContextSaveGState( context );
+ if ( !handled )
+ {
+ // call super
+ SEL _cmd = @selector(drawRect:);
+ wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
+ superimpl(slf, _cmd, *(NSRect*)rect);
+ CGContextRestoreGState( context );
+ CGContextSaveGState( context );
+ }
+ wxpeer->MacPaintChildrenBorders();
+ wxpeer->MacSetCGContextRef( NULL );
+ CGContextRestoreGState( context );
+}
+
+void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
+{
+ wxWindow* wxpeer = (wxWindow*) GetWXPeer();
+ if ( wxpeer )
+ wxpeer->OSXHandleClicked(0);
+}
+
+void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
+{
+}
+
+//
+
+#if OBJC_API_VERSION >= 2
+
+#define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
+ class_addMethod(c, s, i, t );
+
+#else
+
+#define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
+ { s, t, i },
+
+#endif
+
+void wxOSXCocoaClassAddWXMethods(Class c)
+{
+
+#if OBJC_API_VERSION < 2
+ static objc_method wxmethods[] =
+ {
+#endif
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(resetCursorRects), (IMP) wxOSX_resetCursorRects, "v@:" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
+
+ wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
+
+#if wxUSE_DRAG_AND_DROP
+ wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
+ wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
+#endif
+
+#if OBJC_API_VERSION < 2
+ } ;
+ static int method_count = WXSIZEOF( wxmethods );
+ static objc_method_list *wxmethodlist = NULL;
+ if ( wxmethodlist == NULL )
+ {
+ wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
+ memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
+ wxmethodlist->method_count = method_count;
+ wxmethodlist->obsolete = 0;
+ }
+ class_addMethods( c, wxmethodlist );
+#endif
+}
+
+//
+// C++ implementation class
+//
+
+IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
+
+wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl ) :
+ wxWidgetImpl( peer, isRootControl )
+{
+ Init();
+ m_osxView = w;
+
+ // check if the user wants to create the control initially hidden
+ if ( !peer->IsShown() )
+ SetVisibility(false);
+
+ // gc aware handling
+ if ( m_osxView )
+ CFRetain(m_osxView);
+ [m_osxView release];
+}
+
+wxWidgetCocoaImpl::wxWidgetCocoaImpl()
+{
+ Init();
+}
+
+void wxWidgetCocoaImpl::Init()
+{
+ m_osxView = NULL;
+ m_isFlipped = true;
+ m_lastKeyDownEvent = NULL;
+ m_hasEditor = false;
+}
+
+wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
+{
+ RemoveAssociations( this );
+
+ if ( !IsRootControl() )
+ {
+ NSView *sv = [m_osxView superview];
+ if ( sv != nil )
+ [m_osxView removeFromSuperview];
+ }
+ // gc aware handling
+ if ( m_osxView )
+ CFRelease(m_osxView);
+}
+
+bool wxWidgetCocoaImpl::IsVisible() const
+{
+ return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
+}
+
+void wxWidgetCocoaImpl::SetVisibility( bool visible )
+{
+ [m_osxView setHidden:(visible ? NO:YES)];
+}
+
+// ----------------------------------------------------------------------------
+// window animation stuff
+// ----------------------------------------------------------------------------
+
+// define a delegate used to refresh the window during animation
+@interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
+{
+ wxWindow *m_win;
+ bool m_isDone;
+}
+
+- (id)init:(wxWindow *)win;
+
+- (bool)isDone;
+
+// NSAnimationDelegate methods
+- (void)animationDidEnd:(NSAnimation*)animation;
+- (void)animation:(NSAnimation*)animation
+ didReachProgressMark:(NSAnimationProgress)progress;
+@end
+
+@implementation wxNSAnimationDelegate
+
+- (id)init:(wxWindow *)win
+{
+ [super init];
+
+ m_win = win;
+ m_isDone = false;
+
+ return self;
+}
+
+- (bool)isDone
+{
+ return m_isDone;
+}
+
+- (void)animation:(NSAnimation*)animation
+ didReachProgressMark:(NSAnimationProgress)progress
+{
+ wxUnusedVar(animation);
+ wxUnusedVar(progress);
+
+ m_win->SendSizeEvent();
+}
+
+- (void)animationDidEnd:(NSAnimation*)animation
+{
+ m_isDone = true;
+}
+
+@end
+
+/* static */
+bool
+wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
+ bool show,
+ wxShowEffect effect,
+ unsigned timeout)
+{
+ // create the dictionary describing the animation to perform on this view
+ NSObject * const
+ viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
+ NSMutableDictionary * const
+ dict = [NSMutableDictionary dictionaryWithCapacity:4];
+ [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
+
+ // determine the start and end rectangles assuming we're hiding the window
+ const wxRect rectOrig = win->GetRect();
+ wxRect rectStart,
+ rectEnd;
+ rectStart =
+ rectEnd = rectOrig;
+
+ if ( show )
+ {
+ if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
+ effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
+ effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
+ else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
+ effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
+ effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
+ else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
+ effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
+ effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
+ else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
+ effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
+ effect = wxSHOW_EFFECT_ROLL_TO_TOP;
+ }
+
+ switch ( effect )
+ {
+ case wxSHOW_EFFECT_ROLL_TO_LEFT:
+ case wxSHOW_EFFECT_SLIDE_TO_LEFT:
+ rectEnd.width = 0;
+ break;
+
+ case wxSHOW_EFFECT_ROLL_TO_RIGHT:
+ case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
+ rectEnd.x = rectStart.GetRight();
+ rectEnd.width = 0;
+ break;
+
+ case wxSHOW_EFFECT_ROLL_TO_TOP:
+ case wxSHOW_EFFECT_SLIDE_TO_TOP:
+ rectEnd.height = 0;
+ break;
+
+ case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
+ case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
+ rectEnd.y = rectStart.GetBottom();
+ rectEnd.height = 0;
+ break;
+
+ case wxSHOW_EFFECT_EXPAND:
+ rectEnd.x = rectStart.x + rectStart.width / 2;
+ rectEnd.y = rectStart.y + rectStart.height / 2;
+ rectEnd.width =
+ rectEnd.height = 0;
+ break;
+
+ case wxSHOW_EFFECT_BLEND:
+ [dict setObject:(show ? NSViewAnimationFadeInEffect
+ : NSViewAnimationFadeOutEffect)
+ forKey:NSViewAnimationEffectKey];
+ break;
+
+ case wxSHOW_EFFECT_NONE:
+ case wxSHOW_EFFECT_MAX:
+ wxFAIL_MSG( "unexpected animation effect" );
+ return false;
+
+ default:
+ wxFAIL_MSG( "unknown animation effect" );
+ return false;
+ };
+
+ if ( show )
+ {
+ // we need to restore it to the original rectangle instead of making it
+ // disappear
+ wxSwap(rectStart, rectEnd);
+
+ // and as the window is currently hidden, we need to show it for the
+ // animation to be visible at all (but don't restore it at its full
+ // rectangle as it shouldn't appear immediately)
+ win->SetSize(rectStart);
+ win->Show();
+ }
+
+ NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
+ ? [(NSView *)viewOrWin superview]
+ : nil;
+ const NSRect rStart = wxToNSRect(parentView, rectStart);
+ const NSRect rEnd = wxToNSRect(parentView, rectEnd);
+
+ [dict setObject:[NSValue valueWithRect:rStart]
+ forKey:NSViewAnimationStartFrameKey];
+ [dict setObject:[NSValue valueWithRect:rEnd]
+ forKey:NSViewAnimationEndFrameKey];
+
+ // create an animation using the values in the above dictionary
+ NSViewAnimation * const
+ anim = [[NSViewAnimation alloc]
+ initWithViewAnimations:[NSArray arrayWithObject:dict]];
+
+ if ( !timeout )
+ {
+ // what is a good default duration? Windows uses 200ms, Web frameworks
+ // use anything from 250ms to 1s... choose something in the middle
+ timeout = 500;
+ }
+
+ [anim setDuration:timeout/1000.]; // duration is in seconds here
+
+ // if the window being animated changes its layout depending on its size
+ // (which is almost always the case) we need to redo it during animation
+ //
+ // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
+ // controls in wxInfoBar visibly jump around)
+ const int NUM_LAYOUTS = 20;
+ for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
+ [anim addProgressMark:f];
+
+ wxNSAnimationDelegate * const
+ animDelegate = [[wxNSAnimationDelegate alloc] init:win];
+ [anim setDelegate:animDelegate];
+ [anim startAnimation];
+
+ // Cocoa is capable of doing animation asynchronously or even from separate
+ // thread but wx API doesn't provide any way to be notified about the
+ // animation end and without this we really must ensure that the window has
+ // the expected (i.e. the same as if a simple Show() had been used) size
+ // when we return, so block here until the animation finishes
+ //
+ // notice that because the default animation mode is NSAnimationBlocking,
+ // no user input events ought to be processed from here
+ {
+ wxEventLoopGuarantor ensureEventLoopExistence;
+ wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
+ while ( ![animDelegate isDone] )
+ loop->Dispatch();
+ }
+
+ if ( !show )
+ {
+ // NSViewAnimation is smart enough to hide the NSView being animated at
+ // the end but we also must ensure that it's hidden for wx too
+ win->Hide();
+
+ // and we must also restore its size because it isn't expected to
+ // change just because the window was hidden
+ win->SetSize(rectOrig);
+ }
+ else
+ {
+ // refresh it once again after the end to ensure that everything is in
+ // place
+ win->SendSizeEvent();
+ }
+
+ [anim setDelegate:nil];
+ [animDelegate release];
+ [anim release];
+
+ return true;
+}
+
+bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
+ wxShowEffect effect,
+ unsigned timeout)
+{
+ return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
+}
+
+void wxWidgetCocoaImpl::Raise()
+{
+ // Not implemented
+}
+
+void wxWidgetCocoaImpl::Lower()
+{
+ // Not implemented
+}
+
+void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
+{
+#if 1
+ SetNeedsDisplay() ;
+#else
+ // We should do something like this, but it wasn't working in 10.4.
+ if (GetNeedsDisplay() )
+ {
+ SetNeedsDisplay() ;
+ }
+ NSRect r = wxToNSRect( [m_osxView superview], *rect );
+ NSSize offset = NSMakeSize((float)dx, (float)dy);
+ [m_osxView scrollRect:r by:offset];
+#endif
+}
+
+void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
+{
+ wxWindowMac* parent = GetWXPeer()->GetParent();
+ // under Cocoa we might have a contentView in the wxParent to which we have to
+ // adjust the coordinates
+ if (parent && [m_osxView superview] != parent->GetHandle() )
+ {
+ int cx = 0,cy = 0,cw = 0,ch = 0;
+ if ( parent->GetPeer() )
+ {
+ parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
+ x -= cx;
+ y -= cy;
+ }
+ }
+ [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
+ NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
+ [m_osxView setFrame:r];
+ [[m_osxView superview] setNeedsDisplayInRect:r];
+
+ wxNSView* wxview = (wxNSView*)m_osxView;
+#if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
+ if ([wxview respondsToSelector:@selector(updateTrackingArea)] )
+ [wxview updateTrackingArea];
+#else
+ if ([m_osxView respondsToSelector:@selector(trackingTag)] )
+ {
+ if ( [wxview trackingTag] )
+ [wxview removeTrackingRect: [wxview trackingTag]];
+
+ [wxview setTrackingTag: [wxview addTrackingRect: [m_osxView bounds] owner: wxview userData: nil assumeInside: NO]];
+ }
+#endif
+}
+
+void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
+{
+ wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
+ x = r.GetLeft();
+ y = r.GetTop();
+}
+
+void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
+{
+ NSRect rect = [m_osxView frame];
+ width = (int)rect.size.width;
+ height = (int)rect.size.height;
+}
+
+void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
+{
+ if ( [m_osxView respondsToSelector:@selector(contentView) ] )
+ {
+ NSView* cv = [m_osxView contentView];
+
+ NSRect bounds = [m_osxView bounds];
+ NSRect rect = [cv frame];
+
+ int y = (int)rect.origin.y;
+ int x = (int)rect.origin.x;
+ if ( ![ m_osxView isFlipped ] )
+ y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
+ left = x;
+ top = y;
+ width = (int)rect.size.width;
+ height = (int)rect.size.height;
+ }
+ else
+ {
+ left = top = 0;
+ GetSize( width, height );
+ }
+}
+
+void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
+{
+ if ( where )
+ [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
+ else
+ [m_osxView setNeedsDisplay:YES];
+}
+
+bool wxWidgetCocoaImpl::GetNeedsDisplay() const
+{
+ return [m_osxView needsDisplay];
+}
+
+bool wxWidgetCocoaImpl::CanFocus() const
+{
+ return [m_osxView canBecomeKeyView] == YES;
+}
projects / wxWidgets.git / blobdiff