+ \
+ /usr/include"
+
+SEARCH_LIB="`echo "$SEARCH_INCLUDE" | sed s/include/lib/g` "
+
+dnl ------------------------------------------------------------------------
+dnl Check for libraries
+dnl ------------------------------------------------------------------------
+
+dnl flush the cache because checking for libraries below might abort
+AC_CACHE_SAVE
+
+dnl ---------------------------------------------------------------------------
+dnl Optional libraries
+dnl
+dnl --with-<lib>=sys
+dnl looks for system library and fails if not found
+dnl
+dnl --with-<lib>
+dnl --with-<lib>=yes
+dnl looks for system library and, if not found, prints a warning,
+dnl falls back to the builtin wx version, and continues configuration
+dnl
+dnl --with-<lib>=builtin
+dnl uses builtin wx version without searching for system library
+dnl
+dnl --with-<lib>=no
+dnl --without-<lib>
+dnl do not use library (neither system nor builtin wx version)
+dnl
+dnl ---------------------------------------------------------------------------
+
+dnl ------------------------------------------------------------------------
+dnl Check for regex libraries
+dnl ------------------------------------------------------------------------
+
+REGEX_INCLUDE=
+if test "$wxUSE_REGEX" != "no"; then
+ AC_DEFINE(wxUSE_REGEX)
+
+ if test "$wxUSE_REGEX" = "sys" -o "$wxUSE_REGEX" = "yes" ; then
+ dnl according to Unix 98 specs, regcomp() is in libc but I believe that
+ dnl on some old systems it may be in libregex - check for it too?
+ AC_CHECK_HEADER(regex.h, AC_CHECK_FUNCS(regcomp))
+
+ if test "x$ac_cv_func_regcomp" != "xyes"; then
+ if test "$wxUSE_REGEX" = "sys" ; then
+ AC_MSG_ERROR([system regex library not found! Use --with-regex to use built-in version])
+ else
+ AC_MSG_WARN([system regex library not found, will use built-in instead])
+ wxUSE_REGEX=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_REGEX=sys
+ fi
+ fi
+
+ if test "$wxUSE_REGEX" = "builtin" ; then
+ REGEX_INCLUDE="-I\${top_srcdir}/src/regex"
+ fi
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for zlib compression library
+dnl ------------------------------------------------------------------------
+
+ZLIB_INCLUDE=
+ZLIB_LINK=
+if test "$wxUSE_ZLIB" != "no" ; then
+ AC_DEFINE(wxUSE_ZLIB)
+
+ if test "$wxUSE_ZLIB" = "sys" -o "$wxUSE_ZLIB" = "yes" ; then
+ AC_CHECK_HEADER(zlib.h, AC_CHECK_LIB(z, deflate, ZLIB_LINK=" -lz"))
+
+ if test "x$ZLIB_LINK" = "x" ; then
+ if test "$wxUSE_ZLIB" = "sys" ; then
+ AC_MSG_ERROR([system zlib compression library not found! Use --with-zlib=builtin to use built-in version])
+ else
+ AC_MSG_WARN([system zlib compression library not found, will use built-in instead])
+ wxUSE_ZLIB=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_ZLIB=sys
+ fi
+ fi
+
+ if test "$wxUSE_ZLIB" = "builtin" ; then
+ ZLIB_INCLUDE="-I\${top_srcdir}/src/zlib"
+ fi
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for png library
+dnl ------------------------------------------------------------------------
+
+PNG_INCLUDE=
+PNG_LINK=
+if test "$wxUSE_LIBPNG" != "no" ; then
+ AC_DEFINE(wxUSE_LIBPNG)
+
+ if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBPNG" = "builtin" ; then
+ AC_MSG_WARN([wxMGL doesn't work with builtin png library, will use MGL one instead])
+ wxUSE_LIBPNG=sys
+ fi
+
+ dnl for the check below to have a chance to succeed, we must already have
+ dnl libz somewhere (don't do this when bulding wxMGL since its libpng
+ dnl doesn't depend on zlib)
+ if test "$wxUSE_MGL" != 1 -a "$wxUSE_LIBPNG" = "sys" -a "$wxUSE_ZLIB" != "sys" ; then
+ AC_MSG_WARN([system png library doesn't work without system zlib, will use built-in instead])
+ wxUSE_LIBPNG=builtin
+ fi
+
+ if test "$wxUSE_MGL" != 1 ; then
+ dnl Don't check for libpng when building wxMGL, libmgl contains it
+ if test "$wxUSE_LIBPNG" = "sys" -o "$wxUSE_LIBPNG" = "yes" ; then
+ AC_CHECK_HEADER(png.h,
+ AC_CHECK_LIB(png, png_check_sig,
+ PNG_LINK=" -lpng",
+ ,
+ [-lz -lm])
+ )
+
+ if test "x$PNG_LINK" = "x" ; then
+ if test "$wxUSE_LIBPNG" = "sys" ; then
+ AC_MSG_ERROR([system png library not found! Use --with-libpng=builtin to use built-in version])
+ else
+ AC_MSG_WARN([system png library not found, will use built-in instead])
+ wxUSE_LIBPNG=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_LIBPNG=yes
+ fi
+ fi
+ fi
+
+ if test "$wxUSE_LIBPNG" = "builtin" ; then
+ PNG_INCLUDE="-I\${top_srcdir}/src/png"
+ fi
+
+ SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS png"
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for jpeg library
+dnl ------------------------------------------------------------------------
+
+JPEG_INCLUDE=
+JPEG_LINK=
+if test "$wxUSE_LIBJPEG" != "no" ; then
+ AC_DEFINE(wxUSE_LIBJPEG)
+
+ if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBJPEG" = "builtin" ; then
+ AC_MSG_WARN([wxMGL doesn't work with builtin jpeg library, will use MGL one instead])
+ wxUSE_LIBJPEG=sys
+ fi
+
+ if test "$wxUSE_MGL" != 1 ; then
+ dnl Don't check for libjpeg when building wxMGL, libmgl contains it
+ if test "$wxUSE_LIBJPEG" = "sys" -o "$wxUSE_LIBJPEG" = "yes" ; then
+ dnl can't use AC_CHECK_HEADER as jconfig.h defines things like
+ dnl HAVE_STDLIB_H which are already defined and this provokes
+ dnl a compiler warning which configure considers as an error...
+ AC_MSG_CHECKING(for jpeglib.h)
+ AC_CACHE_VAL(ac_cv_header_jpeglib_h,
+ AC_TRY_COMPILE(
+ [
+ #undef HAVE_STDLIB_H
+ #include <stdio.h>
+ #include <jpeglib.h>
+ ],
+ [
+ ],
+ ac_cv_header_jpeglib_h=yes,
+ ac_cv_header_jpeglib_h=no
+ )
+ )
+ AC_MSG_RESULT($ac_cv_header_jpeglib_h)
+
+ if test "$ac_cv_header_jpeglib_h" = "yes"; then
+ AC_CHECK_LIB(jpeg, jpeg_read_header, JPEG_LINK=" -ljpeg")
+ fi
+
+ if test "x$JPEG_LINK" = "x" ; then
+ if test "$wxUSE_LIBJPEG" = "sys" ; then
+ AC_MSG_ERROR([system jpeg library not found! Use --with-libjpeg=builtin to use built-in version])
+ else
+ AC_MSG_WARN([system jpeg library not found, will use built-in instead])
+ wxUSE_LIBJPEG=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_LIBJPEG=sys
+ fi
+ fi
+ fi
+
+ if test "$wxUSE_LIBJPEG" = "builtin" ; then
+ JPEG_INCLUDE="-I\${top_srcdir}/src/jpeg"
+ fi
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for tiff library
+dnl ------------------------------------------------------------------------
+
+TIFF_INCLUDE=
+TIFF_LINK=
+if test "$wxUSE_LIBTIFF" != "no" ; then
+ AC_DEFINE(wxUSE_LIBTIFF)
+
+ if test "$wxUSE_LIBTIFF" = "sys" -o "$wxUSE_LIBTIFF" = "yes" ; then
+ AC_CHECK_HEADER(tiffio.h,
+ AC_CHECK_LIB(tiff, TIFFError,
+ TIFF_LINK=" -ltiff",
+ ,
+ -lm)
+ )
+
+ if test "x$TIFF_LINK" = "x" ; then
+ if test "$wxUSE_LIBTIFF" = "sys" ; then
+ AC_MSG_ERROR([system tiff library not found! Use --with-libtiff=builtin to use built-in version])
+ else
+ AC_MSG_WARN([system tiff library not found, will use built-in instead])
+ wxUSE_LIBTIFF=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_LIBTIFF=sys
+ fi
+ fi
+
+ if test "$wxUSE_LIBTIFF" = "builtin" ; then
+ TIFF_INCLUDE="-I\${top_srcdir}/src/tiff"
+ fi
+fi
+
+dnl ----------------------------------------------------------------
+dnl search for toolkit (widget sets)
+dnl ----------------------------------------------------------------
+
+AFMINSTALL=
+
+TOOLKIT=
+TOOLKIT_INCLUDE=
+WIDGET_SET=
+
+dnl are we building for a win32 target environment?
+dnl If so, setup common stuff needed for both GUI and Base libs.
+if test "$USE_WIN32" = 1 ; then
+ AC_CHECK_HEADERS(w32api.h)
+ AC_CHECK_HEADER(windows.h, [],
+ [
+ AC_MSG_ERROR(please set CFLAGS to contain the location of windows.h)
+ ])
+
+ dnl check if can use _WIN32_IE macro
+ AC_CACHE_CHECK([if w32api has good enough MSIE support], wx_cv_w32api_win32_ie,
+ [
+ AC_TRY_COMPILE([#include <w32api.h>],
+ [
+ #define wxCHECK_W32API_VERSION( major, minor ) \
+ ( defined( __W32API_MAJOR_VERSION ) && defined( __W32API_MINOR_VERSION ) \
+ && ( ( __W32API_MAJOR_VERSION > (major) ) \
+ || ( __W32API_MAJOR_VERSION == (major) && __W32API_MINOR_VERSION >= (minor))))
+
+ #if !wxCHECK_W32API_VERSION(1,1)
+ #error You need w32api 1.1 or newer
+ #endif
+ ], [
+ wx_cv_w32api_win32_ie=yes
+ ], [
+ wx_cv_w32api_win32_ie=no
+ ])
+ ])
+ if test "$wx_cv_w32api_win32_ie" = "yes" ; then
+ CPPFLAGS="$CPPFLAGS -D_WIN32_IE=0x400"
+ fi
+
+ dnl --- FIXME: This is still a somewhat random list of libs,
+ dnl --- some of them should probably be included conditionally.
+ LIBS="$LIBS -lwinspool -lwinmm -lshell32 -lcomctl32 -lctl3d32 -ladvapi32 -lwsock32"
+
+ case "${host}" in
+ *-*-cygwin* )
+ dnl Cygwin doesn't include these by default
+ LIBS="$LIBS -lkernel32 -luser32 -lgdi32 -lcomdlg32"
+ TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WIN95__"
+ esac
+
+ dnl add extra odbc libs if we have compiled in odbc
+ if test "$wxUSE_ODBC" = "yes" ; then
+ LIBS=" -lodbc32 -lole32 -loleaut32 $LIBS"
+ fi
+
+ RESFLAGS="--include-dir \$(top_srcdir)/include --include-dir \$(top_srcdir)/\$(program_dir) --define __WIN32__ --define __WIN95__ --define __GNUWIN32__"
+ RESPROGRAMOBJ="\$(PROGRAM)_resources.o"
+fi
+
+if test "$wxUSE_GUI" = "yes"; then
+ USE_GUI=1
+
+ GUI_TK_LIBRARY=
+
+ WXGTK12=
+ WXGTK127=
+ WXGTK20=
+
+ if test "$wxUSE_MSW" = 1 ; then
+ TOOLKIT=MSW
+ GUIDIST=MSW_DIST
+
+ dnl -mwindows causes a heap of other default gui libs to be linked in.
+ dnl FIXME: If cygwin needs this, please push it above, if not, please
+ dnl remove this comment :-)
+ case "${host}" in
+ *-*-mingw32* )
+ LDFLAGS="$LDFLAGS -Wl,--subsystem,windows -mwindows"
+ esac
+ fi
+
+ if test "$wxUSE_GTK" = 1; then
+ AC_MSG_CHECKING([for GTK+ version])
+
+ gtk_version_cached=1
+ AC_CACHE_VAL(wx_cv_lib_gtk,
+ [
+ dnl stupid GTK+ AM macros produce their own messages, so we
+ dnl have to pass to the next line
+ gtk_version_cached=0
+ AC_MSG_RESULT()
+
+ dnl we must link against lgthread unless the user
+ dnl used --disable-threads
+ GTK_MODULES=
+ if test "$wxUSE_THREADS" = "yes"; then
+ GTK_MODULES=gthread
+ fi
+
+ wx_cv_lib_gtk=
+ if test "x$wxUSE_GTK2" = "xyes"; then
+ AM_PATH_GTK_2_0(2.0.0, wx_cv_lib_gtk=2.0, , $GTK_MODULES)
+ fi
+
+ if test -z "$wx_cv_lib_gtk"; then
+ AM_PATH_GTK(1.2.7, wx_cv_lib_gtk=1.2.7, , $GTK_MODULES)
+ fi
+
+ if test -z "$wx_cv_lib_gtk"; then
+ AM_PATH_GTK(1.2.3, wx_cv_lib_gtk=1.2.3, , $GTK_MODULES)
+ fi
+
+ if test -z "$wx_cv_lib_gtk"; then
+ dnl looks better in AC_MSG_RESULT
+ wx_cv_lib_gtk=none
+ else
+ dnl we need to cache GTK_CFLAGS and GTK_LIBS for the
+ dnl subsequent runs
+ wx_cv_cflags_gtk=$GTK_CFLAGS
+ wx_cv_libs_gtk=$GTK_LIBS
+ fi
+ ]
+ )
+
+ dnl if it wasn't cached, the messages from AM_PATH_GTK() above are
+ dnl enough
+ if test "$gtk_version_cached" = 1; then
+ AC_MSG_RESULT($wx_cv_lib_gtk)
+ fi
+
+ case "$wx_cv_lib_gtk" in
+ 2.0) WXGTK20=1
+ ;;
+ 1.2.7) WXGTK127=1
+ WXGTK12=1
+ ;;
+ 1.2.3) WXGTK12=1
+ ;;
+ *) AC_MSG_ERROR([
+Please check that gtk-config is in path, the directory
+where GTK+ libraries are installed (returned by
+'gtk-config --libs' command) is in LD_LIBRARY_PATH or
+equivalent variable and GTK+ is version 1.2.3 or above.
+ ])
+ ;;
+ esac
+
+ TOOLKIT_INCLUDE="$wx_cv_cflags_gtk"
+ GUI_TK_LIBRARY="$wx_cv_libs_gtk"
+
+ AFMINSTALL=afminstall
+ TOOLKIT=GTK
+ GUIDIST=GTK_DIST
+
+ dnl test for XIM support in libgdk
+ AC_CHECK_LIB(gdk, gdk_im_open, AC_DEFINE(HAVE_XIM))
+ fi
+
+ if test "$wxUSE_MGL" = 1; then
+ AC_MSG_CHECKING(for SciTech MGL library)
+ if test "x$MGL_ROOT" = x ; then
+ AC_MSG_RESULT(not found)
+ AC_MSG_ERROR([Cannot find MGL library. Make sure MGL_ROOT is set.])
+ else
+ AC_MSG_RESULT($MGL_ROOT)
+ fi
+
+ dnl Find MGL library that we want
+ dnl FIXME_MGL - test for MGL variants for freebsd etc.
+ case "${host}" in
+ *-*-linux* )
+ mgl_os=linux/gcc/glibc
+ ;;
+ *-pc-msdosdjgpp )
+ mgl_os=dos32/dj2
+ ;;
+ *)
+ AC_MSG_ERROR(This system type ${host} is not yet supported by wxMGL.)
+ esac
+
+ mgl_lib_type=""
+
+ if test "$wxUSE_DEBUG_FLAG" = yes ; then
+ if test -f $MGL_ROOT/lib/debug/$mgl_os/libmgl.a -o \
+ -f $MGL_ROOT/lib/debug/$mgl_os/libmgl.so; then
+ mgl_lib_type=debug
+ fi
+ fi
+ if test "x$mgl_lib_type" = x ; then
+ if test -f $MGL_ROOT/lib/release/$mgl_os/libmgl.a -o \
+ -f $MGL_ROOT/lib/release/$mgl_os/libmgl.so; then
+ mgl_lib_type=release
+ else
+ AC_MSG_ERROR([Cannot find MGL libraries, make sure they are compiled.])
+ fi
+ fi
+
+ TOOLKIT_INCLUDE="-I$MGL_ROOT/include"
+ GUI_TK_LIBRARY="-L$MGL_ROOT/lib/$mgl_lib_type/$mgl_os -lmgl -lmglcpp -lpm"
+
+ AFMINSTALL=afminstall
+ TOOLKIT=MGL
+ GUIDIST=MGL_DIST
+ fi
+
+ if test "$wxUSE_MICROWIN" = 1; then
+ AC_MSG_CHECKING(for MicroWindows)
+ if test "x$MICROWINDOWS" = x ; then
+ AC_MSG_RESULT(not found)
+ AC_MSG_ERROR([Cannot find MicroWindows library. Make sure MICROWINDOWS is set.])
+ else
+ AC_MSG_RESULT($MICROWINDOWS)
+ fi
+
+ if test -f $MICROWINDOWS/lib/libmwin.a; then
+ AC_MSG_RESULT(MicroWindows' libraries found.)
+ else
+ AC_MSG_ERROR([Cannot find MicroWindows libraries, make sure they are compiled.])
+ fi
+
+ TOOLKIT_INCLUDE="-I$MICROWINDOWS/include"
+ GUI_TK_LIBRARY="-L$MICROWINDOWS/lib -lmwin -lmwengine -mwfonts -mwdrivers -mwinlib"
+
+ AFMINSTALL=afminstall
+ TOOLKIT=MICROWIN
+ GUIDIST=MICROWIN_DIST
+
+ TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXUNIVERSAL__ -D__WXMSW__ -D__WIN95__ -D__WIN32__ -DMWIN -DMICROWIN_NOCONTROLS -DMICROWIN_TODO=1"
+ fi
+
+ if test "$wxUSE_X11" = 1; then
+ dnl use standard macros to check for X headers/libs, this brings support
+ dnl for the standard configure options --x-includes and --x-libraries
+ AC_PATH_XTRA
+
+ if test "$no_x" = "yes"; then
+ AC_MSG_ERROR(X11 not found, please use --x-includes and/or --x-libraries options)
+ fi
+
+ GUI_TK_LIBRARY="$X_LIBS"
+ TOOLKIT_INCLUDE="$X_CFLAGS"
+ AFMINSTALL=afminstall
+ COMPILED_X_PROGRAM=0
+
+ if test "$wxUSE_NANOX" = "yes"; then
+ AC_MSG_CHECKING(for MicroWindows/NanoX distribution)
+ if test "x$MICROWIN" = x ; then
+ AC_MSG_RESULT(not found)
+ AC_MSG_ERROR([Cannot find MicroWindows library. Make sure MICROWIN is set.])
+ else
+ AC_MSG_RESULT($MICROWIN)
+ AC_DEFINE(wxUSE_NANOX)
+ fi
+ fi
+
+ xpm_link=
+ AC_MSG_CHECKING(for Xpm library)
+ WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
+ if test "$ac_find_libraries" != "" ; then
+ WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY$ac_path_to_link"
+ xpm_link=" -lXpm"
+ AC_DEFINE(wxHAVE_LIB_XPM)
+ AC_MSG_RESULT(found at $ac_find_libraries)
+ else
+ AC_TRY_COMPILE(
+ [
+ #include <X11/xpm.h>
+ ],
+ [
+ int version;
+ version = XpmLibraryVersion();
+ ],
+ [
+ xpm_link=" -lXpm"
+ AC_DEFINE(wxHAVE_LIB_XPM)
+ AC_MSG_RESULT(found in default search path)
+ COMPILED_X_PROGRAM=0
+ ],
+ [
+ AC_MSG_RESULT(no)
+ AC_MSG_WARN(library will be compiled without support for images in XPM format)
+ ]
+ )
+ fi
+
+ if test "$wxUSE_NANOX" = "yes"; then
+ TOOLKIT_INCLUDE="-I\$(top_srcdir)/include/wx/x11/nanox -I\$(MICROWIN)/src/include $TOOLKIT_INCLUDE"
+ TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__NANOX__ -DMWPIXEL_FORMAT=MWPF_TRUECOLOR0888 -DHAVE_FILEIO -DHAVE_BMP_SUPPORT=1 -DHAVE_GIF_SUPPORT=1 -DHAVE_PNM_SUPPORT=1 -DHAVE_XPM_SUPPORT=1 -DLINUX=1 -DUNIX=1 -DUSE_EXPOSURE -DSCREEN_HEIGHT=480 -DSCREEN_WIDTH=640 -DSCREEN_DEPTH=4 -DX11=1"
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY \$(MICROWIN)/src/lib/libnano-X.a"
+ else
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lX11$xpm_link"
+ fi
+
+ TOOLKIT_VPATH="\${top_srcdir}/src/x11"
+ TOOLKIT=X11
+ GUIDIST=X11_DIST
+ fi
+
+ if test "$wxUSE_WINE" = 1; then
+ AC_CHECK_HEADER(windows.h, [],
+ [
+ AC_MSG_ERROR(please set CFLAGS to contain the location of windows.h)
+ ])
+
+ xpm_link=
+ AC_MSG_CHECKING(for Xpm library)
+ WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
+ if test "$ac_find_libraries" != "" ; then
+ GUI_TK_LIBRARY="-L$ac_find_libraries"
+ xpm_link=" -lXpm"
+ AC_DEFINE(wxHAVE_LIB_XPM)
+ AC_MSG_RESULT(found at $ac_find_libraries)
+ else
+ AC_MSG_RESULT(no)
+ AC_MSG_WARN(library will be compiled without support for images in XPM format)
+ fi
+
+ mesa_link=
+ AC_MSG_CHECKING(for Mesa library)
+ WX_PATH_FIND_LIBRARIES($SEARCH_LIB,MesaGL)
+ if test "$ac_find_libraries" != "" ; then
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY -L$ac_find_libraries"
+ mesa_link=" -lMesaGL"
+ AC_MSG_RESULT(found at $ac_find_libraries)
+ else
+ AC_MSG_ERROR(no)
+ fi
+
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lwine$mesa_link$xpm_link -lXxf86dga -lXxf86vm -lSM -lICE -lXext -lXmu -lX11 -lncurses"
+ TOOLKIT=MSW
+ GUIDIST=MSW_DIST
+ TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXWINE__"
+ fi
+
+ if test "$wxUSE_MOTIF" = 1; then
+ dnl use standard macros to check for X headers/libs, this brings support
+ dnl for the standard configure options --x-includes and --x-libraries
+ AC_PATH_XTRA
+
+ if test "$no_x" = "yes"; then
+ AC_MSG_ERROR(X11 not found, please use --x-includes and/or --x-libraries options)
+ fi
+
+ GUI_TK_LIBRARY="$X_LIBS"
+ TOOLKIT_INCLUDE="$X_CFLAGS"
+ AFMINSTALL=afminstall
+ COMPILED_X_PROGRAM=0
+
+ AC_MSG_CHECKING(for Motif/Lesstif headers)
+ WX_PATH_FIND_INCLUDES($SEARCH_INCLUDE, Xm/Xm.h)
+ if test "$ac_find_includes" != "" ; then
+ AC_MSG_RESULT(found $ac_find_includes)
+ else
+ AC_TRY_COMPILE(
+ [
+ #include <Xm/Xm.h>
+ ],
+ [
+ int version;
+ version = xmUseVersion;
+ ],
+ [
+ AC_MSG_RESULT(found in default search path)
+ COMPILED_X_PROGRAM=1
+ ],
+ [
+ AC_MSG_RESULT(no)
+ AC_MSG_ERROR(please set CFLAGS to contain the location of Xm/Xm.h)
+ ]
+ )
+ fi
+
+ if test "$COMPILED_X_PROGRAM" = 0; then
+ AC_MSG_CHECKING(for Motif/Lesstif library)
+ WX_PATH_FIND_LIBRARIES($SEARCH_LIB, Xm)
+ if test "$ac_find_libraries" != "" ; then
+ WX_INCLUDE_PATH_EXIST($ac_find_includes, $TOOLKIT_INCLUDE)
+ WX_LINK_PATH_EXIST($ac_find_libraries, $GUI_TK_LIBRARY)
+
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY$ac_path_to_link"
+ TOOLKIT_INCLUDE="$TOOLKIT_INCLUDE$ac_path_to_include"
+ AC_MSG_RESULT(found at $ac_find_libraries)
+ else
+ dnl it might happen that we found headers in one of the standard
+ dnl paths but the libs are elsewhere - we do need to try to
+ dnl compile a sample program then here
+ AC_TRY_COMPILE(
+ [
+ #include <Xm/Xm.h>
+ ],
+ [
+ int version;
+ version = xmUseVersion;
+ ],
+ [
+ AC_MSG_RESULT(found in default search path)
+ COMPILED_X_PROGRAM=1
+ ],
+ [
+ AC_MSG_RESULT(no)
+ AC_MSG_ERROR(please set LDFLAGS to contain the location of libXm)
+ ]
+ )
+ fi
+ fi
+
+ xpm_link=
+ AC_MSG_CHECKING(for Xpm library)
+ WX_PATH_FIND_LIBRARIES($SEARCH_LIB,Xpm)
+ if test "$ac_find_libraries" != "" ; then
+ WX_LINK_PATH_EXIST($ac_find_libraries,$GUI_TK_LIBRARY)
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY$ac_path_to_link"
+ xpm_link=" -lXpm"
+ AC_DEFINE(wxHAVE_LIB_XPM)
+ AC_MSG_RESULT(found at $ac_find_libraries)
+ else
+ AC_TRY_COMPILE(
+ [
+ #include <X11/xpm.h>
+ ],
+ [
+ int version;
+ version = XpmLibraryVersion();
+ ],
+ [
+ xpm_link=" -lXpm"
+ AC_DEFINE(wxHAVE_LIB_XPM)
+ AC_MSG_RESULT(found in default search path)
+ COMPILED_X_PROGRAM=0
+ ],
+ [
+ AC_MSG_RESULT(no)
+ AC_MSG_WARN(library will be compiled without support for images in XPM format)
+ ]
+ )
+ fi
+
+ GUI_TK_LIBRARY="$GUI_TK_LIBRARY -lXm$xpm_link -lXmu -lXext -lXt -lX11"
+ TOOLKIT_VPATH="\${top_srcdir}/src/motif${PATH_IFS}\${top_srcdir}/src/motif/xmcombo"
+ TOOLKIT=MOTIF
+ GUIDIST=MOTIF_DIST
+ fi
+
+ if test "$wxUSE_MAC" = 1; then
+ if test "$wxUSE_PRECOMP" = "yes"; then
+ CPPFLAGS="$CPPFLAGS -cpp-precomp"
+ fi
+ CPPFLAGS="$CPPFLAGS -I/Developer/Headers/FlatCarbon -I\${top_srcdir}/src/mac/morefile"
+ CFLAGS="$CFLAGS -fpascal-strings"
+ CXXFLAGS="$CXXFLAGS -fpascal-strings"
+
+ TOOLKIT_VPATH="\${top_srcdir}/src/mac${PATH_IFS}\${top_srcdir}/src/mac/morefile"
+ TOOLKIT=MAC
+ dnl we can't call this MAC_DIST or autoconf thinks its a macro
+ GUIDIST=MACX_DIST
+ fi
+
+ if test "$wxUSE_PM" = 1; then
+ TOOLKIT=PM
+ GUIDIST=GTK_DIST
+ fi
+
+ dnl the name of the directory where the files for this toolkit live
+ if test "$TOOLKIT" = "PM" ; then
+ TOOLKIT_DIR="os2"
+ else
+ TOOLKIT_DIR=`echo ${TOOLKIT} | tr "[[A-Z]]" "[[a-z]]"`
+ fi
+
+ dnl misc other files depending on the port
+ PORT_FILES="\${top_srcdir}/src/\$(TOOLKITDIR)/files.lst"
+
+ if test "$wxUSE_UNIVERSAL" = "yes"; then
+ ALL_OBJECTS="\$(GUI_LOWLEVEL_OBJS) \${UNIVOBJS}"
+
+ dnl ALL_SOURCES and ALL_HEADERS shouldn't include really all sources
+ dnl and headers as some/most are not needed for wxUniv but I don't
+ dnl have time to add GUI_LOWLEVEL_SOURCES/HEADERS stuff now (TODO!)
+ ALL_SOURCES="\$(ALL_SOURCES) \${UNIV_SOURCES}"
+ ALL_HEADERS="\$(ALL_HEADERS) \${UNIV_HEADERS}"
+
+ PORT_FILES="${PORT_FILES} \${top_srcdir}/src/univ/files.lst"
+ if test "$wxUSE_X11" = 1; then
+ TOOLKIT_VPATH="\${top_srcdir}/src/${TOOLKIT_DIR}${PATH_IFS}\${top_srcdir}/src/univ${PATH_IFS}\${top_srcdir}/src/univ/themes"
+ else
+ TOOLKIT_VPATH="\${top_srcdir}/src/univ${PATH_IFS}\${top_srcdir}/src/univ/themes${PATH_IFS}\${top_srcdir}/src/${TOOLKIT_DIR}"
+ fi
+ TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WXUNIVERSAL__"
+ WIDGET_SET=univ
+ else
+ ALL_OBJECTS="\$(GUIOBJS)"
+ ALL_SOURCES="\$(ALL_SOURCES)"
+ ALL_HEADERS="\$(ALL_HEADERS)"
+ fi
+
+ ALL_OBJECTS="${ALL_OBJECTS} \$(COMMONOBJS) \$(GENERICOBJS)"
+
+ if test "$TOOLKIT" != "MSW" -a "$USE_DOS" != 1; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(UNIXOBJS)"
+ fi
+
+ if test "$wxUSE_HTML" = "yes"; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(HTMLOBJS)"
+ fi
+
+ if test "$wxUSE_LIBJPEG" = "builtin" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(JPEGOBJS)"
+ fi
+ if test "$wxUSE_LIBTIFF" = "builtin" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(TIFFOBJS)"
+ fi
+ if test "$wxUSE_LIBPNG" = "builtin" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(PNGOBJS)"
+ fi
+
+ dnl distribute samples/demos/utils with GUI versions
+ GUIDIST="${GUIDIST} SAMPLES_DIST DEMOS_DIST UTILS_DIST MISC_DIST"
+ DISTDIR="wx\$(TOOLKIT)"
+else
+ USE_GUI=0
+
+ dnl this doesn't quite work right for wxBase, but the places
+ dnl where it is wrong aren't fatal (yet) though.
+ TOOLKIT_DIR="base"
+
+ dnl the sources, their dependenices and the headers
+ if test "$USE_WIN32" = 1 ; then
+ ALL_OBJECTS="\${BASE_OBJS} \${BASE_MSW_OBJS}"
+ TOOLKIT_VPATH="\${top_srcdir}/src/msw"
+
+ dnl yes, the toolkit for wxBase on win32 is actually MSW
+ dnl wxBase on unix does not need a 'TOOLKIT' defined.
+ TOOLKIT="MSW"
+ else
+ ALL_OBJECTS="\${BASE_OBJS} \${BASE_UNIX_OBJS}"
+ TOOLKIT_VPATH="\${top_srcdir}/src/unix"
+ fi
+
+ ALL_SOURCES="\$(ALL_SOURCES)"
+ ALL_HEADERS="\$(ALL_HEADERS)"
+
+ PORT_FILES="\${top_srcdir}/src/files.lst"
+
+ dnl distribute only wxBase sources/headers
+ GUIDIST="BASE_DIST"
+ DISTDIR="wxBase"
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl Optional libraries included when system library is not used
+dnl ---------------------------------------------------------------------------
+
+dnl ODBC objects are Unix only
+if test "$TOOLKIT" != "MSW" -a "$wxUSE_ODBC" = "yes" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(IODBCOBJS)"
+fi
+
+if test "$wxUSE_REGEX" = "builtin" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(REGEXOBJS)"
+fi
+if test "$wxUSE_ZLIB" = "builtin" ; then
+ ALL_OBJECTS="${ALL_OBJECTS} \$(ZLIBOBJS)"
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl OpenGL libraries
+dnl ---------------------------------------------------------------------------
+if test "$wxUSE_OPENGL" = "yes"; then
+ if test "$wxUSE_MAC" = 1; then
+ OPENGL_LIBS="-framework OpenGL -framework AGL"
+ else
+
+ AC_CHECK_HEADER(GL/gl.h,
+ [
+ AC_MSG_CHECKING([for -lGL])
+ WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],[GL])
+ if test "$ac_find_libraries" != "" ; then
+ WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
+ if test "$ac_path_to_link" = " -L/usr/lib" ; then
+ LDFLAGS_GL="$LDFLAGS"
+ else
+ LDFLAGS_GL="$LDFLAGS$ac_path_to_link"
+ fi
+ OPENGL_LIBS="-lGL -lGLU"
+ AC_MSG_RESULT([yes])
+ else
+ AC_MSG_RESULT([no])
+ AC_MSG_CHECKING([for -lMesaGL])
+ WX_PATH_FIND_LIBRARIES([$SEARCH_LIB],[MesaGL])
+ if test "$ac_find_libraries" != "" ; then
+ WX_LINK_PATH_EXIST([$ac_find_libraries],[$LDFLAGS])
+ LDFLAGS_GL="$LDFLAGS$ac_path_to_link"
+ OPENGL_LIBS="-lMesaGL -lMesaGLU"
+ AC_MSG_RESULT([yes])
+ else
+ AC_MSG_RESULT([no])
+ fi
+ fi
+ ])
+
+ dnl check for OpenGL libs availability first
+ dnl -lGL requires -lm with soem OpenGL versions
+
+# AC_CHECK_HEADER(GL/gl.h,
+# [
+# AC_CHECK_LIB(GL, glFlush,
+# [
+# OPENGL_LIBS="-lGL -lGLU"
+# ],
+# [
+# AC_CHECK_LIB(MesaGL, glFlush,
+# [
+# OPENGL_LIBS="-lMesaGL -lMesaGLU"
+# ],
+# [],
+# [-lm])
+# ],
+# [-lm])
+# ])
+
+ if test "x$OPENGL_LIBS" = "x"; then
+ dnl it should be an error and not a warning because OpenGL is not on
+ dnl by default and so if it had been explicitely requested, we
+ dnl shouldn't just fall back to compiling the library without it
+ AC_MSG_ERROR(OpenGL libraries not available)
+ fi
+ fi
+
+ if test "$wxUSE_OPENGL" = "yes"; then
+ AC_DEFINE(wxUSE_OPENGL)
+ AC_DEFINE(wxUSE_GLCANVAS)
+ SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS opengl"
+ fi
+fi
+
+if test -z "$TOOLKIT_VPATH" ; then
+ TOOLKIT_VPATH="\${top_srcdir}/src/${TOOLKIT_DIR}"
+fi
+
+dnl the symbol which allows conditional compilation for the given toolkit
+if test -n "$TOOLKIT" ; then
+ TOOLCHAIN_DEFS="${TOOLCHAIN_DEFS} -D__WX${TOOLKIT}__"
+fi
+
+lib_unicode_suffix=
+if test "$wxUSE_UNICODE" = "yes"; then
+ lib_unicode_suffix=u
+fi
+
+lib_debug_suffix=
+if test "$wxUSE_DEBUG_FLAG" = "yes"; then
+ lib_debug_suffix=d
+fi
+
+TOOLCHAIN_NAME="${TOOLKIT_DIR}${WIDGET_SET}${lib_unicode_suffix}${lib_debug_suffix}-${WX_RELEASE}"
+TOOLCHAIN_NAME_GL="${TOOLKIT_DIR}${WIDGET_SET}${lib_unicode_suffix}${lib_debug_suffix}_gl-${WX_RELEASE}"
+
+if test "$cross_compiling" = "yes"; then
+ TOOLCHAIN_NAME="${TOOLCHAIN_NAME}-${host_alias}"
+ TOOLCHAIN_NAME_GL="${TOOLCHAIN_NAME_GL}-${host_alias}"
+fi
+
+dnl library link name
+WX_LIBRARY="wx_${TOOLCHAIN_NAME}"
+WX_LIBRARY_GL="wx_${TOOLCHAIN_NAME_GL}"
+
+dnl the name of the shared library
+WX_LIBRARY_NAME_SHARED="lib${WX_LIBRARY}.${SO_SUFFIX}.${WX_CURRENT}.${WX_REVISION}.${WX_AGE}"
+WX_LIBRARY_NAME_SHARED_GL="lib${WX_LIBRARY_GL}.${SO_SUFFIX}.${WX_CURRENT}.${WX_REVISION}.${WX_AGE}"
+
+dnl the name of the links to the shared library
+WX_LIBRARY_LINK1="lib${WX_LIBRARY}.${SO_SUFFIX}.${WX_CURRENT}"
+WX_LIBRARY_LINK2="lib${WX_LIBRARY}.${SO_SUFFIX}"
+WX_LIBRARY_LINK1_GL="lib${WX_LIBRARY_GL}.${SO_SUFFIX}.${WX_CURRENT}"
+WX_LIBRARY_LINK2_GL="lib${WX_LIBRARY_GL}.${SO_SUFFIX}"
+
+dnl the name of the resources file for wxMac
+WX_RESOURCES_MACOSX="lib${WX_LIBRARY}.rsrc"
+WX_RESOURCES_MACOSX_COMPILED="lib${WX_LIBRARY}.r"
+
+case "${host}" in
+ *-*-cygwin* | *-*-mingw32* )
+
+ dnl If we are cross compiling we want to use the 'full' unix type name for the
+ dnl lib, but for a native install use the windows style naming convention.
+ dnl (excepting again that we strip the ELF style version numbers off it).
+
+ dnl FIXME: is this GL stuff actually even used for wxMSW? should it be??
+
+ if test "$cross_compiling" != "yes"; then
+ WX_LIBRARY="wxmsw${WX_MSW_VERSION}${lib_unicode_suffix}${lib_debug_suffix}"
+ WX_LIBRARY_GL="wxmsw_gl${WX_MSW_VERSION}${lib_unicode_suffix}${lib_debug_suffix}"
+ WX_LIBRARY_NAME_SHARED="${WX_LIBRARY}.${SO_SUFFIX}"
+ WX_LIBRARY_NAME_SHARED_GL="${WX_LIBRARY_GL}.${SO_SUFFIX}"
+ else
+ WX_LIBRARY_NAME_SHARED="lib${WX_LIBRARY}.${SO_SUFFIX}"
+ WX_LIBRARY_NAME_SHARED_GL="lib${WX_LIBRARY_GL}.${SO_SUFFIX}"
+ fi
+
+esac
+
+dnl the name of the static library
+WX_LIBRARY_NAME_STATIC="lib${WX_LIBRARY}.a"
+WX_LIBRARY_NAME_STATIC_GL="lib${WX_LIBRARY_GL}.a"
+
+dnl define which libs wx-config should link.
+WXCONFIG_LIBS="-l${WX_LIBRARY}"
+WXCONFIG_LIBS_STATIC="lib${WX_LIBRARY}.a"
+
+if test "$wxUSE_OPENGL" = "yes"; then
+ WXCONFIG_LIBS_GL="-l${WX_LIBRARY_GL} ${OPENGL_LIBS}"
+ WXCONFIG_LIBS_STATIC_GL="lib${WX_LIBRARY_GL}.a ${OPENGL_LIBS}"
+fi
+
+
+dnl --- the marker for quick search, leave it here: SHARED_LIB_SETUP ---
+
+if test "$wxUSE_SHARED" = "yes"; then
+ case "${host}" in
+ *-pc-os2_emx | *-pc-os2-emx | \
+ *-pc-msdosdjgpp )
+ dnl only static for now
+ wxUSE_SHARED=no
+ AC_MSG_WARN([Host system doesn't support shared libraries, disabling])
+ ;;
+ esac
+fi
+
+if test "$wxUSE_SHARED" = "yes"; then
+
+ dnl install targets
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS CREATE_INSTALLED_LINKS_GL"
+ WX_ALL="\$(build_libdir)/${WX_LIBRARY_LINK1} \$(build_libdir)/${WX_LIBRARY_LINK1_GL}"
+ else
+ WX_ALL_INSTALLED="CREATE_INSTALLED_LINKS"
+ WX_ALL="\$(build_libdir)/${WX_LIBRARY_LINK1}"
+ fi
+
+ dnl the extra compiler flags needed for compilation of shared library
+ if test "$GCC" = "yes"; then
+ dnl the switch for gcc is the same under all platforms
+ PIC_FLAG="-fPIC"
+ fi
+
+ dnl the command to use for creating the shared library
+ SHARED_LD="${CXX} -shared -o"
+
+ case "${host}" in
+ *-hp-hpux* )
+ dnl default settings are good for gcc but not for the native HP-UX
+ if test "$GCC" == "yes"; then
+ SHARED_LD="${SHARED_LD} ${PIC_FLAG}"
+ else
+ dnl no idea why it wants it, but it does
+ LDFLAGS="$LDFLAGS -L/usr/lib"
+
+ SHARED_LD="${CXX} -b -o"
+ PIC_FLAG="+Z"
+ fi
+
+ dnl install shared libs without symlinks
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="preinstall_gl"
+ WX_ALL="\$(build_libdir)/${WX_LIBRARY_NAME_SHARED} \$(build_libdir)/${WX_LIBRARY_NAME_SHARED_GL}"
+ else
+ WX_ALL="\$(build_libdir)/${WX_LIBRARY_NAME_SHARED}"
+ fi
+ ;;
+
+ *-*-linux* )
+ if test "$GCC" != "yes"; then
+ AC_CACHE_CHECK([for Intel compiler], wx_cv_prog_icc,
+ [
+ AC_TRY_COMPILE([],
+ [
+ #ifndef __INTEL_COMPILER
+ #error Not icc
+ #endif
+ ],
+ wx_cv_prog_icc=yes,
+ wx_cv_prog_icc=no
+ )
+ ])
+ if test "$wx_cv_prog_icc" = "yes"; then
+ PIC_FLAG="-KPIC"
+ fi
+ fi
+
+ if test "$wxUSE_SONAME" = "yes" ; then
+ SONAME_FLAGS="-Wl,-soname,${WX_LIBRARY_LINK1}"
+ SONAME_FLAGS_GL="-Wl,-soname,${WX_LIBRARY_LINK1_GL}"
+ dnl substitute this in makelib.env for the contrib libs
+ WX_TARGET_LIBRARY_SONAME="-Wl,-soname,\$(TARGETLIB_LINK1)"
+ fi
+ ;;
+
+ *-*-solaris2* )
+ if test "$GCC" = yes ; then
+ dnl newer versions of gcc need -isystem to compile X headers on
+ dnl Solaris (which use old style C syntax)
+ CPPFLAGS="$CPPFLAGS -isystem /usr/openwin/include"
+ else
+ SHARED_LD="${CXX} -G -o"
+ PIC_FLAG="-KPIC"
+ SONAME_FLAGS="-h ${WX_LIBRARY_NAME_SHARED}"
+ SONAME_FLAGS_GL="-h ${WX_LIBRARY_NAME_SHARED_GL}"
+ fi
+ ;;
+
+ *-*-darwin* )
+ dnl For Unix to MacOS X porting instructions, see:
+ dnl http://fink.sourceforge.net/doc/porting/porting.html
+ CFLAGS="$CFLAGS -fno-common -DDYLIB_INIT"
+ CXXFLAGS="$CXXFLAGS -fno-common -DDYLIB_INIT"
+ dnl Executables must necessarily fully bind the wxWindows library at
+ dnl program launch otherwise lazy binding breaks RTTI class info
+ LDFLAGS="$LDFLAGS -Wl,-bind_at_load"
+ SHARED_LD="$CXX -dynamiclib -init _wxWindowsDylibInit -o"
+ PIC_FLAG="-dynamic -fPIC"
+ SONAME_FLAGS="-compatibility_version ${WX_RELEASE} -current_version ${WX_VERSION}"
+ SONAME_FLAGS_GL=${SONAME_FLAGS}
+ ;;
+
+ *-*-aix* )
+ SHARED_LD="/usr/lpp/xlC/bin/makeC++SharedLib -p 0 -o"
+ ;;
+
+ *-*-cygwin* | *-*-mingw32* )
+
+ WX_LIBRARY_IMPORTLIB="${WX_LIBRARY_NAME_SHARED}.a"
+
+ SHARED_LD="${CXX} -shared -Wl,--out-implib,lib/${WX_LIBRARY_IMPORTLIB} -o"
+ TOOLCHAIN_DLL_DEFS="${TOOLCHAIN_DLL_DEFS} -DWXUSINGDLL=1"
+
+ PIC_FLAG="-UWXUSINGDLL -DWXMAKINGDLL=1 -D_DLL=1 -D_WINDLL=1"
+
+ dnl install shared libs without symlinks
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="preinstall_gl"
+ WX_ALL="\$(build_libdir)/${WX_LIBRARY_NAME_SHARED} \$(build_libdir)/${WX_LIBRARY_NAME_SHARED_GL}"
+ else
+ WX_ALL="\$(build_libdir)/${WX_LIBRARY_NAME_SHARED}"
+ fi
+ ;;
+
+ *-*-beos* )
+ dnl can't use gcc under BeOS for shared library creation because it
+ dnl complains about missing 'main'
+ SHARED_LD="${LD} -shared -o"
+ ;;
+
+ *-*-freebsd* | *-*-openbsd* | *-*-netbsd* | \
+ *-*-sunos4* | \
+ *-*-irix5* | *-*-irix6* | \
+ *-*-osf* | \
+ *-*-dgux5* | \
+ *-*-sysv5* )
+ dnl defaults are ok
+ ;;
+
+ *)
+ AC_MSG_ERROR(unknown system type $host.)
+ esac
+
+ dnl set target to shared if not explicitly chose static before
+ if test "x$WX_TARGET_LIBRARY" = "x"; then
+ WX_TARGET_LIBRARY="${WX_LIBRARY_NAME_SHARED}"
+ WX_TARGET_LIBRARY_GL="${WX_LIBRARY_NAME_SHARED_GL}"
+ fi
+
+ dnl do not alter the LIBRARY_TYPE strings "so" and "a", they are magic
+ WX_TARGET_LIBRARY_TYPE="so"
+ INSTALL_LIBRARY='$(INSTALL_PROGRAM)'
+fi
+
+dnl do not 'else' this, it may be changed in the above conditional.
+if test "$wxUSE_SHARED" = "no"; then
+
+ dnl give static wxBase and wxMSW build a working install target
+ if test "$wxUSE_GUI" = "no" -o "$USE_WIN32" = 1 ; then
+ dnl we're here because WX_ALL_INSTALLED is empty, but play safe anyway
+ WX_ALL_INSTALLED="${WX_ALL_INSTALLED} preinstall"
+ fi
+
+ if test "$wxUSE_MAC" = 1; then
+ WX_ALL_INSTALLED="${WX_ALL_INSTALLED} preinstall"
+ fi
+
+ if test "$wxUSE_OPENGL" = "yes"; then
+ WX_ALL_INSTALLED="${WX_ALL_INSTALLED} preinstall_gl"
+ WX_ALL="\$(build_libdir)/${WX_LIBRARY_NAME_STATIC} \$(build_libdir)/${WX_LIBRARY_NAME_STATIC_GL}"
+ else
+ WX_ALL="\$(build_libdir)/${WX_LIBRARY_NAME_STATIC}"
+ fi
+
+ WX_TARGET_LIBRARY="${WX_LIBRARY_NAME_STATIC}"
+ WX_TARGET_LIBRARY_GL="${WX_LIBRARY_NAME_STATIC_GL}"
+
+ WX_TARGET_LIBRARY_TYPE="a"
+ INSTALL_LIBRARY='$(INSTALL_DATA)'
+fi
+
+if test "$wxUSE_MAC" = 1; then
+ dnl add the resources target for wxMac
+ WX_ALL="${WX_ALL} \$(build_libdir)/lib${WX_LIBRARY}.r"
+ WX_ALL_INSTALLED="${WX_ALL_INSTALLED} preinstall_res"
+ AC_CHECK_PROG(RESCOMP, Rez, Rez, /Developer/Tools/Rez)
+ AC_CHECK_PROG(DEREZ, DeRez, DeRez, /Developer/Tools/DeRez)
+ MACOSX_BUNDLE="bundle"
+ LIBWXMACRES="\$(top_builddir)/lib/lib${WX_LIBRARY}.r"
+ LIBWXMACRESCOMP="\$(RESCOMP) Carbon.r -t APPL ${LIBWXMACRES} -o \$(BIN_PROGRAM)"
+ LIBWXMACRESWXCONFIG="${RESCOMP} Carbon.r -t APPL \${prefix}/lib/${WX_RESOURCES_MACOSX_COMPILED} -o"
+else
+ if test "$wxUSE_PM" = 1; then
+ LIBWXMACRESCOMP="emxbind -ep \$(BIN_PROGRAM)"
+ fi
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for headers
+dnl ------------------------------------------------------------------------
+
+dnl test for strings.h needed under AIX, but do not check for it wxMac as
+dnl it exists but is only a simple redirection to string.h and it is in
+dnl conflict with Strings.h in FlatCarbon headers
+if test "$wxUSE_MAC" != 1; then
+ dnl defines HAVE_STRINGS_H
+ AC_CHECK_HEADERS(strings.h)
+fi
+
+dnl defines HAVE_STDLIB_H
+AC_CHECK_HEADERS(stdlib.h)
+dnl defines HAVE_MALLOC_H
+AC_CHECK_HEADERS(malloc.h)
+dnl defines HAVE_UNISTD_H
+AC_CHECK_HEADERS(unistd.h)
+dnl defines HAVE_WCHAR_H
+AC_CHECK_HEADERS(wchar.h)
+
+dnl maybe wchar_t is in wcstr.h if we don't have wchar.h?
+if test "$ac_cv_header_wchar_h" != "yes"; then
+ dnl defines HAVE_WCSTR_H
+ AC_CHECK_HEADERS(wcstr.h)
+fi
+
+dnl checking for wctype.h is useless as we need wcslen(), not just wchar_t and
+dnl this function is never provided by it
+dnl AC_CHECK_HEADERS(wctype.h)
+
+dnl defines HAVE_FNMATCH_H
+AC_CHECK_HEADERS(fnmatch.h)
+dnl defines HAVE_LANGINFO_H (GNU libc locale parameters)
+AC_CHECK_HEADERS(langinfo.h)
+
+if test "$wxUSE_GUI" = "yes"; then
+ if test "$wxUSE_UNIX" = "yes"; then
+ dnl defines HAVE_X11_XKBLIB_H
+ AC_CHECK_HEADERS(X11/XKBlib.h)
+ fi
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl Checks for typedefs
+dnl ---------------------------------------------------------------------------
+
+dnl defines mode_t if not already defined
+AC_TYPE_MODE_T
+dnl defines off_t if not already defined
+AC_TYPE_OFF_T
+dnl defines pid_t if not already defined
+AC_TYPE_PID_T
+dnl defines size_t if not already defined
+AC_TYPE_SIZE_T
+dnl defines uid_t and gid_t if not already defined
+AC_TYPE_UID_T
+
+dnl check for wchar_t
+dnl Mac OS X does not provide wchar.h and wchar_t is defined by stdlib.h (GD)
+dnl on Cygwin wchar.h needs stddef.h to be #included by hand
+AC_CACHE_CHECK([for wchar_t], wx_cv_type_wchar_t,
+[
+ AC_TRY_COMPILE(
+ [
+ #ifdef HAVE_WCHAR_H
+ # ifdef __CYGWIN__
+ # include <stddef.h>
+ # endif
+ # include <wchar.h>
+ #endif
+ #ifdef HAVE_STDLIB_H
+ # include <stdlib.h>
+ #endif
+ ],
+ [
+ wchar_t wc, *ws;
+ wc = L'a';
+ ws = L"Hello, world!";
+ ],
+ wx_cv_type_wchar_t=yes,
+ wx_cv_type_wchar_t=no
+ )
+])
+
+if test "$wx_cv_type_wchar_t" = "yes"; then
+ AC_DEFINE(wxUSE_WCHAR_T)
+fi
+
+dnl check what exactly size_t is on this machine - this is necessary to avoid
+dnl ambiguos overloads in several places, notably wx/string.h and wx/array.h
+AC_LANG_SAVE
+AC_LANG_CPLUSPLUS
+AC_CACHE_CHECK([if size_t is unsigned int],
+ wx_cv_size_t_is_uint,
+ dnl an obvious check like AC_TRY_COMPILE[struct Foo { ... };] doesn't work
+ dnl with egcs (at least) up to 1.1.1 as it allows you to compile duplicate
+ dnl methods in a local class (i.e. class inside a function) declaration
+ dnl without any objections!!
+ dnl
+ dnl hence the hack below: we must have Foo at global scope!
+ AC_TRY_COMPILE([#include <stddef.h>],
+ [
+ return 0; }
+
+ struct Foo { void foo(size_t); void foo(unsigned int); };
+
+ int bar() {
+ ],
+ wx_cv_size_t_is_uint=no,
+ wx_cv_size_t_is_uint=yes
+ )
+)
+
+if test "$wx_cv_size_t_is_uint" = "yes"; then
+ AC_DEFINE(wxSIZE_T_IS_UINT)
+else
+ AC_CACHE_CHECK([if size_t is unsigned long],
+ wx_cv_size_t_is_ulong,
+ AC_TRY_COMPILE([#include <stddef.h>],
+ [
+ return 0; }
+
+ struct Foo { void foo(size_t); void foo(unsigned long); };
+
+ int bar() {
+ ],
+ wx_cv_size_t_is_ulong=no,
+ wx_cv_size_t_is_ulong=yes
+ )
+ )
+
+ if test "$wx_cv_size_t_is_ulong" = "yes"; then
+ AC_DEFINE(wxSIZE_T_IS_ULONG)
+ fi
+fi
+
+AC_LANG_RESTORE
+
+dnl ---------------------------------------------------------------------------
+dnl Checks for structures
+dnl ---------------------------------------------------------------------------
+
+dnl does passwd struct has the pw_gecos field?
+AC_CACHE_CHECK([for pw_gecos in struct passwd], wx_cv_struct_pw_gecos,
+ [
+ AC_TRY_COMPILE([#include <pwd.h>],
+ [
+ char *p;
+ struct passwd *pw;
+ p = pw->pw_gecos;
+ ],
+ [
+ wx_cv_struct_pw_gecos=yes
+ ],
+ [
+ wx_cv_struct_pw_gecos=no
+ ]
+ )
+ ]
+)
+
+if test "$wx_cv_struct_pw_gecos" = "yes"; then
+ AC_DEFINE(HAVE_PW_GECOS)
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl Checks for compiler characteristics
+dnl ---------------------------------------------------------------------------
+
+dnl defines const to be empty if c-compiler does not support const fully
+AC_C_CONST
+dnl defines inline to a sensible value for the c-compiler
+AC_C_INLINE
+
+dnl check the sizes of integral types (give some reasonable default values for
+dnl cross-compiling)
+dnl defines the size of certain types of variables in SIZEOF_<TYPE>
+AC_CHECK_SIZEOF(char, 1)
+AC_CHECK_SIZEOF(short, 2)
+AC_CHECK_SIZEOF(void *, 4)
+AC_CHECK_SIZEOF(int, 4)
+AC_CHECK_SIZEOF(long, 4)
+
+case "${host}" in
+ arm-*-linux* )
+ AC_CHECK_SIZEOF(long long, 8)
+ ;;
+ * )
+ AC_CHECK_SIZEOF(long long, 0)
+esac
+
+
+dnl we have to do it ourselves because SGI/Irix's stdio.h does not include
+dnl wchar_t and AC_CHECK_SIZEOF only includes stdio.h
+dnl Mac OS X does not provide wchar.h and wchar_t is defined by stdlib.h (GD)
+AC_CACHE_CHECK([size of wchar_t], wx_cv_sizeof_wchar_t,
+[
+ AC_TRY_RUN(
+ [
+ #ifdef HAVE_WCHAR_H
+ # ifdef __CYGWIN__
+ # include <stddef.h>
+ # endif
+ # include <wchar.h>
+ #endif
+ #ifdef HAVE_STDLIB_H
+ # include <stdlib.h>
+ #endif
+ #include <stdio.h>
+ int main()
+ {
+ FILE *f=fopen("conftestval", "w");
+ if (!f) exit(1);
+ fprintf(f, "%i", sizeof(wchar_t));
+ exit(0);
+ }
+ ],
+ wx_cv_sizeof_wchar_t=`cat conftestval`,
+ wx_cv_sizeof_wchar_t=0,
+ wx_cv_sizeof_wchar_t=4
+ )
+])
+
+AC_DEFINE_UNQUOTED(SIZEOF_WCHAR_T, $wx_cv_sizeof_wchar_t)
+
+dnl for bytesex stuff (don't use AC_C_BIGENDIAN to allow cross-compiling)
+WX_C_BIGENDIAN
+
+dnl check for iostream (as opposed to iostream.h) standard header
+WX_CPP_NEW_HEADERS(, AC_DEFINE(wxUSE_IOSTREAMH))
+
+dnl check whether C++ compiler supports bool built-in type
+WX_CPP_BOOL
+
+dnl ---------------------------------------------------------------------------
+dnl Check for functions
+dnl ---------------------------------------------------------------------------
+
+dnl check for wcslen
+AC_CHECK_LIB(c, wcslen, [
+ AC_DEFINE(HAVE_WCSLEN)
+ WCHAR_LINK=
+ ], [
+ AC_CHECK_LIB(w, wcslen, [
+ AC_DEFINE(HAVE_WCSLEN)
+ WCHAR_LINK=" -lw"
+ ], [
+ AC_CHECK_LIB(msvcrt, wcslen, [
+ AC_DEFINE(HAVE_WCSLEN)
+ WCHAR_LINK=
+ ])
+ ])
+ ])
+
+dnl use wcsrtombs instead of wcstombs which is buggy in old GNU libc versions
+dnl if possible
+AC_CHECK_FUNCS(wcsrtombs)
+
+dnl check for vprintf/vsprintf() which are GNU extensions
+AC_FUNC_VPRINTF
+
+dnl check for vsscanf() and vsnprintf() - on some platforms (Linux, glibc
+dnl 2.1.1 for the first one, HP-UX for the second) it's available in the
+dnl library but the prototype is missing, so we can't use AC_CHECK_FUNCS() here,
+dnl do it manually. We can't use AC_TRY_COMPILE(), either, because it doesn't
+dnl check if the symbol is available at linking time
+
+dnl we use AC_TRY_LINK() here instead of AC_TRY_RUN() to make the checks
+dnl work for cross-compilation, but AC_TRY_LINK() normally only compiles
+dnl one function while we need at least 2 - hence the ugly hack below. To
+dnl understand why it works, remember that AC_TRY_LINK() just prepends
+dnl "int main() {" in the beginning of the code and "; return 0; }" at the
+dnl end...
+
+dnl if we fail to find vsnprintf, also try for _vsnprintf as that is what
+dnl we'll find under MSW if it exists.
+
+dnl final note: AC_TRY_LINK will only be executed if there is nothing in
+dnl the cache so we have to do AC_DEFINE(HAVE_VSNPRINTF) below and not inside
+dnl it or the symbol wouldn't be defined for the 2nd and subsequent configure
+dnl runs
+
+dnl check for vsnprintf() - a safe version of vsprintf()
+AC_CACHE_CHECK([for vsnprintf], wx_cv_func_vsnprintf,
+[
+ AC_TRY_LINK([
+ #include <stdio.h>
+ #include <stdarg.h>
+ ], [
+ int wx_test_vsnprintf(const char *, ...);
+
+ wx_test_vsnprintf("%s");
+ return 0;
+ }
+
+ int wx_test_vsnprintf(const char *fmt, ...)
+ {
+ char *s;
+
+ va_list argp;
+ va_start(argp, fmt);
+ vsnprintf(s, 42, fmt, argp);
+ va_end(argp);
+ ], [
+ wx_cv_func_vsnprintf=yes
+ ], [
+ AC_TRY_LINK([
+ #include <stdio.h>
+ #include <stdarg.h>
+ ], [
+ int wx_test_vsnprintf(const char *, ...);
+
+ wx_test_vsnprintf("%s");
+ return 0;
+ }
+
+ int wx_test_vsnprintf(const char *fmt, ...)
+ {
+ char *s;
+
+ va_list argp;
+ va_start(argp, fmt);
+ _vsnprintf(s, 42, fmt, argp);
+ va_end(argp);
+ ], [
+ wx_cv_func_vsnprintf=yes
+ ], [
+ wx_cv_func_vsnprintf=no
+ ])
+ ])
+])
+
+if test "$wx_cv_func_vsnprintf" = yes; then
+ AC_DEFINE(HAVE_VSNPRINTF)
+else
+ AC_MSG_WARN(unsafe function vsprintf will be used instead of vsnprintf)
+fi
+
+dnl check for vsscanf()
+AC_CACHE_CHECK([for vsscanf], wx_cv_func_vsscanf,
+[
+ AC_TRY_COMPILE([
+ #include <stdio.h>
+ #include <stdarg.h>
+ ], [
+ int wx_test_vsscanf(const char *, ...);
+
+ wx_test_vsscanf("%d");
+ return 0;
+ }
+
+ int wx_test_vsscanf(const char *fmt, ...)
+ {
+ va_list argp;
+ va_start(argp, fmt);
+ vsscanf("42", fmt, argp);
+ va_end(argp);
+ ], [
+ wx_cv_func_vsscanf=yes
+ ], [
+ wx_cv_func_vsscanf=no
+ ])
+])
+
+if test "$wx_cv_func_vsscanf" = yes; then
+ AC_DEFINE(HAVE_VSSCANF)
+fi
+
+dnl the following tests are for Unix(like) systems only
+if test "$TOOLKIT" != "MSW"; then
+
+dnl check for available version of iconv()
+
+AC_LANG_SAVE
+AC_LANG_CPLUSPLUS
+AM_ICONV
+LIBS="$LIBICONV $LIBS"
+AC_LANG_RESTORE
+
+dnl check for POSIX signals if we need them
+if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes" -a "$wxUSE_UNIX" = "yes"; then
+ AC_CHECK_FUNCS(sigaction)
+
+ if test "$ac_cv_func_sigaction" = "no"; then
+ AC_MSG_WARN([No POSIX signal functions on this system, wxApp::OnFatalException will not be called])
+ wxUSE_ON_FATAL_EXCEPTION=no
+ fi
+
+ if test "$wxUSE_ON_FATAL_EXCEPTION" = "yes"; then
+ AC_LANG_SAVE
+ AC_LANG_CPLUSPLUS
+
+ AC_CACHE_CHECK([for sa_handler type], wx_cv_type_sa_handler,
+ [
+ AC_TRY_COMPILE([#include <signal.h>],
+ [
+ extern void testSigHandler(int);
+
+ struct sigaction sa;
+ sa.sa_handler = testSigHandler;
+ ], [
+ wx_cv_type_sa_handler=int
+ ], [
+ wx_cv_type_sa_handler=void
+ ])
+ ])
+
+ AC_LANG_RESTORE
+
+ AC_DEFINE_UNQUOTED(wxTYPE_SA_HANDLER, $wx_cv_type_sa_handler)
+ fi
+fi
+
+dnl check for vfork() (even if it's the same as fork() in modern Unices)
+AC_CHECK_FUNCS(vfork)
+
+dnl check for the function for temp files creation
+AC_CHECK_FUNCS(mkstemp mktemp, break)
+
+dnl get the library function to use for wxGetDiskSpace(): it is statfs() under
+dnl Linux and *BSD and statvfs() under Solaris
+AC_CACHE_CHECK(for statfs, wx_cv_func_statfs,
+ AC_TRY_COMPILE(
+ [
+ #if defined(__BSD__)
+ #include <sys/param.h>
+ #include <sys/mount.h>
+ #else
+ #include <sys/vfs.h>
+ #endif
+ ],
+ [
+ long l;
+ struct statfs fs;
+ statfs("/", &fs);
+ l = fs.f_bsize;
+ l += fs.f_blocks;
+ l += fs.f_bavail;
+ ],
+ [
+ wx_cv_func_statfs=yes
+ ],
+ [
+ wx_cv_func_statfs=no
+ ]
+ )
+)
+
+if test "$wx_cv_func_statfs" = "yes"; then
+ AC_DEFINE(HAVE_STATFS)
+else
+ AC_CACHE_CHECK(for statvfs, wx_cv_func_statvfs,
+ AC_TRY_COMPILE(
+ [
+ #include <sys/statvfs.h>
+ ],
+ [
+ long l;
+ struct statvfs fs;
+ statvfs("/", &fs);
+ l = fs.f_bsize;
+ l += fs.f_blocks;
+ l += fs.f_bavail;
+ ],
+ [
+ wx_cv_func_statvfs=yes
+ ],
+ [
+ wx_cv_func_statvfs=no
+ ]
+ )
+ )
+
+ if test "$wx_cv_func_statvfs" = "yes"; then
+ AC_DEFINE(HAVE_STATVFS)
+ else
+ AC_MSG_WARN([wxGetDiskSpace() function won't work without statfs()])
+ fi
+fi
+
+dnl check for fcntl() or at least flock() needed by Unix implementation of
+dnl wxSingleInstanceChecker
+if test "$wxUSE_SNGLINST_CHECKER" = "yes"; then
+ AC_CHECK_FUNCS(fcntl flock, break)
+
+ if test "$ac_cv_func_fcntl" != "yes" -a "$ac_cv_func_flock" != "yes"; then
+ AC_MSG_WARN(wxSingleInstanceChecker not available)
+ wxUSE_SNGLINST_CHECKER=no
+ fi
+fi
+
+dnl check for timegm() used by datetime.cpp
+AC_CHECK_FUNCS(timegm)
+
+dnl look for a function to modify the environment
+AC_CHECK_FUNCS(putenv setenv, break)
+
+HAVE_SOME_SLEEP_FUNC=0
+if test "$USE_BEOS" = 1; then
+ dnl BeOS has its own (wonder where did they get it from) sleep() function
+ dnl in unistd.h
+ AC_DEFINE(HAVE_SLEEP)
+ HAVE_SOME_SLEEP_FUNC=1
+fi
+
+if test "$USE_DARWIN" = 1; then
+ dnl Mac OS X has both nanosleep and usleep
+ dnl but only usleep is defined in unistd.h
+ AC_DEFINE(HAVE_USLEEP)
+ HAVE_SOME_SLEEP_FUNC=1
+fi
+
+if test "$HAVE_SOME_SLEEP_FUNC" != 1; then
+ dnl try nanosleep() in libc and libposix4, if this fails - usleep()
+ POSIX4_LINK=
+ AC_CHECK_FUNCS(nanosleep,
+ AC_DEFINE(HAVE_NANOSLEEP),
+ [
+ AC_CHECK_LIB(posix4, nanosleep,
+ [
+ AC_DEFINE(HAVE_NANOSLEEP)
+ POSIX4_LINK=" -lposix4"
+ ],
+ [
+ AC_CHECK_FUNCS(usleep,
+ AC_DEFINE(HAVE_USLEEP),
+ AC_MSG_WARN([wxSleep() function will not work])
+ )
+ ]
+ )
+ ]
+ )
+fi
+
+dnl check for uname (POSIX) and gethostname (BSD)
+AC_CHECK_FUNCS(uname gethostname, break)
+
+dnl check for MT-safe version of strtok (on DEC Alpha, it's ok for C compiler
+dnl but not for C++ one - hence change language)
+AC_LANG_SAVE
+AC_LANG_CPLUSPLUS
+
+AC_CHECK_FUNCS(strtok_r)
+
+AC_LANG_RESTORE
+
+dnl check for inet_addr and inet_aton (these may live either in libc, or in
+dnl libnsl or libresolv or libsocket)
+INET_LINK=
+AC_CHECK_FUNCS(inet_addr,
+ AC_DEFINE(HAVE_INET_ADDR),
+ [
+ AC_CHECK_LIB(nsl, inet_addr,
+ INET_LINK="nsl",
+ AC_CHECK_LIB(resolv, inet_addr,
+ INET_LINK="resolv",
+ AC_CHECK_LIB(socket, inet_addr,
+ INET_LINK="socket"
+ )
+ )
+ )
+ ]
+)
+
+AC_CHECK_FUNCS(inet_aton,
+ AC_DEFINE(HAVE_INET_ATON),
+ [
+ dnl only check it in the same lib
+ AC_CHECK_LIB($INET_LINK, inet_aton, AC_DEFINE(HAVE_INET_ATON))
+ ])
+
+if test "x$INET_LINK" != "x"; then
+ AC_DEFINE(HAVE_INET_ADDR)
+ INET_LINK=" -l$INET_LINK"
+fi
+
+fi
+dnl if !MSW
+
+dnl ===========================================================================
+dnl Now we have all the info we need - use it!
+dnl ===========================================================================
+
+dnl flush the cache
+AC_CACHE_SAVE
+
+dnl ---------------------------------------------------------------------------
+dnl thread support for Unix (always available under Win32)
+dnl ---------------------------------------------------------------------------
+
+dnl under MSW we always have thread support
+CPP_MT_FLAG=
+if test "$TOOLKIT" != "MSW"; then
+
+ dnl the code below:
+ dnl
+ dnl defines THREADS_LINK and THREADS_CFLAGS which are the options
+ dnl necessary to build the MT programs for the linker and compiler
+ dnl respectively
+ dnl
+ dnl sets wxUSE_THREADS=1 if thread support is activated
+
+ THREADS_LINK=
+ THREADS_CFLAGS=
+
+ if test "$wxUSE_THREADS" = "yes" ; then
+ if test "$wxUSE_WINE" = 1 ; then
+ AC_MSG_WARN([Threads are not supported under WINE... disabled])
+ wxUSE_THREADS="no"
+ elif test "$USE_BEOS" = 1; then
+ AC_MSG_WARN([BeOS threads are not yet supported... disabled])
+ wxUSE_THREADS="no"
+ fi
+ fi
+
+ if test "$wxUSE_THREADS" = "yes" ; then
+ dnl find if POSIX threads are available
+ dnl
+ dnl the tests here are based on ACX_PTHREAD macro from autoconf macro
+ dnl archive from http://ac-archive.sourceforge.net/
+ dnl
+ dnl thanks to Steven G. Johnson <stevenj@alum.mit.edu> and Alejandro
+ dnl Forero Cuervo <bachue@bachue.com> for the original code
+
+ dnl TODO: cache the result
+
+ dnl define the list of the thread options to try in the loop below
+ dnl with the convention that anything starting with '-' is a cpp flag
+ dnl while anything else is a library (i.e. there is an implicit "-l")
+ THREAD_OPTS="-pthread"
+ case "${host}" in
+ *-*-solaris2* | *-*-sunos4* )
+ if test "x$GCC" = "xyes"; then
+ dnl Solaris/gcc combination use this one for some reason
+ THREAD_OPTS="-pthreads $THREAD_OPTS"
+ else
+ THREAD_OPTS="-mt $THREAD_OPTS"
+ fi
+ ;;
+ *-*-freebsd*)
+ dnl look, in order, for the kernel threads, then Linux threads
+ dnl and finally the userland threads
+ THREAD_OPTS="-kthread lthread $THREAD_OPTS c_r"
+ ;;
+ *-*-aix* )
+ dnl AIX calls the library libpthreads - thanks IBM!
+ THREAD_OPTS="pthreads"
+ ;;
+ esac
+
+ dnl simply linking with libpthread should make the test below work but
+ dnl it's far from certain that the threaded programs compiled without
+ dnl any special switches actually work, so try it after all the others
+ THREAD_OPTS="$THREAD_OPTS pthread none"
+
+ dnl now test for all possibilities
+ THREADS_OK=no
+ for flag in $THREAD_OPTS; do
+ case $flag in
+ none)
+ AC_MSG_CHECKING([whether pthreads work without any flags])
+ ;;
+
+ -*)
+ AC_MSG_CHECKING([whether pthreads work with $flag])
+ THREADS_CFLAGS="$flag"
+ ;;
+
+ *)
+ AC_MSG_CHECKING([for the pthreads library -l$flag])
+ THREADS_LINK="-l$flag"
+ ;;
+ esac
+
+ save_LIBS="$LIBS"
+ save_CFLAGS="$CFLAGS"
+ LIBS="$THREADS_LINK $LIBS"
+ CFLAGS="$THREADS_CFLAGS $CFLAGS"
+
+ AC_TRY_LINK([#include <pthread.h>],
+ [pthread_create(0,0,0,0);],
+ THREADS_OK=yes)
+
+ LIBS="$save_LIBS"
+ CFLAGS="$save_CFLAGS"
+
+ AC_MSG_RESULT($THREADS_OK)
+ if test "x$THREADS_OK" = "xyes"; then
+ break;
+ fi
+
+ THREADS_LINK=""
+ THREADS_CFLAGS=""
+ done
+
+ if test "x$THREADS_OK" != "xyes"; then
+ wxUSE_THREADS=no
+ AC_MSG_WARN([No thread support on this system... disabled])
+ else
+ dnl yes, these special compiler flags should be used with the
+ dnl linker as well
+ LIBS="$THREADS_LINK $THREADS_CFLAGS $LIBS"
+
+ AC_MSG_CHECKING([if more special flags are required for pthreads])
+ flag=no
+ case "${host}" in
+ *-aix* | *-freebsd*)
+ flag="-D_THREAD_SAFE"
+ ;;
+ *solaris* | alpha*-osf*)
+ flag="-D_REENTRANT"
+ ;;
+ esac
+ AC_MSG_RESULT(${flag})
+ if test "x$flag" != xno; then
+ THREADS_CFLAGS="$THREADS_CFLAGS $flag"
+ fi
+
+ if test "x$THREADS_CFLAGS" != "x"; then
+ dnl don't add these options to CPPFLAGS as cpp might not know them
+ CFLAGS="$CFLAGS $THREADS_CFLAGS"
+ CXXFLAGS="$CXXFLAGS $THREADS_CFLAGS"
+ fi
+ fi
+ fi
+
+ dnl do other tests only if we are using threads
+ if test "$wxUSE_THREADS" = "yes" ; then
+ AC_CHECK_FUNCS(thr_setconcurrency)
+
+ AC_CHECK_HEADERS(sched.h)
+ if test "$ac_cv_header_sched_h" = "yes"; then
+ AC_CHECK_FUNC(sched_yield,
+ AC_DEFINE(HAVE_SCHED_YIELD),
+ [
+ AC_CHECK_LIB(posix4,
+ sched_yield,
+ [AC_DEFINE(HAVE_SCHED_YIELD) POSIX4_LINK=" -lposix4"],
+ AC_MSG_WARN(wxThread::Yield will not work properly)
+ )
+ ]
+ )
+ fi
+
+ dnl to be able to set the thread priority, we need to have all of the
+ dnl following functions:
+ dnl 1. pthread_attr_getschedpolicy
+ dnl 2. sched_get_priority_min and sched_get_priority_max
+ dnl (this one can be in either libpthread or libposix4 (under Solaris))
+ dnl 3. pthread_attr_getschedparam and pthread_attr_setschedparam
+ HAVE_PRIOR_FUNCS=0
+ AC_CHECK_FUNC(pthread_attr_getschedpolicy,
+ AC_CHECK_FUNC(pthread_attr_setschedparam,
+ AC_CHECK_FUNC(sched_get_priority_max,
+ HAVE_PRIOR_FUNCS=1,
+ AC_CHECK_LIB([posix4], sched_get_priority_max,
+ [
+ HAVE_PRIOR_FUNCS=1
+ POSIX4_LINK=" -lposix4"
+ ],
+ )
+ )
+ )
+ )
+
+ if test "$HAVE_PRIOR_FUNCS" = 1; then
+ AC_DEFINE(HAVE_THREAD_PRIORITY_FUNCTIONS)
+ else
+ AC_MSG_WARN(Setting thread priority will not work)
+ fi
+
+ AC_CHECK_FUNC(pthread_cancel,
+ AC_DEFINE(HAVE_PTHREAD_CANCEL),
+ AC_MSG_WARN([wxThread::Kill() will not work properly]))
+
+ AC_CACHE_CHECK([for pthread_cleanup_push/pop], wx_cv_func_pthread_cleanup_push,
+ [
+ AC_TRY_COMPILE([#include <pthread.h>],
+ [
+ pthread_cleanup_push(NULL, NULL);
+ pthread_cleanup_pop(0);
+ ], [
+ wx_cv_func_pthread_cleanup_push=yes
+ ], [
+ wx_cv_func_pthread_cleanup_push=no
+ ])
+ ])
+
+ if test "$wx_cv_func_pthread_cleanup_push" = "yes"; then
+ AC_DEFINE(HAVE_THREAD_CLEANUP_FUNCTIONS)
+ fi
+
+ dnl mutexattr_t initialization is done in quite different ways on different
+ dnl platforms, so check for a few things:
+ dnl
+ dnl HAVE_MUTEX_RECURSIVE means that we can create recursive mutexes
+ dnl HAVE_MUTEXATTR_SETTYPE means that we do it using
+ dnl pthread_mutexattr_settype(PTHREAD_MUTEX_RECURSIVE) and if it is not
+ dnl defined, we do it by directly assigned
+ dnl PTHREAD_MUTEX_RECURSIVE_MUTEX_INITIALIZER_NP to attr
+
+ dnl we need _GNU_SOURCE to get PTHREAD_MUTEX_RECURSIVE with glibc 2.1+
+ dnl (strictly speaking we only need _XOPEN_SOURCE=500 but just defining
+ dnl this disables _BSD_SOURCE which breaks libtiff compilation, so it is
+ dnl simpler to just define _GNU_SOURCE to get everything)
+ if test "x$wx_lib_glibc21" = "xyes"; then
+ CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
+ fi
projects / wxWidgets.git / blobdiff