src/osx/cocoa/window.mm

   1 /////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/window.mm
   3 // Purpose:     widgets (non tlw) for cocoa
   4 // Author:      Stefan Csomor
   5 // Modified by:
   6 // Created:     2008-06-20
   7 // RCS-ID:      $Id: window.mm 48805 2007-09-19 14:52:25Z SC $
   8 // Copyright:   (c) Stefan Csomor
   9 // Licence:     wxWindows licence
  10 /////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #ifndef WX_PRECOMP
  15     #include "wx/dcclient.h"
  16     #include "wx/frame.h"
  17     #include "wx/log.h"
  18     #include "wx/textctrl.h"
  19     #include "wx/combobox.h"
  20 #endif
  21
  22 #ifdef __WXMAC__
  23     #include "wx/osx/private.h"
  24 #endif
  25
  26 #include "wx/evtloop.h"
  27
  28 #if wxUSE_CARET
  29     #include "wx/caret.h"
  30 #endif
  31
  32 #if wxUSE_DRAG_AND_DROP
  33     #include "wx/dnd.h"
  34 #endif
  35
  36 #if wxUSE_TOOLTIPS
  37     #include "wx/tooltip.h"
  38 #endif
  39
  40 #include <objc/objc-runtime.h>
  41
  42 // Get the window with the focus
  43
  44 NSView* GetViewFromResponder( NSResponder* responder )
  45 {
  46     NSView* view = nil;
  47     if ( [responder isKindOfClass:[NSTextView class]] )
  48     {
  49         NSView* delegate = (NSView*) [(NSTextView*)responder delegate];
  50         if ( [delegate isKindOfClass:[NSTextField class] ] )
  51             view = delegate;
  52         else
  53             view =  (NSView*) responder;
  54     }
  55     else
  56     {
  57         if ( [responder isKindOfClass:[NSView class]] )
  58             view = (NSView*) responder;
  59     }
  60     return view;
  61 }
  62
  63 NSView* GetFocusedViewInWindow( NSWindow* keyWindow )
  64 {
  65     NSView* focusedView = nil;
  66     if ( keyWindow != nil )
  67         focusedView = GetViewFromResponder([keyWindow firstResponder]);
  68
  69     return focusedView;
  70 }
  71
  72 WXWidget wxWidgetImpl::FindFocus()
  73 {
  74     return GetFocusedViewInWindow( [NSApp keyWindow] );
  75 }
  76
  77 NSRect wxOSXGetFrameForControl( wxWindowMac* window , const wxPoint& pos , const wxSize &size , bool adjustForOrigin )
  78 {
  79     int x, y, w, h ;
  80
  81     window->MacGetBoundsForControl( pos , size , x , y, w, h , adjustForOrigin ) ;
  82     wxRect bounds(x,y,w,h);
  83     NSView* sv = (window->GetParent()->GetHandle() );
  84
  85     return wxToNSRect( sv, bounds );
  86 }
  87
  88 @interface wxNSView : NSView
  89 {
  90     NSTrackingRectTag rectTag;
  91 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
  92     NSTrackingArea* _trackingArea;
  93 #endif
  94 }
  95
  96 // the tracking tag is needed to track mouse enter / exit events
  97 - (void) setTrackingTag: (NSTrackingRectTag)tag;
  98 - (NSTrackingRectTag) trackingTag;
  99 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 100 // under 10.5 we can also track mouse moved events on non-focused windows if
 101 // we use the new NSTrackingArea APIs.
 102 - (void) updateTrackingArea;
 103 - (NSTrackingArea*) trackingArea;
 104 #endif
 105 @end // wxNSView
 106
 107 @interface NSView(PossibleMethods)
 108 - (void)setTitle:(NSString *)aString;
 109 - (void)setStringValue:(NSString *)aString;
 110 - (void)setIntValue:(int)anInt;
 111 - (void)setFloatValue:(float)aFloat;
 112 - (void)setDoubleValue:(double)aDouble;
 113
 114 - (double)minValue;
 115 - (double)maxValue;
 116 - (void)setMinValue:(double)aDouble;
 117 - (void)setMaxValue:(double)aDouble;
 118
 119 - (void)sizeToFit;
 120
 121 - (BOOL)isEnabled;
 122 - (void)setEnabled:(BOOL)flag;
 123
 124 - (void)setImage:(NSImage *)image;
 125 - (void)setControlSize:(NSControlSize)size;
 126
 127 - (void)setFont:(NSFont *)fontObject;
 128
 129 - (id)contentView;
 130
 131 - (void)setTarget:(id)anObject;
 132 - (void)setAction:(SEL)aSelector;
 133 - (void)setDoubleAction:(SEL)aSelector;
 134 - (void)setBackgroundColor:(NSColor*)aColor;
 135 - (void)setOpaque:(BOOL)opaque;
 136 - (void)setTextColor:(NSColor *)color;
 137 - (void)setImagePosition:(NSCellImagePosition)aPosition;
 138 @end
 139
 140 long wxOSXTranslateCocoaKey( NSEvent* event )
 141 {
 142     long retval = 0;
 143
 144     if ([event type] != NSFlagsChanged)
 145     {
 146         NSString* s = [event charactersIgnoringModifiers];
 147         // backspace char reports as delete w/modifiers for some reason
 148         if ([s length] == 1)
 149         {
 150             switch ( [s characterAtIndex:0] )
 151             {
 152                 // backspace key
 153                 case 0x7F :
 154                 case 8 :
 155                     retval = WXK_BACK;
 156                     break;
 157                 case NSUpArrowFunctionKey :
 158                     retval = WXK_UP;
 159                     break;
 160                 case NSDownArrowFunctionKey :
 161                     retval = WXK_DOWN;
 162                     break;
 163                 case NSLeftArrowFunctionKey :
 164                     retval = WXK_LEFT;
 165                     break;
 166                 case NSRightArrowFunctionKey :
 167                     retval = WXK_RIGHT;
 168                     break;
 169                 case NSInsertFunctionKey  :
 170                     retval = WXK_INSERT;
 171                     break;
 172                 case NSDeleteFunctionKey  :
 173                     retval = WXK_DELETE;
 174                     break;
 175                 case NSHomeFunctionKey  :
 176                     retval = WXK_HOME;
 177                     break;
 178         //        case NSBeginFunctionKey  :
 179         //            retval = WXK_BEGIN;
 180         //            break;
 181                 case NSEndFunctionKey  :
 182                     retval = WXK_END;
 183                     break;
 184                 case NSPageUpFunctionKey  :
 185                     retval = WXK_PAGEUP;
 186                     break;
 187                case NSPageDownFunctionKey  :
 188                     retval = WXK_PAGEDOWN;
 189                     break;
 190                case NSHelpFunctionKey  :
 191                     retval = WXK_HELP;
 192                     break;
 193                 default:
 194                     int intchar = [s characterAtIndex: 0];
 195                     if ( intchar >= NSF1FunctionKey && intchar <= NSF24FunctionKey )
 196                         retval = WXK_F1 + (intchar - NSF1FunctionKey );
 197                     break;
 198             }
 199         }
 200     }
 201
 202     // Some keys don't seem to have constants. The code mimics the approach
 203     // taken by WebKit. See:
 204     // http://trac.webkit.org/browser/trunk/WebCore/platform/mac/KeyEventMac.mm
 205     switch( [event keyCode] )
 206     {
 207         // command key
 208         case 54:
 209         case 55:
 210             retval = WXK_COMMAND;
 211             break;
 212         // caps locks key
 213         case 57: // Capslock
 214             retval = WXK_CAPITAL;
 215             break;
 216         // shift key
 217         case 56: // Left Shift
 218         case 60: // Right Shift
 219             retval = WXK_SHIFT;
 220             break;
 221         // alt key
 222         case 58: // Left Alt
 223         case 61: // Right Alt
 224             retval = WXK_ALT;
 225             break;
 226         // ctrl key
 227         case 59: // Left Ctrl
 228         case 62: // Right Ctrl
 229             retval = WXK_CONTROL;
 230             break;
 231         // clear key
 232         case 71:
 233             retval = WXK_CLEAR;
 234             break;
 235         // tab key
 236         case 48:
 237             retval = WXK_TAB;
 238             break;
 239
 240         case 75: // /
 241             retval = WXK_NUMPAD_DIVIDE;
 242             break;
 243         case 67: // *
 244             retval = WXK_NUMPAD_MULTIPLY;
 245             break;
 246         case 78: // -
 247             retval = WXK_NUMPAD_SUBTRACT;
 248             break;
 249         case 69: // +
 250             retval = WXK_NUMPAD_ADD;
 251             break;
 252         case 76: // Enter
 253             retval = WXK_NUMPAD_ENTER;
 254             break;
 255         case 65: // .
 256             retval = WXK_NUMPAD_DECIMAL;
 257             break;
 258         case 82: // 0
 259             retval = WXK_NUMPAD0;
 260             break;
 261         case 83: // 1
 262             retval = WXK_NUMPAD1;
 263             break;
 264         case 84: // 2
 265             retval = WXK_NUMPAD2;
 266             break;
 267         case 85: // 3
 268             retval = WXK_NUMPAD3;
 269             break;
 270         case 86: // 4
 271             retval = WXK_NUMPAD4;
 272             break;
 273         case 87: // 5
 274             retval = WXK_NUMPAD5;
 275             break;
 276         case 88: // 6
 277             retval = WXK_NUMPAD6;
 278             break;
 279         case 89: // 7
 280             retval = WXK_NUMPAD7;
 281             break;
 282         case 91: // 8
 283             retval = WXK_NUMPAD8;
 284             break;
 285         case 92: // 9
 286             retval = WXK_NUMPAD9;
 287             break;
 288         default:
 289             //retval = [event keyCode];
 290             break;
 291     }
 292     return retval;
 293 }
 294
 295 void wxWidgetCocoaImpl::SetupKeyEvent(wxKeyEvent &wxevent , NSEvent * nsEvent, NSString* charString)
 296 {
 297     UInt32 modifiers = [nsEvent modifierFlags] ;
 298     int eventType = [nsEvent type];
 299
 300     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 301     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 302     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 303     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 304
 305     wxevent.m_rawCode = [nsEvent keyCode];
 306     wxevent.m_rawFlags = modifiers;
 307
 308     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 309
 310     wxString chars;
 311     if ( eventType != NSFlagsChanged )
 312     {
 313         NSString* nschars = [nsEvent charactersIgnoringModifiers];
 314         if ( charString )
 315         {
 316             // if charString is set, it did not come from key up / key down
 317             wxevent.SetEventType( wxEVT_CHAR );
 318             chars = wxCFStringRef::AsString(charString);
 319         }
 320         else if ( nschars )
 321         {
 322             chars = wxCFStringRef::AsString(nschars);
 323         }
 324     }
 325
 326     int aunichar = chars.Length() > 0 ? chars[0] : 0;
 327     long keyval = 0;
 328
 329     if (wxevent.GetEventType() != wxEVT_CHAR)
 330     {
 331         keyval = wxOSXTranslateCocoaKey(nsEvent) ;
 332         switch (eventType)
 333         {
 334             case NSKeyDown :
 335                 wxevent.SetEventType( wxEVT_KEY_DOWN )  ;
 336                 break;
 337             case NSKeyUp :
 338                 wxevent.SetEventType( wxEVT_KEY_UP )  ;
 339                 break;
 340             case NSFlagsChanged :
 341                 switch (keyval)
 342                 {
 343                     case WXK_CONTROL:
 344                         wxevent.SetEventType( wxevent.m_controlDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 345                         break;
 346                     case WXK_SHIFT:
 347                         wxevent.SetEventType( wxevent.m_shiftDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 348                         break;
 349                     case WXK_ALT:
 350                         wxevent.SetEventType( wxevent.m_altDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 351                         break;
 352                     case WXK_COMMAND:
 353                         wxevent.SetEventType( wxevent.m_metaDown ? wxEVT_KEY_DOWN : wxEVT_KEY_UP);
 354                         break;
 355                 }
 356                 break;
 357             default :
 358                 break ;
 359         }
 360     }
 361
 362     if ( !keyval )
 363     {
 364         if ( wxevent.GetEventType() == wxEVT_KEY_UP || wxevent.GetEventType() == wxEVT_KEY_DOWN )
 365             keyval = wxToupper( aunichar ) ;
 366         else
 367             keyval = aunichar;
 368     }
 369
 370 #if wxUSE_UNICODE
 371     wxevent.m_uniChar = aunichar;
 372 #endif
 373     wxevent.m_keyCode = keyval;
 374
 375     wxWindowMac* peer = GetWXPeer();
 376     if ( peer )
 377     {
 378         wxevent.SetEventObject(peer);
 379         wxevent.SetId(peer->GetId()) ;
 380     }
 381 }
 382
 383 UInt32 g_lastButton = 0 ;
 384 bool g_lastButtonWasFakeRight = false ;
 385
 386 // better scroll wheel support
 387 // see http://lists.apple.com/archives/cocoa-dev/2007/Feb/msg00050.html
 388
 389 @interface NSEvent (DeviceDelta)
 390 - (CGFloat)deviceDeltaX;
 391 - (CGFloat)deviceDeltaY;
 392 @end
 393
 394 void wxWidgetCocoaImpl::SetupMouseEvent( wxMouseEvent &wxevent , NSEvent * nsEvent )
 395 {
 396     int eventType = [nsEvent type];
 397     UInt32 modifiers = [nsEvent modifierFlags] ;
 398
 399     NSPoint locationInWindow = [nsEvent locationInWindow];
 400
 401     // adjust coordinates for the window of the target view
 402     if ( [nsEvent window] != [m_osxView window] )
 403     {
 404         if ( [nsEvent window] != nil )
 405             locationInWindow = [[nsEvent window] convertBaseToScreen:locationInWindow];
 406
 407         if ( [m_osxView window] != nil )
 408             locationInWindow = [[m_osxView window] convertScreenToBase:locationInWindow];
 409     }
 410
 411     NSPoint locationInView = [m_osxView convertPoint:locationInWindow fromView:nil];
 412     wxPoint locationInViewWX = wxFromNSPoint( m_osxView, locationInView );
 413
 414     // these parameters are not given for all events
 415     UInt32 button = [nsEvent buttonNumber];
 416     UInt32 clickCount = 0;
 417
 418     wxevent.m_x = locationInViewWX.x;
 419     wxevent.m_y = locationInViewWX.y;
 420     wxevent.m_shiftDown = modifiers & NSShiftKeyMask;
 421     wxevent.m_controlDown = modifiers & NSControlKeyMask;
 422     wxevent.m_altDown = modifiers & NSAlternateKeyMask;
 423     wxevent.m_metaDown = modifiers & NSCommandKeyMask;
 424     wxevent.SetTimestamp( (int)([nsEvent timestamp] * 1000) ) ;
 425
 426     UInt32 mouseChord = 0;
 427
 428     switch (eventType)
 429     {
 430         case NSLeftMouseDown :
 431         case NSLeftMouseDragged :
 432             mouseChord = 1U;
 433             break;
 434         case NSRightMouseDown :
 435         case NSRightMouseDragged :
 436             mouseChord = 2U;
 437             break;
 438         case NSOtherMouseDown :
 439         case NSOtherMouseDragged :
 440             mouseChord = 4U;
 441             break;
 442     }
 443
 444     // a control click is interpreted as a right click
 445     bool thisButtonIsFakeRight = false ;
 446     if ( button == 0 && (modifiers & NSControlKeyMask) )
 447     {
 448         button = 1 ;
 449         thisButtonIsFakeRight = true ;
 450     }
 451
 452     // otherwise we report double clicks by connecting a left click with a ctrl-left click
 453     if ( clickCount > 1 && button != g_lastButton )
 454         clickCount = 1 ;
 455
 456     // we must make sure that our synthetic 'right' button corresponds in
 457     // mouse down, moved and mouse up, and does not deliver a right down and left up
 458     switch (eventType)
 459     {
 460         case NSLeftMouseDown :
 461         case NSRightMouseDown :
 462         case NSOtherMouseDown :
 463             g_lastButton = button ;
 464             g_lastButtonWasFakeRight = thisButtonIsFakeRight ;
 465             break;
 466      }
 467
 468     if ( button == 0 )
 469     {
 470         g_lastButton = 0 ;
 471         g_lastButtonWasFakeRight = false ;
 472     }
 473     else if ( g_lastButton == 1 && g_lastButtonWasFakeRight )
 474         button = g_lastButton ;
 475
 476     // Adjust the chord mask to remove the primary button and add the
 477     // secondary button.  It is possible that the secondary button is
 478     // already pressed, e.g. on a mouse connected to a laptop, but this
 479     // possibility is ignored here:
 480     if( thisButtonIsFakeRight && ( mouseChord & 1U ) )
 481         mouseChord = ((mouseChord & ~1U) | 2U);
 482
 483     if(mouseChord & 1U)
 484                 wxevent.m_leftDown = true ;
 485     if(mouseChord & 2U)
 486                 wxevent.m_rightDown = true ;
 487     if(mouseChord & 4U)
 488                 wxevent.m_middleDown = true ;
 489
 490     // translate into wx types
 491     switch (eventType)
 492     {
 493         case NSLeftMouseDown :
 494         case NSRightMouseDown :
 495         case NSOtherMouseDown :
 496             clickCount = [nsEvent clickCount];
 497             switch ( button )
 498             {
 499                 case 0 :
 500                     wxevent.SetEventType( clickCount > 1 ? wxEVT_LEFT_DCLICK : wxEVT_LEFT_DOWN )  ;
 501                     break ;
 502
 503                 case 1 :
 504                     wxevent.SetEventType( clickCount > 1 ? wxEVT_RIGHT_DCLICK : wxEVT_RIGHT_DOWN ) ;
 505                     break ;
 506
 507                 case 2 :
 508                     wxevent.SetEventType( clickCount > 1 ? wxEVT_MIDDLE_DCLICK : wxEVT_MIDDLE_DOWN ) ;
 509                     break ;
 510
 511                 default:
 512                     break ;
 513             }
 514             break ;
 515
 516         case NSLeftMouseUp :
 517         case NSRightMouseUp :
 518         case NSOtherMouseUp :
 519             clickCount = [nsEvent clickCount];
 520             switch ( button )
 521             {
 522                 case 0 :
 523                     wxevent.SetEventType( wxEVT_LEFT_UP )  ;
 524                     break ;
 525
 526                 case 1 :
 527                     wxevent.SetEventType( wxEVT_RIGHT_UP ) ;
 528                     break ;
 529
 530                 case 2 :
 531                     wxevent.SetEventType( wxEVT_MIDDLE_UP ) ;
 532                     break ;
 533
 534                 default:
 535                     break ;
 536             }
 537             break ;
 538
 539      case NSScrollWheel :
 540         {
 541             float deltaX = 0.0;
 542             float deltaY = 0.0;
 543
 544             wxevent.SetEventType( wxEVT_MOUSEWHEEL ) ;
 545
 546             // see http://developer.apple.com/qa/qa2005/qa1453.html
 547             // for more details on why we have to look for the exact type
 548
 549             const EventRef cEvent = (EventRef) [nsEvent eventRef];
 550             bool isMouseScrollEvent = false;
 551             if ( cEvent )
 552                 isMouseScrollEvent = ::GetEventKind(cEvent) == kEventMouseScroll;
 553
 554             if ( isMouseScrollEvent )
 555             {
 556                 deltaX = [nsEvent deviceDeltaX];
 557                 deltaY = [nsEvent deviceDeltaY];
 558             }
 559             else
 560             {
 561                 deltaX = ([nsEvent deltaX] * 10);
 562                 deltaY = ([nsEvent deltaY] * 10);
 563             }
 564
 565             wxevent.m_wheelDelta = 10;
 566             wxevent.m_linesPerAction = 1;
 567
 568             if ( fabs(deltaX) > fabs(deltaY) )
 569             {
 570                 wxevent.m_wheelAxis = 1;
 571                 wxevent.m_wheelRotation = (int)deltaX;
 572             }
 573             else
 574             {
 575                 wxevent.m_wheelRotation = (int)deltaY;
 576             }
 577
 578         }
 579         break ;
 580
 581         case NSMouseEntered :
 582             wxevent.SetEventType( wxEVT_ENTER_WINDOW ) ;
 583             break;
 584         case NSMouseExited :
 585             wxevent.SetEventType( wxEVT_LEAVE_WINDOW ) ;
 586             break;
 587         case NSLeftMouseDragged :
 588         case NSRightMouseDragged :
 589         case NSOtherMouseDragged :
 590         case NSMouseMoved :
 591             wxevent.SetEventType( wxEVT_MOTION ) ;
 592             break;
 593         default :
 594             break ;
 595     }
 596
 597     wxevent.m_clickCount = clickCount;
 598     wxWindowMac* peer = GetWXPeer();
 599     if ( peer )
 600     {
 601         wxevent.SetEventObject(peer);
 602         wxevent.SetId(peer->GetId()) ;
 603     }
 604 }
 605
 606 @implementation wxNSView
 607
 608 + (void)initialize
 609 {
 610     static BOOL initialized = NO;
 611     if (!initialized)
 612     {
 613         initialized = YES;
 614         wxOSXCocoaClassAddWXMethods( self );
 615     }
 616 }
 617
 618 - (void) setTrackingTag: (NSTrackingRectTag)tag
 619 {
 620     rectTag = tag;
 621 }
 622
 623 - (NSTrackingRectTag) trackingTag
 624 {
 625     return rectTag;
 626 }
 627
 628 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
 629 - (void) updateTrackingArea
 630 {
 631     if (_trackingArea)
 632     {
 633         [self removeTrackingArea: _trackingArea];
 634         [_trackingArea release];
 635     }
 636
 637     NSTrackingAreaOptions options = NSTrackingMouseEnteredAndExited|NSTrackingMouseMoved|NSTrackingActiveAlways;
 638
 639     NSTrackingArea* area = [[NSTrackingArea alloc] initWithRect: [self bounds] options: options owner: self userInfo: nil];
 640     [self addTrackingArea: area];
 641
 642     _trackingArea = area;
 643 }
 644
 645 - (NSTrackingArea*) trackingArea
 646 {
 647     return _trackingArea;
 648 }
 649 #endif
 650 @end // wxNSView
 651
 652 //
 653 // event handlers
 654 //
 655
 656 #if wxUSE_DRAG_AND_DROP
 657
 658 // see http://lists.apple.com/archives/Cocoa-dev/2005/Jul/msg01244.html
 659 // for details on the NSPasteboard -> PasteboardRef conversion
 660
 661 NSDragOperation wxOSX_draggingEntered( id self, SEL _cmd, id <NSDraggingInfo>sender )
 662 {
 663     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 664     if (impl == NULL)
 665         return NSDragOperationNone;
 666
 667     return impl->draggingEntered(sender, self, _cmd);
 668 }
 669
 670 void wxOSX_draggingExited( id self, SEL _cmd, id <NSDraggingInfo> sender )
 671 {
 672     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 673     if (impl == NULL)
 674         return ;
 675
 676     return impl->draggingExited(sender, self, _cmd);
 677 }
 678
 679 NSDragOperation wxOSX_draggingUpdated( id self, SEL _cmd, id <NSDraggingInfo>sender )
 680 {
 681     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 682     if (impl == NULL)
 683         return NSDragOperationNone;
 684
 685     return impl->draggingUpdated(sender, self, _cmd);
 686 }
 687
 688 BOOL wxOSX_performDragOperation( id self, SEL _cmd, id <NSDraggingInfo> sender )
 689 {
 690     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 691     if (impl == NULL)
 692         return NSDragOperationNone;
 693
 694     return impl->performDragOperation(sender, self, _cmd) ? YES:NO ;
 695 }
 696
 697 #endif
 698
 699 void wxOSX_mouseEvent(NSView* self, SEL _cmd, NSEvent *event)
 700 {
 701     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 702     if (impl == NULL)
 703         return;
 704
 705     impl->mouseEvent(event, self, _cmd);
 706 }
 707
 708 BOOL wxOSX_acceptsFirstMouse(NSView* WXUNUSED(self), SEL WXUNUSED(_cmd), NSEvent *WXUNUSED(event))
 709 {
 710     // This is needed to support click through, otherwise the first click on a window
 711     // will not do anything unless it is the active window already.
 712     return YES;
 713 }
 714
 715 void wxOSX_keyEvent(NSView* self, SEL _cmd, NSEvent *event)
 716 {
 717     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 718     if (impl == NULL)
 719         return;
 720
 721     impl->keyEvent(event, self, _cmd);
 722 }
 723
 724 void wxOSX_insertText(NSView* self, SEL _cmd, NSString* text)
 725 {
 726     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 727     if (impl == NULL)
 728         return;
 729
 730     impl->insertText(text, self, _cmd);
 731 }
 732
 733 BOOL wxOSX_performKeyEquivalent(NSView* self, SEL _cmd, NSEvent *event)
 734 {
 735     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 736     if (impl == NULL)
 737         return NO;
 738
 739     return impl->performKeyEquivalent(event, self, _cmd);
 740 }
 741
 742 BOOL wxOSX_acceptsFirstResponder(NSView* self, SEL _cmd)
 743 {
 744     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 745     if (impl == NULL)
 746         return NO;
 747
 748     return impl->acceptsFirstResponder(self, _cmd);
 749 }
 750
 751 BOOL wxOSX_becomeFirstResponder(NSView* self, SEL _cmd)
 752 {
 753     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 754     if (impl == NULL)
 755         return NO;
 756
 757     return impl->becomeFirstResponder(self, _cmd);
 758 }
 759
 760 BOOL wxOSX_resignFirstResponder(NSView* self, SEL _cmd)
 761 {
 762     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 763     if (impl == NULL)
 764         return NO;
 765
 766     return impl->resignFirstResponder(self, _cmd);
 767 }
 768
 769 void wxOSX_resetCursorRects(NSView* self, SEL _cmd)
 770 {
 771     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 772     if (impl == NULL)
 773         return;
 774
 775     impl->resetCursorRects(self, _cmd);
 776 }
 777
 778 BOOL wxOSX_isFlipped(NSView* self, SEL _cmd)
 779 {
 780     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 781     if (impl == NULL)
 782         return NO;
 783
 784     return impl->isFlipped(self, _cmd) ? YES:NO;
 785 }
 786
 787 typedef void (*wxOSX_DrawRectHandlerPtr)(NSView* self, SEL _cmd, NSRect rect);
 788
 789 void wxOSX_drawRect(NSView* self, SEL _cmd, NSRect rect)
 790 {
 791     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 792     if (impl == NULL)
 793         return;
 794
 795 #ifdef wxUSE_THREADS
 796     // OS X starts a NSUIHeartBeatThread for animating the default button in a
 797     // dialog. This causes a drawRect of the active dialog from outside the
 798     // main UI thread. This causes an occasional crash since the wx drawing
 799     // objects (like wxPen) are not thread safe.
 800     //
 801     // Notice that NSUIHeartBeatThread seems to be undocumented and doing
 802     // [NSWindow setAllowsConcurrentViewDrawing:NO] does not affect it.
 803     if ( !wxThread::IsMain() )
 804     {
 805       // just call the superclass handler, we don't need any custom wx drawing
 806       // here and it seems to work fine:
 807       wxOSX_DrawRectHandlerPtr
 808           superimpl = (wxOSX_DrawRectHandlerPtr)
 809                         [[self superclass] instanceMethodForSelector:_cmd];
 810       superimpl(self, _cmd, rect);
 811       return;
 812     }
 813 #endif // wxUSE_THREADS
 814
 815     return impl->drawRect(&rect, self, _cmd);
 816 }
 817
 818 void wxOSX_controlAction(NSView* self, SEL _cmd, id sender)
 819 {
 820     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 821     if (impl == NULL)
 822         return;
 823
 824     impl->controlAction(self, _cmd, sender);
 825 }
 826
 827 void wxOSX_controlDoubleAction(NSView* self, SEL _cmd, id sender)
 828 {
 829     wxWidgetCocoaImpl* impl = (wxWidgetCocoaImpl* ) wxWidgetImpl::FindFromWXWidget( self );
 830     if (impl == NULL)
 831         return;
 832
 833     impl->controlDoubleAction(self, _cmd, sender);
 834 }
 835
 836 unsigned int wxWidgetCocoaImpl::draggingEntered(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 837 {
 838     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 839     NSPasteboard *pboard = [sender draggingPasteboard];
 840     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 841
 842     wxWindow* wxpeer = GetWXPeer();
 843     if ( wxpeer == NULL )
 844         return NSDragOperationNone;
 845
 846     wxDropTarget* target = wxpeer->GetDropTarget();
 847     if ( target == NULL )
 848         return NSDragOperationNone;
 849
 850     wxDragResult result = wxDragNone;
 851     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 852     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 853
 854     if ( sourceDragMask & NSDragOperationLink )
 855         result = wxDragLink;
 856     else if ( sourceDragMask & NSDragOperationCopy )
 857         result = wxDragCopy;
 858     else if ( sourceDragMask & NSDragOperationMove )
 859         result = wxDragMove;
 860
 861     PasteboardRef pboardRef;
 862     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 863     target->SetCurrentDragPasteboard(pboardRef);
 864     result = target->OnEnter(pt.x, pt.y, result);
 865     CFRelease(pboardRef);
 866
 867     NSDragOperation nsresult = NSDragOperationNone;
 868     switch (result )
 869     {
 870         case wxDragLink:
 871             nsresult = NSDragOperationLink;
 872         case wxDragMove:
 873             nsresult = NSDragOperationMove;
 874         case wxDragCopy:
 875             nsresult = NSDragOperationCopy;
 876         default :
 877             break;
 878     }
 879     return nsresult;
 880 }
 881
 882 void wxWidgetCocoaImpl::draggingExited(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 883 {
 884     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 885     NSPasteboard *pboard = [sender draggingPasteboard];
 886
 887     wxWindow* wxpeer = GetWXPeer();
 888     if ( wxpeer == NULL )
 889         return;
 890
 891     wxDropTarget* target = wxpeer->GetDropTarget();
 892     if ( target == NULL )
 893         return;
 894
 895     PasteboardRef pboardRef;
 896     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 897     target->SetCurrentDragPasteboard(pboardRef);
 898     target->OnLeave();
 899     CFRelease(pboardRef);
 900  }
 901
 902 unsigned int wxWidgetCocoaImpl::draggingUpdated(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 903 {
 904     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 905     NSPasteboard *pboard = [sender draggingPasteboard];
 906     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 907
 908     wxWindow* wxpeer = GetWXPeer();
 909     if ( wxpeer == NULL )
 910         return NSDragOperationNone;
 911
 912     wxDropTarget* target = wxpeer->GetDropTarget();
 913     if ( target == NULL )
 914         return NSDragOperationNone;
 915
 916     wxDragResult result = wxDragNone;
 917     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 918     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 919
 920     if ( sourceDragMask & NSDragOperationLink )
 921         result = wxDragLink;
 922     else if ( sourceDragMask & NSDragOperationCopy )
 923         result = wxDragCopy;
 924     else if ( sourceDragMask & NSDragOperationMove )
 925         result = wxDragMove;
 926
 927     PasteboardRef pboardRef;
 928     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 929     target->SetCurrentDragPasteboard(pboardRef);
 930     result = target->OnDragOver(pt.x, pt.y, result);
 931     CFRelease(pboardRef);
 932
 933     NSDragOperation nsresult = NSDragOperationNone;
 934     switch (result )
 935     {
 936         case wxDragLink:
 937             nsresult = NSDragOperationLink;
 938         case wxDragMove:
 939             nsresult = NSDragOperationMove;
 940         case wxDragCopy:
 941             nsresult = NSDragOperationCopy;
 942         default :
 943             break;
 944     }
 945     return nsresult;
 946 }
 947
 948 bool wxWidgetCocoaImpl::performDragOperation(void* s, WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
 949 {
 950     id <NSDraggingInfo>sender = (id <NSDraggingInfo>) s;
 951
 952     NSPasteboard *pboard = [sender draggingPasteboard];
 953     NSDragOperation sourceDragMask = [sender draggingSourceOperationMask];
 954
 955     wxWindow* wxpeer = GetWXPeer();
 956     wxDropTarget* target = wxpeer->GetDropTarget();
 957     wxDragResult result = wxDragNone;
 958     NSPoint nspoint = [m_osxView convertPoint:[sender draggingLocation] fromView:nil];
 959     wxPoint pt = wxFromNSPoint( m_osxView, nspoint );
 960
 961     if ( sourceDragMask & NSDragOperationLink )
 962         result = wxDragLink;
 963     else if ( sourceDragMask & NSDragOperationCopy )
 964         result = wxDragCopy;
 965     else if ( sourceDragMask & NSDragOperationMove )
 966         result = wxDragMove;
 967
 968     PasteboardRef pboardRef;
 969     PasteboardCreate((CFStringRef)[pboard name], &pboardRef);
 970     target->SetCurrentDragPasteboard(pboardRef);
 971
 972     if (target->OnDrop(pt.x, pt.y))
 973         result = target->OnData(pt.x, pt.y, result);
 974
 975     CFRelease(pboardRef);
 976
 977     return result != wxDragNone;
 978 }
 979
 980 typedef void (*wxOSX_TextEventHandlerPtr)(NSView* self, SEL _cmd, NSString *event);
 981 typedef void (*wxOSX_EventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
 982 typedef BOOL (*wxOSX_PerformKeyEventHandlerPtr)(NSView* self, SEL _cmd, NSEvent *event);
 983 typedef BOOL (*wxOSX_FocusHandlerPtr)(NSView* self, SEL _cmd);
 984 typedef BOOL (*wxOSX_ResetCursorRectsHandlerPtr)(NSView* self, SEL _cmd);
 985
 986 void wxWidgetCocoaImpl::mouseEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
 987 {
 988     if ( !DoHandleMouseEvent(event) )
 989     {
 990         // for plain NSView mouse events would propagate to parents otherwise
 991         if (!m_wxPeer->MacIsUserPane())
 992         {
 993             wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
 994             superimpl(slf, (SEL)_cmd, event);
 995         }
 996     }
 997 }
 998
 999 void wxWidgetCocoaImpl::keyEvent(WX_NSEvent event, WXWidget slf, void *_cmd)
1000 {
1001     if ( [event type] == NSKeyDown )
1002         m_lastKeyDownEvent = event;
1003     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
1004     {
1005         wxOSX_EventHandlerPtr superimpl = (wxOSX_EventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1006         superimpl(slf, (SEL)_cmd, event);
1007     }
1008     m_lastKeyDownEvent = NULL;
1009 }
1010
1011 void wxWidgetCocoaImpl::insertText(NSString* text, WXWidget slf, void *_cmd)
1012 {
1013     if ( m_lastKeyDownEvent==NULL || m_hasEditor || !DoHandleCharEvent(m_lastKeyDownEvent, text) )
1014     {
1015         wxOSX_TextEventHandlerPtr superimpl = (wxOSX_TextEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1016         superimpl(slf, (SEL)_cmd, text);
1017     }
1018 }
1019
1020
1021 bool wxWidgetCocoaImpl::performKeyEquivalent(WX_NSEvent event, WXWidget slf, void *_cmd)
1022 {
1023     if ( GetFocusedViewInWindow([slf window]) != slf || m_hasEditor || !DoHandleKeyEvent(event) )
1024     {
1025         wxOSX_PerformKeyEventHandlerPtr superimpl = (wxOSX_PerformKeyEventHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1026         return superimpl(slf, (SEL)_cmd, event);
1027     }
1028     return YES;
1029 }
1030
1031 bool wxWidgetCocoaImpl::acceptsFirstResponder(WXWidget slf, void *_cmd)
1032 {
1033     if ( m_wxPeer->MacIsUserPane() )
1034         return m_wxPeer->AcceptsFocus();
1035     else
1036     {
1037         wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1038         return superimpl(slf, (SEL)_cmd);
1039     }
1040 }
1041
1042 bool wxWidgetCocoaImpl::becomeFirstResponder(WXWidget slf, void *_cmd)
1043 {
1044     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1045     // get the current focus before running becomeFirstResponder
1046     NSView* otherView = FindFocus();
1047
1048     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1049     BOOL r = superimpl(slf, (SEL)_cmd);
1050     if ( r )
1051     {
1052         DoNotifyFocusEvent( true, otherWindow );
1053     }
1054
1055     return r;
1056 }
1057
1058 bool wxWidgetCocoaImpl::resignFirstResponder(WXWidget slf, void *_cmd)
1059 {
1060     wxOSX_FocusHandlerPtr superimpl = (wxOSX_FocusHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1061     BOOL r = superimpl(slf, (SEL)_cmd);
1062     // get the current focus after running resignFirstResponder
1063     // note that this value isn't reliable, it might return the same view that
1064     // is resigning
1065     NSView* otherView = FindFocus();
1066     wxWidgetImpl* otherWindow = FindFromWXWidget(otherView);
1067
1068     // It doesn't make sense to notify about the loss of focus if we're not
1069     // really losing it and the window which has just gained focus is the same
1070     // one as this window itself. Of course, this should never happen in the
1071     // first place but somehow it does in wxGrid code and without this check we
1072     // enter into an infinite recursion, see #12267.
1073     if ( otherWindow == this )
1074         return r;
1075
1076     // NSTextViews have an editor as true responder, therefore the might get the
1077     // resign notification if their editor takes over, don't trigger any event then
1078     if ( r && !m_hasEditor)
1079     {
1080         DoNotifyFocusEvent( false, otherWindow );
1081     }
1082     return r;
1083 }
1084
1085 void wxWidgetCocoaImpl::resetCursorRects(WXWidget slf, void *_cmd)
1086 {
1087     wxWindow* wxpeer = GetWXPeer();
1088     if ( wxpeer )
1089     {
1090         NSCursor *cursor = (NSCursor*)wxpeer->GetCursor().GetHCURSOR();
1091         if (cursor == NULL)
1092         {
1093             wxOSX_ResetCursorRectsHandlerPtr superimpl = (wxOSX_ResetCursorRectsHandlerPtr) [[slf superclass] instanceMethodForSelector:(SEL)_cmd];
1094             superimpl(slf, (SEL)_cmd);
1095         }
1096         else
1097         {
1098             [slf addCursorRect: [slf bounds]
1099                 cursor: cursor];
1100         }
1101     }
1102 }
1103
1104 bool wxWidgetCocoaImpl::isFlipped(WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd))
1105 {
1106     return m_isFlipped;
1107 }
1108
1109
1110 #define OSX_DEBUG_DRAWING 0
1111
1112 void wxWidgetCocoaImpl::drawRect(void* rect, WXWidget slf, void *WXUNUSED(_cmd))
1113 {
1114     // preparing the update region
1115
1116     wxRegion updateRgn;
1117     const NSRect *rects;
1118     NSInteger count;
1119
1120     [slf getRectsBeingDrawn:&rects count:&count];
1121     for ( int i = 0 ; i < count ; ++i )
1122     {
1123         updateRgn.Union(wxFromNSRect(slf, rects[i]));
1124     }
1125
1126     wxWindow* wxpeer = GetWXPeer();
1127
1128     if ( wxpeer->MacGetLeftBorderSize() != 0 || wxpeer->MacGetTopBorderSize() != 0 )
1129     {
1130         // as this update region is in native window locals we must adapt it to wx window local
1131         updateRgn.Offset( wxpeer->MacGetLeftBorderSize() , wxpeer->MacGetTopBorderSize() );
1132     }
1133
1134     if ( wxpeer->MacGetTopLevelWindow()->GetWindowStyle() & wxFRAME_SHAPED )
1135     {
1136         int xoffset = 0, yoffset = 0;
1137         wxRegion rgn = wxpeer->MacGetTopLevelWindow()->GetShape();
1138         wxpeer->MacRootWindowToWindow( &xoffset, &yoffset );
1139         rgn.Offset( xoffset, yoffset );
1140         updateRgn.Intersect(rgn);
1141     }
1142
1143     wxpeer->GetUpdateRegion() = updateRgn;
1144
1145     // setting up the drawing context
1146
1147     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1148     CGContextSaveGState( context );
1149
1150 #if OSX_DEBUG_DRAWING
1151     CGContextBeginPath( context );
1152     CGContextMoveToPoint(context, 0, 0);
1153     NSRect bounds = [slf bounds];
1154     CGContextAddLineToPoint(context, 10, 0);
1155     CGContextMoveToPoint(context, 0, 0);
1156     CGContextAddLineToPoint(context, 0, 10);
1157     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1158     CGContextAddLineToPoint(context, bounds.size.width, bounds.size.height-10);
1159     CGContextMoveToPoint(context, bounds.size.width, bounds.size.height);
1160     CGContextAddLineToPoint(context, bounds.size.width-10, bounds.size.height);
1161     CGContextClosePath( context );
1162     CGContextStrokePath(context);
1163 #endif
1164
1165     if ( !m_isFlipped )
1166     {
1167         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1168         CGContextScaleCTM( context, 1, -1 );
1169     }
1170
1171     wxpeer->MacSetCGContextRef( context );
1172
1173     bool handled = wxpeer->MacDoRedraw( 0 );
1174     CGContextRestoreGState( context );
1175
1176     CGContextSaveGState( context );
1177     if ( !handled )
1178     {
1179         // call super
1180         SEL _cmd = @selector(drawRect:);
1181         wxOSX_DrawRectHandlerPtr superimpl = (wxOSX_DrawRectHandlerPtr) [[slf superclass] instanceMethodForSelector:_cmd];
1182         superimpl(slf, _cmd, *(NSRect*)rect);
1183         CGContextRestoreGState( context );
1184         CGContextSaveGState( context );
1185     }
1186     // as we called restore above, we have to flip again if necessary
1187     if ( !m_isFlipped )
1188     {
1189         CGContextTranslateCTM( context, 0,  [m_osxView bounds].size.height );
1190         CGContextScaleCTM( context, 1, -1 );
1191     }
1192     wxpeer->MacPaintChildrenBorders();
1193     wxpeer->MacSetCGContextRef( NULL );
1194     CGContextRestoreGState( context );
1195 }
1196
1197 void wxWidgetCocoaImpl::controlAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1198 {
1199     wxWindow* wxpeer = (wxWindow*) GetWXPeer();
1200     if ( wxpeer )
1201         wxpeer->OSXHandleClicked(0);
1202 }
1203
1204 void wxWidgetCocoaImpl::controlDoubleAction( WXWidget WXUNUSED(slf), void *WXUNUSED(_cmd), void *WXUNUSED(sender))
1205 {
1206 }
1207
1208 void wxWidgetCocoaImpl::controlTextDidChange()
1209 {
1210     wxWindow* wxpeer = (wxWindow*)GetWXPeer();
1211     if ( wxpeer )
1212     {
1213         // since native rtti doesn't have to be enabled and wx' rtti is not aware of the mixin wxTextEntry, workaround is needed
1214         wxTextCtrl *tc = wxDynamicCast( wxpeer , wxTextCtrl );
1215         wxComboBox *cb = wxDynamicCast( wxpeer , wxComboBox );
1216         if ( tc )
1217             tc->SendTextUpdatedEventIfAllowed();
1218         else if ( cb )
1219             cb->SendTextUpdatedEventIfAllowed();
1220         else
1221         {
1222             wxFAIL_MSG("Unexpected class for controlTextDidChange event");
1223         }
1224     }
1225 }
1226
1227 //
1228
1229 #if OBJC_API_VERSION >= 2
1230
1231 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1232     class_addMethod(c, s, i, t );
1233
1234 #else
1235
1236 #define wxOSX_CLASS_ADD_METHOD( c, s, i, t ) \
1237     { s, t, i },
1238
1239 #endif
1240
1241 void wxOSXCocoaClassAddWXMethods(Class c)
1242 {
1243
1244 #if OBJC_API_VERSION < 2
1245     static objc_method wxmethods[] =
1246     {
1247 #endif
1248
1249     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1250     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1251     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDown:), (IMP) wxOSX_mouseEvent, "v@:@" )
1252
1253     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1254     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1255     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseUp:), (IMP) wxOSX_mouseEvent, "v@:@" )
1256
1257     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseMoved:), (IMP) wxOSX_mouseEvent, "v@:@" )
1258
1259     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1260     wxOSX_CLASS_ADD_METHOD(c, @selector(rightMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1261     wxOSX_CLASS_ADD_METHOD(c, @selector(otherMouseDragged:), (IMP) wxOSX_mouseEvent, "v@:@" )
1262
1263     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstMouse:), (IMP) wxOSX_acceptsFirstMouse, "v@:@" )
1264
1265     wxOSX_CLASS_ADD_METHOD(c, @selector(scrollWheel:), (IMP) wxOSX_mouseEvent, "v@:@" )
1266     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseEntered:), (IMP) wxOSX_mouseEvent, "v@:@" )
1267     wxOSX_CLASS_ADD_METHOD(c, @selector(mouseExited:), (IMP) wxOSX_mouseEvent, "v@:@" )
1268
1269     wxOSX_CLASS_ADD_METHOD(c, @selector(keyDown:), (IMP) wxOSX_keyEvent, "v@:@" )
1270     wxOSX_CLASS_ADD_METHOD(c, @selector(keyUp:), (IMP) wxOSX_keyEvent, "v@:@" )
1271     wxOSX_CLASS_ADD_METHOD(c, @selector(flagsChanged:), (IMP) wxOSX_keyEvent, "v@:@" )
1272
1273     wxOSX_CLASS_ADD_METHOD(c, @selector(insertText:), (IMP) wxOSX_insertText, "v@:@" )
1274
1275     wxOSX_CLASS_ADD_METHOD(c, @selector(performKeyEquivalent:), (IMP) wxOSX_performKeyEquivalent, "c@:@" )
1276
1277     wxOSX_CLASS_ADD_METHOD(c, @selector(acceptsFirstResponder), (IMP) wxOSX_acceptsFirstResponder, "c@:" )
1278     wxOSX_CLASS_ADD_METHOD(c, @selector(becomeFirstResponder), (IMP) wxOSX_becomeFirstResponder, "c@:" )
1279     wxOSX_CLASS_ADD_METHOD(c, @selector(resignFirstResponder), (IMP) wxOSX_resignFirstResponder, "c@:" )
1280     wxOSX_CLASS_ADD_METHOD(c, @selector(resetCursorRects), (IMP) wxOSX_resetCursorRects, "v@:" )
1281
1282     wxOSX_CLASS_ADD_METHOD(c, @selector(isFlipped), (IMP) wxOSX_isFlipped, "c@:" )
1283     wxOSX_CLASS_ADD_METHOD(c, @selector(drawRect:), (IMP) wxOSX_drawRect, "v@:{_NSRect={_NSPoint=ff}{_NSSize=ff}}" )
1284
1285     wxOSX_CLASS_ADD_METHOD(c, @selector(controlAction:), (IMP) wxOSX_controlAction, "v@:@" )
1286     wxOSX_CLASS_ADD_METHOD(c, @selector(controlDoubleAction:), (IMP) wxOSX_controlDoubleAction, "v@:@" )
1287
1288 #if wxUSE_DRAG_AND_DROP
1289     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingEntered:), (IMP) wxOSX_draggingEntered, "I@:@" )
1290     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingUpdated:), (IMP) wxOSX_draggingUpdated, "I@:@" )
1291     wxOSX_CLASS_ADD_METHOD(c, @selector(draggingExited:), (IMP) wxOSX_draggingExited, "v@:@" )
1292     wxOSX_CLASS_ADD_METHOD(c, @selector(performDragOperation:), (IMP) wxOSX_performDragOperation, "c@:@" )
1293 #endif
1294
1295 #if OBJC_API_VERSION < 2
1296     } ;
1297     static int method_count = WXSIZEOF( wxmethods );
1298     static objc_method_list *wxmethodlist = NULL;
1299     if ( wxmethodlist == NULL )
1300     {
1301         wxmethodlist = (objc_method_list*) malloc(sizeof(objc_method_list) + sizeof(wxmethods) );
1302         memcpy( &wxmethodlist->method_list[0], &wxmethods[0], sizeof(wxmethods) );
1303         wxmethodlist->method_count = method_count;
1304         wxmethodlist->obsolete = 0;
1305     }
1306     class_addMethods( c, wxmethodlist );
1307 #endif
1308 }
1309
1310 //
1311 // C++ implementation class
1312 //
1313
1314 IMPLEMENT_DYNAMIC_CLASS( wxWidgetCocoaImpl , wxWidgetImpl )
1315
1316 wxWidgetCocoaImpl::wxWidgetCocoaImpl( wxWindowMac* peer , WXWidget w, bool isRootControl ) :
1317     wxWidgetImpl( peer, isRootControl )
1318 {
1319     Init();
1320     m_osxView = w;
1321
1322     // check if the user wants to create the control initially hidden
1323     if ( !peer->IsShown() )
1324         SetVisibility(false);
1325
1326     // gc aware handling
1327     if ( m_osxView )
1328         CFRetain(m_osxView);
1329     [m_osxView release];
1330 }
1331
1332 wxWidgetCocoaImpl::wxWidgetCocoaImpl()
1333 {
1334     Init();
1335 }
1336
1337 void wxWidgetCocoaImpl::Init()
1338 {
1339     m_osxView = NULL;
1340     m_isFlipped = true;
1341     m_lastKeyDownEvent = NULL;
1342     m_hasEditor = false;
1343 }
1344
1345 wxWidgetCocoaImpl::~wxWidgetCocoaImpl()
1346 {
1347     RemoveAssociations( this );
1348
1349     if ( !IsRootControl() )
1350     {
1351         NSView *sv = [m_osxView superview];
1352         if ( sv != nil )
1353             [m_osxView removeFromSuperview];
1354     }
1355     // gc aware handling
1356     if ( m_osxView )
1357         CFRelease(m_osxView);
1358 }
1359
1360 bool wxWidgetCocoaImpl::IsVisible() const
1361 {
1362     return [m_osxView isHiddenOrHasHiddenAncestor] == NO;
1363 }
1364
1365 void wxWidgetCocoaImpl::SetVisibility( bool visible )
1366 {
1367     [m_osxView setHidden:(visible ? NO:YES)];
1368 }
1369
1370 // ----------------------------------------------------------------------------
1371 // window animation stuff
1372 // ----------------------------------------------------------------------------
1373
1374 // define a delegate used to refresh the window during animation
1375 @interface wxNSAnimationDelegate : NSObject wxOSX_10_6_AND_LATER(<NSAnimationDelegate>)
1376 {
1377     wxWindow *m_win;
1378     bool m_isDone;
1379 }
1380
1381 - (id)init:(wxWindow *)win;
1382
1383 - (bool)isDone;
1384
1385 // NSAnimationDelegate methods
1386 - (void)animationDidEnd:(NSAnimation*)animation;
1387 - (void)animation:(NSAnimation*)animation
1388         didReachProgressMark:(NSAnimationProgress)progress;
1389 @end
1390
1391 @implementation wxNSAnimationDelegate
1392
1393 - (id)init:(wxWindow *)win
1394 {
1395     [super init];
1396
1397     m_win = win;
1398     m_isDone = false;
1399
1400     return self;
1401 }
1402
1403 - (bool)isDone
1404 {
1405     return m_isDone;
1406 }
1407
1408 - (void)animation:(NSAnimation*)animation
1409         didReachProgressMark:(NSAnimationProgress)progress
1410 {
1411     wxUnusedVar(animation);
1412     wxUnusedVar(progress);
1413
1414     m_win->SendSizeEvent();
1415 }
1416
1417 - (void)animationDidEnd:(NSAnimation*)animation
1418 {
1419     wxUnusedVar(animation);
1420     m_isDone = true;
1421 }
1422
1423 @end
1424
1425 /* static */
1426 bool
1427 wxWidgetCocoaImpl::ShowViewOrWindowWithEffect(wxWindow *win,
1428                                               bool show,
1429                                               wxShowEffect effect,
1430                                               unsigned timeout)
1431 {
1432     // create the dictionary describing the animation to perform on this view
1433     NSObject * const
1434         viewOrWin = static_cast<NSObject *>(win->OSXGetViewOrWindow());
1435     NSMutableDictionary * const
1436         dict = [NSMutableDictionary dictionaryWithCapacity:4];
1437     [dict setObject:viewOrWin forKey:NSViewAnimationTargetKey];
1438
1439     // determine the start and end rectangles assuming we're hiding the window
1440     const wxRect rectOrig = win->GetRect();
1441     wxRect rectStart,
1442            rectEnd;
1443     rectStart =
1444     rectEnd = rectOrig;
1445
1446     if ( show )
1447     {
1448         if ( effect == wxSHOW_EFFECT_ROLL_TO_LEFT ||
1449                 effect == wxSHOW_EFFECT_SLIDE_TO_LEFT )
1450             effect = wxSHOW_EFFECT_ROLL_TO_RIGHT;
1451         else if ( effect == wxSHOW_EFFECT_ROLL_TO_RIGHT ||
1452                     effect == wxSHOW_EFFECT_SLIDE_TO_RIGHT )
1453             effect = wxSHOW_EFFECT_ROLL_TO_LEFT;
1454         else if ( effect == wxSHOW_EFFECT_ROLL_TO_TOP ||
1455                     effect == wxSHOW_EFFECT_SLIDE_TO_TOP )
1456             effect = wxSHOW_EFFECT_ROLL_TO_BOTTOM;
1457         else if ( effect == wxSHOW_EFFECT_ROLL_TO_BOTTOM ||
1458                     effect == wxSHOW_EFFECT_SLIDE_TO_BOTTOM )
1459             effect = wxSHOW_EFFECT_ROLL_TO_TOP;
1460     }
1461
1462     switch ( effect )
1463     {
1464         case wxSHOW_EFFECT_ROLL_TO_LEFT:
1465         case wxSHOW_EFFECT_SLIDE_TO_LEFT:
1466             rectEnd.width = 0;
1467             break;
1468
1469         case wxSHOW_EFFECT_ROLL_TO_RIGHT:
1470         case wxSHOW_EFFECT_SLIDE_TO_RIGHT:
1471             rectEnd.x = rectStart.GetRight();
1472             rectEnd.width = 0;
1473             break;
1474
1475         case wxSHOW_EFFECT_ROLL_TO_TOP:
1476         case wxSHOW_EFFECT_SLIDE_TO_TOP:
1477             rectEnd.height = 0;
1478             break;
1479
1480         case wxSHOW_EFFECT_ROLL_TO_BOTTOM:
1481         case wxSHOW_EFFECT_SLIDE_TO_BOTTOM:
1482             rectEnd.y = rectStart.GetBottom();
1483             rectEnd.height = 0;
1484             break;
1485
1486         case wxSHOW_EFFECT_EXPAND:
1487             rectEnd.x = rectStart.x + rectStart.width / 2;
1488             rectEnd.y = rectStart.y + rectStart.height / 2;
1489             rectEnd.width =
1490             rectEnd.height = 0;
1491             break;
1492
1493         case wxSHOW_EFFECT_BLEND:
1494             [dict setObject:(show ? NSViewAnimationFadeInEffect
1495                                   : NSViewAnimationFadeOutEffect)
1496                   forKey:NSViewAnimationEffectKey];
1497             break;
1498
1499         case wxSHOW_EFFECT_NONE:
1500         case wxSHOW_EFFECT_MAX:
1501             wxFAIL_MSG( "unexpected animation effect" );
1502             return false;
1503
1504         default:
1505             wxFAIL_MSG( "unknown animation effect" );
1506             return false;
1507     };
1508
1509     if ( show )
1510     {
1511         // we need to restore it to the original rectangle instead of making it
1512         // disappear
1513         wxSwap(rectStart, rectEnd);
1514
1515         // and as the window is currently hidden, we need to show it for the
1516         // animation to be visible at all (but don't restore it at its full
1517         // rectangle as it shouldn't appear immediately)
1518         win->SetSize(rectStart);
1519         win->Show();
1520     }
1521
1522     NSView * const parentView = [viewOrWin isKindOfClass:[NSView class]]
1523                                     ? [(NSView *)viewOrWin superview]
1524                                     : nil;
1525     const NSRect rStart = wxToNSRect(parentView, rectStart);
1526     const NSRect rEnd = wxToNSRect(parentView, rectEnd);
1527
1528     [dict setObject:[NSValue valueWithRect:rStart]
1529           forKey:NSViewAnimationStartFrameKey];
1530     [dict setObject:[NSValue valueWithRect:rEnd]
1531           forKey:NSViewAnimationEndFrameKey];
1532
1533     // create an animation using the values in the above dictionary
1534     NSViewAnimation * const
1535         anim = [[NSViewAnimation alloc]
1536                 initWithViewAnimations:[NSArray arrayWithObject:dict]];
1537
1538     if ( !timeout )
1539     {
1540         // what is a good default duration? Windows uses 200ms, Web frameworks
1541         // use anything from 250ms to 1s... choose something in the middle
1542         timeout = 500;
1543     }
1544
1545     [anim setDuration:timeout/1000.];   // duration is in seconds here
1546
1547     // if the window being animated changes its layout depending on its size
1548     // (which is almost always the case) we need to redo it during animation
1549     //
1550     // the number of layouts here is arbitrary, but 10 seems like too few (e.g.
1551     // controls in wxInfoBar visibly jump around)
1552     const int NUM_LAYOUTS = 20;
1553     for ( float f = 1./NUM_LAYOUTS; f < 1.; f += 1./NUM_LAYOUTS )
1554         [anim addProgressMark:f];
1555
1556     wxNSAnimationDelegate * const
1557         animDelegate = [[wxNSAnimationDelegate alloc] init:win];
1558     [anim setDelegate:animDelegate];
1559     [anim startAnimation];
1560
1561     // Cocoa is capable of doing animation asynchronously or even from separate
1562     // thread but wx API doesn't provide any way to be notified about the
1563     // animation end and without this we really must ensure that the window has
1564     // the expected (i.e. the same as if a simple Show() had been used) size
1565     // when we return, so block here until the animation finishes
1566     //
1567     // notice that because the default animation mode is NSAnimationBlocking,
1568     // no user input events ought to be processed from here
1569     {
1570         wxEventLoopGuarantor ensureEventLoopExistence;
1571         wxEventLoopBase * const loop = wxEventLoopBase::GetActive();
1572         while ( ![animDelegate isDone] )
1573             loop->Dispatch();
1574     }
1575
1576     if ( !show )
1577     {
1578         // NSViewAnimation is smart enough to hide the NSView being animated at
1579         // the end but we also must ensure that it's hidden for wx too
1580         win->Hide();
1581
1582         // and we must also restore its size because it isn't expected to
1583         // change just because the window was hidden
1584         win->SetSize(rectOrig);
1585     }
1586     else
1587     {
1588         // refresh it once again after the end to ensure that everything is in
1589         // place
1590         win->SendSizeEvent();
1591     }
1592
1593     [anim setDelegate:nil];
1594     [animDelegate release];
1595     [anim release];
1596
1597     return true;
1598 }
1599
1600 bool wxWidgetCocoaImpl::ShowWithEffect(bool show,
1601                                        wxShowEffect effect,
1602                                        unsigned timeout)
1603 {
1604     return ShowViewOrWindowWithEffect(m_wxPeer, show, effect, timeout);
1605 }
1606
1607 void wxWidgetCocoaImpl::Raise()
1608 {
1609     // Not implemented
1610 }
1611
1612 void wxWidgetCocoaImpl::Lower()
1613 {
1614     // Not implemented
1615 }
1616
1617 void wxWidgetCocoaImpl::ScrollRect( const wxRect *WXUNUSED(rect), int WXUNUSED(dx), int WXUNUSED(dy) )
1618 {
1619 #if 1
1620     SetNeedsDisplay() ;
1621 #else
1622     // We should do something like this, but it wasn't working in 10.4.
1623     if (GetNeedsDisplay() )
1624     {
1625         SetNeedsDisplay() ;
1626     }
1627     NSRect r = wxToNSRect( [m_osxView superview], *rect );
1628     NSSize offset = NSMakeSize((float)dx, (float)dy);
1629     [m_osxView scrollRect:r by:offset];
1630 #endif
1631 }
1632
1633 void wxWidgetCocoaImpl::Move(int x, int y, int width, int height)
1634 {
1635     wxWindowMac* parent = GetWXPeer()->GetParent();
1636     // under Cocoa we might have a contentView in the wxParent to which we have to
1637     // adjust the coordinates
1638     if (parent && [m_osxView superview] != parent->GetHandle() )
1639     {
1640         int cx = 0,cy = 0,cw = 0,ch = 0;
1641         if ( parent->GetPeer() )
1642         {
1643             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1644             x -= cx;
1645             y -= cy;
1646         }
1647     }
1648     [[m_osxView superview] setNeedsDisplayInRect:[m_osxView frame]];
1649     NSRect r = wxToNSRect( [m_osxView superview], wxRect(x,y,width, height) );
1650     [m_osxView setFrame:r];
1651     [[m_osxView superview] setNeedsDisplayInRect:r];
1652
1653     wxNSView* wxview = (wxNSView*)m_osxView;
1654 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
1655     if ([wxview respondsToSelector:@selector(updateTrackingArea)] )
1656         [wxview updateTrackingArea];
1657 #else
1658     if ([m_osxView respondsToSelector:@selector(trackingTag)] )
1659     {
1660         if ( [wxview trackingTag] )
1661             [wxview removeTrackingRect: [wxview trackingTag]];
1662
1663         [wxview setTrackingTag: [wxview addTrackingRect: [m_osxView bounds] owner: wxview userData: nil assumeInside: NO]];
1664     }
1665 #endif
1666 }
1667
1668 void wxWidgetCocoaImpl::GetPosition( int &x, int &y ) const
1669 {
1670     wxRect r = wxFromNSRect( [m_osxView superview], [m_osxView frame] );
1671     x = r.GetLeft();
1672     y = r.GetTop();
1673
1674     // under Cocoa we might have a contentView in the wxParent to which we have to
1675     // adjust the coordinates
1676     wxWindowMac* parent = GetWXPeer()->GetParent();
1677     if (parent && [m_osxView superview] != parent->GetHandle() )
1678     {
1679         int cx = 0,cy = 0,cw = 0,ch = 0;
1680         if ( parent->GetPeer() )
1681         {
1682             parent->GetPeer()->GetContentArea(cx, cy, cw, ch);
1683             x += cx;
1684             y += cy;
1685         }
1686     }
1687 }
1688
1689 void wxWidgetCocoaImpl::GetSize( int &width, int &height ) const
1690 {
1691     NSRect rect = [m_osxView frame];
1692     width = (int)rect.size.width;
1693     height = (int)rect.size.height;
1694 }
1695
1696 void wxWidgetCocoaImpl::GetContentArea( int&left, int &top, int &width, int &height ) const
1697 {
1698     if ( [m_osxView respondsToSelector:@selector(contentView) ] )
1699     {
1700         NSView* cv = [m_osxView contentView];
1701
1702         NSRect bounds = [m_osxView bounds];
1703         NSRect rect = [cv frame];
1704
1705         int y = (int)rect.origin.y;
1706         int x = (int)rect.origin.x;
1707         if ( ![ m_osxView isFlipped ] )
1708             y = (int)(bounds.size.height - (rect.origin.y + rect.size.height));
1709         left = x;
1710         top = y;
1711         width = (int)rect.size.width;
1712         height = (int)rect.size.height;
1713     }
1714     else
1715     {
1716         left = top = 0;
1717         GetSize( width, height );
1718     }
1719 }
1720
1721 void wxWidgetCocoaImpl::SetNeedsDisplay( const wxRect* where )
1722 {
1723     if ( where )
1724         [m_osxView setNeedsDisplayInRect:wxToNSRect(m_osxView, *where )];
1725     else
1726         [m_osxView setNeedsDisplay:YES];
1727 }
1728
1729 bool wxWidgetCocoaImpl::GetNeedsDisplay() const
1730 {
1731     return [m_osxView needsDisplay];
1732 }
1733
1734 bool wxWidgetCocoaImpl::CanFocus() const
1735 {
1736     return [m_osxView canBecomeKeyView] == YES;
1737 }
1738
1739 bool wxWidgetCocoaImpl::HasFocus() const
1740 {
1741     return ( FindFocus() == m_osxView );
1742 }
1743
1744 bool wxWidgetCocoaImpl::SetFocus()
1745 {
1746     if ( !CanFocus() )
1747         return false;
1748
1749     [[m_osxView window] makeKeyAndOrderFront:nil] ;
1750     [[m_osxView window] makeFirstResponder: m_osxView] ;
1751     return true;
1752 }
1753
1754
1755 void wxWidgetCocoaImpl::RemoveFromParent()
1756 {
1757     [m_osxView removeFromSuperview];
1758 }
1759
1760 void wxWidgetCocoaImpl::Embed( wxWidgetImpl *parent )
1761 {
1762     NSView* container = parent->GetWXWidget() ;
1763     wxASSERT_MSG( container != NULL , wxT("No valid mac container control") ) ;
1764     [container addSubview:m_osxView];
1765 }
1766
1767 void wxWidgetCocoaImpl::SetBackgroundColour( const wxColour &col )
1768 {
1769     NSView* targetView = m_osxView;
1770     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1771         targetView = [(NSScrollView*) m_osxView documentView];
1772
1773     if ( [targetView respondsToSelector:@selector(setBackgroundColor:) ] )
1774     {
1775         [targetView setBackgroundColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
1776                                                                 green:(CGFloat) (col.Green() / 255.0)
1777                                                                  blue:(CGFloat) (col.Blue() / 255.0)
1778                                                                 alpha:(CGFloat) (col.Alpha() / 255.0)]];
1779     }
1780 }
1781
1782 bool wxWidgetCocoaImpl::SetBackgroundStyle( wxBackgroundStyle style )
1783 {
1784     BOOL opaque = ( style == wxBG_STYLE_PAINT );
1785
1786     if ( [m_osxView respondsToSelector:@selector(setOpaque:) ] )
1787     {
1788         [m_osxView setOpaque: opaque];
1789     }
1790
1791     return true ;
1792 }
1793
1794 void wxWidgetCocoaImpl::SetLabel( const wxString& title, wxFontEncoding encoding )
1795 {
1796     if ( [m_osxView respondsToSelector:@selector(setTitle:) ] )
1797     {
1798         wxCFStringRef cf( title , encoding );
1799         [m_osxView setTitle:cf.AsNSString()];
1800     }
1801     else if ( [m_osxView respondsToSelector:@selector(setStringValue:) ] )
1802     {
1803         wxCFStringRef cf( title , encoding );
1804         [m_osxView setStringValue:cf.AsNSString()];
1805     }
1806 }
1807
1808
1809 void  wxWidgetImpl::Convert( wxPoint *pt , wxWidgetImpl *from , wxWidgetImpl *to )
1810 {
1811     NSPoint p = wxToNSPoint( from->GetWXWidget(), *pt );
1812     p = [from->GetWXWidget() convertPoint:p toView:to->GetWXWidget() ];
1813     *pt = wxFromNSPoint( to->GetWXWidget(), p );
1814 }
1815
1816 wxInt32 wxWidgetCocoaImpl::GetValue() const
1817 {
1818     return [(NSControl*)m_osxView intValue];
1819 }
1820
1821 void wxWidgetCocoaImpl::SetValue( wxInt32 v )
1822 {
1823     if (  [m_osxView respondsToSelector:@selector(setIntValue:)] )
1824     {
1825         [m_osxView setIntValue:v];
1826     }
1827     else if (  [m_osxView respondsToSelector:@selector(setFloatValue:)] )
1828     {
1829         [m_osxView setFloatValue:(double)v];
1830     }
1831     else if (  [m_osxView respondsToSelector:@selector(setDoubleValue:)] )
1832     {
1833         [m_osxView setDoubleValue:(double)v];
1834     }
1835 }
1836
1837 void wxWidgetCocoaImpl::SetMinimum( wxInt32 v )
1838 {
1839     if (  [m_osxView respondsToSelector:@selector(setMinValue:)] )
1840     {
1841         [m_osxView setMinValue:(double)v];
1842     }
1843 }
1844
1845 void wxWidgetCocoaImpl::SetMaximum( wxInt32 v )
1846 {
1847     if (  [m_osxView respondsToSelector:@selector(setMaxValue:)] )
1848     {
1849         [m_osxView setMaxValue:(double)v];
1850     }
1851 }
1852
1853 wxInt32 wxWidgetCocoaImpl::GetMinimum() const
1854 {
1855     if (  [m_osxView respondsToSelector:@selector(minValue)] )
1856     {
1857         return (int)[m_osxView minValue];
1858     }
1859     return 0;
1860 }
1861
1862 wxInt32 wxWidgetCocoaImpl::GetMaximum() const
1863 {
1864     if (  [m_osxView respondsToSelector:@selector(maxValue)] )
1865     {
1866         return (int)[m_osxView maxValue];
1867     }
1868     return 0;
1869 }
1870
1871 wxBitmap wxWidgetCocoaImpl::GetBitmap() const
1872 {
1873     wxBitmap bmp;
1874
1875     // TODO: how to create a wxBitmap from NSImage?
1876 #if 0
1877     if ( [m_osxView respondsToSelector:@selector(image:)] )
1878         bmp = [m_osxView image];
1879 #endif
1880
1881     return bmp;
1882 }
1883
1884 void wxWidgetCocoaImpl::SetBitmap( const wxBitmap& bitmap )
1885 {
1886     if (  [m_osxView respondsToSelector:@selector(setImage:)] )
1887     {
1888         [m_osxView setImage:bitmap.GetNSImage()];
1889         [m_osxView setNeedsDisplay:YES];
1890     }
1891 }
1892
1893 void wxWidgetCocoaImpl::SetBitmapPosition( wxDirection dir )
1894 {
1895     if ( [m_osxView respondsToSelector:@selector(setImagePosition:)] )
1896     {
1897         NSCellImagePosition pos;
1898         switch ( dir )
1899         {
1900             case wxLEFT:
1901                 pos = NSImageLeft;
1902                 break;
1903
1904             case wxRIGHT:
1905                 pos = NSImageRight;
1906                 break;
1907
1908             case wxTOP:
1909                 pos = NSImageAbove;
1910                 break;
1911
1912             case wxBOTTOM:
1913                 pos = NSImageBelow;
1914                 break;
1915
1916             default:
1917                 wxFAIL_MSG( "invalid image position" );
1918                 pos = NSNoImage;
1919         }
1920
1921         [m_osxView setImagePosition:pos];
1922     }
1923 }
1924
1925 void wxWidgetCocoaImpl::SetupTabs( const wxNotebook& WXUNUSED(notebook))
1926 {
1927     // implementation in subclass
1928 }
1929
1930 void wxWidgetCocoaImpl::GetBestRect( wxRect *r ) const
1931 {
1932     r->x = r->y = r->width = r->height = 0;
1933
1934     if (  [m_osxView respondsToSelector:@selector(sizeToFit)] )
1935     {
1936         NSRect former = [m_osxView frame];
1937         [m_osxView sizeToFit];
1938         NSRect best = [m_osxView frame];
1939         [m_osxView setFrame:former];
1940         r->width = (int)best.size.width;
1941         r->height = (int)best.size.height;
1942     }
1943 }
1944
1945 bool wxWidgetCocoaImpl::IsEnabled() const
1946 {
1947     NSView* targetView = m_osxView;
1948     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1949         targetView = [(NSScrollView*) m_osxView documentView];
1950
1951     if ( [targetView respondsToSelector:@selector(isEnabled) ] )
1952         return [targetView isEnabled];
1953     return true;
1954 }
1955
1956 void wxWidgetCocoaImpl::Enable( bool enable )
1957 {
1958     NSView* targetView = m_osxView;
1959     if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
1960         targetView = [(NSScrollView*) m_osxView documentView];
1961
1962     if ( [targetView respondsToSelector:@selector(setEnabled:) ] )
1963         [targetView setEnabled:enable];
1964 }
1965
1966 void wxWidgetCocoaImpl::PulseGauge()
1967 {
1968 }
1969
1970 void wxWidgetCocoaImpl::SetScrollThumb( wxInt32 WXUNUSED(val), wxInt32 WXUNUSED(view) )
1971 {
1972 }
1973
1974 void wxWidgetCocoaImpl::SetControlSize( wxWindowVariant variant )
1975 {
1976     NSControlSize size = NSRegularControlSize;
1977
1978     switch ( variant )
1979     {
1980         case wxWINDOW_VARIANT_NORMAL :
1981             size = NSRegularControlSize;
1982             break ;
1983
1984         case wxWINDOW_VARIANT_SMALL :
1985             size = NSSmallControlSize;
1986             break ;
1987
1988         case wxWINDOW_VARIANT_MINI :
1989             size = NSMiniControlSize;
1990             break ;
1991
1992         case wxWINDOW_VARIANT_LARGE :
1993             size = NSRegularControlSize;
1994             break ;
1995
1996         default:
1997             wxFAIL_MSG(wxT("unexpected window variant"));
1998             break ;
1999     }
2000     if ( [m_osxView respondsToSelector:@selector(setControlSize:)] )
2001         [m_osxView setControlSize:size];
2002     else if ([m_osxView respondsToSelector:@selector(cell)])
2003     {
2004         id cell = [(id)m_osxView cell];
2005         if ([cell respondsToSelector:@selector(setControlSize:)])
2006             [cell setControlSize:size];
2007     }
2008 }
2009
2010 void wxWidgetCocoaImpl::SetFont(wxFont const& font, wxColour const&col, long, bool)
2011 {
2012     if ([m_osxView respondsToSelector:@selector(setFont:)])
2013         [m_osxView setFont: font.OSXGetNSFont()];
2014     if ([m_osxView respondsToSelector:@selector(setTextColor:)])
2015         [m_osxView setTextColor:[NSColor colorWithCalibratedRed:(CGFloat) (col.Red() / 255.0)
2016                                                                  green:(CGFloat) (col.Green() / 255.0)
2017                                                                   blue:(CGFloat) (col.Blue() / 255.0)
2018                                                                  alpha:(CGFloat) (col.Alpha() / 255.0)]];
2019 }
2020
2021 void wxWidgetCocoaImpl::SetToolTip(wxToolTip* tooltip)
2022 {
2023     if (tooltip)
2024     {
2025         wxCFStringRef cf( tooltip->GetTip() , m_wxPeer->GetFont().GetEncoding() );
2026         [m_osxView setToolTip: cf.AsNSString()];
2027     }
2028     else
2029         [m_osxView setToolTip: nil];
2030
2031 }
2032
2033 void wxWidgetCocoaImpl::InstallEventHandler( WXWidget control )
2034 {
2035     WXWidget c =  control ? control : (WXWidget) m_osxView;
2036     wxWidgetImpl::Associate( c, this ) ;
2037     if ([c respondsToSelector:@selector(setAction:)])
2038     {
2039         [c setTarget: c];
2040         [c setAction: @selector(controlAction:)];
2041         if ([c respondsToSelector:@selector(setDoubleAction:)])
2042         {
2043             [c setDoubleAction: @selector(controlDoubleAction:)];
2044         }
2045
2046     }
2047 }
2048
2049 bool wxWidgetCocoaImpl::DoHandleCharEvent(NSEvent *event, NSString *text)
2050 {
2051     wxKeyEvent wxevent(wxEVT_CHAR);
2052     SetupKeyEvent( wxevent, event, text );
2053
2054     return GetWXPeer()->OSXHandleKeyEvent(wxevent);
2055 }
2056
2057 bool wxWidgetCocoaImpl::DoHandleKeyEvent(NSEvent *event)
2058 {
2059     wxKeyEvent wxevent(wxEVT_KEY_DOWN);
2060     SetupKeyEvent( wxevent, event );
2061     bool result = GetWXPeer()->OSXHandleKeyEvent(wxevent);
2062
2063     // this will fire higher level events, like insertText, to help
2064     // us handle EVT_CHAR, etc.
2065
2066     if ( m_wxPeer->MacIsUserPane() && [event type] == NSKeyDown)
2067     {
2068         if ( !result )
2069         {
2070             if ( wxevent.GetKeyCode() < WXK_SPACE || wxevent.GetKeyCode() == WXK_DELETE || wxevent.GetKeyCode() >= WXK_START )
2071             {
2072                 // eventually we could setup a doCommandBySelector catcher and retransform this into the wx key chars
2073                 wxKeyEvent wxevent2(wxevent) ;
2074                 wxevent2.SetEventType(wxEVT_CHAR);
2075                 GetWXPeer()->OSXHandleKeyEvent(wxevent2);
2076             }
2077             else
2078             {
2079                 if ( [m_osxView isKindOfClass:[NSScrollView class] ] )
2080                     [[(NSScrollView*)m_osxView documentView] interpretKeyEvents:[NSArray arrayWithObject:event]];
2081                 else
2082                     [m_osxView interpretKeyEvents:[NSArray arrayWithObject:event]];
2083             }
2084             result = true;
2085         }
2086     }
2087
2088     return result;
2089 }
2090
2091 bool wxWidgetCocoaImpl::DoHandleMouseEvent(NSEvent *event)
2092 {
2093     wxMouseEvent wxevent(wxEVT_LEFT_DOWN);
2094     SetupMouseEvent(wxevent , event) ;
2095
2096     return GetWXPeer()->HandleWindowEvent(wxevent);
2097 }
2098
2099 void wxWidgetCocoaImpl::DoNotifyFocusEvent(bool receivedFocus, wxWidgetImpl* otherWindow)
2100 {
2101     wxWindow* thisWindow = GetWXPeer();
2102     if ( thisWindow->MacGetTopLevelWindow() && NeedsFocusRect() )
2103     {
2104         thisWindow->MacInvalidateBorders();
2105     }
2106
2107     if ( receivedFocus )
2108     {
2109         wxLogTrace(wxT("Focus"), wxT("focus set(%p)"), static_cast<void*>(thisWindow));
2110         wxChildFocusEvent eventFocus((wxWindow*)thisWindow);
2111         thisWindow->HandleWindowEvent(eventFocus);
2112
2113 #if wxUSE_CARET
2114         if ( thisWindow->GetCaret() )
2115             thisWindow->GetCaret()->OnSetFocus();
2116 #endif
2117
2118         wxFocusEvent event(wxEVT_SET_FOCUS, thisWindow->GetId());
2119         event.SetEventObject(thisWindow);
2120         if (otherWindow)
2121             event.SetWindow(otherWindow->GetWXPeer());
2122         thisWindow->HandleWindowEvent(event) ;
2123     }
2124     else // !receivedFocuss
2125     {
2126 #if wxUSE_CARET
2127         if ( thisWindow->GetCaret() )
2128             thisWindow->GetCaret()->OnKillFocus();
2129 #endif
2130
2131         wxLogTrace(wxT("Focus"), wxT("focus lost(%p)"), static_cast<void*>(thisWindow));
2132
2133         wxFocusEvent event( wxEVT_KILL_FOCUS, thisWindow->GetId());
2134         event.SetEventObject(thisWindow);
2135         if (otherWindow)
2136             event.SetWindow(otherWindow->GetWXPeer());
2137         thisWindow->HandleWindowEvent(event) ;
2138     }
2139 }
2140
2141 void wxWidgetCocoaImpl::SetCursor(const wxCursor& cursor)
2142 {
2143     NSPoint location = [NSEvent mouseLocation];
2144     location = [[m_osxView window] convertScreenToBase:location];
2145     NSPoint locationInView = [m_osxView convertPoint:location fromView:nil];
2146
2147     if( NSMouseInRect(locationInView, [m_osxView bounds], YES) )
2148     {
2149         [(NSCursor*)cursor.GetHCURSOR() set];
2150     }
2151     [[m_osxView window] invalidateCursorRectsForView:m_osxView];
2152 }
2153
2154 void wxWidgetCocoaImpl::CaptureMouse()
2155 {
2156     [[m_osxView window] disableCursorRects];
2157 }
2158
2159 void wxWidgetCocoaImpl::ReleaseMouse()
2160 {
2161     [[m_osxView window] enableCursorRects];
2162 }
2163
2164 void wxWidgetCocoaImpl::SetFlipped(bool flipped)
2165 {
2166     m_isFlipped = flipped;
2167 }
2168
2169 //
2170 // Factory methods
2171 //
2172
2173 wxWidgetImpl* wxWidgetImpl::CreateUserPane( wxWindowMac* wxpeer, wxWindowMac* WXUNUSED(parent),
2174     wxWindowID WXUNUSED(id), const wxPoint& pos, const wxSize& size,
2175     long WXUNUSED(style), long WXUNUSED(extraStyle))
2176 {
2177     NSRect r = wxOSXGetFrameForControl( wxpeer, pos , size ) ;
2178     wxNSView* v = [[wxNSView alloc] initWithFrame:r];
2179
2180     // temporary hook for dnd
2181     [v registerForDraggedTypes:[NSArray arrayWithObjects:
2182         NSStringPboardType, NSFilenamesPboardType, NSTIFFPboardType, NSPICTPboardType, NSPDFPboardType, nil]];
2183
2184     wxWidgetCocoaImpl* c = new wxWidgetCocoaImpl( wxpeer, v );
2185     return c;
2186 }
2187
2188 wxWidgetImpl* wxWidgetImpl::CreateContentView( wxNonOwnedWindow* now )
2189 {
2190     NSWindow* tlw = now->GetWXWindow();
2191
2192     wxWidgetCocoaImpl* c = NULL;
2193     if ( now->IsNativeWindowWrapper() )
2194     {
2195         NSView* cv = [tlw contentView];
2196         c = new wxWidgetCocoaImpl( now, cv, true );
2197         // increase ref count, because the impl destructor will decrement it again
2198         CFRetain(cv);
2199         if ( !now->IsShown() )
2200             [cv setHidden:NO];
2201
2202     }
2203     else
2204     {
2205         wxNSView* v = [[wxNSView alloc] initWithFrame:[[tlw contentView] frame]];
2206         c = new wxWidgetCocoaImpl( now, v, true );
2207         c->InstallEventHandler();
2208         [tlw setContentView:v];
2209     }
2210     return c;
2211 }