distrib/msw/zipdist.bat

   1 @echo off
   2 rem Zip up an external, generic + Windows distribution of wxWindows 2.0
   3 set src=%wxwin
   4 set dest=%src\deliver
   5 set wise=0
   6
   7 Rem Set this to the required version
   8 set version=2_1_13
   9
  10 if "%src" == "" goto usage
  11 if "%dest" == "" goto usage
  12 if "%1" == "-help" goto usage
  13 if "%1" == "--help" goto usage
  14 if "%1" == "/?" goto usage
  15 if "%1" == "wiseonly" goto dounzip
  16 if "%1" == "wise" set wise=1
  17 echo About to archive an external wxWindows distribution:
  18 echo   From   %src
  19 echo   To     %dest
  20 if "%wise" == "1" echo with WISE setup creation.
  21 echo CTRL-C if this is not correct.
  22 pause
  23
  24 erase %dest\wx*.zip
  25 erase %dest\ogl3.zip
  26 erase %dest\tex2rtf2.zip
  27 erase %dest\jpeg.zip
  28 erase %dest\tiff.zip
  29
  30 if direxist %dest\wx deltree /Y %dest\wx
  31
  32 cd %src
  33 echo Zipping...
  34
  35 zip32 -@ %dest\wx%version%_gen.zip < %src\distrib\msw\generic.rsp
  36 zip32 -@ -u %dest\wx%version%_gen.zip < %src\distrib\msw\makefile.rsp
  37 zip32 -@ %dest\wx%version%_msw.zip < %src\distrib\msw\msw.rsp
  38 zip32 -@ -u %dest\wx%version%_msw.zip < %src\distrib\msw\makefile.rsp
  39 zip32 -@ %dest\wx%version%_gtk.zip < %src\distrib\msw\gtk.rsp
  40 zip32 -@ -u %dest\wx%version%_gtk.zip < %src\distrib\msw\makefile.rsp
  41 zip32 -@ %dest\wx%version%_stubs.zip < %src\distrib\msw\stubs.rsp
  42 zip32 -@ %dest\wx%version%_mot.zip < %src\distrib\msw\motif.rsp
  43 zip32 -@ -u %dest\wx%version%_mot.zip < %src\distrib\msw\makefile.rsp
  44 Rem (Obsolete) zip32 -@ %dest\wx%version%_user.zip < %src\distrib\msw\user.rsp
  45
  46 zip32 -@ %dest\wx%version%_doc.zip < %src\distrib\msw\docsrc.rsp
  47 zip32 -@ %dest\wx%version%_hlp.zip < %src\distrib\msw\wx_hlp.rsp
  48 zip32 -@ %dest\wx%version%_htm.zip < %src\distrib\msw\wx_html.rsp
  49 zip32 -@ %dest\wx%version%_pdf.zip < %src\distrib\msw\wx_pdf.rsp
  50 zip32 -@ %dest\wx%version%_wrd.zip < %src\distrib\msw\wx_word.rsp
  51
  52 rem VC++ project files
  53 zip32 -@ %dest\wx%version%_vc.zip < %src\distrib\msw\vc.rsp
  54
  55 rem BC++ project files
  56 zip32 -@ %dest\wx%version%_bc.zip < %src\distrib\msw\bc.rsp
  57
  58 rem CodeWarrior project files
  59 zip32 -@ %dest\wx%version%_cw.zip < %src\distrib\msw\cw.rsp
  60
  61 rem OGL 3
  62 zip32 -@ %dest\ogl3.zip < %src\distrib\msw\ogl.rsp
  63
  64 rem GLCanvas: obsolete, now in main library
  65 rem zip32 -@ %dest\glcanvas.zip < %src\distrib\msw\glcanvas.rsp
  66
  67 rem Tex2RTF
  68 zip32 -@ %dest\tex2rtf2.zip < %src\distrib\msw\tex2rtf.rsp
  69
  70 rem wxTreeLayout
  71 zip32 -@ %dest\treedraw.zip < %src\distrib\msw\wxtree.rsp
  72
  73 rem JPEG source
  74 zip32 -@ %dest\jpeg.zip < %src\distrib\msw\jpeg.rsp
  75
  76 rem TIFF source
  77 zip32 -@ %dest\tiff.zip < %src\distrib\msw\tiff.rsp
  78
  79 copy %src\docs\changes.txt %dest
  80 copy %src\docs\msw\install.txt %dest\install_msw.txt
  81 copy %src\docs\motif\install.txt %dest\install_motif.txt
  82 copy %src\docs\gtk\install.txt %dest\install_gtk.txt
  83 copy %src\docs\readme.txt %dest
  84 copy %src\docs\release.txt %dest
  85 copy %src\docs\motif\makewxmotif %dest
  86 copy %src\docs\gtk\makewxgtk %dest
  87
  88 Rem Skip WISE setup if wise is 0.
  89 if "%wise" == "0" goto end
  90
  91 :dounzip
  92
  93 cd %dest
  94
  95 rem Unzip the Windows files into 'wx'
  96 mkdir %dest\wx
  97
  98 Rem After this change of directory, we're in the
  99 Rem temporary 'wx' directory and not acting on
 100 Rem the source wxWindows directory.
 101 cd %dest\wx
 102 unzip32 -o ..\wx%version%_msw.zip
 103 unzip32 -o ..\wx%version%_gen.zip
 104 unzip32 -o ..\wx%version%_vc.zip
 105 unzip32 -o ..\wx%version%_bc.zip
 106 unzip32 -o ..\wx%version%_hlp.zip
 107 Rem Need Word file, for Remstar DB classes
 108 unzip32 -o ..\wx%version%_wrd.zip
 109 unzip32 -o ..\treedraw.zip
 110 unzip32 -o ..\ogl3.zip
 111 unzip32 -o ..\jpeg.zip
 112 unzip32 -o ..\tiff.zip
 113 unzip32 -o ..\tex2rtf2.zip
 114
 115 rem Now delete a few files that are unnecessary
 116 attrib -R *
 117 erase /Y BuildCVS.txt *.in *.spec *.guess *.sub mkinstalldirs modules install-sh *.sh descrip.mms
 118 erase /Y setup.h.in setup.h_vms
 119 erase /SY Makefile.in
 120 rem erase /Y docs\pdf\ogl.pdf
 121 rem deltree /Y docs\html\ogl
 122
 123 rem Now copy some binary files to 'bin'
 124 if not isdir bin mkdir bin
 125 copy %src\bin\dialoged.exe bin
 126 copy %src\docs\winhelp\dialoged.hlp %src\docs\winhelp\dialoged.cnt bin
 127
 128 rem Time to regenerate the WISE install script, wxwin2.wse.
 129 rem NB: if you've changed wxwin2.wse using WISE, call splitwise.exe
 130 rem from within distrib\msw, to split off wisetop.txt and wisebott.txt.
 131 echo Calling 'makewise' to generate wxwin2.wse...
 132 call %WXWIN\distrib\msw\makewise.bat
 133
 134 erase /Y %dest\setup.*
 135
 136 rem Now invoke WISE install on the new wxwin2.wse
 137 set wisecmd="c:\Program Files\wise\wise32.exe" /C %WXWIN\distrib\msw\wxwin2.wse
 138 echo Invoking %wisecmd...
 139 start /w %wisecmd
 140 Rem ren %WXWIN\deliver\setup.EXE %WXWIN\deliver\setup_%version%.exe
 141
 142 cd %dest
 143
 144 Rem tidy up capitalisation of filenames
 145 ren setup.EXE s
 146 ren s setup.exe
 147
 148 ren setup.w02 s
 149 ren s setup.w02
 150
 151 ren setup.w03 s
 152 ren s setup.w03
 153
 154 ren setup.w04 s
 155 ren s setup.w04
 156
 157 ren setup.w05 s
 158 ren s setup.w05
 159
 160 ren setup.w06 s
 161 ren s setup.w06
 162
 163 ren setup.w07 s
 164 ren s setup.w07
 165
 166 rem Put all the setup files into a single zip archive.
 167 zip32 wx%version%_setup.zip readme.txt setup.*
 168
 169 echo wxWindows archived.
 170
 171 goto end
 172
 173 :usage
 174 echo DOS wxWindows distribution. Zips up all GTK/Motif/MSW/doc files,
 175 echo and optionally makes a deliver\wx directory and a setup.exe
 176 echo if you specify 'wise' (skipping the zipping if you use 'wiseonly').
 177 echo.
 178 echo Usage: zipdist [wise | wiseonly]
 179
 180 :end