src/osx/cocoa/dataview.mm

   1 ///////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/dataview.mm
   3 // Purpose:     wxDataView
   4 // Author:
   5 // Modified by:
   6 // Created:     2009-01-31
   7 // RCS-ID:      $Id: dataview.mm$
   8 // Copyright:
   9 // Licence:     wxWindows licence
  10 ///////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if (wxUSE_DATAVIEWCTRL == 1) && !defined(wxUSE_GENERICDATAVIEWCTRL)
  15
  16 #ifndef WX_PRECOMP
  17     #include "wx/app.h"
  18     #include "wx/toplevel.h"
  19     #include "wx/font.h"
  20     #include "wx/settings.h"
  21     #include "wx/utils.h"
  22 #endif
  23
  24 #include "wx/osx/cocoa/dataview.h"
  25 #include "wx/osx/private.h"
  26 #include "wx/renderer.h"
  27
  28 // ============================================================================
  29 // Constants used locally
  30 // ============================================================================
  31
  32 #define DataViewPboardType @"OutlineViewItem"
  33
  34 // ============================================================================
  35 // Classes used locally in dataview.mm
  36 // ============================================================================
  37
  38 // ============================================================================
  39 // wxPointerObject
  40 // ============================================================================
  41
  42 @implementation wxPointerObject
  43
  44 -(id) init
  45 {
  46     self = [super init];
  47     if (self != nil)
  48         self->pointer = NULL;
  49     return self;
  50 }
  51
  52 -(id) initWithPointer:(void*) initPointer
  53 {
  54     self = [super init];
  55     if (self != nil)
  56         self->pointer = initPointer;
  57     return self;
  58 }
  59
  60 //
  61 // inherited methods from NSObject
  62 //
  63 -(BOOL) isEqual:(id)object
  64 {
  65     return (object != nil) &&
  66              ([object isKindOfClass:[wxPointerObject class]]) &&
  67                  (pointer == [((wxPointerObject*) object) pointer]);
  68 }
  69
  70 -(NSUInteger) hash
  71 {
  72     return (NSUInteger) pointer;
  73 }
  74
  75 -(void*) pointer
  76 {
  77     return pointer;
  78 }
  79
  80 -(void) setPointer:(void*) newPointer
  81 {
  82     pointer = newPointer;
  83 }
  84
  85 @end
  86
  87 namespace
  88 {
  89
  90 inline wxDataViewItem wxDataViewItemFromItem(id item)
  91 {
  92     return wxDataViewItem([static_cast<wxPointerObject *>(item) pointer]);
  93 }
  94
  95 inline wxDataViewItem wxDataViewItemFromMaybeNilItem(id item)
  96 {
  97     return item == nil ? wxDataViewItem() : wxDataViewItemFromItem(item);
  98 }
  99
 100 } // anonymous namespace
 101
 102 // ----------------------------------------------------------------------------
 103 // wxCustomRendererObject
 104 // ----------------------------------------------------------------------------
 105
 106 @interface wxCustomRendererObject : NSObject <NSCopying>
 107 {
 108 @public
 109     wxDataViewCustomRenderer* customRenderer; // not owned by the class
 110 }
 111
 112     -(id) init;
 113     -(id) initWithRenderer:(wxDataViewCustomRenderer*)renderer;
 114 @end
 115
 116 @implementation wxCustomRendererObject
 117
 118 -(id) init
 119 {
 120     self = [super init];
 121     if (self != nil)
 122     {
 123         customRenderer = NULL;
 124     }
 125     return self;
 126 }
 127
 128 -(id) initWithRenderer:(wxDataViewCustomRenderer*)renderer
 129 {
 130     self = [super init];
 131     if (self != nil)
 132     {
 133         customRenderer = renderer;
 134     }
 135     return self;
 136 }
 137
 138 -(id) copyWithZone:(NSZone*)zone
 139 {
 140     wxCustomRendererObject* copy;
 141
 142     copy = [[[self class] allocWithZone:zone] init];
 143     copy->customRenderer = customRenderer;
 144
 145     return copy;
 146 }
 147 @end
 148
 149 // ----------------------------------------------------------------------------
 150 // wxDVCNSTableColumn: exists only to override NSTableColumn:dataCellForRow:
 151 // ----------------------------------------------------------------------------
 152
 153 @interface wxDVCNSTableColumn : NSTableColumn
 154 {
 155 }
 156
 157     -(id) dataCellForRow:(NSInteger)row;
 158 @end
 159
 160 @implementation wxDVCNSTableColumn
 161
 162 -(id) dataCellForRow:(NSInteger)row
 163 {
 164     // what we want to do here is to simply return nil for the cells which
 165     // shouldn't show anything as otherwise we would show e.g. empty combo box
 166     // or progress cells in the columns using the corresponding types even for
 167     // the container rows which is wrong
 168
 169     // half of the problem is just finding the objects we need from the column
 170     // pointer which is itself stashed inside wxPointerObject which we use as
 171     // our identifier
 172     const wxDataViewColumn * const
 173         dvCol = static_cast<wxDataViewColumn *>(
 174                     [(wxPointerObject *)[self identifier] pointer]
 175                 );
 176
 177     const wxDataViewCtrl * const dvc = dvCol->GetOwner();
 178     const wxCocoaDataViewControl * const
 179         peer = static_cast<wxCocoaDataViewControl *>(dvc->GetPeer());
 180
 181
 182     // once we do have everything, simply ask NSOutlineView for the item...
 183     const id item = peer->GetItemAtRow(row);
 184     if ( item )
 185     {
 186         // ... and if it succeeded, ask the model whether it has any value
 187         wxDataViewItem dvItem(wxDataViewItemFromItem(item));
 188
 189         if ( !dvc->GetModel()->HasValue(dvItem, dvCol->GetModelColumn()) )
 190             return nil;
 191     }
 192
 193     return [super dataCellForRow:row];
 194 }
 195
 196 @end
 197
 198 // ============================================================================
 199 // local helpers
 200 // ============================================================================
 201
 202 namespace
 203 {
 204
 205 // convert from NSObject to different C++ types: all these functions check
 206 // that the conversion really makes sense and assert if it doesn't
 207 wxString ObjectToString(NSObject *object)
 208 {
 209     wxCHECK_MSG( [object isKindOfClass:[NSString class]], "",
 210                  wxString::Format
 211                  (
 212                     "string expected but got %s",
 213                     wxCFStringRef::AsString([object className])
 214                  ));
 215
 216     return wxCFStringRef([((NSString*) object) retain]).AsString();
 217 }
 218
 219 bool ObjectToBool(NSObject *object)
 220 {
 221     // actually the value must be of NSCFBoolean class but it's private so we
 222     // can't check for it directly
 223     wxCHECK_MSG( [object isKindOfClass:[NSNumber class]], false,
 224                  wxString::Format
 225                  (
 226                     "number expected but got %s",
 227                     wxCFStringRef::AsString([object className])
 228                  ));
 229
 230     return [(NSNumber *)object boolValue];
 231 }
 232
 233 long ObjectToLong(NSObject *object)
 234 {
 235     wxCHECK_MSG( [object isKindOfClass:[NSNumber class]], -1,
 236                  wxString::Format
 237                  (
 238                     "number expected but got %s",
 239                     wxCFStringRef::AsString([object className])
 240                  ));
 241
 242     return [(NSNumber *)object longValue];
 243 }
 244
 245 wxDateTime ObjectToDate(NSObject *object)
 246 {
 247     wxCHECK_MSG( [object isKindOfClass:[NSDate class]], wxInvalidDateTime,
 248                  wxString::Format
 249                  (
 250                     "date expected but got %s",
 251                     wxCFStringRef::AsString([object className])
 252                  ));
 253
 254     // get the number of seconds since 1970-01-01 UTC and this is the only
 255     // way to convert a double to a wxLongLong
 256     const wxLongLong seconds = [((NSDate*) object) timeIntervalSince1970];
 257
 258     wxDateTime dt(1, wxDateTime::Jan, 1970);
 259     dt.Add(wxTimeSpan(0,0,seconds));
 260
 261     // the user has entered a date in the local timezone but seconds
 262     // contains the number of seconds from date in the local timezone
 263     // since 1970-01-01 UTC; therefore, the timezone information has to be
 264     // transferred to wxWidgets, too:
 265     dt.MakeFromTimezone(wxDateTime::UTC);
 266
 267     return dt;
 268 }
 269
 270 NSInteger CompareItems(id item1, id item2, void* context)
 271 {
 272     NSArray* const sortDescriptors = (NSArray*) context;
 273
 274     NSUInteger const count = [sortDescriptors count];
 275
 276     NSInteger result = NSOrderedSame;
 277     for ( NSUInteger i = 0; i < count && result == NSOrderedSame; ++i )
 278     {
 279         wxSortDescriptorObject* const
 280             sortDescriptor = (wxSortDescriptorObject*)
 281                 [sortDescriptors objectAtIndex:i];
 282
 283         int rc = [sortDescriptor modelPtr]->Compare
 284                  (
 285                      wxDataViewItemFromItem(item1),
 286                      wxDataViewItemFromItem(item2),
 287                      [sortDescriptor columnPtr]->GetModelColumn(),
 288                      [sortDescriptor ascending] == YES
 289                  );
 290
 291         if ( rc < 0 )
 292             result = NSOrderedAscending;
 293         else if ( rc > 0 )
 294             result = NSOrderedDescending;
 295     }
 296
 297     return result;
 298 }
 299
 300 NSTextAlignment ConvertToNativeHorizontalTextAlignment(int alignment)
 301 {
 302     if (alignment & wxALIGN_CENTER_HORIZONTAL)
 303         return NSCenterTextAlignment;
 304     else if (alignment & wxALIGN_RIGHT)
 305         return NSRightTextAlignment;
 306     else
 307         return NSLeftTextAlignment;
 308 }
 309
 310 NSTableColumn* CreateNativeColumn(const wxDataViewColumn *column)
 311 {
 312     wxDataViewRenderer * const renderer = column->GetRenderer();
 313
 314     wxCHECK_MSG( renderer, NULL, "column should have a renderer" );
 315
 316     wxDVCNSTableColumn * const nativeColumn(
 317         [[wxDVCNSTableColumn alloc] initWithIdentifier:
 318             [[[wxPointerObject alloc] initWithPointer:
 319                 const_cast<wxDataViewColumn*>(column)]
 320              autorelease]]
 321     );
 322
 323     // setting the size related parameters:
 324     const int width = column->GetWidthVariable();
 325     int resizingMask;
 326     if (column->IsResizeable())
 327     {
 328         resizingMask = NSTableColumnUserResizingMask;
 329         [nativeColumn setMinWidth:column->GetMinWidth()];
 330         [nativeColumn setMaxWidth:column->GetMaxWidth()];
 331     }
 332     else // column is not resizeable [by user]
 333     {
 334         // if the control doesn't show a header, make the columns resize
 335         // automatically, this is particularly important for the single column
 336         // controls (such as wxDataViewTreeCtrl) as their unique column should
 337         // always take up all the available splace
 338         resizingMask = column->GetOwner()->HasFlag(wxDV_NO_HEADER)
 339                             ? NSTableColumnAutoresizingMask
 340                             : NSTableColumnNoResizing;
 341     }
 342     [nativeColumn setResizingMask:resizingMask];
 343     [nativeColumn setWidth:width];
 344
 345 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_5
 346     // setting the visibility:
 347     [nativeColumn setHidden:static_cast<BOOL>(column->IsHidden())];
 348 #endif
 349
 350     wxDataViewRendererNativeData * const renderData = renderer->GetNativeData();
 351
 352     // setting the header:
 353     [[nativeColumn headerCell] setAlignment:
 354         ConvertToNativeHorizontalTextAlignment(column->GetAlignment())];
 355     [[nativeColumn headerCell] setStringValue:
 356         [[wxCFStringRef(column->GetTitle()).AsNSString() retain] autorelease]];
 357     renderData->ApplyLineBreakMode([nativeColumn headerCell]);
 358
 359     // setting data cell's properties:
 360     [[nativeColumn dataCell] setWraps:NO];
 361     // setting the default data cell:
 362     [nativeColumn setDataCell:renderData->GetColumnCell()];
 363     // setting the editablility:
 364     const bool isEditable = renderer->GetMode() == wxDATAVIEW_CELL_EDITABLE;
 365
 366     [nativeColumn setEditable:isEditable];
 367     [[nativeColumn dataCell] setEditable:isEditable];
 368
 369     return nativeColumn;
 370 }
 371
 372 } // anonymous namespace
 373
 374 // ============================================================================
 375 // Public helper functions for dataview implementation on OSX
 376 // ============================================================================
 377
 378 wxWidgetImplType* CreateDataView(wxWindowMac* wxpeer,
 379                                  wxWindowMac* WXUNUSED(parent),
 380                                  wxWindowID WXUNUSED(id),
 381                                  const wxPoint& pos,
 382                                  const wxSize& size,
 383                                  long style,
 384                                  long WXUNUSED(extraStyle))
 385 {
 386     return new wxCocoaDataViewControl(wxpeer,pos,size,style);
 387 }
 388
 389 // ============================================================================
 390 // wxSortDescriptorObject
 391 // ============================================================================
 392
 393 @implementation wxSortDescriptorObject
 394 -(id) init
 395 {
 396     self = [super init];
 397     if (self != nil)
 398     {
 399         columnPtr = NULL;
 400         modelPtr  = NULL;
 401     }
 402     return self;
 403 }
 404
 405 -(id)
 406 initWithModelPtr:(wxDataViewModel*)initModelPtr
 407     sortingColumnPtr:(wxDataViewColumn*)initColumnPtr
 408     ascending:(BOOL)sortAscending
 409 {
 410     self = [super initWithKey:@"dummy" ascending:sortAscending];
 411     if (self != nil)
 412     {
 413         columnPtr = initColumnPtr;
 414         modelPtr  = initModelPtr;
 415     }
 416     return self;
 417 }
 418
 419 -(id) copyWithZone:(NSZone*)zone
 420 {
 421     wxSortDescriptorObject* copy;
 422
 423
 424     copy = [super copyWithZone:zone];
 425     copy->columnPtr = columnPtr;
 426     copy->modelPtr  = modelPtr;
 427
 428     return copy;
 429 }
 430
 431 //
 432 // access to model column's index
 433 //
 434 -(wxDataViewColumn*) columnPtr
 435 {
 436     return columnPtr;
 437 }
 438
 439 -(wxDataViewModel*) modelPtr
 440 {
 441     return modelPtr;
 442 }
 443
 444 -(void) setColumnPtr:(wxDataViewColumn*)newColumnPtr
 445 {
 446     columnPtr = newColumnPtr;
 447 }
 448
 449 -(void) setModelPtr:(wxDataViewModel*)newModelPtr
 450 {
 451     modelPtr = newModelPtr;
 452 }
 453
 454 @end
 455
 456 // ============================================================================
 457 // wxCocoaOutlineDataSource
 458 // ============================================================================
 459 @implementation wxCocoaOutlineDataSource
 460
 461 //
 462 // constructors / destructor
 463 //
 464 -(id) init
 465 {
 466     self = [super init];
 467     if (self != nil)
 468     {
 469         implementation = NULL;
 470         model          = NULL;
 471
 472         currentParentItem = nil;
 473
 474         children = [[NSMutableArray alloc] init];
 475         items    = [[NSMutableSet   alloc] init];
 476     }
 477     return self;
 478 }
 479
 480 -(void) dealloc
 481 {
 482     [currentParentItem release];
 483
 484     [children release];
 485     [items    release];
 486
 487     [super dealloc];
 488 }
 489
 490 //
 491 // methods of informal protocol:
 492 //
 493 -(BOOL)
 494 outlineView:(NSOutlineView*)outlineView
 495     acceptDrop:(id<NSDraggingInfo>)info
 496     item:(id)item childIndex:(NSInteger)index
 497 {
 498     NSArray* supportedTypes(
 499         [NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]
 500     );
 501
 502     NSPasteboard* pasteboard([info draggingPasteboard]);
 503
 504     NSString* bestType([pasteboard availableTypeFromArray:supportedTypes]);
 505
 506     if ( bestType == nil )
 507         return FALSE;
 508
 509     wxDataViewCtrl * const dvc(implementation->GetDataViewCtrl());
 510
 511     wxCHECK_MSG( dvc, false,
 512                      "Pointer to data view control not set correctly." );
 513     wxCHECK_MSG( dvc->GetModel(), false,
 514                     "Pointer to model not set correctly." );
 515
 516     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_DROP, dvc->GetId());
 517     event.SetEventObject(dvc);
 518     event.SetItem(wxDataViewItemFromItem(item));
 519     event.SetModel(dvc->GetModel());
 520
 521     BOOL dragSuccessful;
 522     if ( [bestType compare:DataViewPboardType] == NSOrderedSame )
 523     {
 524         NSArray* dataArray((NSArray*)
 525                       [pasteboard propertyListForType:DataViewPboardType]);
 526         NSUInteger indexDraggedItem, noOfDraggedItems([dataArray count]);
 527
 528         indexDraggedItem = 0;
 529         while (indexDraggedItem < noOfDraggedItems)
 530         {
 531             wxDataObjectComposite* dataObjects(
 532                 implementation->GetDnDDataObjects((NSData*)
 533                     [dataArray objectAtIndex:indexDraggedItem]));
 534
 535             if (dataObjects && (dataObjects->GetFormatCount() > 0))
 536             {
 537                 wxMemoryBuffer buffer;
 538
 539                 // copy data into data object:
 540                 event.SetDataObject(dataObjects);
 541                 event.SetDataFormat(
 542                     implementation->GetDnDDataFormat(dataObjects));
 543                 // copy data into buffer:
 544                 dataObjects->GetDataHere(
 545                     event.GetDataFormat().GetType(),
 546                     buffer.GetWriteBuf(event.GetDataSize()));
 547                 buffer.UngetWriteBuf(event.GetDataSize());
 548                 event.SetDataBuffer(buffer.GetData());
 549                 // finally, send event:
 550                 if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 551                 {
 552                     dragSuccessful = true;
 553                     ++indexDraggedItem;
 554                 }
 555                 else
 556                 {
 557                     dragSuccessful   = true;
 558                     indexDraggedItem = noOfDraggedItems; // stop loop
 559                 }
 560             }
 561             else
 562             {
 563                 dragSuccessful   = false;
 564                 indexDraggedItem = noOfDraggedItems; // stop loop
 565             }
 566             // clean-up:
 567             delete dataObjects;
 568         }
 569     }
 570     else
 571     {
 572         // needed to convert internally used UTF-16 representation to a UTF-8
 573         // representation
 574         CFDataRef              osxData;
 575         wxDataObjectComposite* dataObjects   (new wxDataObjectComposite());
 576         wxTextDataObject*      textDataObject(new wxTextDataObject());
 577
 578         osxData = ::CFStringCreateExternalRepresentation
 579                     (
 580                      kCFAllocatorDefault,
 581                      (CFStringRef)[pasteboard stringForType:NSStringPboardType],
 582                      kCFStringEncodingUTF8,
 583                      32
 584                     );
 585         if (textDataObject->SetData(::CFDataGetLength(osxData),
 586                                     ::CFDataGetBytePtr(osxData)))
 587             dataObjects->Add(textDataObject);
 588         else
 589             delete textDataObject;
 590         // send event if data could be copied:
 591         if (dataObjects->GetFormatCount() > 0)
 592         {
 593             event.SetDataObject(dataObjects);
 594             event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 595             if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 596                 dragSuccessful = true;
 597             else
 598                 dragSuccessful = false;
 599         }
 600         else
 601             dragSuccessful = false;
 602         // clean up:
 603         ::CFRelease(osxData);
 604         delete dataObjects;
 605     }
 606 }
 607
 608 -(id) outlineView:(NSOutlineView*)outlineView
 609     child:(NSInteger)index
 610     ofItem:(id)item
 611 {
 612     if ((item == currentParentItem) &&
 613             (index < ((NSInteger) [self getChildCount])))
 614         return [self getChild:index];
 615
 616     wxDataViewItemArray dataViewChildren;
 617
 618     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 619     model->GetChildren(wxDataViewItemFromMaybeNilItem(item), dataViewChildren);
 620     [self bufferItem:item withChildren:&dataViewChildren];
 621     if ([sortDescriptors count] > 0)
 622         [children sortUsingFunction:CompareItems context:sortDescriptors];
 623     return [self getChild:index];
 624 }
 625
 626 -(BOOL) outlineView:(NSOutlineView*)outlineView isItemExpandable:(id)item
 627 {
 628     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 629     return model->IsContainer(wxDataViewItemFromItem(item));
 630 }
 631
 632 -(NSInteger) outlineView:(NSOutlineView*)outlineView numberOfChildrenOfItem:(id)item
 633 {
 634     NSInteger noOfChildren;
 635
 636     wxDataViewItemArray dataViewChildren;
 637
 638
 639     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 640     noOfChildren = model->GetChildren(wxDataViewItemFromMaybeNilItem(item),
 641                                       dataViewChildren);
 642     [self bufferItem:item withChildren:&dataViewChildren];
 643     if ([sortDescriptors count] > 0)
 644         [children sortUsingFunction:CompareItems context:sortDescriptors];
 645     return noOfChildren;
 646 }
 647
 648 -(id)
 649 outlineView:(NSOutlineView*)outlineView
 650     objectValueForTableColumn:(NSTableColumn*)tableColumn
 651     byItem:(id)item
 652 {
 653     wxCHECK_MSG( model, nil, "Valid model in data source does not exist." );
 654
 655     wxDataViewColumn* col(static_cast<wxDataViewColumn*>([[tableColumn identifier] pointer]));
 656     const unsigned colIdx = col->GetModelColumn();
 657
 658     wxDataViewItem dataViewItem(wxDataViewItemFromItem(item));
 659
 660     if ( model->HasValue(dataViewItem, colIdx) )
 661     {
 662         wxVariant value;
 663         model->GetValue(value,dataViewItem, colIdx);
 664         col->GetRenderer()->SetValue(value);
 665     }
 666
 667     return nil;
 668 }
 669
 670 -(void)
 671 outlineView:(NSOutlineView*)outlineView
 672     setObjectValue:(id)object
 673     forTableColumn:(NSTableColumn*)tableColumn
 674     byItem:(id)item
 675 {
 676     wxDataViewColumn* col(static_cast<wxDataViewColumn*>([[tableColumn identifier] pointer]));
 677
 678     col->GetRenderer()->
 679         OSXOnCellChanged(object, wxDataViewItemFromItem(item), col->GetModelColumn());
 680 }
 681
 682 -(void) outlineView:(NSOutlineView*)outlineView sortDescriptorsDidChange:(NSArray*)oldDescriptors
 683 {
 684     // Warning: the new sort descriptors are guaranteed to be only of type
 685     // NSSortDescriptor! Therefore, the sort descriptors for the data source
 686     // have to be converted.
 687     NSArray* newDescriptors;
 688
 689     NSMutableArray* wxSortDescriptors;
 690
 691     NSUInteger noOfDescriptors;
 692
 693     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
 694
 695
 696     // convert NSSortDescriptors to wxSortDescriptorObjects:
 697     newDescriptors    = [outlineView sortDescriptors];
 698     noOfDescriptors   = [newDescriptors count];
 699     wxSortDescriptors = [NSMutableArray arrayWithCapacity:noOfDescriptors];
 700     for (NSUInteger i=0; i<noOfDescriptors; ++i)
 701     {
 702         NSSortDescriptor* const newDescriptor = [newDescriptors objectAtIndex:i];
 703
 704         [wxSortDescriptors addObject:[[[wxSortDescriptorObject alloc] initWithModelPtr:model
 705             sortingColumnPtr:dvc->GetColumn([[newDescriptor key] intValue])
 706             ascending:[newDescriptor ascending]] autorelease]];
 707     }
 708     [[outlineView dataSource] setSortDescriptors:wxSortDescriptors];
 709
 710     // send first the event to wxWidgets that the sorting has changed so that
 711     // the program can do special actions before the sorting actually starts:
 712     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_COLUMN_SORTED,dvc->GetId()); // variable defintion
 713
 714     event.SetEventObject(dvc);
 715     if (noOfDescriptors > 0)
 716     {
 717         wxDataViewColumn* const col = [[wxSortDescriptors objectAtIndex:0] columnPtr];
 718
 719         event.SetColumn(dvc->GetColumnPosition(col));
 720         event.SetDataViewColumn(col);
 721     }
 722     dvc->GetEventHandler()->ProcessEvent(event);
 723
 724     // start re-ordering the data;
 725     // children's buffer must be cleared first because it contains the old order:
 726     [self clearChildren];
 727     // sorting is done while reloading the data:
 728     [outlineView reloadData];
 729 }
 730
 731 -(NSDragOperation) outlineView:(NSOutlineView*)outlineView validateDrop:(id<NSDraggingInfo>)info proposedItem:(id)item proposedChildIndex:(NSInteger)index
 732 {
 733     NSArray* supportedTypes([NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]);
 734
 735     NSPasteboard* pasteboard([info draggingPasteboard]);
 736
 737     NSString* bestType([pasteboard availableTypeFromArray:supportedTypes]);
 738     if (bestType == nil)
 739         return NSDragOperationNone;
 740
 741     NSDragOperation dragOperation;
 742     wxDataViewCtrl* const dvc(implementation->GetDataViewCtrl());
 743
 744     wxCHECK_MSG(dvc, false, "Pointer to data view control not set correctly.");
 745     wxCHECK_MSG(dvc->GetModel(), false, "Pointer to model not set correctly.");
 746
 747     wxDataViewEvent
 748         event(wxEVT_COMMAND_DATAVIEW_ITEM_DROP_POSSIBLE,dvc->GetId());
 749
 750     event.SetEventObject(dvc);
 751     event.SetItem(wxDataViewItemFromItem(item));
 752     event.SetModel(dvc->GetModel());
 753     if ([bestType compare:DataViewPboardType] == NSOrderedSame)
 754     {
 755         NSArray*               dataArray((NSArray*)[pasteboard propertyListForType:DataViewPboardType]);
 756         NSUInteger             indexDraggedItem, noOfDraggedItems([dataArray count]);
 757
 758         indexDraggedItem = 0;
 759         while (indexDraggedItem < noOfDraggedItems)
 760         {
 761             wxDataObjectComposite* dataObjects(implementation->GetDnDDataObjects((NSData*)[dataArray objectAtIndex:indexDraggedItem]));
 762
 763             if (dataObjects && (dataObjects->GetFormatCount() > 0))
 764             {
 765                 wxMemoryBuffer buffer;
 766
 767                 // copy data into data object:
 768                 event.SetDataObject(dataObjects);
 769                 event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 770                 // copy data into buffer:
 771                 dataObjects->GetDataHere(event.GetDataFormat().GetType(),buffer.GetWriteBuf(event.GetDataSize()));
 772                 buffer.UngetWriteBuf(event.GetDataSize());
 773                 event.SetDataBuffer(buffer.GetData());
 774                 // finally, send event:
 775                 if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 776                 {
 777                     dragOperation = NSDragOperationEvery;
 778                     ++indexDraggedItem;
 779                 }
 780                 else
 781                 {
 782                     dragOperation    = NSDragOperationNone;
 783                     indexDraggedItem = noOfDraggedItems; // stop loop
 784                 }
 785             }
 786             else
 787             {
 788                 dragOperation    = NSDragOperationNone;
 789                 indexDraggedItem = noOfDraggedItems; // stop loop
 790             }
 791             // clean-up:
 792             delete dataObjects;
 793         }
 794     }
 795     else
 796     {
 797         // needed to convert internally used UTF-16 representation to a UTF-8
 798         // representation
 799         CFDataRef              osxData;
 800         wxDataObjectComposite* dataObjects   (new wxDataObjectComposite());
 801         wxTextDataObject*      textDataObject(new wxTextDataObject());
 802
 803         osxData = ::CFStringCreateExternalRepresentation(kCFAllocatorDefault,(CFStringRef)[pasteboard stringForType:NSStringPboardType],kCFStringEncodingUTF8,32);
 804         if (textDataObject->SetData(::CFDataGetLength(osxData),::CFDataGetBytePtr(osxData)))
 805             dataObjects->Add(textDataObject);
 806         else
 807             delete textDataObject;
 808         // send event if data could be copied:
 809         if (dataObjects->GetFormatCount() > 0)
 810         {
 811             event.SetDataObject(dataObjects);
 812             event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 813             if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 814                 dragOperation = NSDragOperationEvery;
 815             else
 816                 dragOperation = NSDragOperationNone;
 817         }
 818         else
 819             dragOperation = NSDragOperationNone;
 820         // clean up:
 821         ::CFRelease(osxData);
 822         delete dataObjects;
 823     }
 824
 825     return dragOperation;
 826 }
 827
 828 -(BOOL) outlineView:(NSOutlineView*)outlineView writeItems:(NSArray*)writeItems toPasteboard:(NSPasteboard*)pasteboard
 829 {
 830     // the pasteboard will be filled up with an array containing the data as
 831     // returned by the events (including the data type) and a concatenation of
 832     // text (string) data; the text data will only be put onto the pasteboard
 833     // if for all items a string representation exists
 834     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
 835
 836     wxDataViewItemArray dataViewItems;
 837
 838
 839     wxCHECK_MSG(dvc, false,"Pointer to data view control not set correctly.");
 840     wxCHECK_MSG(dvc->GetModel(),false,"Pointer to model not set correctly.");
 841
 842     if ([writeItems count] > 0)
 843     {
 844         bool            dataStringAvailable(true); // a flag indicating if for all items a data string is available
 845         NSMutableArray* dataArray = [[NSMutableArray arrayWithCapacity:[writeItems count]] retain]; // data of all items
 846         wxString        dataString; // contains the string data of all items
 847
 848         // send a begin drag event for all selected items and proceed with
 849         // dragging unless the event is vetoed:
 850         wxDataViewEvent
 851             event(wxEVT_COMMAND_DATAVIEW_ITEM_BEGIN_DRAG,dvc->GetId());
 852
 853         event.SetEventObject(dvc);
 854         event.SetModel(dvc->GetModel());
 855         for (size_t itemCounter=0; itemCounter<[writeItems count]; ++itemCounter)
 856         {
 857             bool                   itemStringAvailable(false);              // a flag indicating if for the current item a string is available
 858             wxDataObjectComposite* itemObject(new wxDataObjectComposite()); // data object for current item
 859             wxString               itemString;                              // contains the TAB concatenated data of an item
 860
 861             event.SetItem(
 862                 wxDataViewItemFromItem([writeItems objectAtIndex:itemCounter]));
 863             itemString = ::ConcatenateDataViewItemValues(dvc,event.GetItem());
 864             itemObject->Add(new wxTextDataObject(itemString));
 865             event.SetDataObject(itemObject);
 866             // check if event has not been vetoed:
 867             if (dvc->HandleWindowEvent(event) && event.IsAllowed() && (event.GetDataObject()->GetFormatCount() > 0))
 868             {
 869                 size_t const noOfFormats = event.GetDataObject()->GetFormatCount();
 870                 wxDataFormat* dataFormats(new wxDataFormat[noOfFormats]);
 871
 872                 event.GetDataObject()->GetAllFormats(dataFormats,wxDataObject::Get);
 873                 for (size_t formatCounter=0; formatCounter<noOfFormats; ++formatCounter)
 874                 {
 875                     // constant definitions for abbreviational purposes:
 876                     wxDataFormatId const idDataFormat = dataFormats[formatCounter].GetType();
 877                     size_t const dataSize       = event.GetDataObject()->GetDataSize(idDataFormat);
 878                     size_t const dataBufferSize = sizeof(wxDataFormatId)+dataSize;
 879                     // variable definitions (used in all case statements):
 880                     wxMemoryBuffer dataBuffer(dataBufferSize);
 881
 882                     dataBuffer.AppendData(&idDataFormat,sizeof(wxDataFormatId));
 883                     switch (idDataFormat)
 884                     {
 885                         case wxDF_TEXT:
 886                             // otherwise wxDF_UNICODETEXT already filled up
 887                             // the string; and the UNICODE representation has
 888                             // priority
 889                             if (!itemStringAvailable)
 890                             {
 891                                 event.GetDataObject()->GetDataHere(wxDF_TEXT,dataBuffer.GetAppendBuf(dataSize));
 892                                 dataBuffer.UngetAppendBuf(dataSize);
 893                                 [dataArray addObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 894                                 itemString = wxString(static_cast<char const*>(dataBuffer.GetData())+sizeof(wxDataFormatId),wxConvLocal);
 895                                 itemStringAvailable = true;
 896                             }
 897                             break;
 898                         case wxDF_UNICODETEXT:
 899                             {
 900                                 event.GetDataObject()->GetDataHere(wxDF_UNICODETEXT,dataBuffer.GetAppendBuf(dataSize));
 901                                 dataBuffer.UngetAppendBuf(dataSize);
 902                                 if (itemStringAvailable) // does an object already exist as an ASCII text (see wxDF_TEXT case statement)?
 903                                     [dataArray replaceObjectAtIndex:itemCounter withObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 904                                 else
 905                                     [dataArray addObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 906                                 itemString = wxString::FromUTF8(static_cast<char const*>(dataBuffer.GetData())+sizeof(wxDataFormatId),dataSize);
 907                                 itemStringAvailable = true;
 908                             } /* block */
 909                             break;
 910                         default:
 911                             wxFAIL_MSG("Data object has invalid or unsupported data format");
 912                             [dataArray release];
 913                             return NO;
 914                     }
 915                 }
 916                 delete[] dataFormats;
 917                 delete itemObject;
 918                 if (dataStringAvailable)
 919                     if (itemStringAvailable)
 920                     {
 921                         if (itemCounter > 0)
 922                             dataString << wxT('\n');
 923                         dataString << itemString;
 924                     }
 925                     else
 926                         dataStringAvailable = false;
 927             }
 928             else
 929             {
 930                 [dataArray release];
 931                 delete itemObject;
 932                 return NO; // dragging was vetoed or no data available
 933             }
 934         }
 935         if (dataStringAvailable)
 936         {
 937             wxCFStringRef osxString(dataString);
 938
 939             [pasteboard declareTypes:[NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil] owner:nil];
 940             [pasteboard setPropertyList:dataArray forType:DataViewPboardType];
 941             [pasteboard setString:osxString.AsNSString() forType:NSStringPboardType];
 942         }
 943         else
 944         {
 945             [pasteboard declareTypes:[NSArray arrayWithObject:DataViewPboardType] owner:nil];
 946             [pasteboard setPropertyList:dataArray forType:DataViewPboardType];
 947         }
 948         return YES;
 949     }
 950     else
 951         return NO; // no items to drag (should never occur)
 952 }
 953
 954 //
 955 // buffer handling
 956 //
 957 -(void) addToBuffer:(wxPointerObject*)item
 958 {
 959     [items addObject:item];
 960 }
 961
 962 -(void) clearBuffer
 963 {
 964     [items removeAllObjects];
 965 }
 966
 967 -(wxPointerObject*) getDataViewItemFromBuffer:(const wxDataViewItem&)item
 968 {
 969     return [items member:[[[wxPointerObject alloc] initWithPointer:item.GetID()] autorelease]];
 970 }
 971
 972 -(wxPointerObject*) getItemFromBuffer:(wxPointerObject*)item
 973 {
 974     return [items member:item];
 975 }
 976
 977 -(BOOL) isInBuffer:(wxPointerObject*)item
 978 {
 979     return [items containsObject:item];
 980 }
 981
 982 -(void) removeFromBuffer:(wxPointerObject*)item
 983 {
 984     [items removeObject:item];
 985 }
 986
 987 //
 988 // children handling
 989 //
 990 -(void) appendChild:(wxPointerObject*)item
 991 {
 992     [children addObject:item];
 993 }
 994
 995 -(void) clearChildren
 996 {
 997     [children removeAllObjects];
 998 }
 999
1000 -(wxPointerObject*) getChild:(NSUInteger)index
1001 {
1002     return [children objectAtIndex:index];
1003 }
1004
1005 -(NSUInteger) getChildCount
1006 {
1007     return [children count];
1008 }
1009
1010 -(void) removeChild:(NSUInteger)index
1011 {
1012     [children removeObjectAtIndex:index];
1013 }
1014
1015 //
1016 // buffer handling
1017 //
1018 -(void) clearBuffers
1019 {
1020     [self clearBuffer];
1021     [self clearChildren];
1022     [self setCurrentParentItem:nil];
1023 }
1024
1025 //
1026 // sorting
1027 //
1028 -(NSArray*) sortDescriptors
1029 {
1030     return sortDescriptors;
1031 }
1032
1033 -(void) setSortDescriptors:(NSArray*)newSortDescriptors
1034 {
1035     [newSortDescriptors retain];
1036     [sortDescriptors release];
1037     sortDescriptors = newSortDescriptors;
1038 }
1039
1040 //
1041 // access to wxWidget's implementation
1042 //
1043 -(wxPointerObject*) currentParentItem
1044 {
1045     return currentParentItem;
1046 }
1047
1048 -(wxCocoaDataViewControl*) implementation
1049 {
1050     return implementation;
1051 }
1052
1053 -(wxDataViewModel*) model
1054 {
1055     return model;
1056 }
1057
1058 -(void) setCurrentParentItem:(wxPointerObject*)newCurrentParentItem
1059 {
1060     [newCurrentParentItem retain];
1061     [currentParentItem release];
1062     currentParentItem = newCurrentParentItem;
1063 }
1064
1065 -(void) setImplementation:(wxCocoaDataViewControl*) newImplementation
1066 {
1067     implementation = newImplementation;
1068 }
1069
1070 -(void) setModel:(wxDataViewModel*) newModel
1071 {
1072     model = newModel;
1073 }
1074
1075 //
1076 // other methods
1077 //
1078 -(void) bufferItem:(wxPointerObject*)parentItem withChildren:(wxDataViewItemArray*)dataViewChildrenPtr
1079 {
1080     NSInteger const noOfChildren = (*dataViewChildrenPtr).GetCount();
1081
1082     [self setCurrentParentItem:parentItem];
1083     [self clearChildren];
1084     for (NSInteger indexChild=0; indexChild<noOfChildren; ++indexChild)
1085     {
1086         wxPointerObject* bufferedPointerObject;
1087         wxPointerObject* newPointerObject([[wxPointerObject alloc] initWithPointer:(*dataViewChildrenPtr)[indexChild].GetID()]);
1088
1089         // The next statement and test looks strange but there is
1090         // unfortunately no workaround: due to the fact that two pointer
1091         // objects are identical if their pointers are identical - because the
1092         // method isEqual has been overloaded - the set operation will only
1093         // add a new pointer object if there is not already one in the set
1094         // having the same pointer. On the other side the children's array
1095         // would always add the new pointer object. This means that different
1096         // pointer objects are stored in the set and array. This will finally
1097         // lead to a crash as objects diverge. To solve this issue it is first
1098         // tested if the child already exists in the set and if it is the case
1099         // the sets object is going to be appended to the array, otheriwse the
1100         // new pointer object is added to the set and array:
1101         bufferedPointerObject = [self getItemFromBuffer:newPointerObject];
1102         if (bufferedPointerObject == nil)
1103         {
1104             [items    addObject:newPointerObject];
1105             [children addObject:newPointerObject];
1106         }
1107         else
1108             [children addObject:bufferedPointerObject];
1109         [newPointerObject release];
1110     }
1111 }
1112
1113 @end
1114
1115 // ============================================================================
1116 // wxCustomCell
1117 // ============================================================================
1118
1119 @implementation wxCustomCell
1120
1121 -(NSSize) cellSize
1122 {
1123     wxCustomRendererObject * const
1124         obj = static_cast<wxCustomRendererObject *>([self objectValue]);
1125
1126
1127     const wxSize size = obj->customRenderer->GetSize();
1128     return NSMakeSize(size.x, size.y);
1129 }
1130
1131 //
1132 // implementations
1133 //
1134 -(void) drawWithFrame:(NSRect)cellFrame inView:(NSView*)controlView
1135 {
1136     wxCustomRendererObject * const
1137         obj = static_cast<wxCustomRendererObject *>([self objectValue]);
1138     if ( !obj )
1139     {
1140         // this may happen for the custom cells in container rows: they don't
1141         // have any values
1142         return;
1143     }
1144
1145     wxDataViewCustomRenderer * const renderer = obj->customRenderer;
1146
1147     wxDC * const dc = renderer->GetDC();
1148     renderer->WXCallRender(wxFromNSRect(controlView, cellFrame), dc, 0);
1149     renderer->SetDC(NULL);
1150 }
1151
1152 -(NSRect) imageRectForBounds:(NSRect)cellFrame
1153 {
1154     return cellFrame;
1155 }
1156
1157 -(NSRect) titleRectForBounds:(NSRect)cellFrame
1158 {
1159     return cellFrame;
1160 }
1161
1162 @end
1163
1164 // ============================================================================
1165 // wxImageTextCell
1166 // ============================================================================
1167 @implementation wxImageTextCell
1168 //
1169 // initialization
1170 //
1171 -(id) init
1172 {
1173     self = [super init];
1174     if (self != nil)
1175     {
1176         // initializing the text part:
1177         [self setSelectable:YES];
1178         // initializing the image part:
1179         image       = nil;
1180         imageSize   = NSMakeSize(16,16);
1181         spaceImageText = 5.0;
1182         xImageShift    = 5.0;
1183     }
1184     return self;
1185 }
1186
1187 -(id) copyWithZone:(NSZone*)zone
1188 {
1189     wxImageTextCell* cell;
1190
1191
1192     cell = (wxImageTextCell*) [super copyWithZone:zone];
1193     cell->image          = [image retain];
1194     cell->imageSize      = imageSize;
1195     cell->spaceImageText = spaceImageText;
1196     cell->xImageShift    = xImageShift;
1197
1198     return cell;
1199 }
1200
1201 -(void) dealloc
1202 {
1203     [image release];
1204
1205     [super dealloc];
1206 }
1207
1208 //
1209 // alignment
1210 //
1211 -(NSTextAlignment) alignment
1212 {
1213     return cellAlignment;
1214 }
1215
1216 -(void) setAlignment:(NSTextAlignment)newAlignment
1217 {
1218     cellAlignment = newAlignment;
1219     switch (newAlignment)
1220     {
1221         case NSCenterTextAlignment:
1222         case NSLeftTextAlignment:
1223         case NSJustifiedTextAlignment:
1224         case NSNaturalTextAlignment:
1225             [super setAlignment:NSLeftTextAlignment];
1226             break;
1227         case NSRightTextAlignment:
1228             [super setAlignment:NSRightTextAlignment];
1229             break;
1230         default:
1231             wxFAIL_MSG("Unknown alignment type.");
1232     }
1233 }
1234
1235 //
1236 // image access
1237 //
1238 -(NSImage*) image
1239 {
1240     return image;
1241 }
1242
1243 -(void) setImage:(NSImage*)newImage
1244 {
1245     [newImage retain];
1246     [image release];
1247     image = newImage;
1248 }
1249
1250 -(NSSize) imageSize
1251 {
1252     return imageSize;
1253 }
1254
1255 -(void) setImageSize:(NSSize) newImageSize
1256 {
1257     imageSize = newImageSize;
1258 }
1259
1260 //
1261 // other methods
1262 //
1263 -(NSSize) cellImageSize
1264 {
1265     return NSMakeSize(imageSize.width+xImageShift+spaceImageText,imageSize.height);
1266 }
1267
1268 -(NSSize) cellSize
1269 {
1270     NSSize cellSize([super cellSize]);
1271
1272
1273     if (imageSize.height > cellSize.height)
1274         cellSize.height = imageSize.height;
1275     cellSize.width += imageSize.width+xImageShift+spaceImageText;
1276
1277     return cellSize;
1278 }
1279
1280 -(NSSize) cellTextSize
1281 {
1282     return [super cellSize];
1283 }
1284
1285 //
1286 // implementations
1287 //
1288 -(void) determineCellParts:(NSRect)cellFrame imagePart:(NSRect*)imageFrame textPart:(NSRect*)textFrame
1289 {
1290     switch (cellAlignment)
1291     {
1292         case NSCenterTextAlignment:
1293             {
1294                 CGFloat const cellSpace = cellFrame.size.width-[self cellSize].width;
1295
1296                 // if the cell's frame is smaller than its contents (at least
1297                 // in x-direction) make sure that the image is visible:
1298                 if (cellSpace <= 0)
1299                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1300                 else // otherwise center the image and text in the cell's frame
1301                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText+0.5*cellSpace,NSMinXEdge);
1302             }
1303             break;
1304         case NSJustifiedTextAlignment:
1305         case NSLeftTextAlignment:
1306         case NSNaturalTextAlignment: // how to determine the natural writing direction? TODO
1307             NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1308             break;
1309         case NSRightTextAlignment:
1310             {
1311                 CGFloat const cellSpace = cellFrame.size.width-[self cellSize].width;
1312
1313                 // if the cell's frame is smaller than its contents (at least
1314                 // in x-direction) make sure that the image is visible:
1315                 if (cellSpace <= 0)
1316                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1317                 else // otherwise right align the image and text in the cell's frame
1318                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText+cellSpace,NSMinXEdge);
1319             }
1320             break;
1321         default:
1322             *imageFrame = NSZeroRect;
1323             *textFrame  = NSZeroRect;
1324             wxFAIL_MSG("Unhandled alignment type.");
1325     }
1326 }
1327
1328 -(void) drawWithFrame:(NSRect)cellFrame inView:(NSView*)controlView
1329 {
1330     NSRect textFrame, imageFrame;
1331
1332
1333     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1334     // draw the image part by ourselves;
1335     // check if the cell has to draw its own background (checking is done by
1336     // the parameter of the textfield's cell):
1337     if ([self drawsBackground])
1338     {
1339         [[self backgroundColor] set];
1340         NSRectFill(imageFrame);
1341     }
1342     if (image != nil)
1343     {
1344         // the image is slightly shifted (xImageShift) and has a fixed size
1345         // but the image's frame might be larger and starts currently on the
1346         // left side of the cell's frame; therefore, the origin and the
1347         // image's frame size have to be adjusted:
1348         if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1349         {
1350             imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1351             imageFrame.size.width = imageSize.width;
1352         }
1353         else
1354         {
1355             imageFrame.origin.x   += xImageShift;
1356             imageFrame.size.width -= xImageShift+spaceImageText;
1357         }
1358         // ...and the image has to be centered in the y-direction:
1359         if (imageFrame.size.height > imageSize.height)
1360             imageFrame.size.height = imageSize.height;
1361         imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1362
1363         // according to the documentation the coordinate system should be
1364         // flipped for NSTableViews (y-coordinate goes from top to bottom); to
1365         // draw an image correctly the coordinate system has to be transformed
1366         // to a bottom-top coordinate system, otherwise the image's
1367         // content is flipped:
1368         NSAffineTransform* coordinateTransform([NSAffineTransform transform]);
1369
1370         if ([controlView isFlipped])
1371         {
1372             [coordinateTransform scaleXBy: 1.0 yBy:-1.0]; // first the coordinate system is brought back to bottom-top orientation
1373             [coordinateTransform translateXBy:0.0 yBy:(-2.0)*imageFrame.origin.y-imageFrame.size.height]; // the coordinate system has to be moved to compensate for the
1374             [coordinateTransform concat];                                                                 // other orientation and the position of the image's frame
1375         }
1376         [image drawInRect:imageFrame fromRect:NSZeroRect operation:NSCompositeSourceOver fraction:1.0]; // suggested method to draw the image
1377         // instead of compositeToPoint:operation:
1378         // take back previous transformation (if the view is not flipped the
1379         // coordinate transformation matrix contains the identity matrix and
1380         // the next two operations do not change the content's transformation
1381         // matrix):
1382         [coordinateTransform invert];
1383         [coordinateTransform concat];
1384     }
1385     // let the textfield cell draw the text part:
1386     if (textFrame.size.width > [self cellTextSize].width)
1387     {
1388         // for unknown reasons the alignment of the text cell is ignored;
1389         // therefore change the size so that alignment does not influence the
1390         // visualization anymore
1391         textFrame.size.width = [self cellTextSize].width;
1392     }
1393     [super drawWithFrame:textFrame inView:controlView];
1394 }
1395
1396 -(void) editWithFrame:(NSRect)aRect inView:(NSView*)controlView editor:(NSText*)textObj delegate:(id)anObject event:(NSEvent*)theEvent
1397 {
1398     NSRect textFrame, imageFrame;
1399
1400
1401     [self determineCellParts:aRect imagePart:&imageFrame textPart:&textFrame];
1402     [super editWithFrame:textFrame inView:controlView editor:textObj delegate:anObject event:theEvent];
1403 }
1404
1405 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_5
1406 -(NSUInteger) hitTestForEvent:(NSEvent*)event inRect:(NSRect)cellFrame ofView:(NSView*)controlView
1407 {
1408     NSPoint point = [controlView convertPoint:[event locationInWindow] fromView:nil];
1409
1410     NSRect imageFrame, textFrame;
1411
1412
1413     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1414     if (image != nil)
1415     {
1416         // the image is shifted...
1417         if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1418         {
1419             imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1420             imageFrame.size.width = imageSize.width;
1421         }
1422         else
1423         {
1424             imageFrame.origin.x   += xImageShift;
1425             imageFrame.size.width -= xImageShift+spaceImageText;
1426         }
1427         // ...and centered:
1428         if (imageFrame.size.height > imageSize.height)
1429             imageFrame.size.height = imageSize.height;
1430         imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1431         // If the point is in the image rect, then it is a content hit (see
1432         // documentation for hitTestForEvent:inRect:ofView):
1433         if (NSMouseInRect(point, imageFrame, [controlView isFlipped]))
1434             return NSCellHitContentArea;
1435     }
1436     // if the image was not hit let's try the text part:
1437     if (textFrame.size.width > [self cellTextSize].width)
1438     {
1439         // for unknown reasons the alignment of the text cell is ignored;
1440         // therefore change the size so that alignment does not influence the
1441         // visualization anymore
1442         textFrame.size.width = [self cellTextSize].width;
1443     }
1444
1445     return [super hitTestForEvent:event inRect:textFrame ofView:controlView];
1446 }
1447 #endif
1448
1449 -(NSRect) imageRectForBounds:(NSRect)cellFrame
1450 {
1451     NSRect textFrame, imageFrame;
1452
1453
1454     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1455     if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1456     {
1457         imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1458         imageFrame.size.width = imageSize.width;
1459     }
1460     else
1461     {
1462         imageFrame.origin.x   += xImageShift;
1463         imageFrame.size.width -= xImageShift+spaceImageText;
1464     }
1465     // ...and centered:
1466     if (imageFrame.size.height > imageSize.height)
1467         imageFrame.size.height = imageSize.height;
1468     imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1469
1470     return imageFrame;
1471 }
1472
1473 -(void) selectWithFrame:(NSRect)aRect inView:(NSView*)controlView editor:(NSText*)textObj delegate:(id)anObject start:(NSInteger)selStart length:(NSInteger)selLength
1474 {
1475     NSRect textFrame, imageFrame;
1476
1477
1478     [self determineCellParts:aRect imagePart:&imageFrame textPart:&textFrame];
1479     [super selectWithFrame:textFrame inView:controlView editor:textObj delegate:anObject start:selStart length:selLength];
1480 }
1481
1482 -(NSRect) titleRectForBounds:(NSRect)cellFrame
1483 {
1484     NSRect textFrame, imageFrame;
1485
1486
1487     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1488     return textFrame;
1489 }
1490
1491 @end
1492
1493 // ============================================================================
1494 // wxCocoaOutlineView
1495 // ============================================================================
1496 @implementation wxCocoaOutlineView
1497
1498 //
1499 // initializers / destructor
1500 //
1501 -(id) init
1502 {
1503     self = [super init];
1504     if (self != nil)
1505     {
1506         currentlyEditedColumn =
1507             currentlyEditedRow = -1;
1508
1509         [self registerForDraggedTypes:[NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]];
1510         [self setDelegate:self];
1511         [self setDoubleAction:@selector(actionDoubleClick:)];
1512         [self setDraggingSourceOperationMask:NSDragOperationEvery forLocal:NO];
1513         [self setDraggingSourceOperationMask:NSDragOperationEvery forLocal:YES];
1514         [self setTarget:self];
1515     }
1516     return self;
1517 }
1518
1519 //
1520 // access to wxWidget's implementation
1521 //
1522 -(wxCocoaDataViewControl*) implementation
1523 {
1524     return implementation;
1525 }
1526
1527 -(void) setImplementation:(wxCocoaDataViewControl*) newImplementation
1528 {
1529     implementation = newImplementation;
1530 }
1531
1532 //
1533 // actions
1534 //
1535 -(void) actionDoubleClick:(id)sender
1536 {
1537     // actually the documentation (NSTableView 2007-10-31) for doubleAction:
1538     // and setDoubleAction: seems to be wrong as this action message is always
1539     // sent whether the cell is editable or not
1540     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1541
1542     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_ACTIVATED,dvc->GetId());
1543
1544
1545     event.SetEventObject(dvc);
1546     event.SetItem(wxDataViewItemFromItem([self itemAtRow:[self clickedRow]]));
1547     dvc->GetEventHandler()->ProcessEvent(event);
1548 }
1549
1550
1551 //
1552 // contextual menus
1553 //
1554 -(NSMenu*) menuForEvent:(NSEvent*)theEvent
1555 {
1556     // this method does not do any special menu event handling but only sends
1557     // an event message; therefore, the user has full control if a context
1558     // menu should be shown or not
1559     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1560
1561     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_CONTEXT_MENU,dvc->GetId());
1562
1563     wxDataViewItemArray selectedItems;
1564
1565
1566     event.SetEventObject(dvc);
1567     event.SetModel(dvc->GetModel());
1568     // get the item information;
1569     // theoretically more than one ID can be returned but the event can only
1570     // handle one item, therefore only the first item of the array is
1571     // returned:
1572     if (dvc->GetSelections(selectedItems) > 0)
1573         event.SetItem(selectedItems[0]);
1574     dvc->GetEventHandler()->ProcessEvent(event);
1575     // nothing is done:
1576     return nil;
1577 }
1578
1579 //
1580 // delegate methods
1581 //
1582 -(void) outlineView:(NSOutlineView*)outlineView mouseDownInHeaderOfTableColumn:(NSTableColumn*)tableColumn
1583 {
1584     wxDataViewColumn* const col(static_cast<wxDataViewColumn*>([[tableColumn identifier] pointer]));
1585
1586     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1587
1588     wxDataViewEvent
1589         event(wxEVT_COMMAND_DATAVIEW_COLUMN_HEADER_CLICK,dvc->GetId());
1590
1591
1592     // first, send an event that the user clicked into a column's header:
1593     event.SetEventObject(dvc);
1594     event.SetColumn(dvc->GetColumnPosition(col));
1595     event.SetDataViewColumn(col);
1596     dvc->HandleWindowEvent(event);
1597
1598     // now, check if the click may have had an influence on sorting, too;
1599     // the sorting setup has to be done only if the clicked table column is
1600     // sortable and has not been used for sorting before the click; if the
1601     // column is already responsible for sorting the native control changes
1602     // the sorting direction automatically and informs the data source via
1603     // outlineView:sortDescriptorsDidChange:
1604     if (col->IsSortable() && ([tableColumn sortDescriptorPrototype] == nil))
1605     {
1606         // remove the sort order from the previously sorted column table (it
1607         // can also be that no sorted column table exists):
1608         UInt32 const noOfColumns = [outlineView numberOfColumns];
1609
1610         for (UInt32 i=0; i<noOfColumns; ++i)
1611             [[[outlineView tableColumns] objectAtIndex:i] setSortDescriptorPrototype:nil];
1612         // make column table sortable:
1613         NSArray*          sortDescriptors;
1614         NSSortDescriptor* sortDescriptor;
1615
1616         sortDescriptor = [[NSSortDescriptor alloc] initWithKey:[NSString stringWithFormat:@"%d",[outlineView columnWithIdentifier:[tableColumn identifier]]]
1617             ascending:YES];
1618         sortDescriptors = [NSArray arrayWithObject:sortDescriptor];
1619         [tableColumn setSortDescriptorPrototype:sortDescriptor];
1620         [outlineView setSortDescriptors:sortDescriptors];
1621         [sortDescriptor release];
1622     }
1623 }
1624
1625 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldCollapseItem:(id)item
1626 {
1627     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1628
1629     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_COLLAPSING,dvc->GetId());
1630
1631
1632     event.SetEventObject(dvc);
1633     event.SetItem       (wxDataViewItemFromItem(item));
1634     event.SetModel      (dvc->GetModel());
1635     // finally send the equivalent wxWidget event:
1636     dvc->GetEventHandler()->ProcessEvent(event);
1637     // opening the container is allowed if not vetoed:
1638     return event.IsAllowed();
1639 }
1640
1641 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldExpandItem:(id)item
1642 {
1643     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1644
1645     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_EXPANDING,dvc->GetId());
1646
1647
1648     event.SetEventObject(dvc);
1649     event.SetItem       (wxDataViewItemFromItem(item));
1650     event.SetModel      (dvc->GetModel());
1651     // finally send the equivalent wxWidget event:
1652     dvc->GetEventHandler()->ProcessEvent(event);
1653     // opening the container is allowed if not vetoed:
1654     return event.IsAllowed();
1655 }
1656
1657 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldSelectTableColumn:(NSTableColumn*)tableColumn
1658 {
1659     return NO;
1660 }
1661
1662 -(void) outlineView:(wxCocoaOutlineView*)outlineView
1663     willDisplayCell:(id)cell
1664     forTableColumn:(NSTableColumn*)tableColumn
1665     item:(id)item
1666 {
1667     wxDataViewCtrl * const dvc = implementation->GetDataViewCtrl();
1668     wxDataViewModel * const model = dvc->GetModel();
1669
1670     wxDataViewColumn * const
1671         dvCol(static_cast<wxDataViewColumn*>(
1672                     [[tableColumn identifier] pointer]
1673                     )
1674              );
1675     const unsigned colIdx = dvCol->GetModelColumn();
1676
1677     wxDataViewItem dvItem(wxDataViewItemFromItem(item));
1678
1679     if ( !model->HasValue(dvItem, colIdx) )
1680         return;
1681
1682     wxDataViewRenderer * const renderer = dvCol->GetRenderer();
1683     wxDataViewRendererNativeData * const data = renderer->GetNativeData();
1684
1685     // let the renderer know about what it's going to render next
1686     data->SetColumnPtr(tableColumn);
1687     data->SetItem(item);
1688     data->SetItemCell(cell);
1689
1690     // use the attributes: notice that we need to do this whether we have them
1691     // or not as even if this cell doesn't have any attributes, the previous
1692     // one might have had some and then we need to reset them back to default
1693     wxDataViewItemAttr attr;
1694     model->GetAttr(dvItem, colIdx, attr);
1695     renderer->OSXApplyAttr(attr);
1696
1697     // and finally do draw it
1698     renderer->MacRender();
1699 }
1700
1701 //
1702 // notifications
1703 //
1704 -(void) outlineViewColumnDidMove:(NSNotification*)notification
1705 {
1706     int const newColumnPosition = [[[notification userInfo] objectForKey:@"NSNewColumn"] intValue];
1707
1708     wxDataViewColumn* const col(static_cast<wxDataViewColumn*>([[[[self tableColumns] objectAtIndex:newColumnPosition] identifier] pointer]));
1709
1710     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1711
1712     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_COLUMN_REORDERED,dvc->GetId());
1713
1714
1715     event.SetEventObject(dvc);
1716     event.SetColumn(dvc->GetColumnPosition(col));
1717     event.SetDataViewColumn(col);
1718     dvc->GetEventHandler()->ProcessEvent(event);
1719 }
1720
1721 -(void) outlineViewItemDidCollapse:(NSNotification*)notification
1722 {
1723     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1724
1725     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_COLLAPSED,dvc->GetId());
1726
1727
1728     event.SetEventObject(dvc);
1729     event.SetItem(wxDataViewItemFromItem(
1730                     [[notification userInfo] objectForKey:@"NSObject"]));
1731     dvc->GetEventHandler()->ProcessEvent(event);
1732 }
1733
1734 -(void) outlineViewItemDidExpand:(NSNotification*)notification
1735 {
1736     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1737
1738     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_EXPANDED,dvc->GetId());
1739
1740
1741     event.SetEventObject(dvc);
1742     event.SetItem(wxDataViewItemFromItem(
1743                     [[notification userInfo] objectForKey:@"NSObject"]));
1744     dvc->GetEventHandler()->ProcessEvent(event);
1745 }
1746
1747 -(void) outlineViewSelectionDidChange:(NSNotification*)notification
1748 {
1749     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1750
1751     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_SELECTION_CHANGED,dvc->GetId());
1752
1753     event.SetEventObject(dvc);
1754     event.SetModel      (dvc->GetModel());
1755     dvc->GetEventHandler()->ProcessEvent(event);
1756 }
1757
1758 -(void) textDidBeginEditing:(NSNotification*)notification
1759 {
1760     // this notification is only sent if the user started modifying the cell
1761     // (not when the user clicked into the cell and the cell's editor is
1762     // called!)
1763
1764     // call method of superclass (otherwise editing does not work correctly -
1765     // the outline data source class is not informed about a change of data):
1766     [super textDidBeginEditing:notification];
1767
1768     // remember the column being edited, it will be used in textDidEndEditing:
1769     currentlyEditedColumn = [self editedColumn];
1770     currentlyEditedRow = [self editedRow];
1771
1772     wxDataViewColumn* const col =
1773         static_cast<wxDataViewColumn*>(
1774                 [[[[self tableColumns] objectAtIndex:currentlyEditedColumn] identifier] pointer]);
1775
1776     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1777
1778
1779     // stop editing of a custom item first (if necessary)
1780     dvc->FinishCustomItemEditing();
1781
1782     // now, send the event:
1783     wxDataViewEvent
1784         event(wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_STARTED,dvc->GetId());
1785
1786     event.SetEventObject(dvc);
1787     event.SetItem(
1788             wxDataViewItemFromItem([self itemAtRow:currentlyEditedRow]));
1789     event.SetColumn(dvc->GetColumnPosition(col));
1790     event.SetDataViewColumn(col);
1791     dvc->GetEventHandler()->ProcessEvent(event);
1792 }
1793
1794 -(void) textDidEndEditing:(NSNotification*)notification
1795 {
1796     // call method of superclass (otherwise editing does not work correctly -
1797     // the outline data source class is not informed about a change of data):
1798     [super textDidEndEditing:notification];
1799
1800     // under OSX an event indicating the end of an editing session can be sent
1801     // even if no event indicating a start of an editing session has been sent
1802     // (see Documentation for NSControl controlTextDidEndEditing:); this is
1803     // not expected by a user of the wxWidgets library and therefore an
1804     // wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_DONE event is only sent if a
1805     // corresponding wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_STARTED has been sent
1806     // before; to check if a wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_STARTED has
1807     // been sent the last edited column/row are valid:
1808     if ( currentlyEditedColumn != -1 && currentlyEditedRow != -1 )
1809     {
1810         wxDataViewColumn* const col =
1811             static_cast<wxDataViewColumn*>(
1812                     [[[[self tableColumns] objectAtIndex:currentlyEditedColumn] identifier] pointer]);
1813
1814         wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1815
1816         // send event to wxWidgets:
1817         wxDataViewEvent
1818             event(wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_DONE,dvc->GetId());
1819
1820         event.SetEventObject(dvc);
1821         event.SetItem(
1822                 wxDataViewItemFromItem([self itemAtRow:currentlyEditedRow]));
1823         event.SetColumn(dvc->GetColumnPosition(col));
1824         event.SetDataViewColumn(col);
1825         dvc->GetEventHandler()->ProcessEvent(event);
1826
1827
1828         // we're not editing any more
1829         currentlyEditedColumn =
1830             currentlyEditedRow = -1;
1831     }
1832 }
1833
1834 @end
1835
1836 // ============================================================================
1837 // wxCocoaDataViewControl
1838 // ============================================================================
1839
1840 wxCocoaDataViewControl::wxCocoaDataViewControl(wxWindow* peer,
1841                                                const wxPoint& pos,
1842                                                const wxSize& size,
1843                                                long style)
1844     : wxWidgetCocoaImpl
1845       (
1846         peer,
1847         [[NSScrollView alloc] initWithFrame:wxOSXGetFrameForControl(peer,pos,size)]
1848       ),
1849       m_DataSource(NULL),
1850       m_OutlineView([[wxCocoaOutlineView alloc] init])
1851 {
1852     // initialize scrollview (the outline view is part of a scrollview):
1853     NSScrollView* scrollview = (NSScrollView*) GetWXWidget();
1854
1855     [scrollview setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
1856     [scrollview setBorderType:NSNoBorder];
1857     [scrollview setHasVerticalScroller:YES];
1858     [scrollview setHasHorizontalScroller:YES];
1859     [scrollview setAutohidesScrollers:YES];
1860     [scrollview setDocumentView:m_OutlineView];
1861
1862     // initialize the native control itself too
1863     InitOutlineView(style);
1864 }
1865
1866 void wxCocoaDataViewControl::InitOutlineView(long style)
1867 {
1868     [m_OutlineView setImplementation:this];
1869     [m_OutlineView setColumnAutoresizingStyle:NSTableViewSequentialColumnAutoresizingStyle];
1870     [m_OutlineView setIndentationPerLevel:GetDataViewCtrl()->GetIndent()];
1871     NSUInteger maskGridStyle(NSTableViewGridNone);
1872     if (style & wxDV_HORIZ_RULES)
1873         maskGridStyle |= NSTableViewSolidHorizontalGridLineMask;
1874     if (style & wxDV_VERT_RULES)
1875         maskGridStyle |= NSTableViewSolidVerticalGridLineMask;
1876     [m_OutlineView setGridStyleMask:maskGridStyle];
1877     [m_OutlineView setAllowsMultipleSelection:           (style & wxDV_MULTIPLE)  != 0];
1878     [m_OutlineView setUsesAlternatingRowBackgroundColors:(style & wxDV_ROW_LINES) != 0];
1879
1880     if ( style & wxDV_NO_HEADER )
1881         [m_OutlineView setHeaderView:nil];
1882 }
1883
1884 wxCocoaDataViewControl::~wxCocoaDataViewControl()
1885 {
1886     [m_DataSource  release];
1887     [m_OutlineView release];
1888 }
1889
1890 //
1891 // column related methods (inherited from wxDataViewWidgetImpl)
1892 //
1893 bool wxCocoaDataViewControl::ClearColumns()
1894 {
1895     // as there is a bug in NSOutlineView version (OSX 10.5.6 #6555162) the
1896     // columns cannot be deleted if there is an outline column in the view;
1897     // therefore, the whole view is deleted and newly constructed:
1898     [m_OutlineView release];
1899     m_OutlineView = [[wxCocoaOutlineView alloc] init];
1900     [((NSScrollView*) GetWXWidget()) setDocumentView:m_OutlineView];
1901     [m_OutlineView setDataSource:m_DataSource];
1902
1903     InitOutlineView(GetDataViewCtrl()->GetWindowStyle());
1904
1905     return true;
1906 }
1907
1908 bool wxCocoaDataViewControl::DeleteColumn(wxDataViewColumn* columnPtr)
1909 {
1910     if ([m_OutlineView outlineTableColumn] == columnPtr->GetNativeData()->GetNativeColumnPtr())
1911         [m_OutlineView setOutlineTableColumn:nil]; // due to a bug this does not work
1912     [m_OutlineView removeTableColumn:columnPtr->GetNativeData()->GetNativeColumnPtr()]; // due to a confirmed bug #6555162 the deletion does not work for
1913     // outline table columns (... and there is no workaround)
1914     return (([m_OutlineView columnWithIdentifier:[[[wxPointerObject alloc] initWithPointer:columnPtr] autorelease]]) == -1);
1915 }
1916
1917 void wxCocoaDataViewControl::DoSetExpanderColumn(const wxDataViewColumn *columnPtr)
1918 {
1919     [m_OutlineView setOutlineTableColumn:columnPtr->GetNativeData()->GetNativeColumnPtr()];
1920 }
1921
1922 wxDataViewColumn* wxCocoaDataViewControl::GetColumn(unsigned int pos) const
1923 {
1924     return static_cast<wxDataViewColumn*>([[[[m_OutlineView tableColumns] objectAtIndex:pos] identifier] pointer]);
1925 }
1926
1927 int wxCocoaDataViewControl::GetColumnPosition(const wxDataViewColumn *columnPtr) const
1928 {
1929     return [m_OutlineView columnWithIdentifier:[[[wxPointerObject alloc] initWithPointer:const_cast<wxDataViewColumn*>(columnPtr)] autorelease]];
1930 }
1931
1932 bool wxCocoaDataViewControl::InsertColumn(unsigned int pos, wxDataViewColumn* columnPtr)
1933 {
1934     // create column and set the native data of the dataview column:
1935     NSTableColumn *nativeColumn = ::CreateNativeColumn(columnPtr);
1936     columnPtr->GetNativeData()->SetNativeColumnPtr(nativeColumn);
1937     // as the native control does not allow the insertion of a column at a
1938     // specified position the column is first appended and - if necessary -
1939     // moved to its final position:
1940     [m_OutlineView addTableColumn:nativeColumn];
1941     if (pos != static_cast<unsigned int>([m_OutlineView numberOfColumns]-1))
1942         [m_OutlineView moveColumn:[m_OutlineView numberOfColumns]-1 toColumn:pos];
1943     // done:
1944     return true;
1945 }
1946
1947 //
1948 // item related methods (inherited from wxDataViewWidgetImpl)
1949 //
1950 bool wxCocoaDataViewControl::Add(const wxDataViewItem& parent, const wxDataViewItem& WXUNUSED(item))
1951 {
1952     if (parent.IsOk())
1953         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
1954     else
1955         [m_OutlineView reloadData];
1956     return true;
1957 }
1958
1959 bool wxCocoaDataViewControl::Add(const wxDataViewItem& parent, const wxDataViewItemArray& WXUNUSED(items))
1960 {
1961     if (parent.IsOk())
1962         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
1963     else
1964         [m_OutlineView reloadData];
1965     return true;
1966 }
1967
1968 void wxCocoaDataViewControl::Collapse(const wxDataViewItem& item)
1969 {
1970     [m_OutlineView collapseItem:[m_DataSource getDataViewItemFromBuffer:item]];
1971 }
1972
1973 void wxCocoaDataViewControl::EnsureVisible(const wxDataViewItem& item, const wxDataViewColumn *columnPtr)
1974 {
1975     if (item.IsOk())
1976     {
1977         [m_OutlineView scrollRowToVisible:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
1978         if (columnPtr)
1979             [m_OutlineView scrollColumnToVisible:GetColumnPosition(columnPtr)];
1980     }
1981 }
1982
1983 void wxCocoaDataViewControl::Expand(const wxDataViewItem& item)
1984 {
1985     [m_OutlineView expandItem:[m_DataSource getDataViewItemFromBuffer:item]];
1986 }
1987
1988 unsigned int wxCocoaDataViewControl::GetCount() const
1989 {
1990     return [m_OutlineView numberOfRows];
1991 }
1992
1993 wxRect wxCocoaDataViewControl::GetRectangle(const wxDataViewItem& item, const wxDataViewColumn *columnPtr)
1994 {
1995     return wxFromNSRect([m_osxView superview],[m_OutlineView frameOfCellAtColumn:GetColumnPosition(columnPtr)
1996             row:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]]);
1997 }
1998
1999 bool wxCocoaDataViewControl::IsExpanded(const wxDataViewItem& item) const
2000 {
2001     return [m_OutlineView isItemExpanded:[m_DataSource getDataViewItemFromBuffer:item]];
2002 }
2003
2004 bool wxCocoaDataViewControl::Reload()
2005 {
2006     [m_DataSource clearBuffers];
2007     [m_OutlineView scrollColumnToVisible:0];
2008     [m_OutlineView scrollRowToVisible:0];
2009     [m_OutlineView reloadData];
2010     return true;
2011 }
2012
2013 bool wxCocoaDataViewControl::Remove(const wxDataViewItem& parent, const wxDataViewItem& WXUNUSED(item))
2014 {
2015     if (parent.IsOk())
2016         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2017     else
2018         [m_OutlineView reloadData];
2019     return true;
2020 }
2021
2022 bool wxCocoaDataViewControl::Remove(const wxDataViewItem& parent, const wxDataViewItemArray& WXUNUSED(item))
2023 {
2024     if (parent.IsOk())
2025         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2026     else
2027         [m_OutlineView reloadData];
2028     return true;
2029 }
2030
2031 bool wxCocoaDataViewControl::Update(const wxDataViewColumn *columnPtr)
2032 {
2033     return false;
2034 }
2035
2036 bool wxCocoaDataViewControl::Update(const wxDataViewItem& WXUNUSED(parent), const wxDataViewItem& item)
2037 {
2038     [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:item]];
2039     return true;
2040 }
2041
2042 bool wxCocoaDataViewControl::Update(const wxDataViewItem& WXUNUSED(parent), const wxDataViewItemArray& items)
2043 {
2044     for (size_t i=0; i<items.GetCount(); ++i)
2045         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:items[i]]];
2046     return true;
2047 }
2048
2049 //
2050 // model related methods
2051 //
2052 bool wxCocoaDataViewControl::AssociateModel(wxDataViewModel* model)
2053 {
2054     [m_DataSource release];
2055     if (model)
2056     {
2057         m_DataSource = [[wxCocoaOutlineDataSource alloc] init];
2058         [m_DataSource setImplementation:this];
2059         [m_DataSource setModel:model];
2060     }
2061     else
2062         m_DataSource = NULL;
2063     [m_OutlineView setDataSource:m_DataSource]; // if there is a data source the data is immediately going to be requested
2064     return true;
2065 }
2066
2067 //
2068 // selection related methods (inherited from wxDataViewWidgetImpl)
2069 //
2070 int wxCocoaDataViewControl::GetSelections(wxDataViewItemArray& sel) const
2071 {
2072     NSIndexSet* selectedRowIndexes([m_OutlineView selectedRowIndexes]);
2073
2074     NSUInteger indexRow;
2075
2076
2077     sel.Empty();
2078     sel.Alloc([selectedRowIndexes count]);
2079     indexRow = [selectedRowIndexes firstIndex];
2080     while (indexRow != NSNotFound)
2081     {
2082         sel.Add(wxDataViewItem([[m_OutlineView itemAtRow:indexRow] pointer]));
2083         indexRow = [selectedRowIndexes indexGreaterThanIndex:indexRow];
2084     }
2085     return sel.GetCount();
2086 }
2087
2088 bool wxCocoaDataViewControl::IsSelected(const wxDataViewItem& item) const
2089 {
2090     return [m_OutlineView isRowSelected:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2091 }
2092
2093 void wxCocoaDataViewControl::Select(const wxDataViewItem& item)
2094 {
2095     if (item.IsOk())
2096         [m_OutlineView selectRowIndexes:[NSIndexSet indexSetWithIndex:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]]
2097             byExtendingSelection:NO];
2098 }
2099
2100 void wxCocoaDataViewControl::SelectAll()
2101 {
2102     [m_OutlineView selectAll:m_OutlineView];
2103 }
2104
2105 void wxCocoaDataViewControl::Unselect(const wxDataViewItem& item)
2106 {
2107     if (item.IsOk())
2108         [m_OutlineView deselectRow:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2109 }
2110
2111 void wxCocoaDataViewControl::UnselectAll()
2112 {
2113     [m_OutlineView deselectAll:m_OutlineView];
2114 }
2115
2116 //
2117 // sorting related methods
2118 //
2119 wxDataViewColumn* wxCocoaDataViewControl::GetSortingColumn() const
2120 {
2121     NSArray* const columns = [m_OutlineView tableColumns];
2122
2123     UInt32 const noOfColumns = [columns count];
2124
2125
2126     for (UInt32 i=0; i<noOfColumns; ++i)
2127         if ([[columns objectAtIndex:i] sortDescriptorPrototype] != nil)
2128             return static_cast<wxDataViewColumn*>([[[columns objectAtIndex:i] identifier] pointer]);
2129     return NULL;
2130 }
2131
2132 void wxCocoaDataViewControl::Resort()
2133 {
2134     [m_DataSource clearChildren];
2135     [m_OutlineView reloadData];
2136 }
2137
2138 //
2139 // other methods (inherited from wxDataViewWidgetImpl)
2140 //
2141 void wxCocoaDataViewControl::DoSetIndent(int indent)
2142 {
2143     [m_OutlineView setIndentationPerLevel:static_cast<CGFloat>(indent)];
2144 }
2145
2146 void wxCocoaDataViewControl::HitTest(const wxPoint& point, wxDataViewItem& item, wxDataViewColumn*& columnPtr) const
2147 {
2148     NSPoint const nativePoint = wxToNSPoint((NSScrollView*) GetWXWidget(),point);
2149
2150     int indexColumn;
2151     int indexRow;
2152
2153
2154     indexColumn = [m_OutlineView columnAtPoint:nativePoint];
2155     indexRow    = [m_OutlineView rowAtPoint:   nativePoint];
2156     if ((indexColumn >= 0) && (indexRow >= 0))
2157     {
2158         columnPtr = static_cast<wxDataViewColumn*>([[[[m_OutlineView tableColumns] objectAtIndex:indexColumn] identifier] pointer]);
2159         item      = wxDataViewItem([[m_OutlineView itemAtRow:indexRow] pointer]);
2160     }
2161     else
2162     {
2163         columnPtr = NULL;
2164         item      = wxDataViewItem();
2165     }
2166 }
2167
2168 void wxCocoaDataViewControl::SetRowHeight(const wxDataViewItem& WXUNUSED(item), unsigned int WXUNUSED(height))
2169     // Not supported by the native control
2170 {
2171 }
2172
2173 void wxCocoaDataViewControl::OnSize()
2174 {
2175     if ([m_OutlineView numberOfColumns] == 1)
2176         [m_OutlineView sizeLastColumnToFit];
2177 }
2178
2179 //
2180 // drag & drop helper methods
2181 //
2182 wxDataFormat wxCocoaDataViewControl::GetDnDDataFormat(wxDataObjectComposite* dataObjects)
2183 {
2184     wxDataFormat resultFormat;
2185     if ( !dataObjects )
2186         return resultFormat;
2187
2188     bool compatible(true);
2189
2190     size_t const noOfFormats = dataObjects->GetFormatCount();
2191     size_t       indexFormat;
2192
2193     wxDataFormat* formats;
2194
2195     // get all formats and check afterwards if the formats are compatible; if
2196     // they are compatible the preferred format is returned otherwise
2197     // wxDF_INVALID is returned;
2198     // currently compatible types (ordered by priority are):
2199     //  - wxDF_UNICODETEXT - wxDF_TEXT
2200     formats = new wxDataFormat[noOfFormats];
2201     dataObjects->GetAllFormats(formats);
2202     indexFormat = 0;
2203     while ((indexFormat < noOfFormats) && compatible)
2204     {
2205         switch (resultFormat.GetType())
2206         {
2207             case wxDF_INVALID:
2208                 resultFormat.SetType(formats[indexFormat].GetType()); // first format (should only be reached if indexFormat == 0)
2209                 break;
2210             case wxDF_TEXT:
2211                 if (formats[indexFormat].GetType() == wxDF_UNICODETEXT)
2212                     resultFormat.SetType(wxDF_UNICODETEXT);
2213                 else // incompatible
2214                 {
2215                     resultFormat.SetType(wxDF_INVALID);
2216                     compatible = false;
2217                 }
2218                 break;
2219             case wxDF_UNICODETEXT:
2220                 if (formats[indexFormat].GetType() != wxDF_TEXT)
2221                 {
2222                     resultFormat.SetType(wxDF_INVALID);
2223                     compatible = false;
2224                 }
2225                 break;
2226             default:
2227                 resultFormat.SetType(wxDF_INVALID); // not (yet) supported format
2228                 compatible = false;
2229         }
2230         ++indexFormat;
2231     }
2232
2233     delete[] formats;
2234
2235     return resultFormat;
2236 }
2237
2238 wxDataObjectComposite* wxCocoaDataViewControl::GetDnDDataObjects(NSData* dataObject) const
2239 {
2240     wxDataFormatId dataFormatID;
2241
2242
2243     [dataObject getBytes:&dataFormatID length:sizeof(wxDataFormatId)];
2244     switch (dataFormatID)
2245     {
2246         case wxDF_TEXT:
2247         case wxDF_UNICODETEXT:
2248             {
2249                 wxTextDataObject* textDataObject(new wxTextDataObject());
2250
2251                 if (textDataObject->SetData(wxDataFormat(dataFormatID),[dataObject length]-sizeof(wxDataFormatId),static_cast<char const*>([dataObject bytes])+sizeof(wxDataFormatId)))
2252                 {
2253                     wxDataObjectComposite* dataObjectComposite(new wxDataObjectComposite());
2254
2255                     dataObjectComposite->Add(textDataObject);
2256                     return dataObjectComposite;
2257                 }
2258                 else
2259                 {
2260                     delete textDataObject;
2261                     return NULL;
2262                 }
2263             }
2264             break;
2265         default:
2266             return NULL;
2267     }
2268 }
2269
2270 id wxCocoaDataViewControl::GetItemAtRow(int row) const
2271 {
2272     return [m_OutlineView itemAtRow:row];
2273 }
2274
2275 // ----------------------------------------------------------------------------
2276 // wxDataViewRendererNativeData
2277 // ----------------------------------------------------------------------------
2278
2279 void wxDataViewRendererNativeData::Init()
2280 {
2281     m_origFont = NULL;
2282     m_origTextColour = NULL;
2283     m_ellipsizeMode = wxELLIPSIZE_MIDDLE;
2284
2285     if ( m_ColumnCell )
2286         ApplyLineBreakMode(m_ColumnCell);
2287 }
2288
2289 void wxDataViewRendererNativeData::ApplyLineBreakMode(NSCell *cell)
2290 {
2291     NSLineBreakMode nsMode = NSLineBreakByWordWrapping;
2292     switch ( m_ellipsizeMode )
2293     {
2294         case wxELLIPSIZE_NONE:
2295             nsMode = NSLineBreakByClipping;
2296             break;
2297
2298         case wxELLIPSIZE_START:
2299             nsMode = NSLineBreakByTruncatingHead;
2300             break;
2301
2302         case wxELLIPSIZE_MIDDLE:
2303             nsMode = NSLineBreakByTruncatingMiddle;
2304             break;
2305
2306         case wxELLIPSIZE_END:
2307             nsMode = NSLineBreakByTruncatingTail;
2308             break;
2309     }
2310
2311     wxASSERT_MSG( nsMode != NSLineBreakByWordWrapping, "unknown wxEllipsizeMode" );
2312
2313     [cell setLineBreakMode: nsMode];
2314 }
2315
2316 // ---------------------------------------------------------
2317 // wxDataViewRenderer
2318 // ---------------------------------------------------------
2319
2320 wxDataViewRenderer::wxDataViewRenderer(const wxString& varianttype,
2321                                        wxDataViewCellMode mode,
2322                                        int align)
2323     : wxDataViewRendererBase(varianttype, mode, align),
2324       m_alignment(align),
2325       m_mode(mode),
2326       m_NativeDataPtr(NULL)
2327 {
2328 }
2329
2330 wxDataViewRenderer::~wxDataViewRenderer()
2331 {
2332     delete m_NativeDataPtr;
2333 }
2334
2335 void wxDataViewRenderer::SetAlignment(int align)
2336 {
2337     m_alignment = align;
2338     [GetNativeData()->GetColumnCell() setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2339 }
2340
2341 void wxDataViewRenderer::SetMode(wxDataViewCellMode mode)
2342 {
2343     m_mode = mode;
2344     if ( GetOwner() )
2345         [GetOwner()->GetNativeData()->GetNativeColumnPtr() setEditable:(mode == wxDATAVIEW_CELL_EDITABLE)];
2346 }
2347
2348 void wxDataViewRenderer::SetNativeData(wxDataViewRendererNativeData* newNativeDataPtr)
2349 {
2350     delete m_NativeDataPtr;
2351     m_NativeDataPtr = newNativeDataPtr;
2352 }
2353
2354 void wxDataViewRenderer::EnableEllipsize(wxEllipsizeMode mode)
2355 {
2356     // we need to store this value to apply it to the columns headerCell in
2357     // CreateNativeColumn()
2358     GetNativeData()->SetEllipsizeMode(mode);
2359
2360     // but we may already apply it to the column cell which will be used for
2361     // this column
2362     GetNativeData()->ApplyLineBreakMode(GetNativeData()->GetColumnCell());
2363 }
2364
2365 wxEllipsizeMode wxDataViewRenderer::GetEllipsizeMode() const
2366 {
2367     return GetNativeData()->GetEllipsizeMode();
2368 }
2369
2370 void
2371 wxDataViewRenderer::OSXOnCellChanged(NSObject *object,
2372                                      const wxDataViewItem& item,
2373                                      unsigned col)
2374 {
2375     // TODO: we probably should get rid of this code entirely and make this
2376     //       function pure virtual, but currently we still have some native
2377     //       renderers (wxDataViewChoiceRenderer) which don't override it and
2378     //       there is also wxDataViewCustomRenderer for which it's not obvious
2379     //       how it should be implemented so keep this "auto-deduction" of
2380     //       variant type from NSObject for now
2381
2382     wxVariant value;
2383     if ( [object isKindOfClass:[NSString class]] )
2384         value = ObjectToString(object);
2385     else if ( [object isKindOfClass:[NSNumber class]] )
2386         value = ObjectToLong(object);
2387     else if ( [object isKindOfClass:[NSDate class]] )
2388         value = ObjectToDate(object);
2389     else
2390     {
2391         wxFAIL_MSG( wxString::Format
2392                     (
2393                      "unknown value type %s",
2394                      wxCFStringRef::AsString([object className])
2395                     ));
2396         return;
2397     }
2398
2399     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2400     model->ChangeValue(value, item, col);
2401 }
2402
2403 void wxDataViewRenderer::OSXApplyAttr(const wxDataViewItemAttr& attr)
2404 {
2405     wxDataViewRendererNativeData * const data = GetNativeData();
2406     NSCell * const cell = data->GetItemCell();
2407
2408     // set the font and text colour to use: we need to do it if we had ever
2409     // changed them before, even if this item itself doesn't have any special
2410     // attributes as otherwise it would reuse the attributes from the previous
2411     // cell rendered using the same renderer
2412     NSFont *font = NULL;
2413     NSColor *colText = NULL;
2414
2415     if ( attr.HasFont() )
2416     {
2417         font = data->GetOriginalFont();
2418         if ( !font )
2419         {
2420             // this is the first time we're setting the font, remember the
2421             // original one before changing it
2422             font = [cell font];
2423             data->SaveOriginalFont(font);
2424         }
2425
2426         if ( font )
2427         {
2428             // FIXME: using wxFont methods here doesn't work for some reason
2429             NSFontManager * const fm = [NSFontManager sharedFontManager];
2430             if ( attr.GetBold() )
2431                 font = [fm convertFont:font toHaveTrait:NSBoldFontMask];
2432             if ( attr.GetItalic() )
2433                 font = [fm convertFont:font toHaveTrait:NSItalicFontMask];
2434         }
2435         //else: can't change font if the cell doesn't have any
2436     }
2437
2438     if ( attr.HasColour() )
2439     {
2440         // we can set font for any cell but only NSTextFieldCell provides
2441         // a method for setting text colour so check that this method is
2442         // available before using it
2443         if ( [cell respondsToSelector:@selector(setTextColor:)] &&
2444                 [cell respondsToSelector:@selector(textColor)] )
2445         {
2446             if ( !data->GetOriginalTextColour() )
2447             {
2448                 // the cast to (untyped) id is safe because of the check above
2449                 data->SaveOriginalTextColour([(id)cell textColor]);
2450             }
2451
2452             const wxColour& c = attr.GetColour();
2453             colText = [NSColor colorWithDeviceRed:c.Red() / 255.
2454                 green:c.Green() / 255.
2455                 blue:c.Blue() / 255.
2456                 alpha:c.Alpha() / 255.];
2457         }
2458     }
2459
2460     if ( !font )
2461         font = data->GetOriginalFont();
2462     if ( !colText )
2463         colText = data->GetOriginalTextColour();
2464
2465     if ( font )
2466         [cell setFont:font];
2467
2468     if ( colText )
2469         [(id)cell setTextColor:colText];
2470 }
2471
2472 IMPLEMENT_ABSTRACT_CLASS(wxDataViewRenderer,wxDataViewRendererBase)
2473
2474 // ---------------------------------------------------------
2475 // wxDataViewCustomRenderer
2476 // ---------------------------------------------------------
2477 wxDataViewCustomRenderer::wxDataViewCustomRenderer(const wxString& varianttype,
2478                                                    wxDataViewCellMode mode,
2479                                                    int align)
2480     : wxDataViewCustomRendererBase(varianttype, mode, align),
2481       m_editorCtrlPtr(NULL),
2482       m_DCPtr(NULL)
2483 {
2484     SetNativeData(new wxDataViewRendererNativeData([[wxCustomCell alloc] init]));
2485 }
2486
2487 bool wxDataViewCustomRenderer::MacRender()
2488 {
2489     [GetNativeData()->GetItemCell() setObjectValue:[[[wxCustomRendererObject alloc] initWithRenderer:this] autorelease]];
2490     return true;
2491 }
2492
2493 void wxDataViewCustomRenderer::OSXApplyAttr(const wxDataViewItemAttr& attr)
2494 {
2495     // simply save the attribute so that it could be reused from our Render()
2496     SetAttr(attr);
2497
2498     // it's not necessary to call the base class version which sets the cell
2499     // properties to correspond to this attribute because we currently don't
2500     // use any NSCell methods in custom renderers anyhow but if we ever start
2501     // doing this (e.g. override RenderText() here to use NSTextFieldCell
2502     // methods), then we should pass it on to wxDataViewRenderer here
2503 }
2504
2505 IMPLEMENT_ABSTRACT_CLASS(wxDataViewCustomRenderer, wxDataViewRenderer)
2506
2507 // ---------------------------------------------------------
2508 // wxDataViewTextRenderer
2509 // ---------------------------------------------------------
2510 wxDataViewTextRenderer::wxDataViewTextRenderer(const wxString& varianttype,
2511                                                wxDataViewCellMode mode,
2512                                                int align)
2513     : wxDataViewRenderer(varianttype,mode,align)
2514 {
2515     NSTextFieldCell* cell;
2516
2517
2518     cell = [[NSTextFieldCell alloc] init];
2519     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2520     SetNativeData(new wxDataViewRendererNativeData(cell));
2521     [cell release];
2522 }
2523
2524 bool wxDataViewTextRenderer::MacRender()
2525 {
2526     if (GetValue().GetType() == GetVariantType())
2527     {
2528         [GetNativeData()->GetItemCell() setObjectValue:wxCFStringRef(GetValue().GetString()).AsNSString()];
2529         return true;
2530     }
2531     else
2532     {
2533         wxFAIL_MSG(wxString("Text renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2534         return false;
2535     }
2536 }
2537
2538 void
2539 wxDataViewTextRenderer::OSXOnCellChanged(NSObject *value,
2540                                          const wxDataViewItem& item,
2541                                          unsigned col)
2542 {
2543     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2544     model->ChangeValue(ObjectToString(value), item, col);
2545 }
2546
2547 IMPLEMENT_CLASS(wxDataViewTextRenderer,wxDataViewRenderer)
2548
2549 // ---------------------------------------------------------
2550 // wxDataViewBitmapRenderer
2551 // ---------------------------------------------------------
2552 wxDataViewBitmapRenderer::wxDataViewBitmapRenderer(const wxString& varianttype,
2553                                                    wxDataViewCellMode mode,
2554                                                    int align)
2555     : wxDataViewRenderer(varianttype,mode,align)
2556 {
2557     NSImageCell* cell;
2558
2559
2560     cell = [[NSImageCell alloc] init];
2561     SetNativeData(new wxDataViewRendererNativeData(cell));
2562     [cell release];
2563 }
2564
2565 // This method returns 'true' if
2566 //  - the passed bitmap is valid and it could be assigned to the native data
2567 //  browser;
2568 //  - the passed bitmap is invalid (or is not initialized); this case
2569 //  simulates a non-existing bitmap.
2570 // In all other cases the method returns 'false'.
2571 bool wxDataViewBitmapRenderer::MacRender()
2572 {
2573     wxCHECK_MSG(GetValue().GetType() == GetVariantType(),false,wxString("Bitmap renderer cannot render value; value type: ") << GetValue().GetType());
2574
2575     wxBitmap bitmap;
2576
2577     bitmap << GetValue();
2578     if (bitmap.IsOk())
2579         [GetNativeData()->GetItemCell() setObjectValue:[[bitmap.GetNSImage() retain] autorelease]];
2580     return true;
2581 }
2582
2583 IMPLEMENT_CLASS(wxDataViewBitmapRenderer,wxDataViewRenderer)
2584
2585 // -------------------------------------
2586 // wxDataViewChoiceRenderer
2587 // -------------------------------------
2588 wxDataViewChoiceRenderer::wxDataViewChoiceRenderer(const wxArrayString& choices,
2589                                                    wxDataViewCellMode mode,
2590                                                    int alignment)
2591     : wxDataViewRenderer(wxT("string"), mode, alignment),
2592       m_choices(choices)
2593 {
2594     NSPopUpButtonCell* cell;
2595
2596
2597     cell = [[NSPopUpButtonCell alloc] init];
2598     [cell setControlSize:NSMiniControlSize];
2599     [cell setFont:[[NSFont fontWithName:[[cell font] fontName] size:[NSFont systemFontSizeForControlSize:NSMiniControlSize]] autorelease]];
2600     for (size_t i=0; i<choices.GetCount(); ++i)
2601         [cell addItemWithTitle:[[wxCFStringRef(choices[i]).AsNSString() retain] autorelease]];
2602     SetNativeData(new wxDataViewRendererNativeData(cell));
2603     [cell release];
2604 }
2605
2606 bool wxDataViewChoiceRenderer::MacRender()
2607 {
2608     if (GetValue().GetType() == GetVariantType())
2609     {
2610         [((NSPopUpButtonCell*) GetNativeData()->GetItemCell()) selectItemWithTitle:[[wxCFStringRef(GetValue().GetString()).AsNSString() retain] autorelease]];
2611         return true;
2612     }
2613     else
2614     {
2615         wxFAIL_MSG(wxString("Choice renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2616         return false;
2617     }
2618 }
2619
2620 IMPLEMENT_CLASS(wxDataViewChoiceRenderer,wxDataViewRenderer)
2621
2622 // ---------------------------------------------------------
2623 // wxDataViewDateRenderer
2624 // ---------------------------------------------------------
2625
2626 wxDataViewDateRenderer::wxDataViewDateRenderer(const wxString& varianttype,
2627                                                wxDataViewCellMode mode,
2628                                                int align)
2629     : wxDataViewRenderer(varianttype,mode,align)
2630 {
2631     NSTextFieldCell* cell;
2632
2633     NSDateFormatter* dateFormatter;
2634
2635
2636     dateFormatter = [[NSDateFormatter alloc] init];
2637     [dateFormatter setFormatterBehavior:NSDateFormatterBehavior10_4];
2638     [dateFormatter setDateStyle:NSDateFormatterShortStyle];
2639     cell = [[NSTextFieldCell alloc] init];
2640     [cell setFormatter:dateFormatter];
2641     SetNativeData(new wxDataViewRendererNativeData(cell,[NSDate dateWithString:@"2000-12-30 20:00:00 +0000"]));
2642     [cell          release];
2643     [dateFormatter release];
2644 }
2645
2646 bool wxDataViewDateRenderer::MacRender()
2647 {
2648     if (GetValue().GetType() == GetVariantType())
2649     {
2650         if (GetValue().GetDateTime().IsValid())
2651         {
2652             // -- find best fitting style to show the date --
2653             // as the style should be identical for all cells a reference date
2654             // instead of the actual cell's date value is used for all cells;
2655             // this reference date is stored in the renderer's native data
2656             // section for speed purposes; otherwise, the reference date's
2657             // string has to be recalculated for each item that may become
2658             // timewise long if a lot of rows using dates exist; the algorithm
2659             // has the preference to display as much information as possible
2660             // in the first instance; but as this is often impossible due to
2661             // space restrictions the style is shortened per loop; finally, if
2662             // the shortest time and date format does not fit into the cell
2663             // the time part is dropped; remark: the time part itself is not
2664             // modified per iteration loop and only uses the short style,
2665             // means that only the hours and minutes are being shown
2666
2667             // GetObject() returns a date for testing the size of a date object
2668             [GetNativeData()->GetItemCell() setObjectValue:GetNativeData()->GetObject()];
2669             [[GetNativeData()->GetItemCell() formatter] setTimeStyle:NSDateFormatterShortStyle];
2670             for (int dateFormatterStyle=4; dateFormatterStyle>0; --dateFormatterStyle)
2671             {
2672                 [[GetNativeData()->GetItemCell() formatter] setDateStyle:(NSDateFormatterStyle)dateFormatterStyle];
2673                 if (dateFormatterStyle == 1)
2674                 {
2675                     // if the shortest style for displaying the date and time
2676                     // is too long to be fully visible remove the time part of
2677                     // the date:
2678                     if ([GetNativeData()->GetItemCell() cellSize].width > [GetNativeData()->GetColumnPtr() width])
2679                         [[GetNativeData()->GetItemCell() formatter] setTimeStyle:NSDateFormatterNoStyle];
2680                     {
2681                         // basically not necessary as the loop would end anyway
2682                         // but let's save the last comparison
2683                         break;
2684                     }
2685                 }
2686                 else if ([GetNativeData()->GetItemCell() cellSize].width <= [GetNativeData()->GetColumnPtr() width])
2687                     break;
2688             }
2689             // set data (the style is set by the previous loop); on OSX the
2690             // date has to be specified with respect to UTC; in wxWidgets the
2691             // date is always entered in the local timezone; so, we have to do
2692             // a conversion from the local to UTC timezone when adding the
2693             // seconds to 1970-01-01 UTC:
2694             [GetNativeData()->GetItemCell() setObjectValue:[NSDate dateWithTimeIntervalSince1970:GetValue().GetDateTime().ToUTC().Subtract(wxDateTime(1,wxDateTime::Jan,1970)).GetSeconds().ToDouble()]];
2695         }
2696         return true;
2697     }
2698     else
2699     {
2700         wxFAIL_MSG(wxString("Date renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2701         return false;
2702     }
2703 }
2704
2705 void
2706 wxDataViewDateRenderer::OSXOnCellChanged(NSObject *value,
2707                                          const wxDataViewItem& item,
2708                                          unsigned col)
2709 {
2710     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2711     model->ChangeValue(ObjectToDate(value), item, col);
2712 }
2713
2714 IMPLEMENT_ABSTRACT_CLASS(wxDataViewDateRenderer,wxDataViewRenderer)
2715
2716 // ---------------------------------------------------------
2717 // wxDataViewIconTextRenderer
2718 // ---------------------------------------------------------
2719 wxDataViewIconTextRenderer::wxDataViewIconTextRenderer(const wxString& varianttype,
2720                                                        wxDataViewCellMode mode,
2721                                                        int align)
2722      : wxDataViewRenderer(varianttype,mode)
2723 {
2724     wxImageTextCell* cell;
2725
2726
2727     cell = [[wxImageTextCell alloc] init];
2728     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2729     SetNativeData(new wxDataViewRendererNativeData(cell));
2730     [cell release];
2731 }
2732
2733 bool wxDataViewIconTextRenderer::MacRender()
2734 {
2735     if (GetValue().GetType() == GetVariantType())
2736     {
2737         wxDataViewIconText iconText;
2738
2739         wxImageTextCell* cell;
2740
2741         cell = (wxImageTextCell*) GetNativeData()->GetItemCell();
2742         iconText << GetValue();
2743         if (iconText.GetIcon().IsOk())
2744             [cell setImage:[[wxBitmap(iconText.GetIcon()).GetNSImage() retain] autorelease]];
2745         [cell setStringValue:[[wxCFStringRef(iconText.GetText()).AsNSString() retain] autorelease]];
2746         return true;
2747     }
2748     else
2749     {
2750         wxFAIL_MSG(wxString("Icon & text renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2751         return false;
2752     }
2753 }
2754
2755 void
2756 wxDataViewIconTextRenderer::OSXOnCellChanged(NSObject *value,
2757                                              const wxDataViewItem& item,
2758                                              unsigned col)
2759 {
2760     wxVariant valueIconText;
2761     valueIconText << wxDataViewIconText(ObjectToString(value));
2762
2763     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2764     model->ChangeValue(valueIconText, item, col);
2765 }
2766
2767 IMPLEMENT_ABSTRACT_CLASS(wxDataViewIconTextRenderer,wxDataViewRenderer)
2768
2769 // ---------------------------------------------------------
2770 // wxDataViewToggleRenderer
2771 // ---------------------------------------------------------
2772 wxDataViewToggleRenderer::wxDataViewToggleRenderer(const wxString& varianttype,
2773                                                    wxDataViewCellMode mode,
2774                                                    int align)
2775     : wxDataViewRenderer(varianttype,mode)
2776 {
2777     NSButtonCell* cell;
2778
2779
2780     cell = [[NSButtonCell alloc] init];
2781     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2782     [cell setButtonType:NSSwitchButton];
2783     [cell setImagePosition:NSImageOnly];
2784     SetNativeData(new wxDataViewRendererNativeData(cell));
2785     [cell release];
2786 }
2787
2788 bool wxDataViewToggleRenderer::MacRender()
2789 {
2790     if (GetValue().GetType() == GetVariantType())
2791     {
2792         [GetNativeData()->GetItemCell() setIntValue:GetValue().GetLong()];
2793         return true;
2794     }
2795     else
2796     {
2797         wxFAIL_MSG(wxString("Toggle renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2798         return false;
2799     }
2800 }
2801
2802 void
2803 wxDataViewToggleRenderer::OSXOnCellChanged(NSObject *value,
2804                                            const wxDataViewItem& item,
2805                                            unsigned col)
2806 {
2807     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2808     model->ChangeValue(ObjectToBool(value), item, col);
2809 }
2810
2811 IMPLEMENT_ABSTRACT_CLASS(wxDataViewToggleRenderer,wxDataViewRenderer)
2812
2813 // ---------------------------------------------------------
2814 // wxDataViewProgressRenderer
2815 // ---------------------------------------------------------
2816 wxDataViewProgressRenderer::wxDataViewProgressRenderer(const wxString& label,
2817                                                        const wxString& varianttype,
2818                                                        wxDataViewCellMode mode,
2819                                                        int align)
2820     : wxDataViewRenderer(varianttype,mode,align)
2821 {
2822     NSLevelIndicatorCell* cell;
2823
2824     cell = [[NSLevelIndicatorCell alloc] initWithLevelIndicatorStyle:NSContinuousCapacityLevelIndicatorStyle];
2825     [cell setMinValue:0];
2826     [cell setMaxValue:100];
2827     SetNativeData(new wxDataViewRendererNativeData(cell));
2828     [cell release];
2829 }
2830
2831 bool wxDataViewProgressRenderer::MacRender()
2832 {
2833     if (GetValue().GetType() == GetVariantType())
2834     {
2835         [GetNativeData()->GetItemCell() setIntValue:GetValue().GetLong()];
2836         return true;
2837     }
2838     else
2839     {
2840         wxFAIL_MSG(wxString("Progress renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2841         return false;
2842     }
2843 }
2844
2845 void
2846 wxDataViewProgressRenderer::OSXOnCellChanged(NSObject *value,
2847                                              const wxDataViewItem& item,
2848                                              unsigned col)
2849 {
2850     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2851     model->ChangeValue(ObjectToLong(value), item, col);
2852 }
2853
2854 IMPLEMENT_ABSTRACT_CLASS(wxDataViewProgressRenderer,wxDataViewRenderer)
2855
2856 // ---------------------------------------------------------
2857 // wxDataViewColumn
2858 // ---------------------------------------------------------
2859
2860 wxDataViewColumn::wxDataViewColumn(const wxString& title,
2861                                    wxDataViewRenderer* renderer,
2862                                    unsigned int model_column,
2863                                    int width,
2864                                    wxAlignment align,
2865                                    int flags)
2866      : wxDataViewColumnBase(renderer, model_column),
2867        m_NativeDataPtr(new wxDataViewColumnNativeData()),
2868        m_title(title)
2869 {
2870     InitCommon(width, align, flags);
2871     if (renderer && (renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
2872         renderer->SetAlignment(align);
2873 }
2874
2875 wxDataViewColumn::wxDataViewColumn(const wxBitmap& bitmap,
2876                                    wxDataViewRenderer* renderer,
2877                                    unsigned int model_column,
2878                                    int width,
2879                                    wxAlignment align,
2880                                    int flags)
2881     : wxDataViewColumnBase(bitmap, renderer, model_column),
2882       m_NativeDataPtr(new wxDataViewColumnNativeData())
2883 {
2884     InitCommon(width, align, flags);
2885     if (renderer && (renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
2886         renderer->SetAlignment(align);
2887 }
2888
2889 wxDataViewColumn::~wxDataViewColumn()
2890 {
2891     delete m_NativeDataPtr;
2892 }
2893
2894 int wxDataViewColumn::GetWidth() const
2895 {
2896     return [m_NativeDataPtr->GetNativeColumnPtr() width];
2897 }
2898
2899 bool wxDataViewColumn::IsSortKey() const
2900 {
2901     NSTableColumn *nsCol = GetNativeData()->GetNativeColumnPtr();
2902     return nsCol && ([nsCol sortDescriptorPrototype] != nil);
2903 }
2904
2905 void wxDataViewColumn::SetAlignment(wxAlignment align)
2906 {
2907     m_alignment = align;
2908     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2909     if (m_renderer && (m_renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
2910         m_renderer->SetAlignment(align);
2911 }
2912
2913 void wxDataViewColumn::SetBitmap(const wxBitmap& bitmap)
2914 {
2915     // bitmaps and titles cannot exist at the same time - if the bitmap is set
2916     // the title is removed:
2917     m_title = wxEmptyString;
2918     wxDataViewColumnBase::SetBitmap(bitmap);
2919     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setImage:[[bitmap.GetNSImage() retain] autorelease]];
2920 }
2921
2922 void wxDataViewColumn::SetMaxWidth(int maxWidth)
2923 {
2924     m_maxWidth = maxWidth;
2925     [m_NativeDataPtr->GetNativeColumnPtr() setMaxWidth:maxWidth];
2926 }
2927
2928 void wxDataViewColumn::SetMinWidth(int minWidth)
2929 {
2930     m_minWidth = minWidth;
2931     [m_NativeDataPtr->GetNativeColumnPtr() setMinWidth:minWidth];
2932 }
2933
2934 void wxDataViewColumn::SetReorderable(bool reorderable)
2935 {
2936 }
2937
2938 void wxDataViewColumn::SetResizeable(bool resizeable)
2939 {
2940     wxDataViewColumnBase::SetResizeable(resizeable);
2941     if (resizeable)
2942         [m_NativeDataPtr->GetNativeColumnPtr() setResizingMask:NSTableColumnUserResizingMask];
2943     else
2944         [m_NativeDataPtr->GetNativeColumnPtr() setResizingMask:NSTableColumnNoResizing];
2945 }
2946
2947 void wxDataViewColumn::SetSortable(bool sortable)
2948 {
2949     wxDataViewColumnBase::SetSortable(sortable);
2950 }
2951
2952 void wxDataViewColumn::SetSortOrder(bool ascending)
2953 {
2954     if (m_ascending != ascending)
2955     {
2956         m_ascending = ascending;
2957         if (IsSortKey())
2958         {
2959             // change sorting order:
2960             NSArray*          sortDescriptors;
2961             NSSortDescriptor* sortDescriptor;
2962             NSTableColumn*    tableColumn;
2963
2964             tableColumn     = m_NativeDataPtr->GetNativeColumnPtr();
2965             sortDescriptor  = [[NSSortDescriptor alloc] initWithKey:[[tableColumn sortDescriptorPrototype] key] ascending:m_ascending];
2966             sortDescriptors = [NSArray arrayWithObject:sortDescriptor];
2967             [tableColumn setSortDescriptorPrototype:sortDescriptor];
2968             [[tableColumn tableView] setSortDescriptors:sortDescriptors];
2969             [sortDescriptor release];
2970         }
2971     }
2972 }
2973
2974 void wxDataViewColumn::SetTitle(const wxString& title)
2975 {
2976     // bitmaps and titles cannot exist at the same time - if the title is set
2977     // the bitmap is removed:
2978     wxDataViewColumnBase::SetBitmap(wxBitmap());
2979     m_title = title;
2980     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setStringValue:[[wxCFStringRef(title).AsNSString() retain] autorelease]];
2981 }
2982
2983 void wxDataViewColumn::SetWidth(int width)
2984 {
2985     [m_NativeDataPtr->GetNativeColumnPtr() setWidth:width];
2986     m_width = width;
2987 }
2988
2989 void wxDataViewColumn::SetAsSortKey(bool WXUNUSED(sort))
2990 {
2991     // see wxGTK native wxDataViewColumn implementation
2992     wxFAIL_MSG("not implemented");
2993 }
2994
2995 void wxDataViewColumn::SetNativeData(wxDataViewColumnNativeData* newNativeDataPtr)
2996 {
2997     delete m_NativeDataPtr;
2998     m_NativeDataPtr = newNativeDataPtr;
2999 }
3000
3001 #endif // (wxUSE_DATAVIEWCTRL == 1) && !defined(wxUSE_GENERICDATAVIEWCTRL)