src/cocoa/cursor.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/cocoa/cursor.mm
   3 // Purpose:     wxCursor class for wxCocoa
   4 // Author:      Ryan Norton
   5 //              David Elliott
   6 // Modified by:
   7 // Created:     2004-10-05
   8 // RCS-ID:      $Id$
   9 // Copyright:   (c) Ryan Norton
  10 //              2007, Software 2000 Ltd.
  11 // Licence:     wxWidgets licence
  12 /////////////////////////////////////////////////////////////////////////////
  13
  14 #include "wx/wxprec.h"
  15
  16 #include "wx/cursor.h"
  17
  18 #ifndef WX_PRECOMP
  19     #include "wx/icon.h"
  20     #include "wx/log.h"
  21 #endif //WX_PRECOMP
  22
  23 #import <AppKit/NSCursor.h>
  24 #import <AppKit/NSImage.h>
  25 #include "wx/cocoa/string.h"
  26 #include "wx/cocoa/autorelease.h"
  27
  28 IMPLEMENT_DYNAMIC_CLASS(wxCursor, wxBitmap)
  29
  30 typedef struct tagClassicCursor
  31 {
  32     wxUint16 bits[16];
  33     wxUint16 mask[16];
  34     wxInt16 hotspot[2];
  35 }ClassicCursor;
  36
  37 ///////////////////////////////////////////////////////////////////////////
  38 // This is a direct copy from src/mac/carbon/cursor.cpp and should be
  39 // changed to use common code if we plan on keeping it this way.
  40 // Note that this is basically an array of classic 'CURS' resources.
  41
  42 const short kwxCursorBullseye = 0 ;
  43 const short kwxCursorBlank = 1 ;
  44 const short kwxCursorPencil = 2 ;
  45 const short kwxCursorMagnifier = 3 ;
  46 const short kwxCursorNoEntry = 4 ;
  47 const short kwxCursorPaintBrush = 5 ;
  48 const short kwxCursorPointRight = 6 ;
  49 const short kwxCursorPointLeft = 7 ;
  50 const short kwxCursorQuestionArrow = 8 ;
  51 const short kwxCursorRightArrow = 9 ;
  52 const short kwxCursorSizeNS = 10 ;
  53 const short kwxCursorSize = 11 ;
  54 const short kwxCursorSizeNESW = 12 ;
  55 const short kwxCursorSizeNWSE = 13 ;
  56 const short kwxCursorRoller = 14 ;
  57 const short kwxCursorLast = kwxCursorRoller ;
  58
  59 ClassicCursor gMacCursors[kwxCursorLast+1] =
  60 {
  61
  62 {
  63 {0x0000, 0x03E0, 0x0630, 0x0808, 0x1004, 0x31C6, 0x2362, 0x2222,
  64 0x2362, 0x31C6, 0x1004, 0x0808, 0x0630, 0x03E0, 0x0000, 0x0000},
  65 {0x0000, 0x03E0, 0x07F0, 0x0FF8, 0x1FFC, 0x3FFE, 0x3FFE, 0x3FFE,
  66 0x3FFE, 0x3FFE, 0x1FFC, 0x0FF8, 0x07F0, 0x03E0, 0x0000, 0x0000},
  67 {0x0007, 0x0008}
  68 },
  69
  70 {
  71 {0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000,
  72 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000},
  73 {0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000,
  74 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000, 0x0000},
  75 {0x0000, 0x0000}
  76 },
  77
  78 {
  79 {0x00F0, 0x0088, 0x0108, 0x0190, 0x0270, 0x0220, 0x0440, 0x0440,
  80 0x0880, 0x0880, 0x1100, 0x1E00, 0x1C00, 0x1800, 0x1000, 0x0000},
  81 {0x00F0, 0x00F8, 0x01F8, 0x01F0, 0x03F0, 0x03E0, 0x07C0, 0x07C0,
  82 0x0F80, 0x0F80, 0x1F00, 0x1E00, 0x1C00, 0x1800, 0x1000, 0x0000},
  83 {0x000E, 0x0003}
  84 },
  85
  86 {
  87 {0x0000, 0x1E00, 0x2100, 0x4080, 0x4080, 0x4080, 0x4080, 0x2180,
  88 0x1FC0, 0x00E0, 0x0070, 0x0038, 0x001C, 0x000E, 0x0006, 0x0000},
  89 {0x3F00, 0x7F80, 0xFFC0, 0xFFC0, 0xFFC0, 0xFFC0, 0xFFC0, 0x7FC0,
  90 0x3FE0, 0x1FF0, 0x00F8, 0x007C, 0x003E, 0x001F, 0x000F, 0x0007},
  91 {0x0004, 0x0004}
  92 },
  93
  94 {
  95 {0x0000, 0x07E0, 0x1FF0, 0x3838, 0x3C0C, 0x6E0E, 0x6706, 0x6386,
  96 0x61C6, 0x60E6, 0x7076, 0x303C, 0x1C1C, 0x0FF8, 0x07E0, 0x0000},
  97 {0x0540, 0x0FF0, 0x3FF8, 0x3C3C, 0x7E0E, 0xFF0F, 0x6F86, 0xE7C7,
  98 0x63E6, 0xE1F7, 0x70FE, 0x707E, 0x3C3C, 0x1FFC, 0x0FF0, 0x0540},
  99 {0x0007, 0x0007}
 100 },
 101
 102 {
 103 {0x0000, 0x0380, 0x0380, 0x0380, 0x0380, 0x0380, 0x0380, 0x0FE0,
 104 0x1FF0, 0x1FF0, 0x0000, 0x1FF0, 0x1FF0, 0x1550, 0x1550, 0x1550},
 105 {0x07C0, 0x07C0, 0x07C0, 0x07C0, 0x07C0, 0x07C0, 0x0FE0, 0x1FF0,
 106 0x3FF8, 0x3FF8, 0x3FF8, 0x3FF8, 0x3FF8, 0x3FF8, 0x3FF8, 0x3FF8},
 107 {0x000B, 0x0007}
 108 },
 109
 110 {
 111 {0x00C0, 0x0140, 0x0640, 0x08C0, 0x3180, 0x47FE, 0x8001, 0x8001,
 112 0x81FE, 0x8040, 0x01C0, 0x0040, 0x03C0, 0xC080, 0x3F80, 0x0000},
 113 {0x00C0, 0x01C0, 0x07C0, 0x0FC0, 0x3F80, 0x7FFE, 0xFFFF, 0xFFFF,
 114 0xFFFE, 0xFFC0, 0xFFC0, 0xFFC0, 0xFFC0, 0xFF80, 0x3F80, 0x0000},
 115 {0x0006, 0x000F}
 116 },
 117
 118 {
 119 {0x0100, 0x0280, 0x0260, 0x0310, 0x018C, 0x7FE3, 0x8000, 0x8000,
 120 0x7F80, 0x0200, 0x0380, 0x0200, 0x03C0, 0x0107, 0x01F8, 0x0000},
 121 {0x0100, 0x0380, 0x03E0, 0x03F0, 0x01FC, 0x7FFF, 0xFFFF, 0xFFFF,
 122 0xFFFF, 0x03FF, 0x03FF, 0x03FF, 0x03FF, 0x01FF, 0x01F8, 0x0000},
 123 {0x0006, 0x0000}
 124 },
 125
 126 {
 127 {0x0000, 0x4078, 0x60FC, 0x71CE, 0x7986, 0x7C06, 0x7E0E, 0x7F1C,
 128 0x7FB8, 0x7C30, 0x6C30, 0x4600, 0x0630, 0x0330, 0x0300, 0x0000},
 129 {0xC078, 0xE0FC, 0xF1FE, 0xFBFF, 0xFFCF, 0xFF8F, 0xFF1F, 0xFFBE,
 130 0xFFFC, 0xFE78, 0xFF78, 0xEFF8, 0xCFF8, 0x87F8, 0x07F8, 0x0300},
 131 {0x0001, 0x0001}
 132 },
 133
 134 {
 135 {0x0000, 0x0002, 0x0006, 0x000E, 0x001E, 0x003E, 0x007E, 0x00FE,
 136 0x01FE, 0x003E, 0x0036, 0x0062, 0x0060, 0x00C0, 0x00C0, 0x0000},
 137 {0x0003, 0x0007, 0x000F, 0x001F, 0x003F, 0x007F, 0x00FF, 0x01FF,
 138 0x03FF, 0x07FF, 0x007F, 0x00F7, 0x00F3, 0x01E1, 0x01E0, 0x01C0},
 139 {0x0001, 0x000E}
 140 },
 141
 142 {
 143 {0x0000, 0x0080, 0x01C0, 0x03E0, 0x0080, 0x0080, 0x0080, 0x1FFC,
 144 0x1FFC, 0x0080, 0x0080, 0x0080, 0x03E0, 0x01C0, 0x0080, 0x0000},
 145 {0x0080, 0x01C0, 0x03E0, 0x07F0, 0x0FF8, 0x01C0, 0x3FFE, 0x3FFE,
 146 0x3FFE, 0x3FFE, 0x01C0, 0x0FF8, 0x07F0, 0x03E0, 0x01C0, 0x0080},
 147 {0x0007, 0x0008}
 148 },
 149
 150 {
 151 {0x0000, 0x0080, 0x01C0, 0x03E0, 0x0080, 0x0888, 0x188C, 0x3FFE,
 152 0x188C, 0x0888, 0x0080, 0x03E0, 0x01C0, 0x0080, 0x0000, 0x0000},
 153 {0x0080, 0x01C0, 0x03E0, 0x07F0, 0x0BE8, 0x1DDC, 0x3FFE, 0x7FFF,
 154 0x3FFE, 0x1DDC, 0x0BE8, 0x07F0, 0x03E0, 0x01C0, 0x0080, 0x0000},
 155 {0x0007, 0x0008}
 156 },
 157
 158 {
 159 {0x0000, 0x001E, 0x000E, 0x060E, 0x0712, 0x03A0, 0x01C0, 0x00E0,
 160 0x0170, 0x1238, 0x1C18, 0x1C00, 0x1E00, 0x0000, 0x0000, 0x0000},
 161 {0x007F, 0x003F, 0x0E1F, 0x0F0F, 0x0F97, 0x07E3, 0x03E1, 0x21F0,
 162 0x31F8, 0x3A7C, 0x3C3C, 0x3E1C, 0x3F00, 0x3F80, 0x0000, 0x0000},
 163 {0x0006, 0x0009}
 164 },
 165
 166 {
 167 {0x0000, 0x7800, 0x7000, 0x7060, 0x48E0, 0x05C0, 0x0380, 0x0700,
 168 0x0E80, 0x1C48, 0x1838, 0x0038, 0x0078, 0x0000, 0x0000, 0x0000},
 169 {0xFE00, 0xFC00, 0xF870, 0xF0F0, 0xE9F0, 0xC7E0, 0x87C0, 0x0F84,
 170 0x1F8C, 0x3E5C, 0x3C3C, 0x387C, 0x00FC, 0x01FC, 0x0000, 0x0000},
 171 {0x0006, 0x0006}
 172 },
 173
 174 {
 175 {0x0006, 0x000E, 0x001C, 0x0018, 0x0020, 0x0040, 0x00F8, 0x0004,
 176 0x1FF4, 0x200C, 0x2AA8, 0x1FF0, 0x1F80, 0x3800, 0x6000, 0x8000},
 177 {0x000F, 0x001F, 0x003E, 0x007C, 0x0070, 0x00E0, 0x01FC, 0x3FF6,
 178 0x7FF6, 0x7FFE, 0x7FFC, 0x7FF8, 0x3FF0, 0x7FC0, 0xF800, 0xE000},
 179 {0x000A, 0x0006}
 180 },
 181
 182 } ;
 183
 184 // End of data copied from src/mac/carbon/cursor.cpp
 185 ///////////////////////////////////////////////////////////////////////////
 186
 187 /* NSCursorCreateWithPrivateId
 188  * Returns a newly allocated (i.e. retainCount == 1) NSCursor based on the
 189  * classic Mac OS cursor data in this source file.  This allows us to
 190  * implement the "stock" wxWidgets cursors which aren't present in Cocoa.
 191  */
 192 static inline NSCursor* NSCursorCreateWithPrivateId(short sIndex)
 193 {
 194     ClassicCursor* pCursor = &gMacCursors[sIndex];
 195
 196     //Classic mac cursors are 1bps 16x16 black and white with a
 197     //identical mask that is 1 for on and 0 for off
 198     NSImage *theImage = [[NSImage alloc] initWithSize:NSMakeSize(16.0,16.0)];
 199
 200     NSBitmapImageRep *theRep = [[NSBitmapImageRep alloc]
 201         initWithBitmapDataPlanes: NULL  // Tell Cocoa to allocate the planes for us.
 202         pixelsWide: 16      // All classic cursors are 16x16
 203         pixelsHigh: 16
 204         bitsPerSample: 1    // All classic cursors are bitmaps with bitmasks
 205         samplesPerPixel: 2  // Sample 0:image 1:mask
 206         hasAlpha: YES       // Identify last sample as a mask
 207         isPlanar: YES       // Use a separate array for each sample
 208         colorSpaceName: NSCalibratedWhiteColorSpace // 0.0=black 1.0=white
 209         bytesPerRow: 2      // Rows in each plane are on 2-byte boundaries (no pad)
 210         bitsPerPixel: 1];   // same as bitsPerSample since data is planar
 211     // XXX: Should we use NSDeviceWhiteColorSpace? Does it matter?
 212
 213     // Ensure that Cocoa allocated 2 and only 2 of the 5 possible planes
 214     unsigned char *planes[5];
 215     [theRep getBitmapDataPlanes:planes];
 216     wxASSERT(planes[0] != NULL);
 217     wxASSERT(planes[1] != NULL);
 218     wxASSERT(planes[2] == NULL);
 219     wxASSERT(planes[3] == NULL);
 220     wxASSERT(planes[4] == NULL);
 221
 222     // NOTE1: The Cursor's bits field is white=0 black=1.. thus the bitwise-not
 223     // Why not use NSCalibratedBlackColorSpace?  Because that reverses the
 224     // sense of the alpha (mask) plane.
 225     // NOTE2: The mask data is 0=off 1=on
 226     // NOTE3: Cocoa asks for "premultiplied" color planes.  Since we have a
 227     // 1-bit color plane and a 1-bit alpha plane we can just do a bitwise-and
 228     // on the two.  The original cursor bitmaps have 0 (white actually) for
 229     // any masked-off pixels.  Therefore every masked-off pixel would be wrong
 230     // since we bit-flip all of the picture bits.  In practice, Cocoa doesn't
 231     // seem to care, but we are following the documentation.
 232
 233     // Fill in the color (black/white) plane
 234     for(int i=0; i<16; ++i)
 235     {
 236         planes[0][2*i  ] = (~pCursor->bits[i] & pCursor->mask[i]) >> 8 & 0xff;
 237         planes[0][2*i+1] = (~pCursor->bits[i] & pCursor->mask[i]) & 0xff;
 238     }
 239     // Fill in the alpha (i.e. mask) plane
 240     for(int i=0; i<16; ++i)
 241     {
 242         planes[1][2*i  ] = pCursor->mask[i] >> 8 & 0xff;
 243         planes[1][2*i+1] = pCursor->mask[i] & 0xff;
 244     }
 245
 246     //add the representation (data) to the image
 247     [theImage addRepresentation:theRep];
 248
 249     //create the new cursor
 250     NSCursor* theCursor =  [[NSCursor alloc]  initWithImage:theImage
 251                                     hotSpot:NSMakePoint(pCursor->hotspot[1], pCursor->hotspot[0])
 252                             ];
 253
 254     //do the usual cleanups
 255     [theRep release];
 256     [theImage release];
 257
 258     //return the new cursor
 259     return theCursor;
 260 }
 261
 262 // TODO: Remove in trunk.. needed for 2.8
 263 NSCursor* wxGetStockCursor( short sIndex )
 264 {
 265     wxLogDebug("Please do not call wxGetStockCursor.");
 266     return NSCursorCreateWithPrivateId(sIndex);
 267 }
 268
 269 wxCursorRefData::wxCursorRefData() :
 270     m_width(32), m_height(32), m_hCursor(nil)
 271 {
 272 }
 273
 274 wxCursorRefData::~wxCursorRefData()
 275 {
 276     if (m_hCursor)
 277         [m_hCursor release];
 278 }
 279
 280 // Cursors
 281 wxCursor::wxCursor()
 282 {
 283 }
 284
 285 wxCursor::wxCursor(const char WXUNUSED(bits)[], int WXUNUSED(width), int WXUNUSED(height),
 286     int WXUNUSED(hotSpotX), int WXUNUSED(hotSpotY), const char WXUNUSED(maskBits)[])
 287 {
 288 }
 289
 290 wxCursor::wxCursor(const wxString& cursor_file, long flags, int hotSpotX, int hotSpotY)
 291 {
 292     m_refData = new wxCursorRefData;
 293
 294     //TODO:  Not sure if this works or not
 295     NSImage* theImage;
 296
 297     if (flags & wxBITMAP_TYPE_MACCURSOR_RESOURCE)
 298     {
 299         //[NSBundle bundleForClass:[self class]]?
 300         theImage = [[NSImage alloc]
 301                         initWithContentsOfFile:[[NSBundle mainBundle] pathForResource:wxNSStringWithWxString(cursor_file) ofType:nil]
 302                     ];
 303
 304     }
 305     else
 306         theImage = [[NSImage alloc] initByReferencingFile:wxNSStringWithWxString(cursor_file)
 307                 ];
 308
 309     wxASSERT(theImage);
 310
 311     M_CURSORDATA->m_hCursor = [[NSCursor alloc] initWithImage:theImage
 312                                         hotSpot:NSMakePoint(hotSpotX, hotSpotY)
 313                                 ];
 314
 315     [theImage release];
 316 }
 317
 318 // Returns a system cursor given the NSCursor class method selector or
 319 // nil if NSCursor does not respond to the message.
 320 // For example, OS X before 10.3 won't respond to pointingHandCursor.
 321 static inline NSCursor* GetSystemCursorWithSelector(SEL cursorSelector)
 322 {
 323     if([NSCursor respondsToSelector: cursorSelector])
 324         return [NSCursor performSelector: cursorSelector];
 325     else
 326         return nil;
 327 }
 328
 329 // Please maintain order as if this were an array keyed on wxStockCursor
 330 static inline SEL GetCursorSelectorForStockCursor(int stock_cursor_id)
 331 {
 332     switch(stock_cursor_id)
 333     {
 334     case wxCURSOR_ARROW:            return @selector(arrowCursor);
 335     case wxCURSOR_RIGHT_ARROW:      break;
 336     case wxCURSOR_BULLSEYE:         break;
 337     case wxCURSOR_CHAR:             break;
 338     case wxCURSOR_CROSS:            return @selector(crosshairCursor);
 339     case wxCURSOR_HAND:             return @selector(pointingHandCursor);
 340     case wxCURSOR_IBEAM:            return @selector(IBeamCursor);
 341     case wxCURSOR_LEFT_BUTTON:      break;
 342     case wxCURSOR_MAGNIFIER:        break;
 343     case wxCURSOR_MIDDLE_BUTTON:    break;
 344     case wxCURSOR_NO_ENTRY:         break;
 345     case wxCURSOR_PAINT_BRUSH:      break;
 346     case wxCURSOR_PENCIL:           break;
 347     case wxCURSOR_POINT_LEFT:       break;
 348     case wxCURSOR_POINT_RIGHT:      break;
 349     case wxCURSOR_QUESTION_ARROW:   break;
 350     case wxCURSOR_RIGHT_BUTTON:     break;
 351     case wxCURSOR_SIZENESW:         break;
 352     case wxCURSOR_SIZENS:           return @selector(resizeUpDownCursor);
 353     case wxCURSOR_SIZENWSE:         break;
 354     case wxCURSOR_SIZEWE:           return @selector(resizeLeftRightCursor);
 355     case wxCURSOR_SIZING:           break;
 356     case wxCURSOR_SPRAYCAN:         break;
 357     case wxCURSOR_WAIT:             break;
 358     case wxCURSOR_WATCH:            break;
 359     case wxCURSOR_BLANK:            break;
 360     case wxCURSOR_ARROWWAIT:        break;
 361     default:                        break;
 362     }
 363     return NULL;
 364 }
 365
 366 // Please maintain order as if this were an array keyed on wxStockCursor
 367 static inline int GetPrivateCursorIdForStockCursor(int stock_cursor_id)
 368 {
 369     switch(stock_cursor_id)
 370     {
 371     case wxCURSOR_ARROW:            break;  // NSCursor
 372     case wxCURSOR_RIGHT_ARROW:      return kwxCursorRightArrow;
 373     case wxCURSOR_BULLSEYE:         return kwxCursorBullseye;
 374     case wxCURSOR_CHAR:             break;
 375     case wxCURSOR_CROSS:            break;  // NSCursor
 376     case wxCURSOR_HAND:             break;  // NSCursor (OS X >= 10.3)
 377     case wxCURSOR_IBEAM:            break;  // NSCursor
 378     case wxCURSOR_LEFT_BUTTON:      break;
 379     case wxCURSOR_MAGNIFIER:        return kwxCursorMagnifier;
 380     case wxCURSOR_MIDDLE_BUTTON:    break;
 381     case wxCURSOR_NO_ENTRY:         return kwxCursorNoEntry;
 382     case wxCURSOR_PAINT_BRUSH:      return kwxCursorPaintBrush;
 383     case wxCURSOR_PENCIL:           return kwxCursorPencil;
 384     case wxCURSOR_POINT_LEFT:       return kwxCursorPointLeft;
 385     case wxCURSOR_POINT_RIGHT:      return kwxCursorPointRight;
 386     case wxCURSOR_QUESTION_ARROW:   return kwxCursorQuestionArrow;
 387     case wxCURSOR_RIGHT_BUTTON:     break;
 388     case wxCURSOR_SIZENESW:         return kwxCursorSizeNESW;
 389     case wxCURSOR_SIZENS:           return kwxCursorSizeNS;  // also NSCursor
 390     case wxCURSOR_SIZENWSE:         return kwxCursorSizeNWSE;
 391     case wxCURSOR_SIZEWE:           break;  // NSCursor
 392     case wxCURSOR_SIZING:           return kwxCursorSize;
 393     case wxCURSOR_SPRAYCAN:         return kwxCursorRoller;
 394     case wxCURSOR_WAIT:             break;
 395     case wxCURSOR_WATCH:            break;
 396     case wxCURSOR_BLANK:            return kwxCursorBlank;
 397     case wxCURSOR_ARROWWAIT:        break;
 398     default:                        break;
 399     }
 400     return -1;
 401 }
 402
 403 // Cursors by stock number (enum wxStockCursor)
 404 wxCursor::wxCursor(int stock_cursor_id)
 405 {
 406     m_refData = new wxCursorRefData;
 407
 408     M_CURSORDATA->m_hCursor = nil;
 409
 410     wxCHECK_RET( stock_cursor_id > wxCURSOR_NONE && stock_cursor_id < wxCURSOR_MAX,
 411             wxT("invalid cursor id in wxCursor() ctor") );
 412
 413     // Stage 1: Try a system cursor
 414     SEL cursorSelector;
 415     if( (cursorSelector = GetCursorSelectorForStockCursor(stock_cursor_id)) != NULL)
 416     {
 417         M_CURSORDATA->m_hCursor = [GetSystemCursorWithSelector(cursorSelector) retain];
 418     }
 419
 420     // TODO: Provide a pointing hand for OS X < 10.3 if desired
 421
 422     // Stage 2: Try one of the 'CURS'-style cursors
 423     if(M_CURSORDATA->m_hCursor == nil)
 424     {
 425         int privateId;
 426         if( (privateId = GetPrivateCursorIdForStockCursor(stock_cursor_id)) >= 0)
 427         {   // wxGetStockCursor is not a get method but an alloc method.
 428             M_CURSORDATA->m_hCursor = NSCursorCreateWithPrivateId(privateId);
 429         }
 430     }
 431
 432     // Stage 3: Give up, complain, and use a normal arrow
 433     if(M_CURSORDATA->m_hCursor == nil)
 434     {
 435         wxLogDebug("Could not find suitable cursor for wxStockCursor = %d.  Using normal pointer.", stock_cursor_id);
 436         M_CURSORDATA->m_hCursor = [[NSCursor arrowCursor] retain];
 437     }
 438
 439     // This should never happen as the arrowCursor should always exist.
 440     wxASSERT(M_CURSORDATA->m_hCursor != nil);
 441 }
 442
 443 wxCursor::~wxCursor()
 444 {
 445 }
 446
 447 // Global cursor setting
 448 void wxSetCursor(const wxCursor& cursor)
 449 {
 450     if (cursor.GetNSCursor())
 451         [cursor.GetNSCursor() push];
 452 }
 453
 454 static int wxBusyCursorCount = 0;
 455
 456 // Set the cursor to the busy cursor for all windows
 457 void wxBeginBusyCursor(const wxCursor *cursor)
 458 {
 459     wxBusyCursorCount ++;
 460     if (wxBusyCursorCount == 1)
 461     {
 462         // TODO
 463     }
 464     else
 465     {
 466         // TODO
 467     }
 468 }
 469
 470 // Restore cursor to normal
 471 void wxEndBusyCursor()
 472 {
 473     if (wxBusyCursorCount == 0)
 474         return;
 475
 476     wxBusyCursorCount --;
 477     if (wxBusyCursorCount == 0)
 478     {
 479         // TODO
 480     }
 481 }
 482
 483 // true if we're between the above two calls
 484 bool wxIsBusy()
 485 {
 486   return (wxBusyCursorCount > 0);
 487 }