src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19     #include "wx/combobox.h"
  20 #endif
  21
  22 #ifdef __WXMAC__
  23     #include "wx/osx/private.h"
  24 #endif
  25
  26 #include "wx/evtloop.h"
  27
  28 #if wxUSE_CARET
  29     #include "wx/caret.h"
  30 #endif
  31
  32 #if wxUSE_DRAG_AND_DROP
  33     #include "wx/dnd.h"
  34 #endif
  35
  36 #if wxUSE_TOOLTIPS
  37     #include "wx/tooltip.h"
  38 #endif
  39
  40 #include <objc/objc-runtime.h>
  41
  42 // Get the window with the focus
  43
  44 NSView* GetViewFromResponder( NSResponder* responder )
  45 {
  46     NSView* view = nil;
  47     if ( [responder isKindOfClass:[NSTextView class]] )
  48     {
  49         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  50         if ( [delegate isKindOfClass:[NSTextField class] ] )
  51             view = delegate;
  52         else
  53             view =  (NSView*) responder;
  54     }
  55     else
  56     {
  57         if ( [responder isKindOfClass:[NSView class]] )
  58             view = (NSView*) responder;
  59     }
  60     return view;
  61 }
  62
  63 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  64 {
  65     NSView* focusedView = nil;
  66     if ( keyWindow != nil )
  67         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  68
  69     return focusedView;
  70 }
  71
  72 WXWidget wxWidgetImpl::FindFocus()
  73 {
  74     return GetFocusedViewInWindow( [NSApp keyWindow] );
  75 }
  76
  77 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  78 {
  79     int x, y, w, h ;
  80
  81     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  82     wxRect bounds(x,y,w,h);
  83     NSView* sv = (window->GetParent()->GetHandle() );
  84
  85     return wxToNSRect( sv, bounds );
  86 }
  87
  88 @interface wxNSView : NSView
  89 {
  90     NSTrackingRectTag rectTag;
  91 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
  92     NSTrackingArea* _trackingArea;
  93 #endif
  94 }
  95
  96 // the tracking tag is needed to track mouse enter / exit events
  97 - (void) setTrackingTag: (NSTrackingRectTag)tag;
  98 - (NSTrackingRectTag) trackingTag;
  99 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 100 // under 10.5 we can also track mouse moved events on non-focused windows if
 101 // we use the new NSTrackingArea APIs.
 102 - (void) updateTrackingArea;
 103 - (NSTrackingArea*) trackingArea;
 104 #endif
 105 @end // wxNSView
 106
 107 @interface NSView(PossibleMethods)
 108 - (void)setTitle:(NSString *)aString;
 109 - (void)setStringValue:(NSString *)aString;
 110 - (void)setIntValue:(int)anInt;
 111 - (void)setFloatValue:(float)aFloat;
 112 - (void)setDoubleValue:(double)aDouble;
 113
 114 - (double)minValue;
 115 - (double)maxValue;
 116 - (void)setMinValue:(double)aDouble;
 117 - (void)setMaxValue:(double)aDouble;
 118
 119 - (void)sizeToFit;
 120
 121 - (BOOL)isEnabled;
 122 - (void)setEnabled:(BOOL)flag;
 123
 124 - (void)setImage:(NSImage *)image;
 125 - (void)setControlSize:(NSControlSize)size;
 126
 127 - (void)setFont:(NSFont *)fontObject;
 128
 129 - (id)contentView;
 130
 131 - (void)setTarget:(id)anObject;
 132 - (void)setAction:(SEL)aSelector;
 133 - (void)setDoubleAction:(SEL)aSelector;
 134 - (void)setBackgroundColor:(NSColor*)aColor;
 135 - (void)setOpaque:(BOOL)opaque;
 136 - (void)setTextColor:(NSColor *)color;
 137 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 138 @end
 139
 140 long wxOSXTranslateCocoaKey( NSEvent* event )
 141 {
 142     long retval = 0;
 143
 144     if ([event type] != NSFlagsChanged)
 145     {
 146         NSString* s = [event charactersIgnoringModifiers];
 147         // backspace char reports as delete w/modifiers for some reason
 148         if ([s length] == 1)
 149         {
 150             switch ( [s characterAtIndex:0] )
 151             {
 152                 // backspace key
 153                 case 0x7F :
 154                 case 8 :
 155                     retval = WXK_BACK;
 156                     break;
 157                 case NSUpArrowFunctionKey :
 158                     retval = WXK_UP;
 159                     break;
 160                 case NSDownArrowFunctionKey :
 161                     retval = WXK_DOWN;
 162                     break;
 163                 case NSLeftArrowFunctionKey :
 164                     retval = WXK_LEFT;
 165                     break;
 166                 case NSRightArrowFunctionKey :
 167                     retval = WXK_RIGHT;
 168                     break;
 169                 case NSInsertFunctionKey  :
 170                     retval = WXK_INSERT;
 171                     break;
 172                 case NSDeleteFunctionKey  :
 173                     retval = WXK_DELETE;
 174                     break;
 175                 case NSHomeFunctionKey  :
 176                     retval = WXK_HOME;
 177                     break;
 178         //        case NSBeginFunctionKey  :
 179         //            retval = WXK_BEGIN;
 180         //            break;
 181                 case NSEndFunctionKey  :
 182                     retval = WXK_END;
 183                     break;
 184                 case NSPageUpFunctionKey  :
 185                     retval = WXK_PAGEUP;
 186                     break;
 187                case NSPageDownFunctionKey  :
 188                     retval = WXK_PAGEDOWN;
 189                     break;
 190                case NSHelpFunctionKey  :
 191                     retval = WXK_HELP;
 192                     break;
 193                 default:
 194                     int intchar = [s characterAtIndex: 0];
 195                     if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 196                         retval = WXK_F1 + (intchar - NSF1FunctionKey );
 197                     break;
 198             }
 199         }
 200     }
 201
 202     // Some keys don't seem to have constants. The code mimics the approach
 203     // taken by WebKit. See:
 204     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 205     switch( [event keyCode] )
 206     {
 207         // command key
 208         case 54:
 209         case 55:
 210             retval = WXK_COMMAND;
 211             break;
 212         // caps locks key
 213         case 57: // Capslock
 214             retval = WXK_CAPITAL;
 215             break;
 216         // shift key
 217         case 56: // Left Shift
 218         case 60: // Right Shift
 219             retval = WXK_SHIFT;
 220             break;
 221         // alt key
 222         case 58: // Left Alt
 223         case 61: // Right Alt
 224             retval = WXK_ALT;
 225             break;
 226         // ctrl key
 227         case 59: // Left Ctrl
 228         case 62: // Right Ctrl
 229             retval = WXK_CONTROL;
 230             break;
 231         // clear key
 232         case 71:
 233             retval = WXK_CLEAR;
 234             break;
 235         // tab key
 236         case 48:
 237             retval = WXK_TAB;
 238             break;
 239
 240         case 75: // /
 241             retval = WXK_NUMPAD_DIVIDE;
 242             break;
 243         case 67: // *
 244             retval = WXK_NUMPAD_MULTIPLY;
 245             break;
 246         case 78: // -
 247             retval = WXK_NUMPAD_SUBTRACT;
 248             break;
 249         case 69: // +
 250             retval = WXK_NUMPAD_ADD;
 251             break;
 252         case 76: // Enter
 253             retval = WXK_NUMPAD_ENTER;
 254             break;
 255         case 65: // .
 256             retval = WXK_NUMPAD_DECIMAL;
 257             break;
 258         case 82: // 0
 259             retval = WXK_NUMPAD0;
 260             break;
 261         case 83: // 1
 262             retval = WXK_NUMPAD1;
 263             break;
 264         case 84: // 2
 265             retval = WXK_NUMPAD2;
 266             break;
 267         case 85: // 3
 268             retval = WXK_NUMPAD3;
 269             break;
 270         case 86: // 4
 271             retval = WXK_NUMPAD4;
 272             break;
 273         case 87: // 5
 274             retval = WXK_NUMPAD5;
 275             break;
 276         case 88: // 6
 277             retval = WXK_NUMPAD6;
 278             break;
 279         case 89: // 7
 280             retval = WXK_NUMPAD7;
 281             break;
 282         case 91: // 8
 283             retval = WXK_NUMPAD8;
 284             break;
 285         case 92: // 9
 286             retval = WXK_NUMPAD9;
 287             break;
 288         default:
 289             //retval = [event keyCode];
 290             break;
 291     }
 292     return retval;
 293 }
 294
 295 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 296 {
 297     UInt32 modifiers = [nsEvent modifierFlags] ;
 298     int eventType = [nsEvent type];
 299
 300     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 301     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 302     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 303     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 304
 305     wxevent.m_rawCode = [nsEvent keyCode];
 306     wxevent.m_rawFlags = modifiers;
 307
 308     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 309
 310     wxString chars;
 311     if ( eventType != NSFlagsChanged )
 312     {
 313         NSString* nschars = [nsEvent charactersIgnoringModifiers];
 314         if ( charString )
 315         {
 316             // if charString is set, it did not come from key up / key down
 317             wxevent.SetEventType( wxEVT_CHAR );
 318             chars = wxCFStringRef::AsString(charString);
 319         }
 320         else if ( nschars )
 321         {
 322             chars = wxCFStringRef::AsString(nschars);
 323         }
 324     }
 325
 326     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 327     long keyval = 0;
 328
 329     if (wxevent.GetEventType() != wxEVT_CHAR)
 330     {
 331         keyval = wxOSXTranslateCocoaKey(nsEvent) ;
 332         switch (eventType)
 333         {
 334             case NSKeyDown :
 335                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 336                 break;
 337             case NSKeyUp :
 338                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 339                 break;
 340             case NSFlagsChanged :
 341                 switch (keyval)
 342                 {
 343                     case WXK_CONTROL:
 344                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 345                         break;
 346                     case WXK_SHIFT:
 347                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 348                         break;
 349                     case WXK_ALT:
 350                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 351                         break;
 352                     case WXK_COMMAND:
 353                         wxevent.SetEventType( wxevent.m_metaDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 354                         break;
 355                 }
 356                 break;
 357             default :
 358                 break ;
 359         }
 360     }
 361
 362     if ( !keyval )
 363     {
 364         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 365             keyval = wxToupper( aunichar ) ;
 366         else
 367             keyval = aunichar;
 368     }
 369
 370 #if wxUSE_UNICODE
 371     wxevent.m_uniChar = aunichar;
 372 #endif
 373     wxevent.m_keyCode = keyval;
 374
 375     wxWindowMac* peer = GetWXPeer();
 376     if ( peer )
 377     {
 378         wxevent.SetEventObject(peer);
 379         wxevent.SetId(peer->GetId()) ;
 380     }
 381 }
 382
 383 UInt32 g_lastButton = 0 ;
 384 bool g_lastButtonWasFakeRight = false ;
 385
 386 // better scroll wheel support
 387 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 388
 389 @interface NSEvent (DeviceDelta)
 390 - (CGFloat)deviceDeltaX;
 391 - (CGFloat)deviceDeltaY;
 392 @end
 393
 394 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 395 {
 396     int eventType = [nsEvent type];
 397     UInt32 modifiers = [nsEvent modifierFlags] ;
 398
 399     NSPoint locationInWindow = [nsEvent locationInWindow];
 400
 401     // adjust coordinates for the window of the target view
 402     if ( [nsEvent window] != [m_osxView window] )
 403     {
 404         if ( [nsEvent window] != nil )
 405             locationInWindow = [[nsEvent window] convertBaseToScreen:locationInWindow];
 406
 407         if ( [m_osxView window] != nil )
 408             locationInWindow = [[m_osxView window] convertScreenToBase:locationInWindow];
 409     }
 410
 411     NSPoint locationInView = [m_osxView convertPoint:locationInWindow fromView:nil];
 412     wxPoint locationInViewWX = wxFromNSPoint( m_osxView, locationInView );
 413
 414     // these parameters are not given for all events
 415     UInt32 button = [nsEvent buttonNumber];
 416     UInt32 clickCount = 0;
 417
 418     wxevent.m_x = locationInViewWX.x;
 419     wxevent.m_y = locationInViewWX.y;
 420     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 421     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 422     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 423     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 424     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 425
 426     UInt32 mouseChord = 0;
 427
 428     switch (eventType)
 429     {
 430         case NSLeftMouseDown :
 431         case NSLeftMouseDragged :
 432             mouseChord = 1U;
 433             break;
 434         case NSRightMouseDown :
 435         case NSRightMouseDragged :
 436             mouseChord = 2U;
 437             break;
 438         case NSOtherMouseDown :
 439         case NSOtherMouseDragged :
 440             mouseChord = 4U;
 441             break;
 442     }
 443
 444     // a control click is interpreted as a right click
 445     bool thisButtonIsFakeRight = false ;
 446     if ( button == 0 && (modifiers & NSControlKeyMask) )
 447     {
 448         button = 1 ;
 449         thisButtonIsFakeRight = true ;
 450     }
 451
 452     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 453     if ( clickCount > 1 && button != g_lastButton )
 454         clickCount = 1 ;
 455
 456     // we must make sure that our synthetic 'right' button corresponds in
 457     // mouse down, moved and mouse up, and does not deliver a right down and left up
 458     switch (eventType)
 459     {
 460         case NSLeftMouseDown :
 461         case NSRightMouseDown :
 462         case NSOtherMouseDown :
 463             g_lastButton = button ;
 464             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 465             break;
 466      }
 467
 468     if ( button == 0 )
 469     {
 470         g_lastButton = 0 ;
 471         g_lastButtonWasFakeRight = false ;
 472     }
 473     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 474         button = g_lastButton ;
 475
 476     // Adjust the chord mask to remove the primary button and add the
 477     // secondary button.  It is possible that the secondary button is
 478     // already pressed, e.g. on a mouse connected to a laptop, but this
 479     // possibility is ignored here:
 480     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 481         mouseChord = ((mouseChord & ~1U) | 2U);
 482
 483     if(mouseChord & 1U)
 484                 wxevent.m_leftDown = true ;
 485     if(mouseChord & 2U)
 486                 wxevent.m_rightDown = true ;
 487     if(mouseChord & 4U)
 488                 wxevent.m_middleDown = true ;
 489
 490     // translate into wx types
 491     switch (eventType)
 492     {
 493         case NSLeftMouseDown :
 494         case NSRightMouseDown :
 495         case NSOtherMouseDown :
 496             clickCount = [nsEvent clickCount];
 497             switch ( button )
 498             {
 499                 case 0 :
 500                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 501                     break ;
 502
 503                 case 1 :
 504                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 505                     break ;
 506
 507                 case 2 :
 508                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 509                     break ;
 510
 511                 default:
 512                     break ;
 513             }
 514             break ;
 515
 516         case NSLeftMouseUp :
 517         case NSRightMouseUp :
 518         case NSOtherMouseUp :
 519             clickCount = [nsEvent clickCount];
 520             switch ( button )
 521             {
 522                 case 0 :
 523                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 524                     break ;
 525
 526                 case 1 :
 527                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 528                     break ;
 529
 530                 case 2 :
 531                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 532                     break ;
 533
 534                 default:
 535                     break ;
 536             }
 537             break ;
 538
 539      case NSScrollWheel :
 540         {
 541             float deltaX = 0.0;
 542             float deltaY = 0.0;
 543
 544             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 545
 546             // see http://developer.apple.com/qa/qa2005/qa1453.html
 547             // for more details on why we have to look for the exact type
 548
 549             const EventRef cEvent = (EventRef) [nsEvent eventRef];
 550             bool isMouseScrollEvent = false;
 551             if ( cEvent )
 552                 isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 553
 554             if ( isMouseScrollEvent )
 555             {
 556                 deltaX = [nsEvent deviceDeltaX];
 557                 deltaY = [nsEvent deviceDeltaY];
 558             }
 559             else
 560             {
 561                 deltaX = ([nsEvent deltaX] * 10);
 562                 deltaY = ([nsEvent deltaY] * 10);
 563             }
 564
 565             wxevent.m_wheelDelta = 10;
 566             wxevent.m_linesPerAction = 1;
 567
 568             if ( fabs(deltaX) > fabs(deltaY) )
 569             {
 570                 wxevent.m_wheelAxis = 1;
 571                 wxevent.m_wheelRotation = (int)deltaX;
 572             }
 573             else
 574             {
 575                 wxevent.m_wheelRotation = (int)deltaY;
 576             }
 577
 578         }
 579         break ;
 580
 581         case NSMouseEntered :
 582             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 583             break;
 584         case NSMouseExited :
 585             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 586             break;
 587         case NSLeftMouseDragged :
 588         case NSRightMouseDragged :
 589         case NSOtherMouseDragged :
 590         case NSMouseMoved :
 591             wxevent.SetEventType( wxEVT_MOTION ) ;
 592             break;
 593         default :
 594             break ;
 595     }
 596
 597     wxevent.m_clickCount = clickCount;
 598     wxWindowMac* peer = GetWXPeer();
 599     if ( peer )
 600     {
 601         wxevent.SetEventObject(peer);
 602         wxevent.SetId(peer->GetId()) ;
 603     }
 604 }
 605
 606 @implementation wxNSView
 607
 608 + (void)initialize
 609 {
 610     static BOOL initialized = NO;
 611     if (!initialized)
 612     {
 613         initialized = YES;
 614         wxOSXCocoaClassAddWXMethods( self );
 615     }
 616 }
 617
 618 - (void) setTrackingTag: (NSTrackingRectTag)tag
 619 {
 620     rectTag = tag;
 621 }
 622
 623 - (NSTrackingRectTag) trackingTag
 624 {
 625     return rectTag;
 626 }
 627
 628 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 629 - (void) updateTrackingArea
 630 {
 631     if (_trackingArea)
 632     {
 633         [self removeTrackingArea: _trackingArea];
 634         [_trackingArea release];
 635     }
 636
 637     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingMouseMoved|NSTrackingActiveAlways;
 638
 639     NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: [self bounds] options: options owner: self userInfo: nil];
 640     [self addTrackingArea: area];
 641
 642     _trackingArea = area;
 643 }
 644
 645 - (NSTrackingArea*) trackingArea
 646 {
 647     return _trackingArea;
 648 }
 649 #endif
 650 @end // wxNSView
 651
 652 //
 653 // event handlers
 654 //
 655
 656 #if wxUSE_DRAG_AND_DROP
 657
 658 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 659 // for details on the NSPasteboard -> PasteboardRef conversion
 660
 661 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 662 {
 663     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 664     if (impl == NULL)
 665         return NSDragOperationNone;
 666
 667     return impl->draggingEntered(sender, self, _cmd);
 668 }
 669
 670 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 671 {
 672     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 673     if (impl == NULL)
 674         return ;
 675
 676     return impl->draggingExited(sender, self, _cmd);
 677 }
 678
 679 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 680 {
 681     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 682     if (impl == NULL)
 683         return NSDragOperationNone;
 684
 685     return impl->draggingUpdated(sender, self, _cmd);
 686 }
 687
 688 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 689 {
 690     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 691     if (impl == NULL)
 692         return NSDragOperationNone;
 693
 694     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 695 }
 696
 697 #endif
 698
 699 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 700 {
 701     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 702     if (impl == NULL)
 703         return;
 704
 705     impl->mouseEvent(event, self, _cmd);
 706 }
 707
 708 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 709 {
 710     // This is needed to support click through, otherwise the first click on a window
 711     // will not do anything unless it is the active window already.
 712     return YES;
 713 }
 714
 715 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 716 {
 717     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 718     if (impl == NULL)
 719         return;
 720
 721     impl->keyEvent(event, self, _cmd);
 722 }
 723
 724 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 725 {
 726     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 727     if (impl == NULL)
 728         return;
 729
 730     impl->insertText(text, self, _cmd);
 731 }
 732
 733 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 734 {
 735     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 736     if (impl == NULL)
 737         return NO;
 738
 739     return impl->performKeyEquivalent(event, self, _cmd);
 740 }
 741
 742 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 743 {
 744     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 745     if (impl == NULL)
 746         return NO;
 747
 748     return impl->acceptsFirstResponder(self, _cmd);
 749 }
 750
 751 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 752 {
 753     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 754     if (impl == NULL)
 755         return NO;
 756
 757     return impl->becomeFirstResponder(self, _cmd);
 758 }
 759
 760 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 761 {
 762     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 763     if (impl == NULL)
 764         return NO;
 765
 766     return impl->resignFirstResponder(self, _cmd);
 767 }
 768
 769 void wxOSX_resetCursorRects(NSView* self, SEL _cmd)
 770 {
 771     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 772     if (impl == NULL)
 773         return;
 774
 775     impl->resetCursorRects(self, _cmd);
 776 }
 777
 778 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 779 {
 780     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 781     if (impl == NULL)
 782         return NO;
 783
 784     return impl->isFlipped(self, _cmd) ? YES:NO;
 785 }
 786
 787 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 788
 789 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 790 {
 791     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 792     if (impl == NULL)
 793         return;
 794
 795 #ifdef wxUSE_THREADS
 796     // OS X starts a NSUIHeartBeatThread for animating the default button in a
 797     // dialog. This causes a drawRect of the active dialog from outside the
 798     // main UI thread. This causes an occasional crash since the wx drawing
 799     // objects (like wxPen) are not thread safe.
 800     //
 801     // Notice that NSUIHeartBeatThread seems to be undocumented and doing
 802     // [NSWindow setAllowsConcurrentViewDrawing:NO] does not affect it.
 803     if ( !wxThread::IsMain() )
 804     {
 805         if ( impl->IsUserPane() )
 806         {
 807             wxWindow* win = impl->GetWXPeer();
 808             if ( win->UseBgCol() )
 809             {
 810
 811                 CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
 812                 CGContextSaveGState( context );
 813
 814                 CGContextSetFillColorWithColor( context, win->GetBackgroundColour().GetCGColor());
 815                 CGContextFillRect( context, NSRectToCGRect(rect) );
 816
 817                 CGContextRestoreGState( context );
 818             }
 819         }
 820         else
 821         {
 822             // just call the superclass handler, we don't need any custom wx drawing
 823             // here and it seems to work fine:
 824             wxOSX_DrawRectHandlerPtr
 825             superimpl = (wxOSX_DrawRectHandlerPtr)
 826             [[self superclass] instanceMethodForSelector:_cmd];
 827             superimpl(self, _cmd, rect);
 828         }
 829
 830       return;
 831     }
 832 #endif // wxUSE_THREADS
 833
 834     return impl->drawRect(&rect, self, _cmd);
 835 }
 836
 837 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
 838 {
 839     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 840     if (impl == NULL)
 841         return;
 842
 843     impl->controlAction(self, _cmd, sender);
 844 }
 845
 846 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
 847 {
 848     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 849     if (impl == NULL)
 850         return;
 851
 852     impl->controlDoubleAction(self, _cmd, sender);
 853 }
 854
 855 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 856 {
 857     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 858     NSPasteboard *pboard = [sender draggingPasteboard];
 859     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 860
 861     wxWindow* wxpeer = GetWXPeer();
 862     if ( wxpeer == NULL )
 863         return NSDragOperationNone;
 864
 865     wxDropTarget* target = wxpeer->GetDropTarget();
 866     if ( target == NULL )
 867         return NSDragOperationNone;
 868
 869     wxDragResult result = wxDragNone;
 870     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 871     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 872
 873     if ( sourceDragMask & NSDragOperationLink )
 874         result = wxDragLink;
 875     else if ( sourceDragMask & NSDragOperationCopy )
 876         result = wxDragCopy;
 877     else if ( sourceDragMask & NSDragOperationMove )
 878         result = wxDragMove;
 879
 880     PasteboardRef pboardRef;
 881     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 882     target->SetCurrentDragPasteboard(pboardRef);
 883     result = target->OnEnter(pt.x, pt.y, result);
 884     CFRelease(pboardRef);
 885
 886     NSDragOperation nsresult = NSDragOperationNone;
 887     switch (result )
 888     {
 889         case wxDragLink:
 890             nsresult = NSDragOperationLink;
 891         case wxDragMove:
 892             nsresult = NSDragOperationMove;
 893         case wxDragCopy:
 894             nsresult = NSDragOperationCopy;
 895         default :
 896             break;
 897     }
 898     return nsresult;
 899 }
 900
 901 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 902 {
 903     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 904     NSPasteboard *pboard = [sender draggingPasteboard];
 905
 906     wxWindow* wxpeer = GetWXPeer();
 907     if ( wxpeer == NULL )
 908         return;
 909
 910     wxDropTarget* target = wxpeer->GetDropTarget();
 911     if ( target == NULL )
 912         return;
 913
 914     PasteboardRef pboardRef;
 915     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 916     target->SetCurrentDragPasteboard(pboardRef);
 917     target->OnLeave();
 918     CFRelease(pboardRef);
 919  }
 920
 921 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 922 {
 923     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 924     NSPasteboard *pboard = [sender draggingPasteboard];
 925     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 926
 927     wxWindow* wxpeer = GetWXPeer();
 928     if ( wxpeer == NULL )
 929         return NSDragOperationNone;
 930
 931     wxDropTarget* target = wxpeer->GetDropTarget();
 932     if ( target == NULL )
 933         return NSDragOperationNone;
 934
 935     wxDragResult result = wxDragNone;
 936     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 937     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 938
 939     if ( sourceDragMask & NSDragOperationLink )
 940         result = wxDragLink;
 941     else if ( sourceDragMask & NSDragOperationCopy )
 942         result = wxDragCopy;
 943     else if ( sourceDragMask & NSDragOperationMove )
 944         result = wxDragMove;
 945
 946     PasteboardRef pboardRef;
 947     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 948     target->SetCurrentDragPasteboard(pboardRef);
 949     result = target->OnDragOver(pt.x, pt.y, result);
 950     CFRelease(pboardRef);
 951
 952     NSDragOperation nsresult = NSDragOperationNone;
 953     switch (result )
 954     {
 955         case wxDragLink:
 956             nsresult = NSDragOperationLink;
 957         case wxDragMove:
 958             nsresult = NSDragOperationMove;
 959         case wxDragCopy:
 960             nsresult = NSDragOperationCopy;
 961         default :
 962             break;
 963     }
 964     return nsresult;
 965 }
 966
 967 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 968 {
 969     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 970
 971     NSPasteboard *pboard = [sender draggingPasteboard];
 972     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 973
 974     wxWindow* wxpeer = GetWXPeer();
 975     wxDropTarget* target = wxpeer->GetDropTarget();
 976     wxDragResult result = wxDragNone;
 977     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 978     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 979
 980     if ( sourceDragMask & NSDragOperationLink )
 981         result = wxDragLink;
 982     else if ( sourceDragMask & NSDragOperationCopy )
 983         result = wxDragCopy;
 984     else if ( sourceDragMask & NSDragOperationMove )
 985         result = wxDragMove;
 986
 987     PasteboardRef pboardRef;
 988     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 989     target->SetCurrentDragPasteboard(pboardRef);
 990
 991     if (target->OnDrop(pt.x, pt.y))
 992         result = target->OnData(pt.x, pt.y, result);
 993
 994     CFRelease(pboardRef);
 995
 996     return result != wxDragNone;
 997 }
 998
 999 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
1000 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1001 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
1002 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
1003 typedef BOOL (*wxOSX_ResetCursorRectsHandlerPtr)(NSView* self, SEL _cmd);
1004
1005 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1006 {
1007     if ( !DoHandleMouseEvent(event) )
1008     {
1009         // for plain NSView mouse events would propagate to parents otherwise
1010         if (!IsUserPane())
1011         {
1012             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1013             superimpl(slf, (SEL)_cmd, event);
1014         }
1015     }
1016 }
1017
1018 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1019 {
1020     if ( [event type] == NSKeyDown )
1021     {
1022         // there are key equivalents that are not command-combos and therefore not handled by cocoa automatically,
1023         // therefore we call the menubar directly here, exit if the menu is handling the shortcut
1024         if ( [[[NSApplication sharedApplication] mainMenu] performKeyEquivalent:event] )
1025             return;
1026
1027         m_lastKeyDownEvent = event;
1028     }
1029
1030     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
1031     {
1032         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1033         superimpl(slf, (SEL)_cmd, event);
1034     }
1035     m_lastKeyDownEvent = NULL;
1036 }
1037
1038 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
1039 {
1040     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
1041     {
1042         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1043         superimpl(slf, (SEL)_cmd, text);
1044     }
1045 }
1046
1047
1048 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
1049 {
1050     bool handled = false;
1051
1052     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
1053     SetupKeyEvent( wxevent, event );
1054
1055     // because performKeyEquivalent is going up the entire view hierarchy, we don't have to
1056     // walk up the ancestors ourselves but let cocoa do it
1057
1058     int command = m_wxPeer->GetAcceleratorTable()->GetCommand( wxevent );
1059     if (command != -1)
1060     {
1061         wxEvtHandler * const handler = m_wxPeer->GetEventHandler();
1062
1063         wxCommandEvent command_event( wxEVT_COMMAND_MENU_SELECTED, command );
1064         handled = handler->ProcessEvent( command_event );
1065
1066         if ( !handled )
1067         {
1068             // accelerators can also be used with buttons, try them too
1069             command_event.SetEventType(wxEVT_COMMAND_BUTTON_CLICKED);
1070             handled = handler->ProcessEvent( command_event );
1071         }
1072     }
1073
1074     if ( !handled )
1075     {
1076         wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1077         return superimpl(slf, (SEL)_cmd, event);
1078     }
1079     return YES;
1080 }
1081
1082 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
1083 {
1084     if ( IsUserPane() )
1085         return m_wxPeer->AcceptsFocus();
1086     else
1087     {
1088         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1089         return superimpl(slf, (SEL)_cmd);
1090     }
1091 }
1092
1093 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1094 {
1095     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1096     // get the current focus before running becomeFirstResponder
1097     NSView* otherView = FindFocus();
1098
1099     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1100     BOOL r = superimpl(slf, (SEL)_cmd);
1101     if ( r )
1102     {
1103         DoNotifyFocusEvent( true, otherWindow );
1104     }
1105
1106     return r;
1107 }
1108
1109 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1110 {
1111     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1112     BOOL r = superimpl(slf, (SEL)_cmd);
1113     // get the current focus after running resignFirstResponder
1114     // note that this value isn't reliable, it might return the same view that
1115     // is resigning
1116     NSView* otherView = FindFocus();
1117     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1118
1119     // It doesn't make sense to notify about the loss of focus if we're not
1120     // really losing it and the window which has just gained focus is the same
1121     // one as this window itself. Of course, this should never happen in the
1122     // first place but somehow it does in wxGrid code and without this check we
1123     // enter into an infinite recursion, see #12267.
1124     if ( otherWindow == this )
1125         return r;
1126
1127     // NSTextViews have an editor as true responder, therefore the might get the
1128     // resign notification if their editor takes over, don't trigger any event then
1129     if ( r && !m_hasEditor)
1130     {
1131         DoNotifyFocusEvent( false, otherWindow );
1132     }
1133     return r;
1134 }
1135
1136 void wxWidgetCocoaImpl::resetCursorRects(WXWidget slf, void *_cmd)
1137 {
1138     wxWindow* wxpeer = GetWXPeer();
1139     if ( wxpeer )
1140     {
1141         NSCursor *cursor = (NSCursor*)wxpeer->GetCursor().GetHCURSOR();
1142         if (cursor == NULL)
1143         {
1144             wxOSX_ResetCursorRectsHandlerPtr superimpl = (wxOSX_ResetCursorRectsHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1145             superimpl(slf, (SEL)_cmd);
1146         }
1147         else
1148         {
1149             [slf addCursorRect: [slf bounds]
1150                 cursor: cursor];
1151         }
1152     }
1153 }
1154
1155 bool wxWidgetCocoaImpl::isFlipped(WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1156 {
1157     return m_isFlipped;
1158 }
1159
1160
1161 #define OSX_DEBUG_DRAWING 0
1162
1163 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1164 {
1165     // preparing the update region
1166
1167     wxRegion updateRgn;
1168     const NSRect *rects;
1169     NSInteger count;
1170
1171     [slf getRectsBeingDrawn:&rects count:&count];
1172     for ( int i = 0 ; i < count ; ++i )
1173     {
1174         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1175     }
1176
1177     wxWindow* wxpeer = GetWXPeer();
1178
1179     if ( wxpeer->MacGetLeftBorderSize() != 0 || wxpeer->MacGetTopBorderSize() != 0 )
1180     {
1181         // as this update region is in native window locals we must adapt it to wx window local
1182         updateRgn.Offset( wxpeer->MacGetLeftBorderSize() , wxpeer->MacGetTopBorderSize() );
1183     }
1184
1185     if ( wxpeer->MacGetTopLevelWindow()->GetWindowStyle() & wxFRAME_SHAPED )
1186     {
1187         int xoffset = 0, yoffset = 0;
1188         wxRegion rgn = wxpeer->MacGetTopLevelWindow()->GetShape();
1189         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1190         rgn.Offset( xoffset, yoffset );
1191         updateRgn.Intersect(rgn);
1192     }
1193
1194     wxpeer->GetUpdateRegion() = updateRgn;
1195
1196     // setting up the drawing context
1197
1198     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1199     CGContextSaveGState( context );
1200
1201 #if OSX_DEBUG_DRAWING
1202     CGContextBeginPath( context );
1203     CGContextMoveToPoint(context, 0, 0);
1204     NSRect bounds = [slf bounds];
1205     CGContextAddLineToPoint(context, 10, 0);
1206     CGContextMoveToPoint(context, 0, 0);
1207     CGContextAddLineToPoint(context, 0, 10);
1208     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1209     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1210     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1211     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1212     CGContextClosePath( context );
1213     CGContextStrokePath(context);
1214 #endif
1215
1216     if ( !m_isFlipped )
1217     {
1218         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1219         CGContextScaleCTM( context, 1, -1 );
1220     }
1221
1222     wxpeer->MacSetCGContextRef( context );
1223
1224     bool handled = wxpeer->MacDoRedraw( 0 );
1225     CGContextRestoreGState( context );
1226
1227     CGContextSaveGState( context );
1228     if ( !handled )
1229     {
1230         // call super
1231         SEL _cmd = @selector(drawRect:);
1232         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1233         superimpl(slf, _cmd, *(NSRect*)rect);
1234         CGContextRestoreGState( context );
1235         CGContextSaveGState( context );
1236     }
1237     // as we called restore above, we have to flip again if necessary
1238     if ( !m_isFlipped )
1239     {
1240         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1241         CGContextScaleCTM( context, 1, -1 );
1242     }
1243     wxpeer->MacPaintChildrenBorders();
1244     wxpeer->MacSetCGContextRef( NULL );
1245     CGContextRestoreGState( context );
1246 }
1247
1248 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1249 {
1250     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1251     if ( wxpeer )
1252         wxpeer->OSXHandleClicked(0);
1253 }
1254
1255 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1256 {
1257 }
1258
1259 void wxWidgetCocoaImpl::controlTextDidChange()
1260 {
1261     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1262     if ( wxpeer )
1263     {
1264         // since native rtti doesn't have to be enabled and wx' rtti is not aware of the mixin wxTextEntry, workaround is needed
1265         wxTextCtrl *tc = wxDynamicCast( wxpeer , wxTextCtrl );
1266         wxComboBox *cb = wxDynamicCast( wxpeer , wxComboBox );
1267         if ( tc )
1268             tc->SendTextUpdatedEventIfAllowed();
1269         else if ( cb )
1270             cb->SendTextUpdatedEventIfAllowed();
1271         else
1272         {
1273             wxFAIL_MSG("Unexpected class for controlTextDidChange event");
1274         }
1275     }
1276 }
1277
1278 //
1279
1280 #if OBJC_API_VERSION >= 2
1281
1282 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1283     class_addMethod(c, s, i, t );
1284
1285 #else
1286
1287 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1288     { s, (char*) t, i },
1289
1290 #endif
1291
1292 void wxOSXCocoaClassAddWXMethods(Class c)
1293 {
1294
1295 #if OBJC_API_VERSION < 2
1296     static objc_method wxmethods[] =
1297     {
1298 #endif
1299
1300     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1301     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1302     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1303
1304     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1305     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1306     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1307
1308     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1309
1310     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1311     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1312     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1313
1314     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1315
1316     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1317     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1318     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1319
1320     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1321     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1322     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1323
1324     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1325
1326     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1327
1328     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1329     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1330     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1331     wxOSX_CLASS_ADD_METHOD(c, @selector(resetCursorRects), (IMP) wxOSX_resetCursorRects, "v@:" )
1332
1333     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1334     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1335
1336     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1337     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1338
1339 #if wxUSE_DRAG_AND_DROP
1340     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1341     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1342     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1343     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1344 #endif
1345
1346 #if OBJC_API_VERSION < 2
1347     } ;
1348     static int method_count = WXSIZEOF( wxmethods );
1349     static objc_method_list *wxmethodlist = NULL;
1350     if ( wxmethodlist == NULL )
1351     {
1352         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1353         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1354         wxmethodlist->method_count = method_count;
1355         wxmethodlist->obsolete = 0;
1356     }
1357     class_addMethods( c, wxmethodlist );
1358 #endif
1359 }
1360
1361 //
1362 // C++ implementation class
1363 //
1364
1365 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1366
1367 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl, bool isUserPane ) :
1368     wxWidgetImpl( peer, isRootControl, isUserPane )
1369 {
1370     Init();
1371     m_osxView = w;
1372
1373     // check if the user wants to create the control initially hidden
1374     if ( !peer->IsShown() )
1375         SetVisibility(false);
1376
1377     // gc aware handling
1378     if ( m_osxView )
1379         CFRetain(m_osxView);
1380     [m_osxView release];
1381 }
1382
1383 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1384 {
1385     Init();
1386 }
1387
1388 void wxWidgetCocoaImpl::Init()
1389 {
1390     m_osxView = NULL;
1391     m_isFlipped = true;
1392     m_lastKeyDownEvent = NULL;
1393     m_hasEditor = false;
1394 }
1395
1396 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1397 {
1398     RemoveAssociations( this );
1399
1400     if ( !IsRootControl() )
1401     {
1402         NSView *sv = [m_osxView superview];
1403         if ( sv != nil )
1404             [m_osxView removeFromSuperview];
1405     }
1406     // gc aware handling
1407     if ( m_osxView )
1408         CFRelease(m_osxView);
1409 }
1410
1411 bool wxWidgetCocoaImpl::IsVisible() const
1412 {
1413     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1414 }
1415
1416 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1417 {
1418     [m_osxView setHidden:(visible ? NO:YES)];
1419 }
1420
1421 // ----------------------------------------------------------------------------
1422 // window animation stuff
1423 // ----------------------------------------------------------------------------
1424
1425 // define a delegate used to refresh the window during animation
1426 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1427 {
1428     wxWindow *m_win;
1429     bool m_isDone;
1430 }
1431
1432 - (id)init:(wxWindow *)win;
1433
1434 - (bool)isDone;
1435
1436 // NSAnimationDelegate methods
1437 - (void)animationDidEnd:(NSAnimation*)animation;
1438 - (void)animation:(NSAnimation*)animation
1439         didReachProgressMark:(NSAnimationProgress)progress;
1440 @end
1441
1442 @implementation wxNSAnimationDelegate
1443
1444 - (id)init:(wxWindow *)win
1445 {
1446     [super init];
1447
1448     m_win = win;
1449     m_isDone = false;
1450
1451     return self;
1452 }
1453
1454 - (bool)isDone
1455 {
1456     return m_isDone;
1457 }
1458
1459 - (void)animation:(NSAnimation*)animation
1460         didReachProgressMark:(NSAnimationProgress)progress
1461 {
1462     wxUnusedVar(animation);
1463     wxUnusedVar(progress);
1464
1465     m_win->SendSizeEvent();
1466 }
1467
1468 - (void)animationDidEnd:(NSAnimation*)animation
1469 {
1470     wxUnusedVar(animation);
1471     m_isDone = true;
1472 }
1473
1474 @end
1475
1476 /* static */
1477 bool
1478 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1479                                               bool show,
1480                                               wxShowEffect effect,
1481                                               unsigned timeout)
1482 {
1483     // create the dictionary describing the animation to perform on this view
1484     NSObject * const
1485         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1486     NSMutableDictionary * const
1487         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1488     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1489
1490     // determine the start and end rectangles assuming we're hiding the window
1491     const wxRect rectOrig = win->GetRect();
1492     wxRect rectStart,
1493            rectEnd;
1494     rectStart =
1495     rectEnd = rectOrig;
1496
1497     if ( show )
1498     {
1499         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1500                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1501             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1502         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1503                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1504             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1505         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1506                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1507             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1508         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1509                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1510             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1511     }
1512
1513     switch ( effect )
1514     {
1515         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1516         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1517             rectEnd.width = 0;
1518             break;
1519
1520         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1521         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1522             rectEnd.x = rectStart.GetRight();
1523             rectEnd.width = 0;
1524             break;
1525
1526         case wxSHOW_EFFECT_ROLL_TO_TOP:
1527         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1528             rectEnd.height = 0;
1529             break;
1530
1531         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1532         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1533             rectEnd.y = rectStart.GetBottom();
1534             rectEnd.height = 0;
1535             break;
1536
1537         case wxSHOW_EFFECT_EXPAND:
1538             rectEnd.x = rectStart.x + rectStart.width / 2;
1539             rectEnd.y = rectStart.y + rectStart.height / 2;
1540             rectEnd.width =
1541             rectEnd.height = 0;
1542             break;
1543
1544         case wxSHOW_EFFECT_BLEND:
1545             [dict setObject:(show ? NSViewAnimationFadeInEffect
1546                                   : NSViewAnimationFadeOutEffect)
1547                   forKey:NSViewAnimationEffectKey];
1548             break;
1549
1550         case wxSHOW_EFFECT_NONE:
1551         case wxSHOW_EFFECT_MAX:
1552             wxFAIL_MSG( "unexpected animation effect" );
1553             return false;
1554
1555         default:
1556             wxFAIL_MSG( "unknown animation effect" );
1557             return false;
1558     };
1559
1560     if ( show )
1561     {
1562         // we need to restore it to the original rectangle instead of making it
1563         // disappear
1564         wxSwap(rectStart, rectEnd);
1565
1566         // and as the window is currently hidden, we need to show it for the
1567         // animation to be visible at all (but don't restore it at its full
1568         // rectangle as it shouldn't appear immediately)
1569         win->SetSize(rectStart);
1570         win->Show();
1571     }
1572
1573     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1574                                     ? [(NSView *)viewOrWin superview]
1575                                     : nil;
1576     const NSRect rStart = wxToNSRect(parentView, rectStart);
1577     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1578
1579     [dict setObject:[NSValue valueWithRect:rStart]
1580           forKey:NSViewAnimationStartFrameKey];
1581     [dict setObject:[NSValue valueWithRect:rEnd]
1582           forKey:NSViewAnimationEndFrameKey];
1583
1584     // create an animation using the values in the above dictionary
1585     NSViewAnimation * const
1586         anim = [[NSViewAnimation alloc]
1587                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1588
1589     if ( !timeout )
1590     {
1591         // what is a good default duration? Windows uses 200ms, Web frameworks
1592         // use anything from 250ms to 1s... choose something in the middle
1593         timeout = 500;
1594     }
1595
1596     [anim setDuration:timeout/1000.];   // duration is in seconds here
1597
1598     // if the window being animated changes its layout depending on its size
1599     // (which is almost always the case) we need to redo it during animation
1600     //
1601     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1602     // controls in wxInfoBar visibly jump around)
1603     const int NUM_LAYOUTS = 20;
1604     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1605         [anim addProgressMark:f];
1606
1607     wxNSAnimationDelegate * const
1608         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1609     [anim setDelegate:animDelegate];
1610     [anim startAnimation];
1611
1612     // Cocoa is capable of doing animation asynchronously or even from separate
1613     // thread but wx API doesn't provide any way to be notified about the
1614     // animation end and without this we really must ensure that the window has
1615     // the expected (i.e. the same as if a simple Show() had been used) size
1616     // when we return, so block here until the animation finishes
1617     //
1618     // notice that because the default animation mode is NSAnimationBlocking,
1619     // no user input events ought to be processed from here
1620     {
1621         wxEventLoopGuarantor ensureEventLoopExistence;
1622         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1623         while ( ![animDelegate isDone] )
1624             loop->Dispatch();
1625     }
1626
1627     if ( !show )
1628     {
1629         // NSViewAnimation is smart enough to hide the NSView being animated at
1630         // the end but we also must ensure that it's hidden for wx too
1631         win->Hide();
1632
1633         // and we must also restore its size because it isn't expected to
1634         // change just because the window was hidden
1635         win->SetSize(rectOrig);
1636     }
1637     else
1638     {
1639         // refresh it once again after the end to ensure that everything is in
1640         // place
1641         win->SendSizeEvent();
1642     }
1643
1644     [anim setDelegate:nil];
1645     [animDelegate release];
1646     [anim release];
1647
1648     return true;
1649 }
1650
1651 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1652                                        wxShowEffect effect,
1653                                        unsigned timeout)
1654 {
1655     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1656 }
1657
1658 void wxWidgetCocoaImpl::Raise()
1659 {
1660     // Not implemented
1661 }
1662
1663 void wxWidgetCocoaImpl::Lower()
1664 {
1665     // Not implemented
1666 }
1667
1668 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
1669 {
1670 #if 1
1671     SetNeedsDisplay() ;
1672 #else
1673     // We should do something like this, but it wasn't working in 10.4.
1674     if (GetNeedsDisplay() )
1675     {
1676         SetNeedsDisplay() ;
1677     }
1678     NSRect r = wxToNSRect( [m_osxView superview], *rect );
1679     NSSize offset = NSMakeSize((float)dx, (float)dy);
1680     [m_osxView scrollRect:r by:offset];
1681 #endif
1682 }
1683
1684 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
1685 {
1686     wxWindowMac* parent = GetWXPeer()->GetParent();
1687     // under Cocoa we might have a contentView in the wxParent to which we have to
1688     // adjust the coordinates
1689     if (parent && [m_osxView superview] != parent->GetHandle() )
1690     {
1691         int cx = 0,cy = 0,cw = 0,ch = 0;
1692         if ( parent->GetPeer() )
1693         {
1694             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1695             x -= cx;
1696             y -= cy;
1697         }
1698     }
1699     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
1700     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
1701     [m_osxView setFrame:r];
1702     [[m_osxView superview] setNeedsDisplayInRect:r];
1703
1704     wxNSView* wxview = (wxNSView*)m_osxView;
1705 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
1706     if ([wxview respondsToSelector:@selector(updateTrackingArea)] )
1707         [wxview updateTrackingArea];
1708 #else
1709     if ([m_osxView respondsToSelector:@selector(trackingTag)] )
1710     {
1711         if ( [wxview trackingTag] )
1712             [wxview removeTrackingRect: [wxview trackingTag]];
1713
1714         [wxview setTrackingTag: [wxview addTrackingRect: [m_osxView bounds] owner: wxview userData: nil assumeInside: NO]];
1715     }
1716 #endif
1717 }
1718
1719 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
1720 {
1721     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
1722     x = r.GetLeft();
1723     y = r.GetTop();
1724
1725     // under Cocoa we might have a contentView in the wxParent to which we have to
1726     // adjust the coordinates
1727     wxWindowMac* parent = GetWXPeer()->GetParent();
1728     if (parent && [m_osxView superview] != parent->GetHandle() )
1729     {
1730         int cx = 0,cy = 0,cw = 0,ch = 0;
1731         if ( parent->GetPeer() )
1732         {
1733             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1734             x += cx;
1735             y += cy;
1736         }
1737     }
1738 }
1739
1740 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
1741 {
1742     NSRect rect = [m_osxView frame];
1743     width = (int)rect.size.width;
1744     height = (int)rect.size.height;
1745 }
1746
1747 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
1748 {
1749     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
1750     {
1751         NSView* cv = [m_osxView contentView];
1752
1753         NSRect bounds = [m_osxView bounds];
1754         NSRect rect = [cv frame];
1755
1756         int y = (int)rect.origin.y;
1757         int x = (int)rect.origin.x;
1758         if ( ![ m_osxView isFlipped ] )
1759             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
1760         left = x;
1761         top = y;
1762         width = (int)rect.size.width;
1763         height = (int)rect.size.height;
1764     }
1765     else
1766     {
1767         left = top = 0;
1768         GetSize( width, height );
1769     }
1770 }
1771
1772 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
1773 {
1774     if ( where )
1775         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
1776     else
1777         [m_osxView setNeedsDisplay:YES];
1778 }
1779
1780 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
1781 {
1782     return [m_osxView needsDisplay];
1783 }
1784
1785 bool wxWidgetCocoaImpl::CanFocus() const
1786 {
1787     return [m_osxView canBecomeKeyView] == YES;
1788 }
1789
1790 bool wxWidgetCocoaImpl::HasFocus() const
1791 {
1792     return ( FindFocus() == m_osxView );
1793 }
1794
1795 bool wxWidgetCocoaImpl::SetFocus()
1796 {
1797     if ( !CanFocus() )
1798         return false;
1799
1800     [[m_osxView window] makeKeyAndOrderFront:nil] ;
1801     [[m_osxView window] makeFirstResponder: m_osxView] ;
1802     return true;
1803 }
1804
1805
1806 void wxWidgetCocoaImpl::RemoveFromParent()
1807 {
1808     [m_osxView removeFromSuperview];
1809 }
1810
1811 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
1812 {
1813     NSView* container = parent->GetWXWidget() ;
1814     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
1815     [container addSubview:m_osxView];
1816 }
1817
1818 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
1819 {
1820     NSView* targetView = m_osxView;
1821     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1822         targetView = [(NSScrollView*) m_osxView documentView];
1823
1824     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
1825     {
1826         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
1827                                                                 green:(CGFloat) (col.Green() / 255.0)
1828                                                                  blue:(CGFloat) (col.Blue() / 255.0)
1829                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
1830     }
1831 }
1832
1833 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
1834 {
1835     BOOL opaque = ( style == wxBG_STYLE_PAINT );
1836
1837     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
1838     {
1839         [m_osxView setOpaque: opaque];
1840     }
1841
1842     return true ;
1843 }
1844
1845 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
1846 {
1847     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
1848     {
1849         wxCFStringRef cf( title , encoding );
1850         [m_osxView setTitle:cf.AsNSString()];
1851     }
1852     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
1853     {
1854         wxCFStringRef cf( title , encoding );
1855         [m_osxView setStringValue:cf.AsNSString()];
1856     }
1857 }
1858
1859
1860 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
1861 {
1862     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
1863     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
1864     *pt = wxFromNSPoint( to->GetWXWidget(), p );
1865 }
1866
1867 wxInt32 wxWidgetCocoaImpl::GetValue() const
1868 {
1869     return [(NSControl*)m_osxView intValue];
1870 }
1871
1872 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
1873 {
1874     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
1875     {
1876         [m_osxView setIntValue:v];
1877     }
1878     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
1879     {
1880         [m_osxView setFloatValue:(double)v];
1881     }
1882     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
1883     {
1884         [m_osxView setDoubleValue:(double)v];
1885     }
1886 }
1887
1888 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
1889 {
1890     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
1891     {
1892         [m_osxView setMinValue:(double)v];
1893     }
1894 }
1895
1896 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
1897 {
1898     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
1899     {
1900         [m_osxView setMaxValue:(double)v];
1901     }
1902 }
1903
1904 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
1905 {
1906     if (  [m_osxView respondsToSelector:@selector(minValue)] )
1907     {
1908         return (int)[m_osxView minValue];
1909     }
1910     return 0;
1911 }
1912
1913 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
1914 {
1915     if (  [m_osxView respondsToSelector:@selector(maxValue)] )
1916     {
1917         return (int)[m_osxView maxValue];
1918     }
1919     return 0;
1920 }
1921
1922 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
1923 {
1924     wxBitmap bmp;
1925
1926     // TODO: how to create a wxBitmap from NSImage?
1927 #if 0
1928     if ( [m_osxView respondsToSelector:@selector(image:)] )
1929         bmp = [m_osxView image];
1930 #endif
1931
1932     return bmp;
1933 }
1934
1935 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
1936 {
1937     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
1938     {
1939         [m_osxView setImage:bitmap.GetNSImage()];
1940         [m_osxView setNeedsDisplay:YES];
1941     }
1942 }
1943
1944 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
1945 {
1946     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
1947     {
1948         NSCellImagePosition pos;
1949         switch ( dir )
1950         {
1951             case wxLEFT:
1952                 pos = NSImageLeft;
1953                 break;
1954
1955             case wxRIGHT:
1956                 pos = NSImageRight;
1957                 break;
1958
1959             case wxTOP:
1960                 pos = NSImageAbove;
1961                 break;
1962
1963             case wxBOTTOM:
1964                 pos = NSImageBelow;
1965                 break;
1966
1967             default:
1968                 wxFAIL_MSG( "invalid image position" );
1969                 pos = NSNoImage;
1970         }
1971
1972         [m_osxView setImagePosition:pos];
1973     }
1974 }
1975
1976 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
1977 {
1978     // implementation in subclass
1979 }
1980
1981 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
1982 {
1983     r->x = r->y = r->width = r->height = 0;
1984
1985     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
1986     {
1987         NSRect former = [m_osxView frame];
1988         [m_osxView sizeToFit];
1989         NSRect best = [m_osxView frame];
1990         [m_osxView setFrame:former];
1991         r->width = (int)best.size.width;
1992         r->height = (int)best.size.height;
1993     }
1994 }
1995
1996 bool wxWidgetCocoaImpl::IsEnabled() const
1997 {
1998     NSView* targetView = m_osxView;
1999     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2000         targetView = [(NSScrollView*) m_osxView documentView];
2001
2002     if ( [targetView respondsToSelector:@selector(isEnabled) ] )
2003         return [targetView isEnabled];
2004     return true;
2005 }
2006
2007 void wxWidgetCocoaImpl::Enable( bool enable )
2008 {
2009     NSView* targetView = m_osxView;
2010     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2011         targetView = [(NSScrollView*) m_osxView documentView];
2012
2013     if ( [targetView respondsToSelector:@selector(setEnabled:) ] )
2014         [targetView setEnabled:enable];
2015 }
2016
2017 void wxWidgetCocoaImpl::PulseGauge()
2018 {
2019 }
2020
2021 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
2022 {
2023 }
2024
2025 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
2026 {
2027     NSControlSize size = NSRegularControlSize;
2028
2029     switch ( variant )
2030     {
2031         case wxWINDOW_VARIANT_NORMAL :
2032             size = NSRegularControlSize;
2033             break ;
2034
2035         case wxWINDOW_VARIANT_SMALL :
2036             size = NSSmallControlSize;
2037             break ;
2038
2039         case wxWINDOW_VARIANT_MINI :
2040             size = NSMiniControlSize;
2041             break ;
2042
2043         case wxWINDOW_VARIANT_LARGE :
2044             size = NSRegularControlSize;
2045             break ;
2046
2047         default:
2048             wxFAIL_MSG(wxT("unexpected window variant"));
2049             break ;
2050     }
2051     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
2052         [m_osxView setControlSize:size];
2053     else if ([m_osxView respondsToSelector:@selector(cell)])
2054     {
2055         id cell = [(id)m_osxView cell];
2056         if ([cell respondsToSelector:@selector(setControlSize:)])
2057             [cell setControlSize:size];
2058     }
2059 }
2060
2061 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
2062 {
2063     if ([m_osxView respondsToSelector:@selector(setFont:)])
2064         [m_osxView setFont: font.OSXGetNSFont()];
2065     if ([m_osxView respondsToSelector:@selector(setTextColor:)])
2066         [m_osxView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2067                                                                  green:(CGFloat) (col.Green() / 255.0)
2068                                                                   blue:(CGFloat) (col.Blue() / 255.0)
2069                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
2070 }
2071
2072 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
2073 {
2074     if (tooltip)
2075     {
2076         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
2077         [m_osxView setToolTip: cf.AsNSString()];
2078     }
2079     else
2080         [m_osxView setToolTip: nil];
2081
2082 }
2083
2084 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
2085 {
2086     WXWidget c =  control ? control : (WXWidget) m_osxView;
2087     wxWidgetImpl::Associate( c, this ) ;
2088     if ([c respondsToSelector:@selector(setAction:)])
2089     {
2090         [c setTarget: c];
2091         [c setAction: @selector(controlAction:)];
2092         if ([c respondsToSelector:@selector(setDoubleAction:)])
2093         {
2094             [c setDoubleAction: @selector(controlDoubleAction:)];
2095         }
2096
2097     }
2098 }
2099
2100 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
2101 {
2102     wxKeyEvent wxevent(wxEVT_CHAR);
2103     SetupKeyEvent( wxevent, event, text );
2104
2105     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
2106 }
2107
2108 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
2109 {
2110     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
2111     SetupKeyEvent( wxevent, event );
2112     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
2113
2114     // this will fire higher level events, like insertText, to help
2115     // us handle EVT_CHAR, etc.
2116
2117     if ( !result )
2118     {
2119         if ( IsUserPane() && [event type] == NSKeyDown)
2120         {
2121             if ( wxevent.GetKeyCode() < WXK_SPACE || wxevent.GetKeyCode() == WXK_DELETE || wxevent.GetKeyCode() >= WXK_START )
2122             {
2123                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
2124                 wxKeyEvent wxevent2(wxevent) ;
2125                 wxevent2.SetEventType(wxEVT_CHAR);
2126                 result = GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2127             }
2128             else
2129             {
2130                 if ( !wxevent.CmdDown() )
2131                 {
2132                     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2133                         [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
2134                     else
2135                         [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
2136                     result = true;
2137                 }
2138             }
2139         }
2140     }
2141
2142     return result;
2143 }
2144
2145 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
2146 {
2147     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2148     SetupMouseEvent(wxevent , event) ;
2149
2150     return GetWXPeer()->HandleWindowEvent(wxevent);
2151 }
2152
2153 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2154 {
2155     wxWindow* thisWindow = GetWXPeer();
2156     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2157     {
2158         thisWindow->MacInvalidateBorders();
2159     }
2160
2161     if ( receivedFocus )
2162     {
2163         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2164         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2165         thisWindow->HandleWindowEvent(eventFocus);
2166
2167 #if wxUSE_CARET
2168         if ( thisWindow->GetCaret() )
2169             thisWindow->GetCaret()->OnSetFocus();
2170 #endif
2171
2172         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2173         event.SetEventObject(thisWindow);
2174         if (otherWindow)
2175             event.SetWindow(otherWindow->GetWXPeer());
2176         thisWindow->HandleWindowEvent(event) ;
2177     }
2178     else // !receivedFocuss
2179     {
2180 #if wxUSE_CARET
2181         if ( thisWindow->GetCaret() )
2182             thisWindow->GetCaret()->OnKillFocus();
2183 #endif
2184
2185         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2186
2187         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2188         event.SetEventObject(thisWindow);
2189         if (otherWindow)
2190             event.SetWindow(otherWindow->GetWXPeer());
2191         thisWindow->HandleWindowEvent(event) ;
2192     }
2193 }
2194
2195 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2196 {
2197     if ( !wxIsBusy() )
2198     {
2199         NSPoint location = [NSEvent mouseLocation];
2200         location = [[m_osxView window] convertScreenToBase:location];
2201         NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2202
2203         if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2204         {
2205             [(NSCursor*)cursor.GetHCURSOR() set];
2206         }
2207     }
2208     [[m_osxView window] invalidateCursorRectsForView:m_osxView];
2209 }
2210
2211 void wxWidgetCocoaImpl::CaptureMouse()
2212 {
2213     [[m_osxView window] disableCursorRects];
2214 }
2215
2216 void wxWidgetCocoaImpl::ReleaseMouse()
2217 {
2218     [[m_osxView window] enableCursorRects];
2219 }
2220
2221 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2222 {
2223     m_isFlipped = flipped;
2224 }
2225
2226 //
2227 // Factory methods
2228 //
2229
2230 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2231     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2232     long WXUNUSED(style), long WXUNUSED(extraStyle))
2233 {
2234     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2235     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2236
2237     // temporary hook for dnd
2238     [v registerForDraggedTypes:[NSArray arrayWithObjects:
2239         NSStringPboardType, NSFilenamesPboardType, NSTIFFPboardType, NSPICTPboardType, NSPDFPboardType, nil]];
2240
2241     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v, false, true );
2242     return c;
2243 }
2244
2245 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2246 {
2247     NSWindow* tlw = now->GetWXWindow();
2248
2249     wxWidgetCocoaImpl* c = NULL;
2250     if ( now->IsNativeWindowWrapper() )
2251     {
2252         NSView* cv = [tlw contentView];
2253         c = new wxWidgetCocoaImpl( now, cv, true );
2254         // increase ref count, because the impl destructor will decrement it again
2255         CFRetain(cv);
2256         if ( !now->IsShown() )
2257             [cv setHidden:NO];
2258
2259     }
2260     else
2261     {
2262         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2263         c = new wxWidgetCocoaImpl( now, v, true );
2264         c->InstallEventHandler();
2265         [tlw setContentView:v];
2266     }
2267     return c;
2268 }