+dnl check for glibc version
+dnl
+dnl VZ: I have no idea why had this check been there originally, but now
+dnl we could probably do without it by just always adding _GNU_SOURCE
+if test "$USE_LINUX" = 1; then
+ AC_CACHE_CHECK([for glibc 2.1 or later], wx_cv_lib_glibc21,[
+ AC_TRY_COMPILE([#include <features.h>],
+ [
+ #if (__GLIBC__ < 2) || (__GLIBC_MINOR__ < 1)
+ #error not glibc2.1
+ #endif
+ ],
+ [
+ wx_cv_lib_glibc21=yes
+ ],
+ [
+ wx_cv_lib_glibc21=no
+ ]
+ )
+ ])
+ if test "$wx_cv_lib_glibc21" = "yes"; then
+ AC_DEFINE(wxHAVE_GLIBC2)
+ fi
+fi
+
+dnl we may need _GNU_SOURCE for 2 things:
+dnl
+dnl 1. to get PTHREAD_MUTEX_RECURSIVE with glibc 2.1+ (strictly speaking we
+dnl only need _XOPEN_SOURCE=500 but just defining this disables _BSD_SOURCE
+dnl which breaks libtiff compilation, so it is simpler to just define
+dnl _GNU_SOURCE to get everything)
+dnl
+dnl 2. for Unicode functions
+if test "x$wx_cv_lib_glibc21" = "xyes"; then
+ if test "$wxUSE_UNICODE" = "yes" -o "$wxUSE_THREADS" = "yes"; then
+ AC_DEFINE(_GNU_SOURCE)
+ fi
+fi
+
+dnl ---------------------------------------------------------------------------
+dnl Optional libraries
+dnl
+dnl --with-<lib>=sys
+dnl looks for system library and fails if not found
+dnl
+dnl --with-<lib>
+dnl --with-<lib>=yes
+dnl looks for system library and, if not found, prints a warning,
+dnl falls back to the builtin wx version, and continues configuration
+dnl
+dnl --with-<lib>=builtin
+dnl uses builtin wx version without searching for system library
+dnl
+dnl --with-<lib>=no
+dnl --without-<lib>
+dnl do not use library (neither system nor builtin wx version)
+dnl
+dnl ---------------------------------------------------------------------------
+
+dnl ------------------------------------------------------------------------
+dnl Check for regex libraries
+dnl ------------------------------------------------------------------------
+
+REGEX_INCLUDE=
+if test "$wxUSE_REGEX" != "no"; then
+ AC_DEFINE(wxUSE_REGEX)
+
+ if test "$wxUSE_REGEX" = "sys" -o "$wxUSE_REGEX" = "yes" ; then
+ dnl according to Unix 98 specs, regcomp() is in libc but I believe that
+ dnl on some old systems it may be in libregex - check for it too?
+ AC_CHECK_HEADER(regex.h, AC_CHECK_FUNCS(regcomp))
+
+ if test "x$ac_cv_func_regcomp" != "xyes"; then
+ if test "$wxUSE_REGEX" = "sys" ; then
+ AC_MSG_ERROR([system regex library not found! Use --with-regex to use built-in version])
+ else
+ AC_MSG_WARN([system regex library not found, will use built-in instead])
+ wxUSE_REGEX=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_REGEX=sys
+ fi
+ fi
+
+ if test "$wxUSE_REGEX" = "builtin" ; then
+ REGEX_INCLUDE="-I\${top_srcdir}/src/regex"
+ fi
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for zlib compression library
+dnl ------------------------------------------------------------------------
+
+ZLIB_INCLUDE=
+ZLIB_LINK=
+if test "$wxUSE_ZLIB" != "no" ; then
+ AC_DEFINE(wxUSE_ZLIB)
+
+ if test "$wxUSE_ZLIB" = "sys" -o "$wxUSE_ZLIB" = "yes" ; then
+ dnl don't test for zlib under Mac -- its verson there is 1.1.3 but we
+ dnl should still use it because hopefully (can someone confirm this?)
+ dnl Apple did fix the security problem in it and not using the system
+ dnl library results in a whole bunch of warnings when linking with
+ dnl Carbon framework
+ if test "$USE_DARWIN" = 1; then
+ system_zlib_h_ok="yes"
+ else
+ dnl we have troubles with ancient zlib versions (e.g. 1.0.4 is
+ dnl known to not work) and although I don't know which is
+ dnl the minimal required version it's safer to test for 1.1.4 as
+ dnl it fixes a security problem in 1.1.3 -- and hopefully nobody
+ dnl has anything more ancient (1.1.3 was released in July 1998)
+ dnl anyhow
+ AC_CACHE_CHECK([for zlib.h >= 1.1.4], ac_cv_header_zlib_h,
+ AC_TRY_RUN(
+ [
+ dnl zlib.h defines ZLIB_VERSION="x.y.z"
+ #include <zlib.h>
+ #include <stdio.h>
+
+ dnl don't use the brackets as quotes, we need them
+ changequote(,)
+ int main()
+ {
+ FILE *f=fopen("conftestval", "w");
+ if (!f) exit(1);
+ fprintf(f, "%s",
+ ZLIB_VERSION[0] == '1' &&
+ (ZLIB_VERSION[2] > '1' ||
+ (ZLIB_VERSION[2] == '1' &&
+ ZLIB_VERSION[4] >= '4')) ? "yes" : "no");
+ exit(0);
+ }
+ changequote([,])
+ ],
+ ac_cv_header_zlib_h=`cat conftestval`,
+ ac_cv_header_zlib_h=no,
+ dnl cross-compiling: don't have an answer, try later
+ unset ac_cv_header_zlib_h
+ )
+ )
+ dnl If the test above did not come up with a value (e.g. cross
+ dnl compiling) then this should give a definitive answer
+ AC_CHECK_HEADER(zlib.h)
+
+ system_zlib_h_ok=$ac_cv_header_zlib_h
+ fi
+
+ if test "$system_zlib_h_ok" = "yes"; then
+ AC_CHECK_LIB(z, deflate, ZLIB_LINK=" -lz")
+ fi
+
+ if test "x$ZLIB_LINK" = "x" ; then
+ if test "$wxUSE_ZLIB" = "sys" ; then
+ AC_MSG_ERROR([zlib library not found or too old! Use --with-zlib=builtin to use built-in version])
+ else
+ AC_MSG_WARN([zlib library not found or too old, will use built-in instead])
+ wxUSE_ZLIB=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_ZLIB=sys
+ fi
+ fi
+
+ if test "$wxUSE_ZLIB" = "builtin" ; then
+ ZLIB_INCLUDE="-I\${top_srcdir}/src/zlib"
+ fi
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for png library
+dnl ------------------------------------------------------------------------
+
+PNG_INCLUDE=
+PNG_LINK=
+if test "$wxUSE_LIBPNG" != "no" ; then
+ AC_DEFINE(wxUSE_LIBPNG)
+
+ if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBPNG" = "builtin" ; then
+ AC_MSG_WARN([wxMGL doesn't work with builtin png library, will use MGL one instead])
+ wxUSE_LIBPNG=sys
+ fi
+
+ dnl for the check below to have a chance to succeed, we must already have
+ dnl libz somewhere (don't do this when bulding wxMGL since its libpng
+ dnl doesn't depend on zlib)
+ if test "$wxUSE_MGL" != 1 -a "$wxUSE_LIBPNG" = "sys" -a "$wxUSE_ZLIB" != "sys" ; then
+ AC_MSG_WARN([system png library doesn't work without system zlib, will use built-in instead])
+ wxUSE_LIBPNG=builtin
+ fi
+
+ if test "$wxUSE_MGL" != 1 ; then
+ dnl Don't check for libpng when building wxMGL, libmgl contains it
+ if test "$wxUSE_LIBPNG" = "sys" -o "$wxUSE_LIBPNG" = "yes" ; then
+ dnl libpng version 0.9 is known to not work, if an even newer
+ dnl version is required, just bump it up in the test below
+ AC_CACHE_CHECK([for png.h > 0.90], ac_cv_header_png_h,
+ AC_TRY_RUN(
+ [
+ dnl png.h defines PNG_LIBPNG_VER=number
+ #include <png.h>
+ #include <stdio.h>
+
+ int main()
+ {
+ FILE *f=fopen("conftestval", "w");
+ if (!f) exit(1);
+ fprintf(f, "%s",
+ PNG_LIBPNG_VER > 90 ? "yes" : "no");
+ exit(0);
+ }
+ ],
+ ac_cv_header_png_h=`cat conftestval`,
+ ac_cv_header_png_h=no,
+ dnl cross-compiling: test (later) if we have any png.h
+ unset ac_cv_header_png_h
+ )
+ )
+ AC_CHECK_HEADER(png.h)
+
+ if test "$ac_cv_header_png_h" = "yes"; then
+ AC_CHECK_LIB(png, png_check_sig, PNG_LINK=" -lpng", , [-lz -lm])
+ fi
+
+ if test "x$PNG_LINK" = "x" ; then
+ if test "$wxUSE_LIBPNG" = "sys" ; then
+ AC_MSG_ERROR([system png library not found or too old! Use --with-libpng=builtin to use built-in version])
+ else
+ AC_MSG_WARN([system png library not found or too old, will use built-in instead])
+ wxUSE_LIBPNG=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_LIBPNG=sys
+ fi
+ fi
+ fi
+
+ if test "$wxUSE_LIBPNG" = "builtin" ; then
+ PNG_INCLUDE="-I\${top_srcdir}/src/png"
+ fi
+
+ SAMPLES_SUBDIRS="$SAMPLES_SUBDIRS png"
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for jpeg library
+dnl ------------------------------------------------------------------------
+
+JPEG_INCLUDE=
+JPEG_LINK=
+if test "$wxUSE_LIBJPEG" != "no" ; then
+ AC_DEFINE(wxUSE_LIBJPEG)
+
+ if test "$wxUSE_MGL" = 1 -a "$wxUSE_LIBJPEG" = "builtin" ; then
+ AC_MSG_WARN([wxMGL doesn't work with builtin jpeg library, will use MGL one instead])
+ wxUSE_LIBJPEG=sys
+ fi
+
+ if test "$wxUSE_MGL" != 1 ; then
+ dnl Don't check for libjpeg when building wxMGL, libmgl contains it
+ if test "$wxUSE_LIBJPEG" = "sys" -o "$wxUSE_LIBJPEG" = "yes" ; then
+ dnl can't use AC_CHECK_HEADER as jconfig.h defines things like
+ dnl HAVE_STDLIB_H which are already defined and this provokes
+ dnl a compiler warning which configure considers as an error...
+ AC_MSG_CHECKING(for jpeglib.h)
+ AC_CACHE_VAL(ac_cv_header_jpeglib_h,
+ AC_TRY_COMPILE(
+ [
+ #undef HAVE_STDLIB_H
+ #include <stdio.h>
+ #include <jpeglib.h>
+ ],
+ [
+ ],
+ ac_cv_header_jpeglib_h=yes,
+ ac_cv_header_jpeglib_h=no
+ )
+ )
+ AC_MSG_RESULT($ac_cv_header_jpeglib_h)
+
+ if test "$ac_cv_header_jpeglib_h" = "yes"; then
+ AC_CHECK_LIB(jpeg, jpeg_read_header, JPEG_LINK=" -ljpeg")
+ fi
+
+ if test "x$JPEG_LINK" = "x" ; then
+ if test "$wxUSE_LIBJPEG" = "sys" ; then
+ AC_MSG_ERROR([system jpeg library not found! Use --with-libjpeg=builtin to use built-in version])
+ else
+ AC_MSG_WARN([system jpeg library not found, will use built-in instead])
+ wxUSE_LIBJPEG=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_LIBJPEG=sys
+ fi
+ fi
+ fi
+
+ if test "$wxUSE_LIBJPEG" = "builtin" ; then
+ JPEG_INCLUDE="-I\${top_srcdir}/src/jpeg"
+ fi
+fi
+
+dnl ------------------------------------------------------------------------
+dnl Check for tiff library
+dnl ------------------------------------------------------------------------
+
+TIFF_INCLUDE=
+TIFF_LINK=
+TIFF_PREREQ_LINKS=-lm
+if test "$wxUSE_LIBTIFF" != "no" ; then
+ AC_DEFINE(wxUSE_LIBTIFF)
+
+ if test "$wxUSE_LIBTIFF" = "sys" -o "$wxUSE_LIBTIFF" = "yes" ; then
+ dnl libtiff may depend on libjpeg and libz so use them in the test
+ dnl below or it would fail
+ if test "$wxUSE_LIBJPEG" = "sys"; then
+ TIFF_PREREQ_LINKS="$TIFF_PREREQ_LINKS $JPEG_LINK"
+ fi
+ if test "$wxUSE_ZLIB" = "sys"; then
+ TIFF_PREREQ_LINKS="$TIFF_PREREQ_LINKS $ZLIB_LINK"
+ fi
+ AC_CHECK_HEADER(tiffio.h,
+ AC_CHECK_LIB(tiff, TIFFError,
+ TIFF_LINK=" -ltiff",
+ ,
+ $TIFF_PREREQ_LINKS)
+ )
+
+ if test "x$TIFF_LINK" = "x" ; then
+ if test "$wxUSE_LIBTIFF" = "sys" ; then
+ AC_MSG_ERROR([system tiff library not found! Use --with-libtiff=builtin to use built-in version])
+ else
+ AC_MSG_WARN([system tiff library not found, will use built-in instead])
+ wxUSE_LIBTIFF=builtin
+ fi
+ else
+ dnl we are using the system library
+ wxUSE_LIBTIFF=sys
+ fi
+ fi
+
+ if test "$wxUSE_LIBTIFF" = "builtin" ; then
+ TIFF_INCLUDE="-I\${top_srcdir}/src/tiff"
+ fi
+fi
+
projects / wxWidgets.git / blobdiff