src/osx/cocoa/textctrl.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/textctrl.mm
   3 // Purpose:     wxTextCtrl
   4 // Author:      Stefan Csomor
   5 // Modified by: Ryan Norton (MLTE GetLineLength and GetLineText)
   6 // Created:     1998-01-01
   7 // RCS-ID:      $Id$
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if wxUSE_TEXTCTRL
  15
  16 #include "wx/textctrl.h"
  17
  18 #ifndef WX_PRECOMP
  19     #include "wx/intl.h"
  20     #include "wx/app.h"
  21     #include "wx/utils.h"
  22     #include "wx/dc.h"
  23     #include "wx/button.h"
  24     #include "wx/menu.h"
  25     #include "wx/settings.h"
  26     #include "wx/msgdlg.h"
  27     #include "wx/toplevel.h"
  28 #endif
  29
  30 #ifdef __DARWIN__
  31     #include <sys/types.h>
  32     #include <sys/stat.h>
  33 #else
  34     #include <stat.h>
  35 #endif
  36
  37 #if wxUSE_STD_IOSTREAM
  38     #if wxUSE_IOSTREAMH
  39         #include <fstream.h>
  40     #else
  41         #include <fstream>
  42     #endif
  43 #endif
  44
  45 #include "wx/filefn.h"
  46 #include "wx/sysopt.h"
  47 #include "wx/thread.h"
  48 #include "wx/textcompleter.h"
  49
  50 #include "wx/osx/private.h"
  51 #include "wx/osx/cocoa/private/textimpl.h"
  52
  53 @interface NSView(EditableView)
  54 - (BOOL)isEditable;
  55 - (void)setEditable:(BOOL)flag;
  56 - (BOOL)isSelectable;
  57 - (void)setSelectable:(BOOL)flag;
  58 @end
  59
  60 // An object of this class is created before the text is modified
  61 // programmatically and destroyed as soon as this is done. It does several
  62 // things, like ensuring that the control is editable to allow setting its text
  63 // at all and eating any unwanted focus loss events from textDidEndEditing:
  64 // which don't really correspond to focus change.
  65 class wxMacEditHelper
  66 {
  67 public :
  68     wxMacEditHelper( NSView* textView )
  69     {
  70         m_viewPreviouslyEdited = ms_viewCurrentlyEdited;
  71         ms_viewCurrentlyEdited =
  72         m_textView = textView;
  73         m_formerEditable = YES;
  74         if ( textView )
  75         {
  76             m_formerEditable = [textView isEditable];
  77             m_formerSelectable = [textView isSelectable];
  78             [textView setEditable:YES];
  79         }
  80     }
  81
  82     ~wxMacEditHelper()
  83     {
  84         if ( m_textView )
  85         {
  86             [m_textView setEditable:m_formerEditable];
  87             [m_textView setSelectable:m_formerSelectable];
  88         }
  89
  90         ms_viewCurrentlyEdited = m_viewPreviouslyEdited;
  91     }
  92
  93     // Returns the last view we were instantiated for or NULL.
  94     static NSView *GetCurrentlyEditedView() { return ms_viewCurrentlyEdited; }
  95
  96 protected :
  97     BOOL m_formerEditable ;
  98     BOOL m_formerSelectable;
  99     NSView* m_textView;
 100
 101     // The original value of ms_viewCurrentlyEdited when this object was
 102     // created.
 103     NSView* m_viewPreviouslyEdited;
 104
 105     static NSView* ms_viewCurrentlyEdited;
 106 } ;
 107
 108 NSView* wxMacEditHelper::ms_viewCurrentlyEdited = nil;
 109
 110 // a minimal NSFormatter that just avoids getting too long entries
 111 @interface wxMaximumLengthFormatter : NSFormatter
 112 {
 113     int maxLength;
 114 }
 115
 116 @end
 117
 118 @implementation wxMaximumLengthFormatter
 119
 120 - (id)init
 121 {
 122     self = [super init];
 123     maxLength = 0;
 124     return self;
 125 }
 126
 127 - (void) setMaxLength:(int) maxlen
 128 {
 129     maxLength = maxlen;
 130 }
 131
 132 - (NSString *)stringForObjectValue:(id)anObject
 133 {
 134     if(![anObject isKindOfClass:[NSString class]])
 135         return nil;
 136     return [NSString stringWithString:anObject];
 137 }
 138
 139 - (BOOL)getObjectValue:(id *)obj forString:(NSString *)string errorDescription:(NSString  **)error
 140 {
 141     *obj = [NSString stringWithString:string];
 142     return YES;
 143 }
 144
 145 - (BOOL)isPartialStringValid:(NSString **)partialStringPtr proposedSelectedRange:(NSRangePointer)proposedSelRangePtr
 146               originalString:(NSString *)origString originalSelectedRange:(NSRange)origSelRange errorDescription:(NSString **)error
 147 {
 148     int len = [*partialStringPtr length];
 149     if ( maxLength > 0 && len > maxLength )
 150     {
 151         // TODO wxEVT_COMMAND_TEXT_MAXLEN
 152         return NO;
 153     }
 154     return YES;
 155 }
 156
 157 @end
 158
 159 @implementation wxNSSecureTextField
 160
 161 + (void)initialize
 162 {
 163     static BOOL initialized = NO;
 164     if (!initialized)
 165     {
 166         initialized = YES;
 167         wxOSXCocoaClassAddWXMethods( self );
 168     }
 169 }
 170
 171 - (void)controlTextDidChange:(NSNotification *)aNotification
 172 {
 173     wxUnusedVar(aNotification);
 174     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 175     if ( impl )
 176         impl->controlTextDidChange();
 177 }
 178
 179 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 180 {
 181     wxUnusedVar(aNotification);
 182     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 183     if ( impl )
 184     {
 185         impl->DoNotifyFocusEvent( false, NULL );
 186     }
 187 }
 188
 189 - (BOOL)control:(NSControl*)control textView:(NSTextView*)textView doCommandBySelector:(SEL)commandSelector
 190 {
 191     wxUnusedVar(textView);
 192
 193     BOOL handled = NO;
 194
 195     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( control );
 196     if ( impl  )
 197     {
 198         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 199         if ( wxpeer )
 200         {
 201             if (commandSelector == @selector(insertNewline:))
 202             {
 203                 wxTopLevelWindow *tlw = wxDynamicCast(wxGetTopLevelParent(wxpeer), wxTopLevelWindow);
 204                 if ( tlw && tlw->GetDefaultItem() )
 205                 {
 206                     wxButton *def = wxDynamicCast(tlw->GetDefaultItem(), wxButton);
 207                     if ( def && def->IsEnabled() )
 208                     {
 209                         wxCommandEvent event(wxEVT_COMMAND_BUTTON_CLICKED, def->GetId() );
 210                         event.SetEventObject(def);
 211                         def->Command(event);
 212                         handled = YES;
 213                     }
 214                 }
 215             }
 216         }
 217     }
 218
 219     return handled;
 220 }
 221
 222 @end
 223
 224 @interface wxNSTextScrollView : NSScrollView
 225 {
 226 }
 227 @end
 228
 229 @implementation wxNSTextScrollView
 230
 231 + (void)initialize
 232 {
 233     static BOOL initialized = NO;
 234     if (!initialized)
 235     {
 236         initialized = YES;
 237         wxOSXCocoaClassAddWXMethods( self );
 238     }
 239 }
 240
 241 @end
 242
 243 @implementation wxNSTextFieldEditor
 244
 245 - (void) keyDown:(NSEvent*) event
 246 {
 247     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 248     lastKeyDownEvent = event;
 249     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 250         [super keyDown:event];
 251     lastKeyDownEvent = nil;
 252 }
 253
 254 - (void) keyUp:(NSEvent*) event
 255 {
 256     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 257     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 258         [super keyUp:event];
 259 }
 260
 261 - (void) flagsChanged:(NSEvent*) event
 262 {
 263     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 264     if ( impl == NULL || !impl->DoHandleKeyEvent(event) )
 265         [super flagsChanged:event];
 266 }
 267
 268 - (BOOL) performKeyEquivalent:(NSEvent*) event
 269 {
 270     BOOL retval = [super performKeyEquivalent:event];
 271     return retval;
 272 }
 273
 274 - (void) insertText:(id) str
 275 {
 276     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( (WXWidget) [self delegate] );
 277     if ( impl == NULL || lastKeyDownEvent==nil || !impl->DoHandleCharEvent(lastKeyDownEvent, str) )
 278     {
 279         [super insertText:str];
 280     }
 281 }
 282
 283 @end
 284
 285 @implementation wxNSTextView
 286
 287 + (void)initialize
 288 {
 289     static BOOL initialized = NO;
 290     if (!initialized)
 291     {
 292         initialized = YES;
 293         wxOSXCocoaClassAddWXMethods( self );
 294     }
 295 }
 296
 297 - (void)textDidChange:(NSNotification *)aNotification
 298 {
 299     wxUnusedVar(aNotification);
 300     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 301     if ( impl )
 302         impl->controlTextDidChange();
 303 }
 304
 305 - (void) setEnabled:(BOOL) flag
 306 {
 307     // from Technical Q&A QA1461
 308     if (flag) {
 309         [self setTextColor: [NSColor controlTextColor]];
 310
 311     } else {
 312         [self setTextColor: [NSColor disabledControlTextColor]];
 313     }
 314
 315     [self setSelectable: flag];
 316     [self setEditable: flag];
 317 }
 318
 319 - (BOOL) isEnabled
 320 {
 321     return [self isEditable];
 322 }
 323
 324 - (void)textDidEndEditing:(NSNotification *)aNotification
 325 {
 326     wxUnusedVar(aNotification);
 327
 328     if ( self == wxMacEditHelper::GetCurrentlyEditedView() )
 329     {
 330         // This notification is generated as the result of calling our own
 331         // wxTextCtrl method (e.g. WriteText()) and doesn't correspond to any
 332         // real focus loss event so skip generating it.
 333         return;
 334     }
 335
 336     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 337     if ( impl )
 338     {
 339         impl->DoNotifyFocusEvent( false, NULL );
 340     }
 341 }
 342
 343 @end
 344
 345 @implementation wxNSTextField
 346
 347 + (void)initialize
 348 {
 349     static BOOL initialized = NO;
 350     if (!initialized)
 351     {
 352         initialized = YES;
 353         wxOSXCocoaClassAddWXMethods( self );
 354     }
 355 }
 356
 357 - (id) initWithFrame:(NSRect) frame
 358 {
 359     self = [super initWithFrame:frame];
 360     fieldEditor = nil;
 361     return self;
 362 }
 363
 364 - (void) dealloc
 365 {
 366     [fieldEditor release];
 367     [super dealloc];
 368 }
 369
 370 - (void) setFieldEditor:(wxNSTextFieldEditor*) editor
 371 {
 372     if ( editor != fieldEditor )
 373     {
 374         [editor retain];
 375         [fieldEditor release];
 376         fieldEditor = editor;
 377     }
 378 }
 379
 380 - (wxNSTextFieldEditor*) fieldEditor
 381 {
 382     return fieldEditor;
 383 }
 384
 385 - (void) setEnabled:(BOOL) flag
 386 {
 387     [super setEnabled: flag];
 388
 389     if (![self drawsBackground]) {
 390         // Static text is drawn incorrectly when disabled.
 391         // For an explanation, see
 392         // http://www.cocoabuilder.com/archive/message/cocoa/2006/7/21/168028
 393         if (flag) {
 394             [self setTextColor: [NSColor controlTextColor]];
 395         } else {
 396             [self setTextColor: [NSColor secondarySelectedControlColor]];
 397         }
 398     }
 399 }
 400
 401 - (void)controlTextDidChange:(NSNotification *)aNotification
 402 {
 403     wxUnusedVar(aNotification);
 404     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 405     if ( impl )
 406         impl->controlTextDidChange();
 407 }
 408
 409 - (NSArray *)control:(NSControl *)control textView:(NSTextView *)textView completions:(NSArray *)words
 410  forPartialWordRange:(NSRange)charRange indexOfSelectedItem:(NSInteger*)index
 411 {
 412     NSMutableArray* matches = NULL;
 413
 414     wxTextWidgetImpl* impl = (wxNSTextFieldControl * ) wxWidgetImpl::FindFromWXWidget( self );
 415     wxTextEntry * const entry = impl->GetTextEntry();
 416     wxTextCompleter * const completer = entry->OSXGetCompleter();
 417     if ( completer )
 418     {
 419         const wxString prefix = entry->GetValue();
 420         if ( completer->Start(prefix) )
 421         {
 422             const wxString
 423                 wordStart = wxCFStringRef::AsString(
 424                               [[textView string] substringWithRange:charRange]
 425                             );
 426
 427             matches = [NSMutableArray array];
 428             for ( ;; )
 429             {
 430                 const wxString s = completer->GetNext();
 431                 if ( s.empty() )
 432                     break;
 433
 434                 // Normally the completer should return only the strings
 435                 // starting with the prefix, but there could be exceptions
 436                 // and, for compatibility with MSW which simply ignores all
 437                 // entries that don't match the current text control contents,
 438                 // we ignore them as well. Besides, our own wxTextCompleterFixed
 439                 // doesn't respect this rule and, moreover, we need to extract
 440                 // just the rest of the string anyhow.
 441                 wxString completion;
 442                 if ( s.StartsWith(prefix, &completion) )
 443                 {
 444                     // We discarded the entire prefix above but actually we
 445                     // should include the part of it that consists of the
 446                     // beginning of the current word, otherwise it would be
 447                     // lost when completion is accepted as OS X supposes that
 448                     // our matches do start with the "partial word range"
 449                     // passed to us.
 450                     const wxCFStringRef fullWord(wordStart + completion);
 451                     [matches addObject: fullWord.AsNSString()];
 452                 }
 453             }
 454         }
 455     }
 456
 457     return matches;
 458 }
 459
 460 - (BOOL)control:(NSControl*)control textView:(NSTextView*)textView doCommandBySelector:(SEL)commandSelector
 461 {
 462     wxUnusedVar(textView);
 463     wxUnusedVar(control);
 464
 465     BOOL handled = NO;
 466
 467     // send back key events wx' common code knows how to handle
 468
 469     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 470     if ( impl  )
 471     {
 472         wxWindow* wxpeer = (wxWindow*) impl->GetWXPeer();
 473         if ( wxpeer )
 474         {
 475             if (commandSelector == @selector(insertNewline:))
 476             {
 477                 [textView insertNewlineIgnoringFieldEditor:self];
 478                 handled = YES;
 479             }
 480             else if ( commandSelector == @selector(insertTab:))
 481             {
 482                 [textView insertTabIgnoringFieldEditor:self];
 483                 handled = YES;
 484             }
 485             else if ( commandSelector == @selector(insertBacktab:))
 486             {
 487                 [textView insertTabIgnoringFieldEditor:self];
 488                 handled = YES;
 489             }
 490         }
 491     }
 492
 493     return handled;
 494 }
 495
 496 - (void)controlTextDidEndEditing:(NSNotification *)aNotification
 497 {
 498     wxUnusedVar(aNotification);
 499     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 500     if ( impl )
 501     {
 502         impl->DoNotifyFocusEvent( false, NULL );
 503     }
 504 }
 505 @end
 506
 507 // wxNSTextViewControl
 508
 509 wxNSTextViewControl::wxNSTextViewControl( wxTextCtrl *wxPeer, WXWidget w )
 510     : wxWidgetCocoaImpl(wxPeer, w),
 511       wxTextWidgetImpl(wxPeer)
 512 {
 513     wxNSTextScrollView* sv = (wxNSTextScrollView*) w;
 514     m_scrollView = sv;
 515
 516     [m_scrollView setHasVerticalScroller:YES];
 517     [m_scrollView setHasHorizontalScroller:NO];
 518     // TODO Remove if no regression, this was causing automatic resizes of multi-line textfields when the tlw changed
 519     // [m_scrollView setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
 520     NSSize contentSize = [m_scrollView contentSize];
 521
 522     wxNSTextView* tv = [[wxNSTextView alloc] initWithFrame: NSMakeRect(0, 0,
 523             contentSize.width, contentSize.height)];
 524     m_textView = tv;
 525     [tv setVerticallyResizable:YES];
 526     [tv setHorizontallyResizable:NO];
 527     [tv setAutoresizingMask:NSViewWidthSizable];
 528
 529     [m_scrollView setDocumentView: tv];
 530
 531     [tv setDelegate: tv];
 532
 533     InstallEventHandler(tv);
 534 }
 535
 536 wxNSTextViewControl::~wxNSTextViewControl()
 537 {
 538     if (m_textView)
 539         [m_textView setDelegate: nil];
 540 }
 541
 542 bool wxNSTextViewControl::CanFocus() const
 543 {
 544     // since this doesn't work (return false), we hardcode
 545     // if (m_textView)
 546     //    return [m_textView canBecomeKeyView];
 547     return true;
 548 }
 549
 550 wxString wxNSTextViewControl::GetStringValue() const
 551 {
 552     if (m_textView)
 553     {
 554         wxString result = wxCFStringRef::AsString([m_textView string], m_wxPeer->GetFont().GetEncoding());
 555         wxMacConvertNewlines13To10( &result ) ;
 556         return result;
 557     }
 558     return wxEmptyString;
 559 }
 560 void wxNSTextViewControl::SetStringValue( const wxString &str)
 561 {
 562     wxString st = str;
 563     wxMacConvertNewlines10To13( &st );
 564     wxMacEditHelper helper(m_textView);
 565
 566     if (m_textView)
 567         [m_textView setString: wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 568 }
 569
 570 void wxNSTextViewControl::Copy()
 571 {
 572     if (m_textView)
 573         [m_textView copy:nil];
 574
 575 }
 576
 577 void wxNSTextViewControl::Cut()
 578 {
 579     if (m_textView)
 580         [m_textView cut:nil];
 581 }
 582
 583 void wxNSTextViewControl::Paste()
 584 {
 585     if (m_textView)
 586         [m_textView paste:nil];
 587 }
 588
 589 bool wxNSTextViewControl::CanPaste() const
 590 {
 591     return true;
 592 }
 593
 594 void wxNSTextViewControl::SetEditable(bool editable)
 595 {
 596     if (m_textView)
 597         [m_textView setEditable: editable];
 598 }
 599
 600 void wxNSTextViewControl::GetSelection( long* from, long* to) const
 601 {
 602     if (m_textView)
 603     {
 604         NSRange range = [m_textView selectedRange];
 605         *from = range.location;
 606         *to = range.location + range.length;
 607     }
 608 }
 609
 610 void wxNSTextViewControl::SetSelection( long from , long to )
 611 {
 612     long textLength = [[m_textView string] length];
 613     if ((from == -1) && (to == -1))
 614     {
 615         from = 0 ;
 616         to = textLength ;
 617     }
 618     else
 619     {
 620         from = wxMin(textLength,wxMax(from,0)) ;
 621         if ( to == -1 )
 622             to = textLength;
 623         else
 624             to = wxMax(0,wxMin(textLength,to)) ;
 625     }
 626
 627     NSRange selrange = NSMakeRange(from, to-from);
 628     [m_textView setSelectedRange:selrange];
 629     [m_textView scrollRangeToVisible:selrange];
 630 }
 631
 632 void wxNSTextViewControl::WriteText(const wxString& str)
 633 {
 634     wxString st = str;
 635     wxMacConvertNewlines10To13( &st );
 636     wxMacEditHelper helper(m_textView);
 637     NSEvent* formerEvent = m_lastKeyDownEvent;
 638     m_lastKeyDownEvent = nil;
 639     [m_textView insertText:wxCFStringRef( st , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 640     m_lastKeyDownEvent = formerEvent;
 641 }
 642
 643 void wxNSTextViewControl::SetFont( const wxFont & font , const wxColour& WXUNUSED(foreground) , long WXUNUSED(windowStyle), bool WXUNUSED(ignoreBlack) )
 644 {
 645     if ([m_textView respondsToSelector:@selector(setFont:)])
 646         [m_textView setFont: font.OSXGetNSFont()];
 647 }
 648
 649 bool wxNSTextViewControl::GetStyle(long position, wxTextAttr& style)
 650 {
 651     if (m_textView && position >=0)
 652     {
 653         NSFont* font = NULL;
 654         NSColor* bgcolor = NULL;
 655         NSColor* fgcolor = NULL;
 656         // NOTE: It appears that other platforms accept GetStyle with the position == length
 657         // but that NSTextStorage does not accept length as a valid position.
 658         // Therefore we return the default control style in that case.
 659         if (position < (long) [[m_textView string] length])
 660         {
 661             NSTextStorage* storage = [m_textView textStorage];
 662             font = [[storage attribute:NSFontAttributeName atIndex:position effectiveRange:NULL] autorelease];
 663             bgcolor = [[storage attribute:NSBackgroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 664             fgcolor = [[storage attribute:NSForegroundColorAttributeName atIndex:position effectiveRange:NULL] autorelease];
 665         }
 666         else
 667         {
 668             NSDictionary* attrs = [m_textView typingAttributes];
 669             font = [[attrs objectForKey:NSFontAttributeName] autorelease];
 670             bgcolor = [[attrs objectForKey:NSBackgroundColorAttributeName] autorelease];
 671             fgcolor = [[attrs objectForKey:NSForegroundColorAttributeName] autorelease];
 672         }
 673
 674         if (font)
 675             style.SetFont(wxFont(font));
 676
 677         if (bgcolor)
 678             style.SetBackgroundColour(wxColour(bgcolor));
 679
 680         if (fgcolor)
 681             style.SetTextColour(wxColour(fgcolor));
 682         return true;
 683     }
 684
 685     return false;
 686 }
 687
 688 void wxNSTextViewControl::SetStyle(long start,
 689                                 long end,
 690                                 const wxTextAttr& style)
 691 {
 692     if ( !m_textView )
 693         return;
 694
 695     if ( start == -1 && end == -1 )
 696     {
 697         NSMutableDictionary* const
 698             attrs = [NSMutableDictionary dictionaryWithCapacity:3];
 699         if ( style.HasFont() )
 700             [attrs setValue:style.GetFont().OSXGetNSFont() forKey:NSFontAttributeName];
 701         if ( style.HasBackgroundColour() )
 702             [attrs setValue:style.GetBackgroundColour().OSXGetNSColor() forKey:NSBackgroundColorAttributeName];
 703         if ( style.HasTextColour() )
 704             [attrs setValue:style.GetTextColour().OSXGetNSColor() forKey:NSForegroundColorAttributeName];
 705
 706         [m_textView setTypingAttributes:attrs];
 707     }
 708     else // Set the attributes just for this range.
 709     {
 710         NSRange range = NSMakeRange(start, end-start);
 711
 712         NSTextStorage* storage = [m_textView textStorage];
 713         if ( style.HasFont() )
 714             [storage addAttribute:NSFontAttributeName value:style.GetFont().OSXGetNSFont() range:range];
 715
 716         if ( style.HasBackgroundColour() )
 717             [storage addAttribute:NSBackgroundColorAttributeName value:style.GetBackgroundColour().OSXGetNSColor() range:range];
 718
 719         if ( style.HasTextColour() )
 720             [storage addAttribute:NSForegroundColorAttributeName value:style.GetTextColour().OSXGetNSColor() range:range];
 721     }
 722 }
 723
 724 void wxNSTextViewControl::CheckSpelling(bool check)
 725 {
 726     if (m_textView)
 727         [m_textView setContinuousSpellCheckingEnabled: check];
 728 }
 729
 730 wxSize wxNSTextViewControl::GetBestSize() const
 731 {
 732     if (m_textView && [m_textView layoutManager])
 733     {
 734         NSRect rect = [[m_textView layoutManager] usedRectForTextContainer: [m_textView textContainer]];
 735         return wxSize((int)(rect.size.width + [m_textView textContainerInset].width),
 736                       (int)(rect.size.height + [m_textView textContainerInset].height));
 737     }
 738     return wxSize(0,0);
 739 }
 740
 741 // wxNSTextFieldControl
 742
 743 wxNSTextFieldControl::wxNSTextFieldControl( wxTextCtrl *text, WXWidget w )
 744     : wxWidgetCocoaImpl(text, w),
 745       wxTextWidgetImpl(text)
 746 {
 747     Init(w);
 748 }
 749
 750 wxNSTextFieldControl::wxNSTextFieldControl(wxWindow *wxPeer,
 751                                            wxTextEntry *entry,
 752                                            WXWidget w)
 753     : wxWidgetCocoaImpl(wxPeer, w),
 754       wxTextWidgetImpl(entry)
 755 {
 756     Init(w);
 757 }
 758
 759 void wxNSTextFieldControl::Init(WXWidget w)
 760 {
 761     NSTextField wxOSX_10_6_AND_LATER(<NSTextFieldDelegate>) *tf = (NSTextField wxOSX_10_6_AND_LATER(<NSTextFieldDelegate>)*) w;
 762     m_textField = tf;
 763     [m_textField setDelegate: tf];
 764     m_selStart = m_selEnd = 0;
 765     m_hasEditor = [w isKindOfClass:[NSTextField class]];
 766 }
 767
 768 wxNSTextFieldControl::~wxNSTextFieldControl()
 769 {
 770     if (m_textField)
 771         [m_textField setDelegate: nil];
 772 }
 773
 774 wxString wxNSTextFieldControl::GetStringValue() const
 775 {
 776     return wxCFStringRef::AsString([m_textField stringValue], m_wxPeer->GetFont().GetEncoding());
 777 }
 778
 779 void wxNSTextFieldControl::SetStringValue( const wxString &str)
 780 {
 781     wxMacEditHelper helper(m_textField);
 782     [m_textField setStringValue: wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 783 }
 784
 785 void wxNSTextFieldControl::SetMaxLength(unsigned long len)
 786 {
 787     wxMaximumLengthFormatter* formatter = [[[wxMaximumLengthFormatter alloc] init] autorelease];
 788     [formatter setMaxLength:len];
 789     [m_textField setFormatter:formatter];
 790 }
 791
 792 void wxNSTextFieldControl::Copy()
 793 {
 794     NSText* editor = [m_textField currentEditor];
 795     if ( editor )
 796     {
 797         [editor copy:nil];
 798     }
 799 }
 800
 801 void wxNSTextFieldControl::Cut()
 802 {
 803     NSText* editor = [m_textField currentEditor];
 804     if ( editor )
 805     {
 806         [editor cut:nil];
 807     }
 808 }
 809
 810 void wxNSTextFieldControl::Paste()
 811 {
 812     NSText* editor = [m_textField currentEditor];
 813     if ( editor )
 814     {
 815         [editor paste:nil];
 816     }
 817 }
 818
 819 bool wxNSTextFieldControl::CanPaste() const
 820 {
 821     return true;
 822 }
 823
 824 void wxNSTextFieldControl::SetEditable(bool editable)
 825 {
 826     [m_textField setEditable:editable];
 827 }
 828
 829 void wxNSTextFieldControl::GetSelection( long* from, long* to) const
 830 {
 831     NSText* editor = [m_textField currentEditor];
 832     if ( editor )
 833     {
 834         NSRange range = [editor selectedRange];
 835         *from = range.location;
 836         *to = range.location + range.length;
 837     }
 838     else
 839     {
 840         *from = m_selStart;
 841         *to = m_selEnd;
 842     }
 843 }
 844
 845 void wxNSTextFieldControl::SetSelection( long from , long to )
 846 {
 847     long textLength = [[m_textField stringValue] length];
 848     if ((from == -1) && (to == -1))
 849     {
 850         from = 0 ;
 851         to = textLength ;
 852     }
 853     else
 854     {
 855         from = wxMin(textLength,wxMax(from,0)) ;
 856         if ( to == -1 )
 857             to = textLength;
 858         else
 859             to = wxMax(0,wxMin(textLength,to)) ;
 860     }
 861
 862     NSText* editor = [m_textField currentEditor];
 863     if ( editor )
 864     {
 865         [editor setSelectedRange:NSMakeRange(from, to-from)];
 866     }
 867     else
 868     {
 869         m_selStart = from;
 870         m_selEnd = to;
 871     }
 872 }
 873
 874 void wxNSTextFieldControl::WriteText(const wxString& str)
 875 {
 876     NSEvent* formerEvent = m_lastKeyDownEvent;
 877     m_lastKeyDownEvent = nil;
 878     NSText* editor = [m_textField currentEditor];
 879     if ( editor )
 880     {
 881         wxMacEditHelper helper(m_textField);
 882         BOOL hasUndo = [editor respondsToSelector:@selector(setAllowsUndo:)];
 883         if ( hasUndo )
 884             [(NSTextView*)editor setAllowsUndo:NO];
 885         [editor insertText:wxCFStringRef( str , m_wxPeer->GetFont().GetEncoding() ).AsNSString()];
 886         if ( hasUndo )
 887             [(NSTextView*)editor setAllowsUndo:YES];
 888     }
 889     else
 890     {
 891         wxString val = GetStringValue() ;
 892         long start , end ;
 893         GetSelection( &start , &end ) ;
 894         val.Remove( start , end - start ) ;
 895         val.insert( start , str ) ;
 896         SetStringValue( val ) ;
 897         SetSelection( start + str.length() , start + str.length() ) ;
 898     }
 899     m_lastKeyDownEvent = formerEvent;
 900 }
 901
 902 void wxNSTextFieldControl::controlAction(WXWidget WXUNUSED(slf),
 903     void* WXUNUSED(_cmd), void *WXUNUSED(sender))
 904 {
 905     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
 906     if ( wxpeer && (wxpeer->GetWindowStyle() & wxTE_PROCESS_ENTER) )
 907     {
 908         wxCommandEvent event(wxEVT_COMMAND_TEXT_ENTER, wxpeer->GetId());
 909         event.SetEventObject( wxpeer );
 910         event.SetString( GetTextEntry()->GetValue() );
 911         wxpeer->HandleWindowEvent( event );
 912     }
 913 }
 914
 915 // as becoming first responder on a window - triggers a resign on the same control, we have to avoid
 916 // the resign notification writing back native selection values before we can set our own
 917
 918 static WXWidget s_widgetBecomingFirstResponder = nil;
 919
 920 bool wxNSTextFieldControl::becomeFirstResponder(WXWidget slf, void *_cmd)
 921 {
 922     s_widgetBecomingFirstResponder = slf;
 923     bool retval = wxWidgetCocoaImpl::becomeFirstResponder(slf, _cmd);
 924     s_widgetBecomingFirstResponder = nil;
 925     if ( retval )
 926     {
 927         NSText* editor = [m_textField currentEditor];
 928         if ( editor )
 929             [editor setSelectedRange:NSMakeRange(m_selStart, m_selEnd-m_selStart)];
 930     }
 931     return retval;
 932 }
 933
 934 bool wxNSTextFieldControl::resignFirstResponder(WXWidget slf, void *_cmd)
 935 {
 936     if ( slf != s_widgetBecomingFirstResponder )
 937     {
 938         NSText* editor = [m_textField currentEditor];
 939         if ( editor )
 940         {
 941             NSRange range = [editor selectedRange];
 942             m_selStart = range.location;
 943             m_selEnd = range.location + range.length;
 944         }
 945     }
 946     return wxWidgetCocoaImpl::resignFirstResponder(slf, _cmd);
 947 }
 948
 949 bool wxNSTextFieldControl::SetHint(const wxString& hint)
 950 {
 951     wxCFStringRef hintstring(hint);
 952     [[m_textField cell] setPlaceholderString:hintstring.AsNSString()];
 953     return true;
 954 }
 955
 956 //
 957 //
 958 //
 959
 960 wxWidgetImplType* wxWidgetImpl::CreateTextControl( wxTextCtrl* wxpeer,
 961                                     wxWindowMac* WXUNUSED(parent),
 962                                     wxWindowID WXUNUSED(id),
 963                                     const wxString& WXUNUSED(str),
 964                                     const wxPoint& pos,
 965                                     const wxSize& size,
 966                                     long style,
 967                                     long WXUNUSED(extraStyle))
 968 {
 969     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
 970     wxWidgetCocoaImpl* c = NULL;
 971
 972     if ( style & wxTE_MULTILINE || style & wxTE_RICH || style & wxTE_RICH2 )
 973     {
 974         wxNSTextScrollView* v = nil;
 975         v = [[wxNSTextScrollView alloc] initWithFrame:r];
 976         c = new wxNSTextViewControl( wxpeer, v );
 977         c->SetNeedsFocusRect( true );
 978     }
 979     else
 980     {
 981         NSTextField* v = nil;
 982         if ( style & wxTE_PASSWORD )
 983             v = [[wxNSSecureTextField alloc] initWithFrame:r];
 984         else
 985             v = [[wxNSTextField alloc] initWithFrame:r];
 986
 987         if ( style & wxTE_RIGHT)
 988         {
 989             [v setAlignment:NSRightTextAlignment];
 990         }
 991         else if ( style & wxTE_CENTRE)
 992         {
 993             [v setAlignment:NSCenterTextAlignment];
 994         }
 995
 996         NSTextFieldCell* cell = [v cell];
 997         [cell setScrollable:YES];
 998         // TODO: Remove if we definitely are sure, it's not needed
 999         // as setting scrolling to yes, should turn off any wrapping
1000         // [cell setLineBreakMode:NSLineBreakByClipping];
1001
1002         c = new wxNSTextFieldControl( wxpeer, wxpeer, v );
1003
1004         if ( (style & wxNO_BORDER) || (style & wxSIMPLE_BORDER) )
1005         {
1006             // under 10.7 the textcontrol can draw its own focus
1007             // even if no border is shown, on previous systems
1008             // we have to emulate this
1009             [v setBezeled:NO];
1010             [v setBordered:NO];
1011             if ( UMAGetSystemVersion() < 0x1070 )
1012                 c->SetNeedsFocusRect( true );
1013         }
1014         else
1015         {
1016             // use native border
1017             c->SetNeedsFrame(false);
1018         }
1019     }
1020
1021     return c;
1022 }
1023
1024
1025 #endif // wxUSE_TEXTCTRL