src/osx/cocoa/textctrl.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/textctrl.mm
   3 // Purpose:     wxTextCtrl
   4 // Author:      Stefan Csomor
   5 // Modified by: Ryan Norton (MLTE GetLineLength and GetLineText)
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_TEXTCTRL
  15
  16 #include "wx/textctrl.h"
  17
  18 #ifndef WX_PRECOMP
  19     #include "wx/intl.h"
  20     #include "wx/app.h"
  21     #include "wx/utils.h"
  22     #include "wx/dc.h"
  23     #include "wx/button.h"
  24     #include "wx/menu.h"
  25     #include "wx/settings.h"
  26     #include "wx/msgdlg.h"
  27     #include "wx/toplevel.h"
  28 #endif
  29
  30 #ifdef __DARWIN__
  31     #include <sys/types.h>
  32     #include <sys/stat.h>
  33 #else
  34     #include <stat.h>
  35 #endif
  36
  37 #if wxUSE_STD_IOSTREAM
  38     #if wxUSE_IOSTREAMH
  39         #include <fstream.h>
  40     #else
  41         #include <fstream>
  42     #endif
  43 #endif
  44
  45 #include "wx/filefn.h"
  46 #include "wx/sysopt.h"
  47 #include "wx/thread.h"
  48 #include "wx/textcompleter.h"
  49
  50 #include "wx/osx/private.h"
  51 #include "wx/osx/cocoa/private/textimpl.h"
  52
  53 @interface NSView(EditableView)
  54 - (BOOL)isEditable;
  55 - (void)setEditable:(BOOL)flag;
  56 - (BOOL)isSelectable;
  57 - (void)setSelectable:(BOOL)flag;
  58 @end
  59
  60 // An object of this class is created before the text is modified
  61 // programmatically and destroyed as soon as this is done. It does several
  62 // things, like ensuring that the control is editable to allow setting its text
  63 // at all and eating any unwanted focus loss events from textDidEndEditing:
  64 // which don't really correspond to focus change.
  65 class wxMacEditHelper
  66 {
  67 public :
  68     wxMacEditHelper( NSView* textView )
  69     {
  70         m_viewPreviouslyEdited = ms_viewCurrentlyEdited;
  71         ms_viewCurrentlyEdited =
  72         m_textView = textView;
  73         m_formerEditable = YES;
  74         if ( textView )
  75         {
  76             m_formerEditable = [textView isEditable];
  77             m_formerSelectable = [textView isSelectable];
  78             [textView setEditable:YES];
  79         }
  80     }
  81
  82     ~wxMacEditHelper()
  83     {
  84         if ( m_textView )
  85         {
  86             [m_textView setEditable:m_formerEditable];
  87             [m_textView setSelectable:m_formerSelectable];
  88         }
  89
  90         ms_viewCurrentlyEdited = m_viewPreviouslyEdited;
  91     }
  92
  93     // Returns the last view we were instantiated for or NULL.
  94     static NSView *GetCurrentlyEditedView() { return ms_viewCurrentlyEdited; }
  95
  96 protected :
  97     BOOL m_formerEditable ;
  98     BOOL m_formerSelectable;
  99     NSView* m_textView;
 100
 101     // The original value of ms_viewCurrentlyEdited when this object was
 102     // created.
 103     NSView* m_viewPreviouslyEdited;
 104
 105     static NSView* ms_viewCurrentlyEdited;
 106 } ;
 107
 108 NSView* wxMacEditHelper::ms_viewCurrentlyEdited = nil;
 109
 110 // a minimal NSFormatter that just avoids getting too long entries
 111 @interface wxMaximumLengthFormatter : NSFormatter
 112 {
 113     int maxLength;
 114 }
 115
 116 @end
 117
 118 @implementation wxMaximumLengthFormatter
 119
 120 - (id)init
 121 {
 122     self = [super init];
 123     maxLength = 0;
 124     return self;
 125 }
 126
 127 - (void) setMaxLength:(int) maxlen
 128 {
 129     maxLength = maxlen;
 130 }
 131
 132 - (NSString *)stringForObjectValue:(id)anObject
 133 {
 134     if(![anObject isKindOfClass:[NSString class]])
 135         return nil;
 136     return [NSString stringWithString:anObject];
 137 }
 138
 139 - (BOOL)getObjectValue:(id *)obj forString:(NSString *)string errorDescription:(NSString  **)error
 140 {
 141     *obj = [NSString stringWithString:string];
 142     return YES;
 143 }
 144
 145 - (BOOL)isPartialStringValid:(NSString **)partialStringPtr proposedSelectedRange:(NSRangePointer)proposedSelRangePtr
 146               originalString:(NSString *)origString originalSelectedRange:(NSRange)origSelRange errorDescription:(NSString **)error
 147 {
 148     int len = [*partialStringPtr length];
 149     if ( maxLength > 0 && len > maxLength )
 150     {
 151         // TODO wxEVT_TEXT_MAXLEN
 152         return NO;
 153     }
 154     return YES;
 155 }
 156
 157 @end
 158
 159 @implementation wxNSSecureTextField
 160
 161 + (void)initialize
 162 {
 163     static BOOL initialized = NO;
 164     if (!initialized)
 165     {
 166         initialized = YES;
 167         wxOSXCocoaClassAddWXMethods( self );
 168     }
 169 }
 170
 171 - (void)controlTextDidChange:(NSNotification *)aNotification
 172 {
 173     wxUnusedVar(aNotification);
 174     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 175     if ( impl )
 176         impl->controlTextDidChange();
 177 }
 178
 179 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 180 {
 181     wxUnusedVar(aNotification);
 182     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 183     if ( impl )
 184     {
 185         NSResponder * responder = wxNonOwnedWindowCocoaImpl::GetNextFirstResponder();
 186         NSView* otherView = wxOSXGetViewFromResponder(responder);
 187
 188         wxWidgetImpl* otherWindow = impl->FindBestFromWXWidget(otherView);
 189         impl->DoNotifyFocusEvent( false, otherWindow );
 190     }
 191 }
 192
 193 - (BOOL)control:(NSControl*)control textView:(NSTextView*)textView doCommandBySelector:(SEL)commandSelector
 194 {
 195     wxUnusedVar(textView);
 196
 197     BOOL handled = NO;
 198
 199     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( control );
 200     if ( impl  )
 201     {
 202         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 203         if ( wxpeer )
 204         {
 205             if (commandSelector == @selector(insertNewline:))
 206             {
 207                 wxTopLevelWindow *tlw = wxDynamicCast(wxGetTopLevelParent(wxpeer), wxTopLevelWindow);
 208                 if ( tlw && tlw->GetDefaultItem() )
 209                 {
 210                     wxButton *def = wxDynamicCast(tlw->GetDefaultItem(), wxButton);
 211                     if ( def && def->IsEnabled() )
 212                     {
 213                         wxCommandEvent event(wxEVT_BUTTON, def->GetId() );
 214                         event.SetEventObject(def);
 215                         def->Command(event);
 216                         handled = YES;
 217                     }
 218                 }
 219             }
 220         }
 221     }
 222
 223     return handled;
 224 }
 225
 226 @end
 227
 228 @interface wxNSTextScrollView : NSScrollView
 229 {
 230 }
 231 @end
 232
 233 @implementation wxNSTextScrollView
 234
 235 + (void)initialize
 236 {
 237     static BOOL initialized = NO;
 238     if (!initialized)
 239     {
 240         initialized = YES;
 241         wxOSXCocoaClassAddWXMethods( self );
 242     }
 243 }
 244
 245 @end
 246
 247 @implementation wxNSTextFieldEditor
 248
 249 - (void) keyDown:(NSEvent*) event
 250 {
 251     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 252     lastKeyDownEvent = event;
 253     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 254         [super keyDown:event];
 255     lastKeyDownEvent = nil;
 256 }
 257
 258 - (void) keyUp:(NSEvent*) event
 259 {
 260     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 261     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 262         [super keyUp:event];
 263 }
 264
 265 - (void) flagsChanged:(NSEvent*) event
 266 {
 267     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 268     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 269         [super flagsChanged:event];
 270 }
 271
 272 - (BOOL) performKeyEquivalent:(NSEvent*) event
 273 {
 274     BOOL retval = [super performKeyEquivalent:event];
 275     return retval;
 276 }
 277
 278 - (void) insertText:(id) str
 279 {
 280     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 281     if ( impl == NULL || lastKeyDownEvent==nil || !impl->DoHandleCharEvent(lastKeyDownEvent, str) )
 282     {
 283         [super insertText:str];
 284     }
 285 }
 286
 287 @end
 288
 289 @implementation wxNSTextView
 290
 291 + (void)initialize
 292 {
 293     static BOOL initialized = NO;
 294     if (!initialized)
 295     {
 296         initialized = YES;
 297         wxOSXCocoaClassAddWXMethods( self );
 298     }
 299 }
 300
 301 - (void)textDidChange:(NSNotification *)aNotification
 302 {
 303     wxUnusedVar(aNotification);
 304     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 305     if ( impl )
 306         impl->controlTextDidChange();
 307 }
 308
 309 - (void) setEnabled:(BOOL) flag
 310 {
 311     // from Technical Q&A QA1461
 312     if (flag) {
 313         [self setTextColor: [NSColor controlTextColor]];
 314
 315     } else {
 316         [self setTextColor: [NSColor disabledControlTextColor]];
 317     }
 318
 319     [self setSelectable: flag];
 320     [self setEditable: flag];
 321 }
 322
 323 - (BOOL) isEnabled
 324 {
 325     return [self isEditable];
 326 }
 327
 328 - (void)textDidEndEditing:(NSNotification *)aNotification
 329 {
 330     wxUnusedVar(aNotification);
 331
 332     if ( self == wxMacEditHelper::GetCurrentlyEditedView() )
 333     {
 334         // This notification is generated as the result of calling our own
 335         // wxTextCtrl method (e.g. WriteText()) and doesn't correspond to any
 336         // real focus loss event so skip generating it.
 337         return;
 338     }
 339
 340     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 341     if ( impl )
 342     {
 343         NSResponder * responder = wxNonOwnedWindowCocoaImpl::GetNextFirstResponder();
 344         NSView* otherView = wxOSXGetViewFromResponder(responder);
 345
 346         wxWidgetImpl* otherWindow = impl->FindBestFromWXWidget(otherView);
 347         impl->DoNotifyFocusEvent( false, otherWindow );
 348     }
 349 }
 350
 351 @end
 352
 353 @implementation wxNSTextField
 354
 355 + (void)initialize
 356 {
 357     static BOOL initialized = NO;
 358     if (!initialized)
 359     {
 360         initialized = YES;
 361         wxOSXCocoaClassAddWXMethods( self );
 362     }
 363 }
 364
 365 - (id) initWithFrame:(NSRect) frame
 366 {
 367     self = [super initWithFrame:frame];
 368     fieldEditor = nil;
 369     return self;
 370 }
 371
 372 - (void) dealloc
 373 {
 374     [fieldEditor release];
 375     [super dealloc];
 376 }
 377
 378 - (void) setFieldEditor:(wxNSTextFieldEditor*) editor
 379 {
 380     if ( editor != fieldEditor )
 381     {
 382         [editor retain];
 383         [fieldEditor release];
 384         fieldEditor = editor;
 385     }
 386 }
 387
 388 - (wxNSTextFieldEditor*) fieldEditor
 389 {
 390     return fieldEditor;
 391 }
 392
 393 - (void) setEnabled:(BOOL) flag
 394 {
 395     [super setEnabled: flag];
 396
 397     if (![self drawsBackground]) {
 398         // Static text is drawn incorrectly when disabled.
 399         // For an explanation, see
 400         // http://www.cocoabuilder.com/archive/message/cocoa/2006/7/21/168028
 401         if (flag) {
 402             [self setTextColor: [NSColor controlTextColor]];
 403         } else {
 404             [self setTextColor: [NSColor secondarySelectedControlColor]];
 405         }
 406     }
 407 }
 408
 409 - (void)controlTextDidChange:(NSNotification *)aNotification
 410 {
 411     wxUnusedVar(aNotification);
 412     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 413     if ( impl )
 414         impl->controlTextDidChange();
 415 }
 416
 417 - (NSArray *)control:(NSControl *)control textView:(NSTextView *)textView completions:(NSArray *)words
 418  forPartialWordRange:(NSRange)charRange indexOfSelectedItem:(NSInteger*)index
 419 {
 420     NSMutableArray* matches = NULL;
 421
 422     wxTextWidgetImpl* impl = (wxNSTextFieldControl * ) wxWidgetImpl::FindFromWXWidget( self );
 423     wxTextEntry * const entry = impl->GetTextEntry();
 424     wxTextCompleter * const completer = entry->OSXGetCompleter();
 425     if ( completer )
 426     {
 427         const wxString prefix = entry->GetValue();
 428         if ( completer->Start(prefix) )
 429         {
 430             const wxString
 431                 wordStart = wxCFStringRef::AsString(
 432                               [[textView string] substringWithRange:charRange]
 433                             );
 434
 435             matches = [NSMutableArray array];
 436             for ( ;; )
 437             {
 438                 const wxString s = completer->GetNext();
 439                 if ( s.empty() )
 440                     break;
 441
 442                 // Normally the completer should return only the strings
 443                 // starting with the prefix, but there could be exceptions
 444                 // and, for compatibility with MSW which simply ignores all
 445                 // entries that don't match the current text control contents,
 446                 // we ignore them as well. Besides, our own wxTextCompleterFixed
 447                 // doesn't respect this rule and, moreover, we need to extract
 448                 // just the rest of the string anyhow.
 449                 wxString completion;
 450                 if ( s.StartsWith(prefix, &completion) )
 451                 {
 452                     // We discarded the entire prefix above but actually we
 453                     // should include the part of it that consists of the
 454                     // beginning of the current word, otherwise it would be
 455                     // lost when completion is accepted as OS X supposes that
 456                     // our matches do start with the "partial word range"
 457                     // passed to us.
 458                     const wxCFStringRef fullWord(wordStart + completion);
 459                     [matches addObject: fullWord.AsNSString()];
 460                 }
 461             }
 462         }
 463     }
 464
 465     return matches;
 466 }
 467
 468 - (BOOL)control:(NSControl*)control textView:(NSTextView*)textView doCommandBySelector:(SEL)commandSelector
 469 {
 470     wxUnusedVar(textView);
 471     wxUnusedVar(control);
 472
 473     BOOL handled = NO;
 474
 475     // send back key events wx' common code knows how to handle
 476
 477     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 478     if ( impl  )
 479     {
 480         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 481         if ( wxpeer )
 482         {
 483             if (commandSelector == @selector(insertNewline:))
 484             {
 485                 [textView insertNewlineIgnoringFieldEditor:self];
 486                 handled = YES;
 487             }
 488             else if ( commandSelector == @selector(insertTab:))
 489             {
 490                 [textView insertTabIgnoringFieldEditor:self];
 491                 handled = YES;
 492             }
 493             else if ( commandSelector == @selector(insertBacktab:))
 494             {
 495                 [textView insertTabIgnoringFieldEditor:self];
 496                 handled = YES;
 497             }
 498         }
 499     }
 500
 501     return handled;
 502 }
 503
 504 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 505 {
 506     wxUnusedVar(aNotification);
 507     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 508     if ( impl )
 509     {
 510         wxNSTextFieldControl* timpl = dynamic_cast<wxNSTextFieldControl*>(impl);
 511         if ( fieldEditor )
 512         {
 513             NSRange range = [fieldEditor selectedRange];
 514             timpl->SetInternalSelection(range.location, range.location + range.length);
 515         }
 516
 517         NSResponder * responder = wxNonOwnedWindowCocoaImpl::GetNextFirstResponder();
 518         NSView* otherView = wxOSXGetViewFromResponder(responder);
 519
 520         wxWidgetImpl* otherWindow = impl->FindBestFromWXWidget(otherView);
 521         impl->DoNotifyFocusEvent( false, otherWindow );
 522     }
 523 }
 524 @end
 525
 526 // wxNSTextViewControl
 527
 528 wxNSTextViewControl::wxNSTextViewControl( wxTextCtrl *wxPeer, WXWidget w )
 529     : wxWidgetCocoaImpl(wxPeer, w),
 530       wxTextWidgetImpl(wxPeer)
 531 {
 532     wxNSTextScrollView* sv = (wxNSTextScrollView*) w;
 533     m_scrollView = sv;
 534
 535     [m_scrollView setHasVerticalScroller:YES];
 536     [m_scrollView setHasHorizontalScroller:NO];
 537     // TODO Remove if no regression, this was causing automatic resizes of multi-line textfields when the tlw changed
 538     // [m_scrollView setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
 539     NSSize contentSize = [m_scrollView contentSize];
 540
 541     wxNSTextView* tv = [[wxNSTextView alloc] initWithFrame: NSMakeRect(0, 0,
 542             contentSize.width, contentSize.height)];
 543     m_textView = tv;
 544     [tv setVerticallyResizable:YES];
 545     [tv setHorizontallyResizable:NO];
 546     [tv setAutoresizingMask:NSViewWidthSizable];
 547
 548     [m_scrollView setDocumentView: tv];
 549
 550     [tv setDelegate: tv];
 551
 552     InstallEventHandler(tv);
 553 }
 554
 555 wxNSTextViewControl::~wxNSTextViewControl()
 556 {
 557     if (m_textView)
 558         [m_textView setDelegate: nil];
 559 }
 560
 561 bool wxNSTextViewControl::CanFocus() const
 562 {
 563     // since this doesn't work (return false), we hardcode
 564     // if (m_textView)
 565     //    return [m_textView canBecomeKeyView];
 566     return true;
 567 }
 568
 569 wxString wxNSTextViewControl::GetStringValue() const
 570 {
 571     if (m_textView)
 572     {
 573         wxString result = wxCFStringRef::AsString([m_textView string], m_wxPeer->GetFont().GetEncoding());
 574         wxMacConvertNewlines13To10( &result ) ;
 575         return result;
 576     }
 577     return wxEmptyString;
 578 }
 579 void wxNSTextViewControl::SetStringValue( const wxString &str)
 580 {
 581     wxString st = str;
 582     wxMacConvertNewlines10To13( &st );
 583     wxMacEditHelper helper(m_textView);
 584
 585     if (m_textView)
 586         [m_textView setString: wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 587 }
 588
 589 void wxNSTextViewControl::Copy()
 590 {
 591     if (m_textView)
 592         [m_textView copy:nil];
 593
 594 }
 595
 596 void wxNSTextViewControl::Cut()
 597 {
 598     if (m_textView)
 599         [m_textView cut:nil];
 600 }
 601
 602 void wxNSTextViewControl::Paste()
 603 {
 604     if (m_textView)
 605         [m_textView paste:nil];
 606 }
 607
 608 bool wxNSTextViewControl::CanPaste() const
 609 {
 610     return true;
 611 }
 612
 613 void wxNSTextViewControl::SetEditable(bool editable)
 614 {
 615     if (m_textView)
 616         [m_textView setEditable: editable];
 617 }
 618
 619 void wxNSTextViewControl::GetSelection( long* from, long* to) const
 620 {
 621     if (m_textView)
 622     {
 623         NSRange range = [m_textView selectedRange];
 624         *from = range.location;
 625         *to = range.location + range.length;
 626     }
 627 }
 628
 629 void wxNSTextViewControl::SetSelection( long from , long to )
 630 {
 631     long textLength = [[m_textView string] length];
 632     if ((from == -1) && (to == -1))
 633     {
 634         from = 0 ;
 635         to = textLength ;
 636     }
 637     else
 638     {
 639         from = wxMin(textLength,wxMax(from,0)) ;
 640         if ( to == -1 )
 641             to = textLength;
 642         else
 643             to = wxMax(0,wxMin(textLength,to)) ;
 644     }
 645
 646     NSRange selrange = NSMakeRange(from, to-from);
 647     [m_textView setSelectedRange:selrange];
 648     [m_textView scrollRangeToVisible:selrange];
 649 }
 650
 651 void wxNSTextViewControl::WriteText(const wxString& str)
 652 {
 653     wxString st = str;
 654     wxMacConvertNewlines10To13( &st );
 655     wxMacEditHelper helper(m_textView);
 656     NSEvent* formerEvent = m_lastKeyDownEvent;
 657     m_lastKeyDownEvent = nil;
 658     [m_textView insertText:wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 659     m_lastKeyDownEvent = formerEvent;
 660 }
 661
 662 void wxNSTextViewControl::SetFont( const wxFont & font , const wxColour& WXUNUSED(foreground) , long WXUNUSED(windowStyle), bool WXUNUSED(ignoreBlack) )
 663 {
 664     if ([m_textView respondsToSelector:@selector(setFont:)])
 665         [m_textView setFont: font.OSXGetNSFont()];
 666 }
 667
 668 bool wxNSTextViewControl::GetStyle(long position, wxTextAttr& style)
 669 {
 670     if (m_textView && position >=0)
 671     {
 672         NSFont* font = NULL;
 673         NSColor* bgcolor = NULL;
 674         NSColor* fgcolor = NULL;
 675         // NOTE: It appears that other platforms accept GetStyle with the position == length
 676         // but that NSTextStorage does not accept length as a valid position.
 677         // Therefore we return the default control style in that case.
 678         if (position < (long) [[m_textView string] length])
 679         {
 680             NSTextStorage* storage = [m_textView textStorage];
 681             font = [[storage attribute:NSFontAttributeName atIndex:position effectiveRange:NULL] autorelease];
 682             bgcolor = [[storage attribute:NSBackgroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 683             fgcolor = [[storage attribute:NSForegroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 684         }
 685         else
 686         {
 687             NSDictionary* attrs = [m_textView typingAttributes];
 688             font = [[attrs objectForKey:NSFontAttributeName] autorelease];
 689             bgcolor = [[attrs objectForKey:NSBackgroundColorAttributeName] autorelease];
 690             fgcolor = [[attrs objectForKey:NSForegroundColorAttributeName] autorelease];
 691         }
 692
 693         if (font)
 694             style.SetFont(wxFont(font));
 695
 696         if (bgcolor)
 697             style.SetBackgroundColour(wxColour(bgcolor));
 698
 699         if (fgcolor)
 700             style.SetTextColour(wxColour(fgcolor));
 701         return true;
 702     }
 703
 704     return false;
 705 }
 706
 707 void wxNSTextViewControl::SetStyle(long start,
 708                                 long end,
 709                                 const wxTextAttr& style)
 710 {
 711     if ( !m_textView )
 712         return;
 713
 714     if ( start == -1 && end == -1 )
 715     {
 716         NSMutableDictionary* const
 717             attrs = [NSMutableDictionary dictionaryWithCapacity:3];
 718         if ( style.HasFont() )
 719             [attrs setValue:style.GetFont().OSXGetNSFont() forKey:NSFontAttributeName];
 720         if ( style.HasBackgroundColour() )
 721             [attrs setValue:style.GetBackgroundColour().OSXGetNSColor() forKey:NSBackgroundColorAttributeName];
 722         if ( style.HasTextColour() )
 723             [attrs setValue:style.GetTextColour().OSXGetNSColor() forKey:NSForegroundColorAttributeName];
 724
 725         [m_textView setTypingAttributes:attrs];
 726     }
 727     else // Set the attributes just for this range.
 728     {
 729         NSRange range = NSMakeRange(start, end-start);
 730
 731         NSTextStorage* storage = [m_textView textStorage];
 732         if ( style.HasFont() )
 733             [storage addAttribute:NSFontAttributeName value:style.GetFont().OSXGetNSFont() range:range];
 734
 735         if ( style.HasBackgroundColour() )
 736             [storage addAttribute:NSBackgroundColorAttributeName value:style.GetBackgroundColour().OSXGetNSColor() range:range];
 737
 738         if ( style.HasTextColour() )
 739             [storage addAttribute:NSForegroundColorAttributeName value:style.GetTextColour().OSXGetNSColor() range:range];
 740     }
 741 }
 742
 743 void wxNSTextViewControl::CheckSpelling(bool check)
 744 {
 745     if (m_textView)
 746         [m_textView setContinuousSpellCheckingEnabled: check];
 747 }
 748
 749 wxSize wxNSTextViewControl::GetBestSize() const
 750 {
 751     if (m_textView && [m_textView layoutManager])
 752     {
 753         NSRect rect = [[m_textView layoutManager] usedRectForTextContainer: [m_textView textContainer]];
 754         return wxSize((int)(rect.size.width + [m_textView textContainerInset].width),
 755                       (int)(rect.size.height + [m_textView textContainerInset].height));
 756     }
 757     return wxSize(0,0);
 758 }
 759
 760 // wxNSTextFieldControl
 761
 762 wxNSTextFieldControl::wxNSTextFieldControl( wxTextCtrl *text, WXWidget w )
 763     : wxWidgetCocoaImpl(text, w),
 764       wxTextWidgetImpl(text)
 765 {
 766     Init(w);
 767 }
 768
 769 wxNSTextFieldControl::wxNSTextFieldControl(wxWindow *wxPeer,
 770                                            wxTextEntry *entry,
 771                                            WXWidget w)
 772     : wxWidgetCocoaImpl(wxPeer, w),
 773       wxTextWidgetImpl(entry)
 774 {
 775     Init(w);
 776 }
 777
 778 void wxNSTextFieldControl::Init(WXWidget w)
 779 {
 780     NSTextField wxOSX_10_6_AND_LATER(<NSTextFieldDelegate>) *tf = (NSTextField wxOSX_10_6_AND_LATER(<NSTextFieldDelegate>)*) w;
 781     m_textField = tf;
 782     [m_textField setDelegate: tf];
 783     m_selStart = m_selEnd = 0;
 784     m_hasEditor = [w isKindOfClass:[NSTextField class]];
 785 }
 786
 787 wxNSTextFieldControl::~wxNSTextFieldControl()
 788 {
 789     if (m_textField)
 790         [m_textField setDelegate: nil];
 791 }
 792
 793 wxString wxNSTextFieldControl::GetStringValue() const
 794 {
 795     return wxCFStringRef::AsString([m_textField stringValue], m_wxPeer->GetFont().GetEncoding());
 796 }
 797
 798 void wxNSTextFieldControl::SetStringValue( const wxString &str)
 799 {
 800     wxMacEditHelper helper(m_textField);
 801     [m_textField setStringValue: wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 802 }
 803
 804 void wxNSTextFieldControl::SetMaxLength(unsigned long len)
 805 {
 806     wxMaximumLengthFormatter* formatter = [[[wxMaximumLengthFormatter alloc] init] autorelease];
 807     [formatter setMaxLength:len];
 808     [m_textField setFormatter:formatter];
 809 }
 810
 811 void wxNSTextFieldControl::Copy()
 812 {
 813     NSText* editor = [m_textField currentEditor];
 814     if ( editor )
 815     {
 816         [editor copy:nil];
 817     }
 818 }
 819
 820 void wxNSTextFieldControl::Cut()
 821 {
 822     NSText* editor = [m_textField currentEditor];
 823     if ( editor )
 824     {
 825         [editor cut:nil];
 826     }
 827 }
 828
 829 void wxNSTextFieldControl::Paste()
 830 {
 831     NSText* editor = [m_textField currentEditor];
 832     if ( editor )
 833     {
 834         [editor paste:nil];
 835     }
 836 }
 837
 838 bool wxNSTextFieldControl::CanPaste() const
 839 {
 840     return true;
 841 }
 842
 843 void wxNSTextFieldControl::SetEditable(bool editable)
 844 {
 845     [m_textField setEditable:editable];
 846 }
 847
 848 void wxNSTextFieldControl::GetSelection( long* from, long* to) const
 849 {
 850     NSText* editor = [m_textField currentEditor];
 851     if ( editor )
 852     {
 853         NSRange range = [editor selectedRange];
 854         *from = range.location;
 855         *to = range.location + range.length;
 856     }
 857     else
 858     {
 859         *from = m_selStart;
 860         *to = m_selEnd;
 861     }
 862 }
 863
 864 void wxNSTextFieldControl::SetSelection( long from , long to )
 865 {
 866     long textLength = [[m_textField stringValue] length];
 867     if ((from == -1) && (to == -1))
 868     {
 869         from = 0 ;
 870         to = textLength ;
 871     }
 872     else
 873     {
 874         from = wxMin(textLength,wxMax(from,0)) ;
 875         if ( to == -1 )
 876             to = textLength;
 877         else
 878             to = wxMax(0,wxMin(textLength,to)) ;
 879     }
 880
 881     NSText* editor = [m_textField currentEditor];
 882     if ( editor )
 883     {
 884         [editor setSelectedRange:NSMakeRange(from, to-from)];
 885     }
 886
 887     // the editor might still be in existence, but we might be already passed our 'focus lost' storage
 888     // of the selection, so make sure we copy this
 889     m_selStart = from;
 890     m_selEnd = to;
 891 }
 892
 893 void wxNSTextFieldControl::WriteText(const wxString& str)
 894 {
 895     NSEvent* formerEvent = m_lastKeyDownEvent;
 896     m_lastKeyDownEvent = nil;
 897     NSText* editor = [m_textField currentEditor];
 898     if ( editor )
 899     {
 900         wxMacEditHelper helper(m_textField);
 901         BOOL hasUndo = [editor respondsToSelector:@selector(setAllowsUndo:)];
 902         if ( hasUndo )
 903             [(NSTextView*)editor setAllowsUndo:NO];
 904         [editor insertText:wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 905         if ( hasUndo )
 906             [(NSTextView*)editor setAllowsUndo:YES];
 907     }
 908     else
 909     {
 910         wxString val = GetStringValue() ;
 911         long start , end ;
 912         GetSelection( &start , &end ) ;
 913         val.Remove( start , end - start ) ;
 914         val.insert( start , str ) ;
 915         SetStringValue( val ) ;
 916         SetSelection( start + str.length() , start + str.length() ) ;
 917     }
 918     m_lastKeyDownEvent = formerEvent;
 919 }
 920
 921 void wxNSTextFieldControl::controlAction(WXWidget WXUNUSED(slf),
 922     void* WXUNUSED(_cmd), void *WXUNUSED(sender))
 923 {
 924     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
 925     if ( wxpeer && (wxpeer->GetWindowStyle() & wxTE_PROCESS_ENTER) )
 926     {
 927         wxCommandEvent event(wxEVT_TEXT_ENTER, wxpeer->GetId());
 928         event.SetEventObject( wxpeer );
 929         event.SetString( GetTextEntry()->GetValue() );
 930         wxpeer->HandleWindowEvent( event );
 931     }
 932 }
 933
 934 void wxNSTextFieldControl::SetInternalSelection( long from , long to )
 935 {
 936     m_selStart = from;
 937     m_selEnd = to;
 938 }
 939
 940 // as becoming first responder on a window - triggers a resign on the same control, we have to avoid
 941 // the resign notification writing back native selection values before we can set our own
 942
 943 static WXWidget s_widgetBecomingFirstResponder = nil;
 944
 945 bool wxNSTextFieldControl::becomeFirstResponder(WXWidget slf, void *_cmd)
 946 {
 947     s_widgetBecomingFirstResponder = slf;
 948     bool retval = wxWidgetCocoaImpl::becomeFirstResponder(slf, _cmd);
 949     s_widgetBecomingFirstResponder = nil;
 950     if ( retval )
 951     {
 952         NSText* editor = [m_textField currentEditor];
 953         if ( editor )
 954         {
 955             long textLength = [[m_textField stringValue] length];
 956             m_selStart = wxMin(textLength,wxMax(m_selStart,0)) ;
 957             m_selEnd = wxMax(0,wxMin(textLength,m_selEnd)) ;
 958
 959             [editor setSelectedRange:NSMakeRange(m_selStart, m_selEnd-m_selStart)];
 960         }
 961     }
 962     return retval;
 963 }
 964
 965 bool wxNSTextFieldControl::resignFirstResponder(WXWidget slf, void *_cmd)
 966 {
 967     if ( slf != s_widgetBecomingFirstResponder )
 968     {
 969         NSText* editor = [m_textField currentEditor];
 970         if ( editor )
 971         {
 972             NSRange range = [editor selectedRange];
 973             m_selStart = range.location;
 974             m_selEnd = range.location + range.length;
 975         }
 976     }
 977     return wxWidgetCocoaImpl::resignFirstResponder(slf, _cmd);
 978 }
 979
 980 bool wxNSTextFieldControl::SetHint(const wxString& hint)
 981 {
 982     wxCFStringRef hintstring(hint);
 983     [[m_textField cell] setPlaceholderString:hintstring.AsNSString()];
 984     return true;
 985 }
 986
 987 //
 988 //
 989 //
 990
 991 wxWidgetImplType* wxWidgetImpl::CreateTextControl( wxTextCtrl* wxpeer,
 992                                     wxWindowMac* WXUNUSED(parent),
 993                                     wxWindowID WXUNUSED(id),
 994                                     const wxString& WXUNUSED(str),
 995                                     const wxPoint& pos,
 996                                     const wxSize& size,
 997                                     long style,
 998                                     long WXUNUSED(extraStyle))
 999 {
1000     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
1001     wxWidgetCocoaImpl* c = NULL;
1002
1003     if ( style & wxTE_MULTILINE )
1004     {
1005         wxNSTextScrollView* v = nil;
1006         v = [[wxNSTextScrollView alloc] initWithFrame:r];
1007         c = new wxNSTextViewControl( wxpeer, v );
1008         c->SetNeedsFocusRect( true );
1009     }
1010     else
1011     {
1012         NSTextField* v = nil;
1013         if ( style & wxTE_PASSWORD )
1014             v = [[wxNSSecureTextField alloc] initWithFrame:r];
1015         else
1016             v = [[wxNSTextField alloc] initWithFrame:r];
1017
1018         if ( style & wxTE_RIGHT)
1019         {
1020             [v setAlignment:NSRightTextAlignment];
1021         }
1022         else if ( style & wxTE_CENTRE)
1023         {
1024             [v setAlignment:NSCenterTextAlignment];
1025         }
1026
1027         NSTextFieldCell* cell = [v cell];
1028         [cell setScrollable:YES];
1029         // TODO: Remove if we definitely are sure, it's not needed
1030         // as setting scrolling to yes, should turn off any wrapping
1031         // [cell setLineBreakMode:NSLineBreakByClipping];
1032
1033         c = new wxNSTextFieldControl( wxpeer, wxpeer, v );
1034
1035         if ( (style & wxNO_BORDER) || (style & wxSIMPLE_BORDER) )
1036         {
1037             // under 10.7 the textcontrol can draw its own focus
1038             // even if no border is shown, on previous systems
1039             // we have to emulate this
1040             [v setBezeled:NO];
1041             [v setBordered:NO];
1042             if ( UMAGetSystemVersion() < 0x1070 )
1043                 c->SetNeedsFocusRect( true );
1044         }
1045         else
1046         {
1047             // use native border
1048             c->SetNeedsFrame(false);
1049         }
1050     }
1051
1052     return c;
1053 }
1054
1055
1056 #endif // wxUSE_TEXTCTRL