src/osx/cocoa/dataview.mm

   1 ///////////////////////////////////////////////////////////////////////////////
   2 // Name:        src/osx/cocoa/dataview.mm
   3 // Purpose:     wxDataView
   4 // Author:
   5 // Modified by:
   6 // Created:     2009-01-31
   7 // RCS-ID:      $Id: dataview.mm$
   8 // Copyright:
   9 // Licence:     wxWindows licence
  10 ///////////////////////////////////////////////////////////////////////////////
  11
  12 #include "wx/wxprec.h"
  13
  14 #if (wxUSE_DATAVIEWCTRL == 1) && !defined(wxUSE_GENERICDATAVIEWCTRL)
  15
  16 #ifndef WX_PRECOMP
  17     #include "wx/app.h"
  18     #include "wx/toplevel.h"
  19     #include "wx/font.h"
  20     #include "wx/settings.h"
  21     #include "wx/utils.h"
  22 #endif
  23
  24 #include "wx/osx/private.h"
  25 #include "wx/osx/cocoa/dataview.h"
  26 #include "wx/renderer.h"
  27 #include "wx/stopwatch.h"
  28 #include "wx/dcgraph.h"
  29
  30 // ============================================================================
  31 // Constants used locally
  32 // ============================================================================
  33
  34 #define DataViewPboardType @"OutlineViewItem"
  35
  36 // ============================================================================
  37 // Classes used locally in dataview.mm
  38 // ============================================================================
  39
  40 // ============================================================================
  41 // wxPointerObject
  42 // ============================================================================
  43
  44 @implementation wxPointerObject
  45
  46 -(id) init
  47 {
  48     self = [super init];
  49     if (self != nil)
  50         self->pointer = NULL;
  51     return self;
  52 }
  53
  54 -(id) initWithPointer:(void*) initPointer
  55 {
  56     self = [super init];
  57     if (self != nil)
  58         self->pointer = initPointer;
  59     return self;
  60 }
  61
  62 //
  63 // inherited methods from NSObject
  64 //
  65 -(BOOL) isEqual:(id)object
  66 {
  67     return (object != nil) &&
  68              ([object isKindOfClass:[wxPointerObject class]]) &&
  69                  (pointer == [((wxPointerObject*) object) pointer]);
  70 }
  71
  72 -(NSUInteger) hash
  73 {
  74     return (NSUInteger) pointer;
  75 }
  76
  77 -(void*) pointer
  78 {
  79     return pointer;
  80 }
  81
  82 -(void) setPointer:(void*) newPointer
  83 {
  84     pointer = newPointer;
  85 }
  86
  87 @end
  88
  89 namespace
  90 {
  91
  92 inline wxDataViewItem wxDataViewItemFromItem(id item)
  93 {
  94     return wxDataViewItem([static_cast<wxPointerObject *>(item) pointer]);
  95 }
  96
  97 inline wxDataViewItem wxDataViewItemFromMaybeNilItem(id item)
  98 {
  99     return item == nil ? wxDataViewItem() : wxDataViewItemFromItem(item);
 100 }
 101
 102 } // anonymous namespace
 103
 104 // ----------------------------------------------------------------------------
 105 // wxCustomRendererObject
 106 // ----------------------------------------------------------------------------
 107
 108 @interface wxCustomRendererObject : NSObject <NSCopying>
 109 {
 110 @public
 111     wxDataViewCustomRenderer* customRenderer; // not owned by the class
 112 }
 113
 114     -(id) init;
 115     -(id) initWithRenderer:(wxDataViewCustomRenderer*)renderer;
 116 @end
 117
 118 @implementation wxCustomRendererObject
 119
 120 -(id) init
 121 {
 122     self = [super init];
 123     if (self != nil)
 124     {
 125         customRenderer = NULL;
 126     }
 127     return self;
 128 }
 129
 130 -(id) initWithRenderer:(wxDataViewCustomRenderer*)renderer
 131 {
 132     self = [super init];
 133     if (self != nil)
 134     {
 135         customRenderer = renderer;
 136     }
 137     return self;
 138 }
 139
 140 -(id) copyWithZone:(NSZone*)zone
 141 {
 142     wxCustomRendererObject* copy;
 143
 144     copy = [[[self class] allocWithZone:zone] init];
 145     copy->customRenderer = customRenderer;
 146
 147     return copy;
 148 }
 149 @end
 150
 151 // ----------------------------------------------------------------------------
 152 // wxDVCNSTableColumn: exists only to override NSTableColumn:dataCellForRow:
 153 // ----------------------------------------------------------------------------
 154
 155 @interface wxDVCNSTableColumn : NSTableColumn
 156 {
 157 }
 158
 159     // Get the identifier we use for the specified column. This should be used
 160     // for finding columns from identifier only, to initialize the identifier
 161     // of a new column use initWithColumnPointer below instead.
 162     +(NSString*) identifierForColumnPointer:(const wxDataViewColumn*)column;
 163
 164     // Initialize the column with the given pointer to the associated
 165     // wxDataViewColumn. This pointer can later be retrieved using
 166     // getColumnPointer.
 167     -(id) initWithColumnPointer:(const wxDataViewColumn*)column;
 168
 169     // Retrieve the associated column.
 170     -(wxDataViewColumn*) getColumnPointer;
 171
 172     -(id) dataCellForRow:(NSInteger)row;
 173 @end
 174
 175 @implementation wxDVCNSTableColumn
 176
 177 +(NSString*) identifierForColumnPointer:(const wxDataViewColumn*)column
 178 {
 179     // Starting from OS X 10.7 the column identifier must be an NSString and
 180     // not just some arbitrary object, so we serialize the pointer into the
 181     // string. Notice the use of NSInteger which is big enough to store a
 182     // pointer in both 32 and 64 bit builds.
 183     return [NSString stringWithFormat:@"%lu", reinterpret_cast<NSUInteger>(column)];
 184 }
 185
 186 -(id) initWithColumnPointer:(const wxDataViewColumn*)column
 187 {
 188     [self initWithIdentifier: [wxDVCNSTableColumn identifierForColumnPointer:column]];
 189     return self;
 190 }
 191
 192 -(wxDataViewColumn*) getColumnPointer
 193 {
 194     // The case to NSString is needed for OS X < 10.7.
 195     return reinterpret_cast<wxDataViewColumn*>(
 196             [static_cast<NSString*>([self identifier]) integerValue]);
 197 }
 198
 199 -(id) dataCellForRow:(NSInteger)row
 200 {
 201     // what we want to do here is to simply return nil for the cells which
 202     // shouldn't show anything as otherwise we would show e.g. empty combo box
 203     // or progress cells in the columns using the corresponding types even for
 204     // the container rows which is wrong
 205
 206     const wxDataViewColumn * const dvCol = [self getColumnPointer];
 207
 208     const wxDataViewCtrl * const dvc = dvCol->GetOwner();
 209     const wxCocoaDataViewControl * const
 210         peer = static_cast<wxCocoaDataViewControl *>(dvc->GetPeer());
 211
 212
 213     // once we do have everything, simply ask NSOutlineView for the item...
 214     const id item = peer->GetItemAtRow(row);
 215     if ( item )
 216     {
 217         // ... and if it succeeded, ask the model whether it has any value
 218         wxDataViewItem dvItem(wxDataViewItemFromItem(item));
 219
 220         if ( !dvc->GetModel()->HasValue(dvItem, dvCol->GetModelColumn()) )
 221             return nil;
 222     }
 223
 224     return [super dataCellForRow:row];
 225 }
 226
 227 @end
 228
 229 // ============================================================================
 230 // local helpers
 231 // ============================================================================
 232
 233 namespace
 234 {
 235
 236 // convert from NSObject to different C++ types: all these functions check
 237 // that the conversion really makes sense and assert if it doesn't
 238 wxString ObjectToString(NSObject *object)
 239 {
 240     wxCHECK_MSG( [object isKindOfClass:[NSString class]], "",
 241                  wxString::Format
 242                  (
 243                     "string expected but got %s",
 244                     wxCFStringRef::AsString([object className])
 245                  ));
 246
 247     return wxCFStringRef([((NSString*) object) retain]).AsString();
 248 }
 249
 250 bool ObjectToBool(NSObject *object)
 251 {
 252     // actually the value must be of NSCFBoolean class but it's private so we
 253     // can't check for it directly
 254     wxCHECK_MSG( [object isKindOfClass:[NSNumber class]], false,
 255                  wxString::Format
 256                  (
 257                     "number expected but got %s",
 258                     wxCFStringRef::AsString([object className])
 259                  ));
 260
 261     return [(NSNumber *)object boolValue];
 262 }
 263
 264 long ObjectToLong(NSObject *object)
 265 {
 266     wxCHECK_MSG( [object isKindOfClass:[NSNumber class]], -1,
 267                  wxString::Format
 268                  (
 269                     "number expected but got %s",
 270                     wxCFStringRef::AsString([object className])
 271                  ));
 272
 273     return [(NSNumber *)object longValue];
 274 }
 275
 276 wxDateTime ObjectToDate(NSObject *object)
 277 {
 278     wxCHECK_MSG( [object isKindOfClass:[NSDate class]], wxInvalidDateTime,
 279                  wxString::Format
 280                  (
 281                     "date expected but got %s",
 282                     wxCFStringRef::AsString([object className])
 283                  ));
 284
 285     // get the number of seconds since 1970-01-01 UTC and this is the only
 286     // way to convert a double to a wxLongLong
 287     const wxLongLong seconds = [((NSDate*) object) timeIntervalSince1970];
 288
 289     wxDateTime dt(1, wxDateTime::Jan, 1970);
 290     dt.Add(wxTimeSpan(0,0,seconds));
 291
 292     // the user has entered a date in the local timezone but seconds
 293     // contains the number of seconds from date in the local timezone
 294     // since 1970-01-01 UTC; therefore, the timezone information has to be
 295     // transferred to wxWidgets, too:
 296     dt.MakeFromTimezone(wxDateTime::UTC);
 297
 298     return dt;
 299 }
 300
 301 NSInteger CompareItems(id item1, id item2, void* context)
 302 {
 303     NSArray* const sortDescriptors = (NSArray*) context;
 304
 305     NSUInteger const count = [sortDescriptors count];
 306
 307     NSInteger result = NSOrderedSame;
 308     for ( NSUInteger i = 0; i < count && result == NSOrderedSame; ++i )
 309     {
 310         wxSortDescriptorObject* const
 311             sortDescriptor = (wxSortDescriptorObject*)
 312                 [sortDescriptors objectAtIndex:i];
 313
 314         int rc = [sortDescriptor modelPtr]->Compare
 315                  (
 316                      wxDataViewItemFromItem(item1),
 317                      wxDataViewItemFromItem(item2),
 318                      [sortDescriptor columnPtr]->GetModelColumn(),
 319                      [sortDescriptor ascending] == YES
 320                  );
 321
 322         if ( rc < 0 )
 323             result = NSOrderedAscending;
 324         else if ( rc > 0 )
 325             result = NSOrderedDescending;
 326     }
 327
 328     return result;
 329 }
 330
 331 NSTextAlignment ConvertToNativeHorizontalTextAlignment(int alignment)
 332 {
 333     if (alignment & wxALIGN_CENTER_HORIZONTAL)
 334         return NSCenterTextAlignment;
 335     else if (alignment & wxALIGN_RIGHT)
 336         return NSRightTextAlignment;
 337     else
 338         return NSLeftTextAlignment;
 339 }
 340
 341 NSTableColumn* CreateNativeColumn(const wxDataViewColumn *column)
 342 {
 343     wxDataViewRenderer * const renderer = column->GetRenderer();
 344
 345     wxCHECK_MSG( renderer, NULL, "column should have a renderer" );
 346
 347     wxDVCNSTableColumn * const nativeColumn(
 348         [[wxDVCNSTableColumn alloc] initWithColumnPointer: column]
 349     );
 350
 351     // setting the size related parameters:
 352     int resizingMask;
 353     if (column->IsResizeable())
 354     {
 355         resizingMask = NSTableColumnUserResizingMask;
 356         [nativeColumn setMinWidth:column->GetMinWidth()];
 357         [nativeColumn setMaxWidth:column->GetMaxWidth()];
 358     }
 359     else // column is not resizable [by user]
 360     {
 361         // if the control doesn't show a header, make the columns resize
 362         // automatically, this is particularly important for the single column
 363         // controls (such as wxDataViewTreeCtrl) as their unique column should
 364         // always take up all the available splace
 365         resizingMask = column->GetOwner()->HasFlag(wxDV_NO_HEADER)
 366                             ? NSTableColumnAutoresizingMask
 367                             : NSTableColumnNoResizing;
 368     }
 369     [nativeColumn setResizingMask:resizingMask];
 370
 371 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_5
 372     // setting the visibility:
 373     [nativeColumn setHidden:static_cast<BOOL>(column->IsHidden())];
 374 #endif
 375
 376     wxDataViewRendererNativeData * const renderData = renderer->GetNativeData();
 377
 378     // setting the header:
 379     [[nativeColumn headerCell] setAlignment:
 380         ConvertToNativeHorizontalTextAlignment(column->GetAlignment())];
 381     [[nativeColumn headerCell] setStringValue:
 382         [[wxCFStringRef(column->GetTitle()).AsNSString() retain] autorelease]];
 383     renderData->ApplyLineBreakMode([nativeColumn headerCell]);
 384
 385     // setting data cell's properties:
 386     [[nativeColumn dataCell] setWraps:NO];
 387     // setting the default data cell:
 388     [nativeColumn setDataCell:renderData->GetColumnCell()];
 389     // setting the editablility:
 390     const bool isEditable = renderer->GetMode() == wxDATAVIEW_CELL_EDITABLE;
 391
 392     [nativeColumn setEditable:isEditable];
 393     [[nativeColumn dataCell] setEditable:isEditable];
 394
 395     return nativeColumn;
 396 }
 397
 398 } // anonymous namespace
 399
 400 // ============================================================================
 401 // Public helper functions for dataview implementation on OSX
 402 // ============================================================================
 403
 404 wxWidgetImplType* CreateDataView(wxWindowMac* wxpeer,
 405                                  wxWindowMac* WXUNUSED(parent),
 406                                  wxWindowID WXUNUSED(id),
 407                                  const wxPoint& pos,
 408                                  const wxSize& size,
 409                                  long style,
 410                                  long WXUNUSED(extraStyle))
 411 {
 412     return new wxCocoaDataViewControl(wxpeer,pos,size,style);
 413 }
 414
 415 // ============================================================================
 416 // wxSortDescriptorObject
 417 // ============================================================================
 418
 419 @implementation wxSortDescriptorObject
 420 -(id) init
 421 {
 422     self = [super init];
 423     if (self != nil)
 424     {
 425         columnPtr = NULL;
 426         modelPtr  = NULL;
 427     }
 428     return self;
 429 }
 430
 431 -(id)
 432 initWithModelPtr:(wxDataViewModel*)initModelPtr
 433     sortingColumnPtr:(wxDataViewColumn*)initColumnPtr
 434     ascending:(BOOL)sortAscending
 435 {
 436     self = [super initWithKey:@"dummy" ascending:sortAscending];
 437     if (self != nil)
 438     {
 439         columnPtr = initColumnPtr;
 440         modelPtr  = initModelPtr;
 441     }
 442     return self;
 443 }
 444
 445 -(id) copyWithZone:(NSZone*)zone
 446 {
 447     wxSortDescriptorObject* copy;
 448
 449
 450     copy = [super copyWithZone:zone];
 451     copy->columnPtr = columnPtr;
 452     copy->modelPtr  = modelPtr;
 453
 454     return copy;
 455 }
 456
 457 //
 458 // access to model column's index
 459 //
 460 -(wxDataViewColumn*) columnPtr
 461 {
 462     return columnPtr;
 463 }
 464
 465 -(wxDataViewModel*) modelPtr
 466 {
 467     return modelPtr;
 468 }
 469
 470 -(void) setColumnPtr:(wxDataViewColumn*)newColumnPtr
 471 {
 472     columnPtr = newColumnPtr;
 473 }
 474
 475 -(void) setModelPtr:(wxDataViewModel*)newModelPtr
 476 {
 477     modelPtr = newModelPtr;
 478 }
 479
 480 @end
 481
 482 // ============================================================================
 483 // wxCocoaOutlineDataSource
 484 // ============================================================================
 485 @implementation wxCocoaOutlineDataSource
 486
 487 //
 488 // constructors / destructor
 489 //
 490 -(id) init
 491 {
 492     self = [super init];
 493     if (self != nil)
 494     {
 495         implementation = NULL;
 496         model          = NULL;
 497
 498         currentParentItem = nil;
 499
 500         children = [[NSMutableArray alloc] init];
 501         items    = [[NSMutableSet   alloc] init];
 502     }
 503     return self;
 504 }
 505
 506 -(void) dealloc
 507 {
 508     [currentParentItem release];
 509
 510     [children release];
 511     [items    release];
 512
 513     [super dealloc];
 514 }
 515
 516 //
 517 // methods of informal protocol:
 518 //
 519 -(BOOL)
 520 outlineView:(NSOutlineView*)outlineView
 521     acceptDrop:(id<NSDraggingInfo>)info
 522     item:(id)item childIndex:(NSInteger)index
 523 {
 524     wxUnusedVar(outlineView);
 525     wxUnusedVar(index);
 526
 527     NSArray* supportedTypes(
 528         [NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]
 529     );
 530
 531     NSPasteboard* pasteboard([info draggingPasteboard]);
 532
 533     NSString* bestType([pasteboard availableTypeFromArray:supportedTypes]);
 534
 535     if ( bestType == nil )
 536         return FALSE;
 537
 538     wxDataViewCtrl * const dvc(implementation->GetDataViewCtrl());
 539
 540     wxCHECK_MSG( dvc, false,
 541                      "Pointer to data view control not set correctly." );
 542     wxCHECK_MSG( dvc->GetModel(), false,
 543                     "Pointer to model not set correctly." );
 544
 545     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_DROP, dvc->GetId());
 546     event.SetEventObject(dvc);
 547     event.SetItem(wxDataViewItemFromItem(item));
 548     event.SetModel(dvc->GetModel());
 549
 550     BOOL dragSuccessful = false;
 551     if ( [bestType compare:DataViewPboardType] == NSOrderedSame )
 552     {
 553         NSArray* dataArray((NSArray*)
 554                       [pasteboard propertyListForType:DataViewPboardType]);
 555         NSUInteger indexDraggedItem, noOfDraggedItems([dataArray count]);
 556
 557         indexDraggedItem = 0;
 558         while (indexDraggedItem < noOfDraggedItems)
 559         {
 560             wxDataObjectComposite* dataObjects(
 561                 implementation->GetDnDDataObjects((NSData*)
 562                     [dataArray objectAtIndex:indexDraggedItem]));
 563
 564             if (dataObjects && (dataObjects->GetFormatCount() > 0))
 565             {
 566                 wxMemoryBuffer buffer;
 567
 568                 // copy data into data object:
 569                 event.SetDataObject(dataObjects);
 570                 event.SetDataFormat(
 571                     implementation->GetDnDDataFormat(dataObjects));
 572                 // copy data into buffer:
 573                 dataObjects->GetDataHere(
 574                     event.GetDataFormat().GetType(),
 575                     buffer.GetWriteBuf(event.GetDataSize()));
 576                 buffer.UngetWriteBuf(event.GetDataSize());
 577                 event.SetDataBuffer(buffer.GetData());
 578                 // finally, send event:
 579                 if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 580                 {
 581                     dragSuccessful = true;
 582                     ++indexDraggedItem;
 583                 }
 584                 else
 585                 {
 586                     dragSuccessful   = true;
 587                     indexDraggedItem = noOfDraggedItems; // stop loop
 588                 }
 589             }
 590             else
 591             {
 592                 dragSuccessful   = false;
 593                 indexDraggedItem = noOfDraggedItems; // stop loop
 594             }
 595             // clean-up:
 596             delete dataObjects;
 597         }
 598     }
 599     else
 600     {
 601         // needed to convert internally used UTF-16 representation to a UTF-8
 602         // representation
 603         CFDataRef              osxData;
 604         wxDataObjectComposite* dataObjects   (new wxDataObjectComposite());
 605         wxTextDataObject*      textDataObject(new wxTextDataObject());
 606
 607         osxData = ::CFStringCreateExternalRepresentation
 608                     (
 609                      kCFAllocatorDefault,
 610                      (CFStringRef)[pasteboard stringForType:NSStringPboardType],
 611                      kCFStringEncodingUTF8,
 612                      32
 613                     );
 614         if (textDataObject->SetData(::CFDataGetLength(osxData),
 615                                     ::CFDataGetBytePtr(osxData)))
 616             dataObjects->Add(textDataObject);
 617         else
 618             delete textDataObject;
 619         // send event if data could be copied:
 620         if (dataObjects->GetFormatCount() > 0)
 621         {
 622             event.SetDataObject(dataObjects);
 623             event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 624             if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 625                 dragSuccessful = true;
 626             else
 627                 dragSuccessful = false;
 628         }
 629         else
 630             dragSuccessful = false;
 631         // clean up:
 632         ::CFRelease(osxData);
 633         delete dataObjects;
 634     }
 635     return dragSuccessful;
 636 }
 637
 638 -(id) outlineView:(NSOutlineView*)outlineView
 639     child:(NSInteger)index
 640     ofItem:(id)item
 641 {
 642     wxUnusedVar(outlineView);
 643
 644     if ((item == currentParentItem) &&
 645             (index < ((NSInteger) [self getChildCount])))
 646         return [self getChild:index];
 647
 648     wxDataViewItemArray dataViewChildren;
 649
 650     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 651     model->GetChildren(wxDataViewItemFromMaybeNilItem(item), dataViewChildren);
 652     [self bufferItem:item withChildren:&dataViewChildren];
 653     if ([sortDescriptors count] > 0)
 654         [children sortUsingFunction:CompareItems context:sortDescriptors];
 655     return [self getChild:index];
 656 }
 657
 658 -(BOOL) outlineView:(NSOutlineView*)outlineView isItemExpandable:(id)item
 659 {
 660     wxUnusedVar(outlineView);
 661
 662     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 663     return model->IsContainer(wxDataViewItemFromItem(item));
 664 }
 665
 666 -(NSInteger) outlineView:(NSOutlineView*)outlineView numberOfChildrenOfItem:(id)item
 667 {
 668     wxUnusedVar(outlineView);
 669
 670     NSInteger noOfChildren;
 671
 672     wxDataViewItemArray dataViewChildren;
 673
 674
 675     wxCHECK_MSG( model, 0, "Valid model in data source does not exist." );
 676     noOfChildren = model->GetChildren(wxDataViewItemFromMaybeNilItem(item),
 677                                       dataViewChildren);
 678     [self bufferItem:item withChildren:&dataViewChildren];
 679     if ([sortDescriptors count] > 0)
 680         [children sortUsingFunction:CompareItems context:sortDescriptors];
 681     return noOfChildren;
 682 }
 683
 684 -(id)
 685 outlineView:(NSOutlineView*)outlineView
 686     objectValueForTableColumn:(NSTableColumn*)tableColumn
 687     byItem:(id)item
 688 {
 689     wxUnusedVar(outlineView);
 690
 691     wxCHECK_MSG( model, nil, "Valid model in data source does not exist." );
 692
 693     wxDataViewColumn* const
 694         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
 695     const unsigned colIdx = col->GetModelColumn();
 696
 697     wxDataViewItem dataViewItem(wxDataViewItemFromItem(item));
 698
 699     if ( model->HasValue(dataViewItem, colIdx) )
 700     {
 701         wxVariant value;
 702         model->GetValue(value,dataViewItem, colIdx);
 703         col->GetRenderer()->SetValue(value);
 704     }
 705
 706     return nil;
 707 }
 708
 709 -(void)
 710 outlineView:(NSOutlineView*)outlineView
 711     setObjectValue:(id)object
 712     forTableColumn:(NSTableColumn*)tableColumn
 713     byItem:(id)item
 714 {
 715     wxUnusedVar(outlineView);
 716
 717     wxDataViewColumn* const
 718         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
 719
 720     col->GetRenderer()->
 721         OSXOnCellChanged(object, wxDataViewItemFromItem(item), col->GetModelColumn());
 722 }
 723
 724 -(void) outlineView:(NSOutlineView*)outlineView sortDescriptorsDidChange:(NSArray*)oldDescriptors
 725 {
 726     wxUnusedVar(oldDescriptors);
 727
 728     // Warning: the new sort descriptors are guaranteed to be only of type
 729     // NSSortDescriptor! Therefore, the sort descriptors for the data source
 730     // have to be converted.
 731     NSArray* newDescriptors;
 732
 733     NSMutableArray* wxSortDescriptors;
 734
 735     NSUInteger noOfDescriptors;
 736
 737     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
 738
 739
 740     // convert NSSortDescriptors to wxSortDescriptorObjects:
 741     newDescriptors    = [outlineView sortDescriptors];
 742     noOfDescriptors   = [newDescriptors count];
 743     wxSortDescriptors = [NSMutableArray arrayWithCapacity:noOfDescriptors];
 744     for (NSUInteger i=0; i<noOfDescriptors; ++i)
 745     {
 746         NSSortDescriptor* const newDescriptor = [newDescriptors objectAtIndex:i];
 747
 748         [wxSortDescriptors addObject:[[[wxSortDescriptorObject alloc] initWithModelPtr:model
 749             sortingColumnPtr:dvc->GetColumn([[newDescriptor key] intValue])
 750             ascending:[newDescriptor ascending]] autorelease]];
 751     }
 752     [(wxCocoaOutlineDataSource*)[outlineView dataSource] setSortDescriptors:wxSortDescriptors];
 753
 754     // send first the event to wxWidgets that the sorting has changed so that
 755     // the program can do special actions before the sorting actually starts:
 756     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_COLUMN_SORTED,dvc->GetId()); // variable definition
 757
 758     event.SetEventObject(dvc);
 759     if (noOfDescriptors > 0)
 760     {
 761         wxDataViewColumn* const col = [[wxSortDescriptors objectAtIndex:0] columnPtr];
 762
 763         event.SetColumn(dvc->GetColumnPosition(col));
 764         event.SetDataViewColumn(col);
 765     }
 766     dvc->GetEventHandler()->ProcessEvent(event);
 767
 768     // start re-ordering the data;
 769     // children's buffer must be cleared first because it contains the old order:
 770     [self clearChildren];
 771     // sorting is done while reloading the data:
 772     [outlineView reloadData];
 773 }
 774
 775 -(NSDragOperation) outlineView:(NSOutlineView*)outlineView validateDrop:(id<NSDraggingInfo>)info proposedItem:(id)item proposedChildIndex:(NSInteger)index
 776 {
 777     wxUnusedVar(outlineView);
 778     wxUnusedVar(index);
 779
 780     NSArray* supportedTypes([NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]);
 781
 782     NSPasteboard* pasteboard([info draggingPasteboard]);
 783
 784     NSString* bestType([pasteboard availableTypeFromArray:supportedTypes]);
 785     if (bestType == nil)
 786         return NSDragOperationNone;
 787
 788     NSDragOperation dragOperation = NSDragOperationNone;
 789     wxDataViewCtrl* const dvc(implementation->GetDataViewCtrl());
 790
 791     wxCHECK_MSG(dvc, false, "Pointer to data view control not set correctly.");
 792     wxCHECK_MSG(dvc->GetModel(), false, "Pointer to model not set correctly.");
 793
 794     wxDataViewEvent
 795         event(wxEVT_COMMAND_DATAVIEW_ITEM_DROP_POSSIBLE,dvc->GetId());
 796
 797     event.SetEventObject(dvc);
 798     event.SetItem(wxDataViewItemFromItem(item));
 799     event.SetModel(dvc->GetModel());
 800     if ([bestType compare:DataViewPboardType] == NSOrderedSame)
 801     {
 802         NSArray*               dataArray((NSArray*)[pasteboard propertyListForType:DataViewPboardType]);
 803         NSUInteger             indexDraggedItem, noOfDraggedItems([dataArray count]);
 804
 805         indexDraggedItem = 0;
 806         while (indexDraggedItem < noOfDraggedItems)
 807         {
 808             wxDataObjectComposite* dataObjects(implementation->GetDnDDataObjects((NSData*)[dataArray objectAtIndex:indexDraggedItem]));
 809
 810             if (dataObjects && (dataObjects->GetFormatCount() > 0))
 811             {
 812                 wxMemoryBuffer buffer;
 813
 814                 // copy data into data object:
 815                 event.SetDataObject(dataObjects);
 816                 event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 817                 // copy data into buffer:
 818                 dataObjects->GetDataHere(event.GetDataFormat().GetType(),buffer.GetWriteBuf(event.GetDataSize()));
 819                 buffer.UngetWriteBuf(event.GetDataSize());
 820                 event.SetDataBuffer(buffer.GetData());
 821                 // finally, send event:
 822                 if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 823                 {
 824                     dragOperation = NSDragOperationEvery;
 825                     ++indexDraggedItem;
 826                 }
 827                 else
 828                 {
 829                     dragOperation    = NSDragOperationNone;
 830                     indexDraggedItem = noOfDraggedItems; // stop loop
 831                 }
 832             }
 833             else
 834             {
 835                 dragOperation    = NSDragOperationNone;
 836                 indexDraggedItem = noOfDraggedItems; // stop loop
 837             }
 838             // clean-up:
 839             delete dataObjects;
 840         }
 841     }
 842     else
 843     {
 844         // needed to convert internally used UTF-16 representation to a UTF-8
 845         // representation
 846         CFDataRef              osxData;
 847         wxDataObjectComposite* dataObjects   (new wxDataObjectComposite());
 848         wxTextDataObject*      textDataObject(new wxTextDataObject());
 849
 850         osxData = ::CFStringCreateExternalRepresentation(kCFAllocatorDefault,(CFStringRef)[pasteboard stringForType:NSStringPboardType],kCFStringEncodingUTF8,32);
 851         if (textDataObject->SetData(::CFDataGetLength(osxData),::CFDataGetBytePtr(osxData)))
 852             dataObjects->Add(textDataObject);
 853         else
 854             delete textDataObject;
 855         // send event if data could be copied:
 856         if (dataObjects->GetFormatCount() > 0)
 857         {
 858             event.SetDataObject(dataObjects);
 859             event.SetDataFormat(implementation->GetDnDDataFormat(dataObjects));
 860             if (dvc->HandleWindowEvent(event) && event.IsAllowed())
 861                 dragOperation = NSDragOperationEvery;
 862             else
 863                 dragOperation = NSDragOperationNone;
 864         }
 865         else
 866             dragOperation = NSDragOperationNone;
 867         // clean up:
 868         ::CFRelease(osxData);
 869         delete dataObjects;
 870     }
 871
 872     return dragOperation;
 873 }
 874
 875 -(BOOL) outlineView:(NSOutlineView*)outlineView writeItems:(NSArray*)writeItems toPasteboard:(NSPasteboard*)pasteboard
 876 {
 877     wxUnusedVar(outlineView);
 878
 879     // the pasteboard will be filled up with an array containing the data as
 880     // returned by the events (including the data type) and a concatenation of
 881     // text (string) data; the text data will only be put onto the pasteboard
 882     // if for all items a string representation exists
 883     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
 884
 885     wxDataViewItemArray dataViewItems;
 886
 887
 888     wxCHECK_MSG(dvc, false,"Pointer to data view control not set correctly.");
 889     wxCHECK_MSG(dvc->GetModel(),false,"Pointer to model not set correctly.");
 890
 891     if ([writeItems count] > 0)
 892     {
 893         bool            dataStringAvailable(true); // a flag indicating if for all items a data string is available
 894         NSMutableArray* dataArray = [NSMutableArray arrayWithCapacity:[writeItems count]]; // data of all items
 895         wxString        dataString; // contains the string data of all items
 896
 897         // send a begin drag event for all selected items and proceed with
 898         // dragging unless the event is vetoed:
 899         wxDataViewEvent
 900             event(wxEVT_COMMAND_DATAVIEW_ITEM_BEGIN_DRAG,dvc->GetId());
 901
 902         event.SetEventObject(dvc);
 903         event.SetModel(dvc->GetModel());
 904         for (size_t itemCounter=0; itemCounter<[writeItems count]; ++itemCounter)
 905         {
 906             bool                   itemStringAvailable(false);              // a flag indicating if for the current item a string is available
 907             wxDataObjectComposite* itemObject(new wxDataObjectComposite()); // data object for current item
 908             wxString               itemString;                              // contains the TAB concatenated data of an item
 909
 910             event.SetItem(
 911                 wxDataViewItemFromItem([writeItems objectAtIndex:itemCounter]));
 912             itemString = ::ConcatenateDataViewItemValues(dvc,event.GetItem());
 913             itemObject->Add(new wxTextDataObject(itemString));
 914             event.SetDataObject(itemObject);
 915             // check if event has not been vetoed:
 916             if (dvc->HandleWindowEvent(event) && event.IsAllowed() && (event.GetDataObject()->GetFormatCount() > 0))
 917             {
 918                 size_t const noOfFormats = event.GetDataObject()->GetFormatCount();
 919                 wxDataFormat* dataFormats(new wxDataFormat[noOfFormats]);
 920
 921                 event.GetDataObject()->GetAllFormats(dataFormats,wxDataObject::Get);
 922                 for (size_t formatCounter=0; formatCounter<noOfFormats; ++formatCounter)
 923                 {
 924                     // constant definitions for abbreviational purposes:
 925                     wxDataFormatId const idDataFormat = dataFormats[formatCounter].GetType();
 926                     size_t const dataSize       = event.GetDataObject()->GetDataSize(idDataFormat);
 927                     size_t const dataBufferSize = sizeof(wxDataFormatId)+dataSize;
 928                     // variable definitions (used in all case statements):
 929                     wxMemoryBuffer dataBuffer(dataBufferSize);
 930
 931                     dataBuffer.AppendData(&idDataFormat,sizeof(wxDataFormatId));
 932                     switch (idDataFormat)
 933                     {
 934                         case wxDF_TEXT:
 935                             // otherwise wxDF_UNICODETEXT already filled up
 936                             // the string; and the UNICODE representation has
 937                             // priority
 938                             if (!itemStringAvailable)
 939                             {
 940                                 event.GetDataObject()->GetDataHere(wxDF_TEXT,dataBuffer.GetAppendBuf(dataSize));
 941                                 dataBuffer.UngetAppendBuf(dataSize);
 942                                 [dataArray addObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 943                                 itemString = wxString(static_cast<char const*>(dataBuffer.GetData())+sizeof(wxDataFormatId),wxConvLocal);
 944                                 itemStringAvailable = true;
 945                             }
 946                             break;
 947                         case wxDF_UNICODETEXT:
 948                             {
 949                                 event.GetDataObject()->GetDataHere(wxDF_UNICODETEXT,dataBuffer.GetAppendBuf(dataSize));
 950                                 dataBuffer.UngetAppendBuf(dataSize);
 951                                 if (itemStringAvailable) // does an object already exist as an ASCII text (see wxDF_TEXT case statement)?
 952                                     [dataArray replaceObjectAtIndex:itemCounter withObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 953                                 else
 954                                     [dataArray addObject:[NSData dataWithBytes:dataBuffer.GetData() length:dataBufferSize]];
 955                                 itemString = wxString::FromUTF8(static_cast<char const*>(dataBuffer.GetData())+sizeof(wxDataFormatId),dataSize);
 956                                 itemStringAvailable = true;
 957                             } /* block */
 958                             break;
 959                         default:
 960                             wxFAIL_MSG("Data object has invalid or unsupported data format");
 961                             [dataArray release];
 962                             return NO;
 963                     }
 964                 }
 965                 delete[] dataFormats;
 966                 delete itemObject;
 967                 if (dataStringAvailable)
 968                     if (itemStringAvailable)
 969                     {
 970                         if (itemCounter > 0)
 971                             dataString << wxT('\n');
 972                         dataString << itemString;
 973                     }
 974                     else
 975                         dataStringAvailable = false;
 976             }
 977             else
 978             {
 979                 [dataArray release];
 980                 delete itemObject;
 981                 return NO; // dragging was vetoed or no data available
 982             }
 983         }
 984         if (dataStringAvailable)
 985         {
 986             wxCFStringRef osxString(dataString);
 987
 988             [pasteboard declareTypes:[NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil] owner:nil];
 989             [pasteboard setPropertyList:dataArray forType:DataViewPboardType];
 990             [pasteboard setString:osxString.AsNSString() forType:NSStringPboardType];
 991         }
 992         else
 993         {
 994             [pasteboard declareTypes:[NSArray arrayWithObject:DataViewPboardType] owner:nil];
 995             [pasteboard setPropertyList:dataArray forType:DataViewPboardType];
 996         }
 997         return YES;
 998     }
 999     else
1000         return NO; // no items to drag (should never occur)
1001 }
1002
1003 //
1004 // buffer handling
1005 //
1006 -(void) addToBuffer:(wxPointerObject*)item
1007 {
1008     [items addObject:item];
1009 }
1010
1011 -(void) clearBuffer
1012 {
1013     [items removeAllObjects];
1014 }
1015
1016 -(wxPointerObject*) getDataViewItemFromBuffer:(const wxDataViewItem&)item
1017 {
1018     return [items member:[[[wxPointerObject alloc] initWithPointer:item.GetID()] autorelease]];
1019 }
1020
1021 -(wxPointerObject*) getItemFromBuffer:(wxPointerObject*)item
1022 {
1023     return [items member:item];
1024 }
1025
1026 -(BOOL) isInBuffer:(wxPointerObject*)item
1027 {
1028     return [items containsObject:item];
1029 }
1030
1031 -(void) removeFromBuffer:(wxPointerObject*)item
1032 {
1033     [items removeObject:item];
1034 }
1035
1036 //
1037 // children handling
1038 //
1039 -(void) appendChild:(wxPointerObject*)item
1040 {
1041     [children addObject:item];
1042 }
1043
1044 -(void) clearChildren
1045 {
1046     [children removeAllObjects];
1047 }
1048
1049 -(wxPointerObject*) getChild:(NSUInteger)index
1050 {
1051     return [children objectAtIndex:index];
1052 }
1053
1054 -(NSUInteger) getChildCount
1055 {
1056     return [children count];
1057 }
1058
1059 -(void) removeChild:(NSUInteger)index
1060 {
1061     [children removeObjectAtIndex:index];
1062 }
1063
1064 //
1065 // buffer handling
1066 //
1067 -(void) clearBuffers
1068 {
1069     [self clearBuffer];
1070     [self clearChildren];
1071     [self setCurrentParentItem:nil];
1072 }
1073
1074 //
1075 // sorting
1076 //
1077 -(NSArray*) sortDescriptors
1078 {
1079     return sortDescriptors;
1080 }
1081
1082 -(void) setSortDescriptors:(NSArray*)newSortDescriptors
1083 {
1084     [newSortDescriptors retain];
1085     [sortDescriptors release];
1086     sortDescriptors = newSortDescriptors;
1087 }
1088
1089 //
1090 // access to wxWidget's implementation
1091 //
1092 -(wxPointerObject*) currentParentItem
1093 {
1094     return currentParentItem;
1095 }
1096
1097 -(wxCocoaDataViewControl*) implementation
1098 {
1099     return implementation;
1100 }
1101
1102 -(wxDataViewModel*) model
1103 {
1104     return model;
1105 }
1106
1107 -(void) setCurrentParentItem:(wxPointerObject*)newCurrentParentItem
1108 {
1109     [newCurrentParentItem retain];
1110     [currentParentItem release];
1111     currentParentItem = newCurrentParentItem;
1112 }
1113
1114 -(void) setImplementation:(wxCocoaDataViewControl*) newImplementation
1115 {
1116     implementation = newImplementation;
1117 }
1118
1119 -(void) setModel:(wxDataViewModel*) newModel
1120 {
1121     model = newModel;
1122 }
1123
1124 //
1125 // other methods
1126 //
1127 -(void) bufferItem:(wxPointerObject*)parentItem withChildren:(wxDataViewItemArray*)dataViewChildrenPtr
1128 {
1129     NSInteger const noOfChildren = (*dataViewChildrenPtr).GetCount();
1130
1131     [self setCurrentParentItem:parentItem];
1132     [self clearChildren];
1133     for (NSInteger indexChild=0; indexChild<noOfChildren; ++indexChild)
1134     {
1135         wxPointerObject* bufferedPointerObject;
1136         wxPointerObject* newPointerObject([[wxPointerObject alloc] initWithPointer:(*dataViewChildrenPtr)[indexChild].GetID()]);
1137
1138         // The next statement and test looks strange but there is
1139         // unfortunately no workaround: due to the fact that two pointer
1140         // objects are identical if their pointers are identical - because the
1141         // method isEqual has been overloaded - the set operation will only
1142         // add a new pointer object if there is not already one in the set
1143         // having the same pointer. On the other side the children's array
1144         // would always add the new pointer object. This means that different
1145         // pointer objects are stored in the set and array. This will finally
1146         // lead to a crash as objects diverge. To solve this issue it is first
1147         // tested if the child already exists in the set and if it is the case
1148         // the sets object is going to be appended to the array, otheriwse the
1149         // new pointer object is added to the set and array:
1150         bufferedPointerObject = [self getItemFromBuffer:newPointerObject];
1151         if (bufferedPointerObject == nil)
1152         {
1153             [items    addObject:newPointerObject];
1154             [children addObject:newPointerObject];
1155         }
1156         else
1157             [children addObject:bufferedPointerObject];
1158         [newPointerObject release];
1159     }
1160 }
1161
1162 @end
1163
1164 // ============================================================================
1165 // wxCustomCell
1166 // ============================================================================
1167
1168 @implementation wxCustomCell
1169
1170 #if 0 // starting implementation for custom cell clicks
1171
1172 - (id)init
1173 {
1174     self = [super init];
1175     [self setAction:@selector(clickedAction)];
1176     [self setTarget:self];
1177     return self;
1178 }
1179
1180 - (void) clickedAction: (id) sender
1181 {
1182     wxUnusedVar(sender);
1183 }
1184
1185 #endif
1186
1187 -(NSSize) cellSize
1188 {
1189     wxCustomRendererObject * const
1190         obj = static_cast<wxCustomRendererObject *>([self objectValue]);
1191
1192
1193     const wxSize size = obj->customRenderer->GetSize();
1194     return NSMakeSize(size.x, size.y);
1195 }
1196
1197 //
1198 // implementations
1199 //
1200 -(void) drawWithFrame:(NSRect)cellFrame inView:(NSView*)controlView
1201 {
1202     wxCustomRendererObject * const
1203         obj = static_cast<wxCustomRendererObject *>([self objectValue]);
1204     if ( !obj )
1205     {
1206         // this may happen for the custom cells in container rows: they don't
1207         // have any values
1208         return;
1209     }
1210
1211     wxDataViewCustomRenderer * const renderer = obj->customRenderer;
1212
1213     // if this method is called everything is already setup correctly,
1214     CGContextRef context = (CGContextRef) [[NSGraphicsContext currentContext] graphicsPort];
1215     CGContextSaveGState( context );
1216
1217     if ( ![controlView isFlipped] )
1218     {
1219         CGContextTranslateCTM( context, 0,  [controlView bounds].size.height );
1220         CGContextScaleCTM( context, 1, -1 );
1221     }
1222
1223     wxGCDC dc;
1224     wxGraphicsContext* gc = wxGraphicsContext::CreateFromNative(context);
1225     dc.SetGraphicsContext(gc);
1226
1227     int state = 0;
1228     if ( [self isHighlighted] )
1229         state |= wxDATAVIEW_CELL_SELECTED;
1230
1231     renderer->WXCallRender(wxFromNSRect(controlView, cellFrame), &dc, state);
1232
1233     CGContextRestoreGState( context );
1234 }
1235
1236 -(NSRect) imageRectForBounds:(NSRect)cellFrame
1237 {
1238     return cellFrame;
1239 }
1240
1241 -(NSRect) titleRectForBounds:(NSRect)cellFrame
1242 {
1243     return cellFrame;
1244 }
1245
1246 @end
1247
1248 // ============================================================================
1249 // wxImageTextCell
1250 // ============================================================================
1251 @implementation wxImageTextCell
1252 //
1253 // initialization
1254 //
1255 -(id) init
1256 {
1257     self = [super init];
1258     if (self != nil)
1259     {
1260         // initializing the text part:
1261         [self setSelectable:YES];
1262         // initializing the image part:
1263         image       = nil;
1264         imageSize   = NSMakeSize(16,16);
1265         spaceImageText = 5.0;
1266         xImageShift    = 5.0;
1267     }
1268     return self;
1269 }
1270
1271 -(id) copyWithZone:(NSZone*)zone
1272 {
1273     wxImageTextCell* cell;
1274
1275
1276     cell = (wxImageTextCell*) [super copyWithZone:zone];
1277     cell->image          = [image retain];
1278     cell->imageSize      = imageSize;
1279     cell->spaceImageText = spaceImageText;
1280     cell->xImageShift    = xImageShift;
1281
1282     return cell;
1283 }
1284
1285 -(void) dealloc
1286 {
1287     [image release];
1288
1289     [super dealloc];
1290 }
1291
1292 //
1293 // alignment
1294 //
1295 -(NSTextAlignment) alignment
1296 {
1297     return cellAlignment;
1298 }
1299
1300 -(void) setAlignment:(NSTextAlignment)newAlignment
1301 {
1302     cellAlignment = newAlignment;
1303     switch (newAlignment)
1304     {
1305         case NSCenterTextAlignment:
1306         case NSLeftTextAlignment:
1307         case NSJustifiedTextAlignment:
1308         case NSNaturalTextAlignment:
1309             [super setAlignment:NSLeftTextAlignment];
1310             break;
1311         case NSRightTextAlignment:
1312             [super setAlignment:NSRightTextAlignment];
1313             break;
1314         default:
1315             wxFAIL_MSG("Unknown alignment type.");
1316     }
1317 }
1318
1319 //
1320 // image access
1321 //
1322 -(NSImage*) image
1323 {
1324     return image;
1325 }
1326
1327 -(void) setImage:(NSImage*)newImage
1328 {
1329     [newImage retain];
1330     [image release];
1331     image = newImage;
1332 }
1333
1334 -(NSSize) imageSize
1335 {
1336     return imageSize;
1337 }
1338
1339 -(void) setImageSize:(NSSize) newImageSize
1340 {
1341     imageSize = newImageSize;
1342 }
1343
1344 //
1345 // other methods
1346 //
1347 -(NSSize) cellImageSize
1348 {
1349     return NSMakeSize(imageSize.width+xImageShift+spaceImageText,imageSize.height);
1350 }
1351
1352 -(NSSize) cellSize
1353 {
1354     NSSize cellSize([super cellSize]);
1355
1356
1357     if (imageSize.height > cellSize.height)
1358         cellSize.height = imageSize.height;
1359     cellSize.width += imageSize.width+xImageShift+spaceImageText;
1360
1361     return cellSize;
1362 }
1363
1364 -(NSSize) cellTextSize
1365 {
1366     return [super cellSize];
1367 }
1368
1369 //
1370 // implementations
1371 //
1372 -(void) determineCellParts:(NSRect)cellFrame imagePart:(NSRect*)imageFrame textPart:(NSRect*)textFrame
1373 {
1374     switch (cellAlignment)
1375     {
1376         case NSCenterTextAlignment:
1377             {
1378                 CGFloat const cellSpace = cellFrame.size.width-[self cellSize].width;
1379
1380                 // if the cell's frame is smaller than its contents (at least
1381                 // in x-direction) make sure that the image is visible:
1382                 if (cellSpace <= 0)
1383                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1384                 else // otherwise center the image and text in the cell's frame
1385                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText+0.5*cellSpace,NSMinXEdge);
1386             }
1387             break;
1388         case NSJustifiedTextAlignment:
1389         case NSLeftTextAlignment:
1390         case NSNaturalTextAlignment: // how to determine the natural writing direction? TODO
1391             NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1392             break;
1393         case NSRightTextAlignment:
1394             {
1395                 CGFloat const cellSpace = cellFrame.size.width-[self cellSize].width;
1396
1397                 // if the cell's frame is smaller than its contents (at least
1398                 // in x-direction) make sure that the image is visible:
1399                 if (cellSpace <= 0)
1400                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText,NSMinXEdge);
1401                 else // otherwise right align the image and text in the cell's frame
1402                     NSDivideRect(cellFrame,imageFrame,textFrame,xImageShift+imageSize.width+spaceImageText+cellSpace,NSMinXEdge);
1403             }
1404             break;
1405         default:
1406             *imageFrame = NSZeroRect;
1407             *textFrame  = NSZeroRect;
1408             wxFAIL_MSG("Unhandled alignment type.");
1409     }
1410 }
1411
1412 -(void) drawWithFrame:(NSRect)cellFrame inView:(NSView*)controlView
1413 {
1414     NSRect textFrame, imageFrame;
1415
1416
1417     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1418     // draw the image part by ourselves;
1419     // check if the cell has to draw its own background (checking is done by
1420     // the parameter of the textfield's cell):
1421     if ([self drawsBackground])
1422     {
1423         [[self backgroundColor] set];
1424         NSRectFill(imageFrame);
1425     }
1426     if (image != nil)
1427     {
1428         // the image is slightly shifted (xImageShift) and has a fixed size
1429         // but the image's frame might be larger and starts currently on the
1430         // left side of the cell's frame; therefore, the origin and the
1431         // image's frame size have to be adjusted:
1432         if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1433         {
1434             imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1435             imageFrame.size.width = imageSize.width;
1436         }
1437         else
1438         {
1439             imageFrame.origin.x   += xImageShift;
1440             imageFrame.size.width -= xImageShift+spaceImageText;
1441         }
1442         // ...and the image has to be centered in the y-direction:
1443         if (imageFrame.size.height > imageSize.height)
1444             imageFrame.size.height = imageSize.height;
1445         imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1446
1447         // according to the documentation the coordinate system should be
1448         // flipped for NSTableViews (y-coordinate goes from top to bottom); to
1449         // draw an image correctly the coordinate system has to be transformed
1450         // to a bottom-top coordinate system, otherwise the image's
1451         // content is flipped:
1452         NSAffineTransform* coordinateTransform([NSAffineTransform transform]);
1453
1454         if ([controlView isFlipped])
1455         {
1456             [coordinateTransform scaleXBy: 1.0 yBy:-1.0]; // first the coordinate system is brought back to bottom-top orientation
1457             [coordinateTransform translateXBy:0.0 yBy:(-2.0)*imageFrame.origin.y-imageFrame.size.height]; // the coordinate system has to be moved to compensate for the
1458             [coordinateTransform concat];                                                                 // other orientation and the position of the image's frame
1459         }
1460         [image drawInRect:imageFrame fromRect:NSZeroRect operation:NSCompositeSourceOver fraction:1.0]; // suggested method to draw the image
1461         // instead of compositeToPoint:operation:
1462         // take back previous transformation (if the view is not flipped the
1463         // coordinate transformation matrix contains the identity matrix and
1464         // the next two operations do not change the content's transformation
1465         // matrix):
1466         [coordinateTransform invert];
1467         [coordinateTransform concat];
1468     }
1469     // let the textfield cell draw the text part:
1470     if (textFrame.size.width > [self cellTextSize].width)
1471     {
1472         // for unknown reasons the alignment of the text cell is ignored;
1473         // therefore change the size so that alignment does not influence the
1474         // visualization anymore
1475         textFrame.size.width = [self cellTextSize].width;
1476     }
1477     [super drawWithFrame:textFrame inView:controlView];
1478 }
1479
1480 -(void) editWithFrame:(NSRect)aRect inView:(NSView*)controlView editor:(NSText*)textObj delegate:(id)anObject event:(NSEvent*)theEvent
1481 {
1482     NSRect textFrame, imageFrame;
1483
1484
1485     [self determineCellParts:aRect imagePart:&imageFrame textPart:&textFrame];
1486     [super editWithFrame:textFrame inView:controlView editor:textObj delegate:anObject event:theEvent];
1487 }
1488
1489 #if MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_5
1490 -(NSUInteger) hitTestForEvent:(NSEvent*)event inRect:(NSRect)cellFrame ofView:(NSView*)controlView
1491 {
1492     NSPoint point = [controlView convertPoint:[event locationInWindow] fromView:nil];
1493
1494     NSRect imageFrame, textFrame;
1495
1496
1497     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1498     if (image != nil)
1499     {
1500         // the image is shifted...
1501         if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1502         {
1503             imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1504             imageFrame.size.width = imageSize.width;
1505         }
1506         else
1507         {
1508             imageFrame.origin.x   += xImageShift;
1509             imageFrame.size.width -= xImageShift+spaceImageText;
1510         }
1511         // ...and centered:
1512         if (imageFrame.size.height > imageSize.height)
1513             imageFrame.size.height = imageSize.height;
1514         imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1515         // If the point is in the image rect, then it is a content hit (see
1516         // documentation for hitTestForEvent:inRect:ofView):
1517         if (NSMouseInRect(point, imageFrame, [controlView isFlipped]))
1518             return NSCellHitContentArea;
1519     }
1520     // if the image was not hit let's try the text part:
1521     if (textFrame.size.width > [self cellTextSize].width)
1522     {
1523         // for unknown reasons the alignment of the text cell is ignored;
1524         // therefore change the size so that alignment does not influence the
1525         // visualization anymore
1526         textFrame.size.width = [self cellTextSize].width;
1527     }
1528
1529     return [super hitTestForEvent:event inRect:textFrame ofView:controlView];
1530 }
1531 #endif
1532
1533 -(NSRect) imageRectForBounds:(NSRect)cellFrame
1534 {
1535     NSRect textFrame, imageFrame;
1536
1537
1538     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1539     if (imageFrame.size.width >= xImageShift+imageSize.width+spaceImageText)
1540     {
1541         imageFrame.origin.x += imageFrame.size.width-imageSize.width-spaceImageText;
1542         imageFrame.size.width = imageSize.width;
1543     }
1544     else
1545     {
1546         imageFrame.origin.x   += xImageShift;
1547         imageFrame.size.width -= xImageShift+spaceImageText;
1548     }
1549     // ...and centered:
1550     if (imageFrame.size.height > imageSize.height)
1551         imageFrame.size.height = imageSize.height;
1552     imageFrame.origin.y += ceil(0.5*(cellFrame.size.height-imageFrame.size.height));
1553
1554     return imageFrame;
1555 }
1556
1557 -(void) selectWithFrame:(NSRect)aRect inView:(NSView*)controlView editor:(NSText*)textObj delegate:(id)anObject start:(NSInteger)selStart length:(NSInteger)selLength
1558 {
1559     NSRect textFrame, imageFrame;
1560
1561
1562     [self determineCellParts:aRect imagePart:&imageFrame textPart:&textFrame];
1563     [super selectWithFrame:textFrame inView:controlView editor:textObj delegate:anObject start:selStart length:selLength];
1564 }
1565
1566 -(NSRect) titleRectForBounds:(NSRect)cellFrame
1567 {
1568     NSRect textFrame, imageFrame;
1569
1570
1571     [self determineCellParts:cellFrame imagePart:&imageFrame textPart:&textFrame];
1572     return textFrame;
1573 }
1574
1575 @end
1576
1577 // ============================================================================
1578 // wxCocoaOutlineView
1579 // ============================================================================
1580 @implementation wxCocoaOutlineView
1581
1582 //
1583 // initializers / destructor
1584 //
1585 -(id) init
1586 {
1587     self = [super init];
1588     if (self != nil)
1589     {
1590         currentlyEditedColumn =
1591             currentlyEditedRow = -1;
1592
1593         [self registerForDraggedTypes:[NSArray arrayWithObjects:DataViewPboardType,NSStringPboardType,nil]];
1594         [self setDelegate:self];
1595         [self setDoubleAction:@selector(actionDoubleClick:)];
1596         [self setDraggingSourceOperationMask:NSDragOperationEvery forLocal:NO];
1597         [self setDraggingSourceOperationMask:NSDragOperationEvery forLocal:YES];
1598         [self setTarget:self];
1599     }
1600     return self;
1601 }
1602
1603 //
1604 // access to wxWidget's implementation
1605 //
1606 -(wxCocoaDataViewControl*) implementation
1607 {
1608     return implementation;
1609 }
1610
1611 -(void) setImplementation:(wxCocoaDataViewControl*) newImplementation
1612 {
1613     implementation = newImplementation;
1614 }
1615
1616 //
1617 // actions
1618 //
1619 -(void) actionDoubleClick:(id)sender
1620 {
1621     wxUnusedVar(sender);
1622
1623     // actually the documentation (NSTableView 2007-10-31) for doubleAction:
1624     // and setDoubleAction: seems to be wrong as this action message is always
1625     // sent whether the cell is editable or not
1626     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1627
1628     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_ACTIVATED,dvc->GetId());
1629
1630
1631     event.SetEventObject(dvc);
1632     event.SetItem(wxDataViewItemFromItem([self itemAtRow:[self clickedRow]]));
1633     dvc->GetEventHandler()->ProcessEvent(event);
1634 }
1635
1636
1637 //
1638 // contextual menus
1639 //
1640 -(NSMenu*) menuForEvent:(NSEvent*)theEvent
1641 {
1642     wxUnusedVar(theEvent);
1643
1644     // this method does not do any special menu event handling but only sends
1645     // an event message; therefore, the user has full control if a context
1646     // menu should be shown or not
1647     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1648
1649     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_CONTEXT_MENU,dvc->GetId());
1650
1651     wxDataViewItemArray selectedItems;
1652
1653
1654     event.SetEventObject(dvc);
1655     event.SetModel(dvc->GetModel());
1656     // get the item information;
1657     // theoretically more than one ID can be returned but the event can only
1658     // handle one item, therefore only the first item of the array is
1659     // returned:
1660     if (dvc->GetSelections(selectedItems) > 0)
1661         event.SetItem(selectedItems[0]);
1662     dvc->GetEventHandler()->ProcessEvent(event);
1663     // nothing is done:
1664     return nil;
1665 }
1666
1667 //
1668 // delegate methods
1669 //
1670 -(void) outlineView:(NSOutlineView*)outlineView mouseDownInHeaderOfTableColumn:(NSTableColumn*)tableColumn
1671 {
1672     wxDataViewColumn* const
1673         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1674
1675     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1676
1677     wxDataViewEvent
1678         event(wxEVT_COMMAND_DATAVIEW_COLUMN_HEADER_CLICK,dvc->GetId());
1679
1680
1681     // first, send an event that the user clicked into a column's header:
1682     event.SetEventObject(dvc);
1683     event.SetColumn(dvc->GetColumnPosition(col));
1684     event.SetDataViewColumn(col);
1685     dvc->HandleWindowEvent(event);
1686
1687     // now, check if the click may have had an influence on sorting, too;
1688     // the sorting setup has to be done only if the clicked table column is
1689     // sortable and has not been used for sorting before the click; if the
1690     // column is already responsible for sorting the native control changes
1691     // the sorting direction automatically and informs the data source via
1692     // outlineView:sortDescriptorsDidChange:
1693     if (col->IsSortable() && ([tableColumn sortDescriptorPrototype] == nil))
1694     {
1695         // remove the sort order from the previously sorted column table (it
1696         // can also be that no sorted column table exists):
1697         UInt32 const noOfColumns = [outlineView numberOfColumns];
1698
1699         for (UInt32 i=0; i<noOfColumns; ++i)
1700             [[[outlineView tableColumns] objectAtIndex:i] setSortDescriptorPrototype:nil];
1701         // make column table sortable:
1702         NSArray*          sortDescriptors;
1703         NSSortDescriptor* sortDescriptor;
1704
1705         sortDescriptor = [[NSSortDescriptor alloc] initWithKey:[NSString stringWithFormat:@"%d",[outlineView columnWithIdentifier:[tableColumn identifier]]]
1706             ascending:YES];
1707         sortDescriptors = [NSArray arrayWithObject:sortDescriptor];
1708         [tableColumn setSortDescriptorPrototype:sortDescriptor];
1709         [outlineView setSortDescriptors:sortDescriptors];
1710         [sortDescriptor release];
1711     }
1712 }
1713
1714 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldCollapseItem:(id)item
1715 {
1716     wxUnusedVar(outlineView);
1717
1718     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1719
1720     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_COLLAPSING,dvc->GetId());
1721
1722
1723     event.SetEventObject(dvc);
1724     event.SetItem       (wxDataViewItemFromItem(item));
1725     event.SetModel      (dvc->GetModel());
1726     // finally send the equivalent wxWidget event:
1727     dvc->GetEventHandler()->ProcessEvent(event);
1728     // opening the container is allowed if not vetoed:
1729     return event.IsAllowed();
1730 }
1731
1732 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldExpandItem:(id)item
1733 {
1734     wxUnusedVar(outlineView);
1735
1736     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1737
1738     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_EXPANDING,dvc->GetId());
1739
1740
1741     event.SetEventObject(dvc);
1742     event.SetItem       (wxDataViewItemFromItem(item));
1743     event.SetModel      (dvc->GetModel());
1744     // finally send the equivalent wxWidget event:
1745     dvc->GetEventHandler()->ProcessEvent(event);
1746     // opening the container is allowed if not vetoed:
1747     return event.IsAllowed();
1748 }
1749
1750 -(BOOL) outlineView:(NSOutlineView*)outlineView shouldSelectTableColumn:(NSTableColumn*)tableColumn
1751 {
1752     wxUnusedVar(tableColumn);
1753     wxUnusedVar(outlineView);
1754
1755     return NO;
1756 }
1757
1758 -(void) outlineView:(wxCocoaOutlineView*)outlineView
1759     willDisplayCell:(id)cell
1760     forTableColumn:(NSTableColumn*)tableColumn
1761     item:(id)item
1762 {
1763     wxUnusedVar(outlineView);
1764
1765     wxDataViewCtrl * const dvc = implementation->GetDataViewCtrl();
1766     wxDataViewModel * const model = dvc->GetModel();
1767
1768     wxDataViewColumn* const
1769         dvCol([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1770     const unsigned colIdx = dvCol->GetModelColumn();
1771
1772     wxDataViewItem dvItem(wxDataViewItemFromItem(item));
1773
1774     if ( !model->HasValue(dvItem, colIdx) )
1775         return;
1776
1777     wxDataViewRenderer * const renderer = dvCol->GetRenderer();
1778     wxDataViewRendererNativeData * const data = renderer->GetNativeData();
1779
1780     // let the renderer know about what it's going to render next
1781     data->SetColumnPtr(tableColumn);
1782     data->SetItem(item);
1783     data->SetItemCell(cell);
1784
1785     // use the attributes: notice that we need to do this whether we have them
1786     // or not as even if this cell doesn't have any attributes, the previous
1787     // one might have had some and then we need to reset them back to default
1788     wxDataViewItemAttr attr;
1789     model->GetAttr(dvItem, colIdx, attr);
1790     renderer->OSXApplyAttr(attr);
1791
1792     // set the state (enabled/disabled) of the item
1793     renderer->OSXApplyEnabled(model->IsEnabled(dvItem, colIdx));
1794
1795     // and finally do draw it
1796     renderer->MacRender();
1797 }
1798
1799 //
1800 // notifications
1801 //
1802 -(void) outlineViewColumnDidMove:(NSNotification*)notification
1803 {
1804     int const newColumnPosition = [[[notification userInfo] objectForKey:@"NSNewColumn"] intValue];
1805
1806     NSTableColumn*
1807         tableColumn = [[self tableColumns] objectAtIndex:newColumnPosition];
1808     wxDataViewColumn* const
1809         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1810
1811     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1812
1813     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_COLUMN_REORDERED,dvc->GetId());
1814
1815
1816     event.SetEventObject(dvc);
1817     event.SetColumn(dvc->GetColumnPosition(col));
1818     event.SetDataViewColumn(col);
1819     dvc->GetEventHandler()->ProcessEvent(event);
1820 }
1821
1822 -(void) outlineViewItemDidCollapse:(NSNotification*)notification
1823 {
1824     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1825
1826     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_COLLAPSED,dvc->GetId());
1827
1828
1829     event.SetEventObject(dvc);
1830     event.SetItem(wxDataViewItemFromItem(
1831                     [[notification userInfo] objectForKey:@"NSObject"]));
1832     dvc->GetEventHandler()->ProcessEvent(event);
1833 }
1834
1835 -(void) outlineViewItemDidExpand:(NSNotification*)notification
1836 {
1837     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1838
1839     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_ITEM_EXPANDED,dvc->GetId());
1840
1841
1842     event.SetEventObject(dvc);
1843     event.SetItem(wxDataViewItemFromItem(
1844                     [[notification userInfo] objectForKey:@"NSObject"]));
1845     dvc->GetEventHandler()->ProcessEvent(event);
1846 }
1847
1848 -(void) outlineViewSelectionDidChange:(NSNotification*)notification
1849 {
1850     wxUnusedVar(notification);
1851
1852     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1853
1854     wxDataViewEvent event(wxEVT_COMMAND_DATAVIEW_SELECTION_CHANGED,dvc->GetId());
1855
1856     event.SetEventObject(dvc);
1857     event.SetModel(dvc->GetModel());
1858     event.SetItem(dvc->GetSelection());
1859     dvc->GetEventHandler()->ProcessEvent(event);
1860 }
1861
1862 -(void) textDidBeginEditing:(NSNotification*)notification
1863 {
1864     // this notification is only sent if the user started modifying the cell
1865     // (not when the user clicked into the cell and the cell's editor is
1866     // called!)
1867
1868     // call method of superclass (otherwise editing does not work correctly -
1869     // the outline data source class is not informed about a change of data):
1870     [super textDidBeginEditing:notification];
1871
1872     // remember the column being edited, it will be used in textDidEndEditing:
1873     currentlyEditedColumn = [self editedColumn];
1874     currentlyEditedRow = [self editedRow];
1875
1876     NSTableColumn*
1877         tableColumn = [[self tableColumns] objectAtIndex:currentlyEditedColumn];
1878     wxDataViewColumn* const
1879         col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1880
1881     wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1882
1883
1884     // stop editing of a custom item first (if necessary)
1885     dvc->FinishCustomItemEditing();
1886
1887     // now, send the event:
1888     wxDataViewEvent
1889         event(wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_STARTED,dvc->GetId());
1890
1891     event.SetEventObject(dvc);
1892     event.SetItem(
1893             wxDataViewItemFromItem([self itemAtRow:currentlyEditedRow]));
1894     event.SetColumn(dvc->GetColumnPosition(col));
1895     event.SetDataViewColumn(col);
1896     dvc->GetEventHandler()->ProcessEvent(event);
1897 }
1898
1899 -(void) textDidEndEditing:(NSNotification*)notification
1900 {
1901     // call method of superclass (otherwise editing does not work correctly -
1902     // the outline data source class is not informed about a change of data):
1903     [super textDidEndEditing:notification];
1904
1905     // under OSX an event indicating the end of an editing session can be sent
1906     // even if no event indicating a start of an editing session has been sent
1907     // (see Documentation for NSControl controlTextDidEndEditing:); this is
1908     // not expected by a user of the wxWidgets library and therefore an
1909     // wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_DONE event is only sent if a
1910     // corresponding wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_STARTED has been sent
1911     // before; to check if a wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_STARTED has
1912     // been sent the last edited column/row are valid:
1913     if ( currentlyEditedColumn != -1 && currentlyEditedRow != -1 )
1914     {
1915         NSTableColumn*
1916             tableColumn = [[self tableColumns] objectAtIndex:currentlyEditedColumn];
1917         wxDataViewColumn* const
1918             col([static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer]);
1919
1920         wxDataViewCtrl* const dvc = implementation->GetDataViewCtrl();
1921
1922         // send event to wxWidgets:
1923         wxDataViewEvent
1924             event(wxEVT_COMMAND_DATAVIEW_ITEM_EDITING_DONE,dvc->GetId());
1925
1926         event.SetEventObject(dvc);
1927         event.SetItem(
1928                 wxDataViewItemFromItem([self itemAtRow:currentlyEditedRow]));
1929         event.SetColumn(dvc->GetColumnPosition(col));
1930         event.SetDataViewColumn(col);
1931         dvc->GetEventHandler()->ProcessEvent(event);
1932
1933
1934         // we're not editing any more
1935         currentlyEditedColumn =
1936             currentlyEditedRow = -1;
1937     }
1938 }
1939
1940 @end
1941
1942 // ============================================================================
1943 // wxCocoaDataViewControl
1944 // ============================================================================
1945
1946 wxCocoaDataViewControl::wxCocoaDataViewControl(wxWindow* peer,
1947                                                const wxPoint& pos,
1948                                                const wxSize& size,
1949                                                long style)
1950     : wxWidgetCocoaImpl
1951       (
1952         peer,
1953         [[NSScrollView alloc] initWithFrame:wxOSXGetFrameForControl(peer,pos,size)]
1954       ),
1955       m_DataSource(NULL),
1956       m_OutlineView([[wxCocoaOutlineView alloc] init])
1957 {
1958     // initialize scrollview (the outline view is part of a scrollview):
1959     NSScrollView* scrollview = (NSScrollView*) GetWXWidget();
1960
1961     [scrollview setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
1962     [scrollview setBorderType:NSNoBorder];
1963     [scrollview setHasVerticalScroller:YES];
1964     [scrollview setHasHorizontalScroller:YES];
1965     [scrollview setAutohidesScrollers:YES];
1966     [scrollview setDocumentView:m_OutlineView];
1967
1968     // initialize the native control itself too
1969     InitOutlineView(style);
1970 }
1971
1972 void wxCocoaDataViewControl::InitOutlineView(long style)
1973 {
1974     [m_OutlineView setImplementation:this];
1975     [m_OutlineView setColumnAutoresizingStyle:NSTableViewSequentialColumnAutoresizingStyle];
1976     [m_OutlineView setIndentationPerLevel:GetDataViewCtrl()->GetIndent()];
1977     NSUInteger maskGridStyle(NSTableViewGridNone);
1978     if (style & wxDV_HORIZ_RULES)
1979         maskGridStyle |= NSTableViewSolidHorizontalGridLineMask;
1980     if (style & wxDV_VERT_RULES)
1981         maskGridStyle |= NSTableViewSolidVerticalGridLineMask;
1982     [m_OutlineView setGridStyleMask:maskGridStyle];
1983     [m_OutlineView setAllowsMultipleSelection:           (style & wxDV_MULTIPLE)  != 0];
1984     [m_OutlineView setUsesAlternatingRowBackgroundColors:(style & wxDV_ROW_LINES) != 0];
1985
1986     if ( style & wxDV_NO_HEADER )
1987         [m_OutlineView setHeaderView:nil];
1988 }
1989
1990 wxCocoaDataViewControl::~wxCocoaDataViewControl()
1991 {
1992     [m_DataSource  release];
1993     [m_OutlineView release];
1994 }
1995
1996 //
1997 // column related methods (inherited from wxDataViewWidgetImpl)
1998 //
1999 bool wxCocoaDataViewControl::ClearColumns()
2000 {
2001     // as there is a bug in NSOutlineView version (OSX 10.5.6 #6555162) the
2002     // columns cannot be deleted if there is an outline column in the view;
2003     // therefore, the whole view is deleted and newly constructed:
2004     [m_OutlineView release];
2005     m_OutlineView = [[wxCocoaOutlineView alloc] init];
2006     [((NSScrollView*) GetWXWidget()) setDocumentView:m_OutlineView];
2007     [m_OutlineView setDataSource:m_DataSource];
2008
2009     InitOutlineView(GetDataViewCtrl()->GetWindowStyle());
2010
2011     return true;
2012 }
2013
2014 bool wxCocoaDataViewControl::DeleteColumn(wxDataViewColumn* columnPtr)
2015 {
2016     if ([m_OutlineView outlineTableColumn] == columnPtr->GetNativeData()->GetNativeColumnPtr())
2017         [m_OutlineView setOutlineTableColumn:nil]; // due to a bug this does not work
2018     [m_OutlineView removeTableColumn:columnPtr->GetNativeData()->GetNativeColumnPtr()]; // due to a confirmed bug #6555162 the deletion does not work for
2019     // outline table columns (... and there is no workaround)
2020     return (([m_OutlineView columnWithIdentifier:[wxDVCNSTableColumn identifierForColumnPointer:columnPtr]]) == -1);
2021 }
2022
2023 void wxCocoaDataViewControl::DoSetExpanderColumn(const wxDataViewColumn *columnPtr)
2024 {
2025     [m_OutlineView setOutlineTableColumn:columnPtr->GetNativeData()->GetNativeColumnPtr()];
2026 }
2027
2028 wxDataViewColumn* wxCocoaDataViewControl::GetColumn(unsigned int pos) const
2029 {
2030     NSTableColumn* tableColumn = [[m_OutlineView tableColumns] objectAtIndex:pos];
2031     return [static_cast<wxDVCNSTableColumn*>(tableColumn) getColumnPointer];
2032 }
2033
2034 int wxCocoaDataViewControl::GetColumnPosition(const wxDataViewColumn *columnPtr) const
2035 {
2036     return [m_OutlineView columnWithIdentifier:[wxDVCNSTableColumn identifierForColumnPointer:columnPtr]];
2037 }
2038
2039 bool wxCocoaDataViewControl::InsertColumn(unsigned int pos, wxDataViewColumn* columnPtr)
2040 {
2041     // create column and set the native data of the dataview column:
2042     NSTableColumn *nativeColumn = ::CreateNativeColumn(columnPtr);
2043     columnPtr->GetNativeData()->SetNativeColumnPtr(nativeColumn);
2044     // as the native control does not allow the insertion of a column at a
2045     // specified position the column is first appended and - if necessary -
2046     // moved to its final position:
2047     [m_OutlineView addTableColumn:nativeColumn];
2048     if (pos != static_cast<unsigned int>([m_OutlineView numberOfColumns]-1))
2049         [m_OutlineView moveColumn:[m_OutlineView numberOfColumns]-1 toColumn:pos];
2050
2051     // set columns width now that it can be computed even for autosized columns:
2052     columnPtr->SetWidth(columnPtr->GetWidthVariable());
2053
2054     // done:
2055     return true;
2056 }
2057
2058 void wxCocoaDataViewControl::FitColumnWidthToContent(unsigned int pos)
2059 {
2060 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
2061     const int count = GetCount();
2062     NSTableColumn *column = GetColumn(pos)->GetNativeData()->GetNativeColumnPtr();
2063
2064     class MaxWidthCalculator
2065     {
2066     public:
2067         MaxWidthCalculator(wxCocoaOutlineView *view,
2068                            NSTableColumn *column, unsigned columnIndex)
2069             : m_width(0),
2070               m_view(view),
2071               m_column(columnIndex),
2072               m_indent(0)
2073         {
2074             // account for indentation in the column with expander
2075             if ( column == [m_view outlineTableColumn] )
2076                 m_indent = [m_view indentationPerLevel];
2077         }
2078
2079         void UpdateWithWidth(int width)
2080         {
2081             m_width = wxMax(m_width, width);
2082         }
2083
2084         void UpdateWithRow(int row)
2085         {
2086             NSCell *cell = [m_view preparedCellAtColumn:m_column row:row];
2087             unsigned cellWidth = [cell cellSize].width + 1/*round the float up*/;
2088
2089             if ( m_indent )
2090                 cellWidth += m_indent * ([m_view levelForRow:row] + 1);
2091
2092             m_width = wxMax(m_width, cellWidth);
2093         }
2094
2095         int GetMaxWidth() const { return m_width; }
2096
2097     private:
2098         int m_width;
2099         wxCocoaOutlineView *m_view;
2100         unsigned m_column;
2101         int m_indent;
2102     };
2103
2104     MaxWidthCalculator calculator(m_OutlineView, column, pos);
2105
2106     if ( [column headerCell] )
2107     {
2108         calculator.UpdateWithWidth([[column headerCell] cellSize].width + 1/*round the float up*/);
2109     }
2110
2111     // The code below deserves some explanation. For very large controls, we
2112     // simply can't afford to calculate sizes for all items, it takes too
2113     // long. So the best we can do is to check the first and the last N/2
2114     // items in the control for some sufficiently large N and calculate best
2115     // sizes from that. That can result in the calculated best width being too
2116     // small for some outliers, but it's better to get slightly imperfect
2117     // result than to wait several seconds after every update. To avoid highly
2118     // visible miscalculations, we also include all currently visible items
2119     // no matter what.  Finally, the value of N is determined dynamically by
2120     // measuring how much time we spent on the determining item widths so far.
2121
2122 #if wxUSE_STOPWATCH
2123     int top_part_end = count;
2124     static const long CALC_TIMEOUT = 20/*ms*/;
2125     // don't call wxStopWatch::Time() too often
2126     static const unsigned CALC_CHECK_FREQ = 100;
2127     wxStopWatch timer;
2128 #else
2129     // use some hard-coded limit, that's the best we can do without timer
2130     int top_part_end = wxMin(500, count);
2131 #endif // wxUSE_STOPWATCH/!wxUSE_STOPWATCH
2132
2133     int row = 0;
2134
2135     for ( row = 0; row < top_part_end; row++ )
2136     {
2137 #if wxUSE_STOPWATCH
2138         if ( row % CALC_CHECK_FREQ == CALC_CHECK_FREQ-1 &&
2139              timer.Time() > CALC_TIMEOUT )
2140             break;
2141 #endif // wxUSE_STOPWATCH
2142         calculator.UpdateWithRow(row);
2143     }
2144
2145     // row is the first unmeasured item now; that's our value of N/2
2146
2147     if ( row < count )
2148     {
2149         top_part_end = row;
2150
2151         // add bottom N/2 items now:
2152         const int bottom_part_start = wxMax(row, count - row);
2153         for ( row = bottom_part_start; row < count; row++ )
2154             calculator.UpdateWithRow(row);
2155
2156         // finally, include currently visible items in the calculation:
2157         const NSRange visible = [m_OutlineView rowsInRect:[m_OutlineView visibleRect]];
2158         const int first_visible = wxMax(visible.location, top_part_end);
2159         const int last_visible = wxMin(first_visible + visible.length, bottom_part_start);
2160
2161         for ( row = first_visible; row < last_visible; row++ )
2162             calculator.UpdateWithRow(row);
2163
2164         wxLogTrace("dataview",
2165                    "determined best size from %d top, %d bottom plus %d more visible items out of %d total",
2166                    top_part_end,
2167                    count - bottom_part_start,
2168                    wxMax(0, last_visible - first_visible),
2169                    count);
2170     }
2171
2172     [column setWidth:calculator.GetMaxWidth()];
2173 #endif // MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
2174 }
2175
2176 //
2177 // item related methods (inherited from wxDataViewWidgetImpl)
2178 //
2179 bool wxCocoaDataViewControl::Add(const wxDataViewItem& parent, const wxDataViewItem& WXUNUSED(item))
2180 {
2181     if (parent.IsOk())
2182         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2183     else
2184         [m_OutlineView reloadData];
2185     return true;
2186 }
2187
2188 bool wxCocoaDataViewControl::Add(const wxDataViewItem& parent, const wxDataViewItemArray& WXUNUSED(items))
2189 {
2190     if (parent.IsOk())
2191         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2192     else
2193         [m_OutlineView reloadData];
2194     return true;
2195 }
2196
2197 void wxCocoaDataViewControl::Collapse(const wxDataViewItem& item)
2198 {
2199     [m_OutlineView collapseItem:[m_DataSource getDataViewItemFromBuffer:item]];
2200 }
2201
2202 void wxCocoaDataViewControl::EnsureVisible(const wxDataViewItem& item, const wxDataViewColumn *columnPtr)
2203 {
2204     if (item.IsOk())
2205     {
2206         [m_OutlineView scrollRowToVisible:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2207         if (columnPtr)
2208             [m_OutlineView scrollColumnToVisible:GetColumnPosition(columnPtr)];
2209     }
2210 }
2211
2212 void wxCocoaDataViewControl::Expand(const wxDataViewItem& item)
2213 {
2214     [m_OutlineView expandItem:[m_DataSource getDataViewItemFromBuffer:item]];
2215 }
2216
2217 unsigned int wxCocoaDataViewControl::GetCount() const
2218 {
2219     return [m_OutlineView numberOfRows];
2220 }
2221
2222 wxRect wxCocoaDataViewControl::GetRectangle(const wxDataViewItem& item, const wxDataViewColumn *columnPtr)
2223 {
2224     return wxFromNSRect([m_osxView superview],[m_OutlineView frameOfCellAtColumn:GetColumnPosition(columnPtr)
2225             row:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]]);
2226 }
2227
2228 bool wxCocoaDataViewControl::IsExpanded(const wxDataViewItem& item) const
2229 {
2230     return [m_OutlineView isItemExpanded:[m_DataSource getDataViewItemFromBuffer:item]];
2231 }
2232
2233 bool wxCocoaDataViewControl::Reload()
2234 {
2235     [m_DataSource clearBuffers];
2236     [m_OutlineView reloadData];
2237     [m_OutlineView scrollColumnToVisible:0];
2238     [m_OutlineView scrollRowToVisible:0];
2239     return true;
2240 }
2241
2242 bool wxCocoaDataViewControl::Remove(const wxDataViewItem& parent, const wxDataViewItem& WXUNUSED(item))
2243 {
2244     if (parent.IsOk())
2245         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2246     else
2247         [m_OutlineView reloadData];
2248     return true;
2249 }
2250
2251 bool wxCocoaDataViewControl::Remove(const wxDataViewItem& parent, const wxDataViewItemArray& WXUNUSED(item))
2252 {
2253     if (parent.IsOk())
2254         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:parent] reloadChildren:YES];
2255     else
2256         [m_OutlineView reloadData];
2257     return true;
2258 }
2259
2260 bool wxCocoaDataViewControl::Update(const wxDataViewColumn *columnPtr)
2261 {
2262     wxUnusedVar(columnPtr);
2263
2264     return false;
2265 }
2266
2267 bool wxCocoaDataViewControl::Update(const wxDataViewItem& WXUNUSED(parent), const wxDataViewItem& item)
2268 {
2269     [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:item]];
2270     return true;
2271 }
2272
2273 bool wxCocoaDataViewControl::Update(const wxDataViewItem& WXUNUSED(parent), const wxDataViewItemArray& items)
2274 {
2275     for (size_t i=0; i<items.GetCount(); ++i)
2276         [m_OutlineView reloadItem:[m_DataSource getDataViewItemFromBuffer:items[i]]];
2277     return true;
2278 }
2279
2280 //
2281 // model related methods
2282 //
2283 bool wxCocoaDataViewControl::AssociateModel(wxDataViewModel* model)
2284 {
2285     [m_DataSource release];
2286     if (model)
2287     {
2288         m_DataSource = [[wxCocoaOutlineDataSource alloc] init];
2289         [m_DataSource setImplementation:this];
2290         [m_DataSource setModel:model];
2291     }
2292     else
2293         m_DataSource = NULL;
2294     [m_OutlineView setDataSource:m_DataSource]; // if there is a data source the data is immediately going to be requested
2295     return true;
2296 }
2297
2298 //
2299 // selection related methods (inherited from wxDataViewWidgetImpl)
2300 //
2301
2302 wxDataViewItem wxCocoaDataViewControl::GetCurrentItem() const
2303 {
2304     return wxDataViewItem([[m_OutlineView itemAtRow:[m_OutlineView selectedRow]] pointer]);
2305 }
2306
2307 wxDataViewColumn *wxCocoaDataViewControl::GetCurrentColumn() const
2308 {
2309     int col = [m_OutlineView selectedColumn];
2310     if ( col == -1 )
2311         return NULL;
2312     return GetColumn(col);
2313 }
2314
2315 void wxCocoaDataViewControl::SetCurrentItem(const wxDataViewItem& item)
2316 {
2317     // We can't have unselected current item in a NSTableView, as the
2318     // documentation of its deselectRow method explains, the control will
2319     // automatically change the current item to the closest still selected item
2320     // if the current item is deselected. So we have no choice but to select
2321     // the item in the same time as making it current.
2322     Select(item);
2323 }
2324
2325 int wxCocoaDataViewControl::GetSelectedItemsCount() const
2326 {
2327     return [m_OutlineView numberOfSelectedRows];
2328 }
2329
2330 int wxCocoaDataViewControl::GetSelections(wxDataViewItemArray& sel) const
2331 {
2332     NSIndexSet* selectedRowIndexes([m_OutlineView selectedRowIndexes]);
2333
2334     NSUInteger indexRow;
2335
2336
2337     sel.Empty();
2338     sel.Alloc([selectedRowIndexes count]);
2339     indexRow = [selectedRowIndexes firstIndex];
2340     while (indexRow != NSNotFound)
2341     {
2342         sel.Add(wxDataViewItem([[m_OutlineView itemAtRow:indexRow] pointer]));
2343         indexRow = [selectedRowIndexes indexGreaterThanIndex:indexRow];
2344     }
2345     return sel.GetCount();
2346 }
2347
2348 bool wxCocoaDataViewControl::IsSelected(const wxDataViewItem& item) const
2349 {
2350     return [m_OutlineView isRowSelected:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2351 }
2352
2353 void wxCocoaDataViewControl::Select(const wxDataViewItem& item)
2354 {
2355     if (item.IsOk())
2356         [m_OutlineView selectRowIndexes:[NSIndexSet indexSetWithIndex:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]]
2357             byExtendingSelection:GetDataViewCtrl()->HasFlag(wxDV_MULTIPLE) ? YES : NO];
2358 }
2359
2360 void wxCocoaDataViewControl::SelectAll()
2361 {
2362     [m_OutlineView selectAll:m_OutlineView];
2363 }
2364
2365 void wxCocoaDataViewControl::Unselect(const wxDataViewItem& item)
2366 {
2367     if (item.IsOk())
2368         [m_OutlineView deselectRow:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]]];
2369 }
2370
2371 void wxCocoaDataViewControl::UnselectAll()
2372 {
2373     [m_OutlineView deselectAll:m_OutlineView];
2374 }
2375
2376 //
2377 // sorting related methods
2378 //
2379 wxDataViewColumn* wxCocoaDataViewControl::GetSortingColumn() const
2380 {
2381     NSArray* const columns = [m_OutlineView tableColumns];
2382
2383     UInt32 const noOfColumns = [columns count];
2384
2385
2386     for (UInt32 i=0; i<noOfColumns; ++i)
2387         if ([[columns objectAtIndex:i] sortDescriptorPrototype] != nil)
2388             return GetColumn(i);
2389     return NULL;
2390 }
2391
2392 void wxCocoaDataViewControl::Resort()
2393 {
2394     [m_DataSource clearChildren];
2395     [m_OutlineView reloadData];
2396 }
2397
2398 void wxCocoaDataViewControl::StartEditor( const wxDataViewItem & item, unsigned int column )
2399 {
2400     [m_OutlineView editColumn:column row:[m_OutlineView rowForItem:[m_DataSource getDataViewItemFromBuffer:item]] withEvent:nil select:YES];
2401 }
2402
2403 //
2404 // other methods (inherited from wxDataViewWidgetImpl)
2405 //
2406 void wxCocoaDataViewControl::DoSetIndent(int indent)
2407 {
2408     [m_OutlineView setIndentationPerLevel:static_cast<CGFloat>(indent)];
2409 }
2410
2411 void wxCocoaDataViewControl::HitTest(const wxPoint& point, wxDataViewItem& item, wxDataViewColumn*& columnPtr) const
2412 {
2413     NSPoint const nativePoint = wxToNSPoint((NSScrollView*) GetWXWidget(),point);
2414
2415     int indexColumn;
2416     int indexRow;
2417
2418
2419     indexColumn = [m_OutlineView columnAtPoint:nativePoint];
2420     indexRow    = [m_OutlineView rowAtPoint:   nativePoint];
2421     if ((indexColumn >= 0) && (indexRow >= 0))
2422     {
2423         columnPtr = GetColumn(indexColumn);
2424         item      = wxDataViewItem([[m_OutlineView itemAtRow:indexRow] pointer]);
2425     }
2426     else
2427     {
2428         columnPtr = NULL;
2429         item      = wxDataViewItem();
2430     }
2431 }
2432
2433 void wxCocoaDataViewControl::SetRowHeight(const wxDataViewItem& WXUNUSED(item), unsigned int WXUNUSED(height))
2434     // Not supported by the native control
2435 {
2436 }
2437
2438 void wxCocoaDataViewControl::OnSize()
2439 {
2440     if ([m_OutlineView numberOfColumns] == 1)
2441         [m_OutlineView sizeLastColumnToFit];
2442 }
2443
2444 //
2445 // drag & drop helper methods
2446 //
2447 wxDataFormat wxCocoaDataViewControl::GetDnDDataFormat(wxDataObjectComposite* dataObjects)
2448 {
2449     wxDataFormat resultFormat;
2450     if ( !dataObjects )
2451         return resultFormat;
2452
2453     bool compatible(true);
2454
2455     size_t const noOfFormats = dataObjects->GetFormatCount();
2456     size_t       indexFormat;
2457
2458     wxDataFormat* formats;
2459
2460     // get all formats and check afterwards if the formats are compatible; if
2461     // they are compatible the preferred format is returned otherwise
2462     // wxDF_INVALID is returned;
2463     // currently compatible types (ordered by priority are):
2464     //  - wxDF_UNICODETEXT - wxDF_TEXT
2465     formats = new wxDataFormat[noOfFormats];
2466     dataObjects->GetAllFormats(formats);
2467     indexFormat = 0;
2468     while ((indexFormat < noOfFormats) && compatible)
2469     {
2470         switch (resultFormat.GetType())
2471         {
2472             case wxDF_INVALID:
2473                 resultFormat.SetType(formats[indexFormat].GetType()); // first format (should only be reached if indexFormat == 0)
2474                 break;
2475             case wxDF_TEXT:
2476                 if (formats[indexFormat].GetType() == wxDF_UNICODETEXT)
2477                     resultFormat.SetType(wxDF_UNICODETEXT);
2478                 else // incompatible
2479                 {
2480                     resultFormat.SetType(wxDF_INVALID);
2481                     compatible = false;
2482                 }
2483                 break;
2484             case wxDF_UNICODETEXT:
2485                 if (formats[indexFormat].GetType() != wxDF_TEXT)
2486                 {
2487                     resultFormat.SetType(wxDF_INVALID);
2488                     compatible = false;
2489                 }
2490                 break;
2491             default:
2492                 resultFormat.SetType(wxDF_INVALID); // not (yet) supported format
2493                 compatible = false;
2494         }
2495         ++indexFormat;
2496     }
2497
2498     delete[] formats;
2499
2500     return resultFormat;
2501 }
2502
2503 wxDataObjectComposite* wxCocoaDataViewControl::GetDnDDataObjects(NSData* dataObject) const
2504 {
2505     wxDataFormatId dataFormatID;
2506
2507
2508     [dataObject getBytes:&dataFormatID length:sizeof(wxDataFormatId)];
2509     switch (dataFormatID)
2510     {
2511         case wxDF_TEXT:
2512         case wxDF_UNICODETEXT:
2513             {
2514                 wxTextDataObject* textDataObject(new wxTextDataObject());
2515
2516                 if (textDataObject->SetData(wxDataFormat(dataFormatID),[dataObject length]-sizeof(wxDataFormatId),static_cast<char const*>([dataObject bytes])+sizeof(wxDataFormatId)))
2517                 {
2518                     wxDataObjectComposite* dataObjectComposite(new wxDataObjectComposite());
2519
2520                     dataObjectComposite->Add(textDataObject);
2521                     return dataObjectComposite;
2522                 }
2523                 else
2524                 {
2525                     delete textDataObject;
2526                     return NULL;
2527                 }
2528             }
2529             break;
2530         default:
2531             return NULL;
2532     }
2533 }
2534
2535 id wxCocoaDataViewControl::GetItemAtRow(int row) const
2536 {
2537     return [m_OutlineView itemAtRow:row];
2538 }
2539
2540 // ----------------------------------------------------------------------------
2541 // wxDataViewRendererNativeData
2542 // ----------------------------------------------------------------------------
2543
2544 void wxDataViewRendererNativeData::Init()
2545 {
2546     m_origFont = NULL;
2547     m_origTextColour = NULL;
2548     m_ellipsizeMode = wxELLIPSIZE_MIDDLE;
2549
2550     if ( m_ColumnCell )
2551         ApplyLineBreakMode(m_ColumnCell);
2552 }
2553
2554 void wxDataViewRendererNativeData::ApplyLineBreakMode(NSCell *cell)
2555 {
2556     NSLineBreakMode nsMode = NSLineBreakByWordWrapping;
2557     switch ( m_ellipsizeMode )
2558     {
2559         case wxELLIPSIZE_NONE:
2560             nsMode = NSLineBreakByClipping;
2561             break;
2562
2563         case wxELLIPSIZE_START:
2564             nsMode = NSLineBreakByTruncatingHead;
2565             break;
2566
2567         case wxELLIPSIZE_MIDDLE:
2568             nsMode = NSLineBreakByTruncatingMiddle;
2569             break;
2570
2571         case wxELLIPSIZE_END:
2572             nsMode = NSLineBreakByTruncatingTail;
2573             break;
2574     }
2575
2576     wxASSERT_MSG( nsMode != NSLineBreakByWordWrapping, "unknown wxEllipsizeMode" );
2577
2578     [cell setLineBreakMode: nsMode];
2579 }
2580
2581 // ---------------------------------------------------------
2582 // wxDataViewRenderer
2583 // ---------------------------------------------------------
2584
2585 wxDataViewRenderer::wxDataViewRenderer(const wxString& varianttype,
2586                                        wxDataViewCellMode mode,
2587                                        int align)
2588     : wxDataViewRendererBase(varianttype, mode, align),
2589       m_alignment(align),
2590       m_mode(mode),
2591       m_NativeDataPtr(NULL)
2592 {
2593 }
2594
2595 wxDataViewRenderer::~wxDataViewRenderer()
2596 {
2597     delete m_NativeDataPtr;
2598 }
2599
2600 void wxDataViewRenderer::SetAlignment(int align)
2601 {
2602     m_alignment = align;
2603     [GetNativeData()->GetColumnCell() setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2604 }
2605
2606 void wxDataViewRenderer::SetMode(wxDataViewCellMode mode)
2607 {
2608     m_mode = mode;
2609     if ( GetOwner() )
2610         [GetOwner()->GetNativeData()->GetNativeColumnPtr() setEditable:(mode == wxDATAVIEW_CELL_EDITABLE)];
2611 }
2612
2613 void wxDataViewRenderer::SetNativeData(wxDataViewRendererNativeData* newNativeDataPtr)
2614 {
2615     delete m_NativeDataPtr;
2616     m_NativeDataPtr = newNativeDataPtr;
2617 }
2618
2619 void wxDataViewRenderer::EnableEllipsize(wxEllipsizeMode mode)
2620 {
2621     // we need to store this value to apply it to the columns headerCell in
2622     // CreateNativeColumn()
2623     GetNativeData()->SetEllipsizeMode(mode);
2624
2625     // but we may already apply it to the column cell which will be used for
2626     // this column
2627     GetNativeData()->ApplyLineBreakMode(GetNativeData()->GetColumnCell());
2628 }
2629
2630 wxEllipsizeMode wxDataViewRenderer::GetEllipsizeMode() const
2631 {
2632     return GetNativeData()->GetEllipsizeMode();
2633 }
2634
2635 void
2636 wxDataViewRenderer::OSXOnCellChanged(NSObject *object,
2637                                      const wxDataViewItem& item,
2638                                      unsigned col)
2639 {
2640     // TODO: This code should really be removed and this function be made pure
2641     //       virtual. We just need to decide what to do with custom renderers
2642     //       (i.e. wxDataViewCustomRenderer), currently OS X "in place" editing
2643     //       which doesn't really create an editor control is not compatible
2644     //       with the in place editing under other platforms.
2645
2646     wxVariant value;
2647     if ( [object isKindOfClass:[NSString class]] )
2648         value = ObjectToString(object);
2649     else if ( [object isKindOfClass:[NSNumber class]] )
2650         value = ObjectToLong(object);
2651     else if ( [object isKindOfClass:[NSDate class]] )
2652         value = ObjectToDate(object);
2653     else
2654     {
2655         wxFAIL_MSG( wxString::Format
2656                     (
2657                      "unknown value type %s",
2658                      wxCFStringRef::AsString([object className])
2659                     ));
2660         return;
2661     }
2662
2663     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2664     model->ChangeValue(value, item, col);
2665 }
2666
2667 void wxDataViewRenderer::OSXApplyAttr(const wxDataViewItemAttr& attr)
2668 {
2669     wxDataViewRendererNativeData * const data = GetNativeData();
2670     NSCell * const cell = data->GetItemCell();
2671
2672     // set the font and text colour to use: we need to do it if we had ever
2673     // changed them before, even if this item itself doesn't have any special
2674     // attributes as otherwise it would reuse the attributes from the previous
2675     // cell rendered using the same renderer
2676     NSFont *font = NULL;
2677     NSColor *colText = NULL;
2678
2679     if ( attr.HasFont() )
2680     {
2681         font = data->GetOriginalFont();
2682         if ( !font )
2683         {
2684             // this is the first time we're setting the font, remember the
2685             // original one before changing it
2686             font = [cell font];
2687             data->SaveOriginalFont(font);
2688         }
2689
2690         if ( font )
2691         {
2692             // FIXME: using wxFont methods here doesn't work for some reason
2693             NSFontManager * const fm = [NSFontManager sharedFontManager];
2694             if ( attr.GetBold() )
2695                 font = [fm convertFont:font toHaveTrait:NSBoldFontMask];
2696             if ( attr.GetItalic() )
2697                 font = [fm convertFont:font toHaveTrait:NSItalicFontMask];
2698         }
2699         //else: can't change font if the cell doesn't have any
2700     }
2701
2702     if ( attr.HasColour() )
2703     {
2704         // we can set font for any cell but only NSTextFieldCell provides
2705         // a method for setting text colour so check that this method is
2706         // available before using it
2707         if ( [cell respondsToSelector:@selector(setTextColor:)] &&
2708                 [cell respondsToSelector:@selector(textColor)] )
2709         {
2710             if ( !data->GetOriginalTextColour() )
2711             {
2712                 // the cast to (untyped) id is safe because of the check above
2713                 data->SaveOriginalTextColour([(id)cell textColor]);
2714             }
2715
2716             const wxColour& c = attr.GetColour();
2717             colText = [NSColor colorWithCalibratedRed:c.Red() / 255.
2718                 green:c.Green() / 255.
2719                 blue:c.Blue() / 255.
2720                 alpha:c.Alpha() / 255.];
2721         }
2722     }
2723
2724     if ( !font )
2725         font = data->GetOriginalFont();
2726     if ( !colText )
2727         colText = data->GetOriginalTextColour();
2728
2729     if ( font )
2730         [cell setFont:font];
2731
2732     if ( colText )
2733         [(id)cell setTextColor:colText];
2734 }
2735
2736 void wxDataViewRenderer::OSXApplyEnabled(bool enabled)
2737 {
2738     [GetNativeData()->GetItemCell() setEnabled:enabled];
2739 }
2740
2741 IMPLEMENT_ABSTRACT_CLASS(wxDataViewRenderer,wxDataViewRendererBase)
2742
2743 // ---------------------------------------------------------
2744 // wxDataViewCustomRenderer
2745 // ---------------------------------------------------------
2746 wxDataViewCustomRenderer::wxDataViewCustomRenderer(const wxString& varianttype,
2747                                                    wxDataViewCellMode mode,
2748                                                    int align)
2749     : wxDataViewCustomRendererBase(varianttype, mode, align),
2750       m_editorCtrlPtr(NULL),
2751       m_DCPtr(NULL)
2752 {
2753     SetNativeData(new wxDataViewRendererNativeData([[wxCustomCell alloc] init]));
2754 }
2755
2756 bool wxDataViewCustomRenderer::MacRender()
2757 {
2758     [GetNativeData()->GetItemCell() setObjectValue:[[[wxCustomRendererObject alloc] initWithRenderer:this] autorelease]];
2759     return true;
2760 }
2761
2762 void wxDataViewCustomRenderer::OSXApplyAttr(const wxDataViewItemAttr& attr)
2763 {
2764     // simply save the attribute so that it could be reused from our Render()
2765     SetAttr(attr);
2766
2767     // it's not necessary to call the base class version which sets the cell
2768     // properties to correspond to this attribute because we currently don't
2769     // use any NSCell methods in custom renderers anyhow but if we ever start
2770     // doing this (e.g. override RenderText() here to use NSTextFieldCell
2771     // methods), then we should pass it on to wxDataViewRenderer here
2772 }
2773
2774 IMPLEMENT_ABSTRACT_CLASS(wxDataViewCustomRenderer, wxDataViewRenderer)
2775
2776 // ---------------------------------------------------------
2777 // wxDataViewTextRenderer
2778 // ---------------------------------------------------------
2779 wxDataViewTextRenderer::wxDataViewTextRenderer(const wxString& varianttype,
2780                                                wxDataViewCellMode mode,
2781                                                int align)
2782     : wxDataViewRenderer(varianttype,mode,align)
2783 {
2784     NSTextFieldCell* cell;
2785
2786
2787     cell = [[NSTextFieldCell alloc] init];
2788     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
2789     SetNativeData(new wxDataViewRendererNativeData(cell));
2790     [cell release];
2791 }
2792
2793 bool wxDataViewTextRenderer::MacRender()
2794 {
2795     if (GetValue().GetType() == GetVariantType())
2796     {
2797         [GetNativeData()->GetItemCell() setObjectValue:wxCFStringRef(GetValue().GetString()).AsNSString()];
2798         return true;
2799     }
2800     else
2801     {
2802         wxFAIL_MSG(wxString("Text renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2803         return false;
2804     }
2805 }
2806
2807 void
2808 wxDataViewTextRenderer::OSXOnCellChanged(NSObject *value,
2809                                          const wxDataViewItem& item,
2810                                          unsigned col)
2811 {
2812     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2813     model->ChangeValue(ObjectToString(value), item, col);
2814 }
2815
2816 IMPLEMENT_CLASS(wxDataViewTextRenderer,wxDataViewRenderer)
2817
2818 // ---------------------------------------------------------
2819 // wxDataViewBitmapRenderer
2820 // ---------------------------------------------------------
2821 wxDataViewBitmapRenderer::wxDataViewBitmapRenderer(const wxString& varianttype,
2822                                                    wxDataViewCellMode mode,
2823                                                    int align)
2824     : wxDataViewRenderer(varianttype,mode,align)
2825 {
2826     NSImageCell* cell;
2827
2828
2829     cell = [[NSImageCell alloc] init];
2830     SetNativeData(new wxDataViewRendererNativeData(cell));
2831     [cell release];
2832 }
2833
2834 // This method returns 'true' if
2835 //  - the passed bitmap is valid and it could be assigned to the native data
2836 //  browser;
2837 //  - the passed bitmap is invalid (or is not initialized); this case
2838 //  simulates a non-existing bitmap.
2839 // In all other cases the method returns 'false'.
2840 bool wxDataViewBitmapRenderer::MacRender()
2841 {
2842     wxCHECK_MSG(GetValue().GetType() == GetVariantType(),false,wxString("Bitmap renderer cannot render value; value type: ") << GetValue().GetType());
2843
2844     wxBitmap bitmap;
2845
2846     bitmap << GetValue();
2847     if (bitmap.IsOk())
2848         [GetNativeData()->GetItemCell() setObjectValue:[[bitmap.GetNSImage() retain] autorelease]];
2849     return true;
2850 }
2851
2852 IMPLEMENT_CLASS(wxDataViewBitmapRenderer,wxDataViewRenderer)
2853
2854 // -------------------------------------
2855 // wxDataViewChoiceRenderer
2856 // -------------------------------------
2857 wxDataViewChoiceRenderer::wxDataViewChoiceRenderer(const wxArrayString& choices,
2858                                                    wxDataViewCellMode mode,
2859                                                    int alignment)
2860     : wxDataViewRenderer(wxT("string"), mode, alignment),
2861       m_choices(choices)
2862 {
2863     NSPopUpButtonCell* cell;
2864
2865
2866     cell = [[NSPopUpButtonCell alloc] init];
2867     [cell setControlSize:NSMiniControlSize];
2868     [cell setFont:[NSFont fontWithName:[[cell font] fontName] size:[NSFont systemFontSizeForControlSize:NSMiniControlSize]]];
2869     for (size_t i=0; i<choices.GetCount(); ++i)
2870         [cell addItemWithTitle:wxCFStringRef(choices[i]).AsNSString()];
2871     SetNativeData(new wxDataViewRendererNativeData(cell));
2872     [cell release];
2873 }
2874
2875 void
2876 wxDataViewChoiceRenderer::OSXOnCellChanged(NSObject *value,
2877                                            const wxDataViewItem& item,
2878                                            unsigned col)
2879 {
2880     // At least under OS X 10.7 we get the index of the item selected and not
2881     // its string.
2882     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2883     model->ChangeValue(GetChoice(ObjectToLong(value)), item, col);
2884 }
2885
2886 bool wxDataViewChoiceRenderer::MacRender()
2887 {
2888     if (GetValue().GetType() == GetVariantType())
2889     {
2890         [((NSPopUpButtonCell*) GetNativeData()->GetItemCell()) selectItemWithTitle:[[wxCFStringRef(GetValue().GetString()).AsNSString() retain] autorelease]];
2891         return true;
2892     }
2893     else
2894     {
2895         wxFAIL_MSG(wxString("Choice renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2896         return false;
2897     }
2898 }
2899
2900 IMPLEMENT_CLASS(wxDataViewChoiceRenderer,wxDataViewRenderer)
2901
2902 // ---------------------------------------------------------
2903 // wxDataViewDateRenderer
2904 // ---------------------------------------------------------
2905
2906 wxDataViewDateRenderer::wxDataViewDateRenderer(const wxString& varianttype,
2907                                                wxDataViewCellMode mode,
2908                                                int align)
2909     : wxDataViewRenderer(varianttype,mode,align)
2910 {
2911     NSTextFieldCell* cell;
2912
2913     NSDateFormatter* dateFormatter;
2914
2915
2916     dateFormatter = [[NSDateFormatter alloc] init];
2917     [dateFormatter setFormatterBehavior:NSDateFormatterBehavior10_4];
2918     [dateFormatter setDateStyle:NSDateFormatterShortStyle];
2919     cell = [[NSTextFieldCell alloc] init];
2920     [cell setFormatter:dateFormatter];
2921     SetNativeData(new wxDataViewRendererNativeData(cell,[NSDate dateWithString:@"2000-12-30 20:00:00 +0000"]));
2922     [cell          release];
2923     [dateFormatter release];
2924 }
2925
2926 bool wxDataViewDateRenderer::MacRender()
2927 {
2928     if (GetValue().GetType() == GetVariantType())
2929     {
2930         if (GetValue().GetDateTime().IsValid())
2931         {
2932             // -- find best fitting style to show the date --
2933             // as the style should be identical for all cells a reference date
2934             // instead of the actual cell's date value is used for all cells;
2935             // this reference date is stored in the renderer's native data
2936             // section for speed purposes; otherwise, the reference date's
2937             // string has to be recalculated for each item that may become
2938             // timewise long if a lot of rows using dates exist; the algorithm
2939             // has the preference to display as much information as possible
2940             // in the first instance; but as this is often impossible due to
2941             // space restrictions the style is shortened per loop; finally, if
2942             // the shortest time and date format does not fit into the cell
2943             // the time part is dropped; remark: the time part itself is not
2944             // modified per iteration loop and only uses the short style,
2945             // means that only the hours and minutes are being shown
2946
2947             // GetObject() returns a date for testing the size of a date object
2948             [GetNativeData()->GetItemCell() setObjectValue:GetNativeData()->GetObject()];
2949             [[GetNativeData()->GetItemCell() formatter] setTimeStyle:NSDateFormatterShortStyle];
2950             for (int dateFormatterStyle=4; dateFormatterStyle>0; --dateFormatterStyle)
2951             {
2952                 [[GetNativeData()->GetItemCell() formatter] setDateStyle:(NSDateFormatterStyle)dateFormatterStyle];
2953                 if (dateFormatterStyle == 1)
2954                 {
2955                     // if the shortest style for displaying the date and time
2956                     // is too long to be fully visible remove the time part of
2957                     // the date:
2958                     if ([GetNativeData()->GetItemCell() cellSize].width > [GetNativeData()->GetColumnPtr() width])
2959                         [[GetNativeData()->GetItemCell() formatter] setTimeStyle:NSDateFormatterNoStyle];
2960                     {
2961                         // basically not necessary as the loop would end anyway
2962                         // but let's save the last comparison
2963                         break;
2964                     }
2965                 }
2966                 else if ([GetNativeData()->GetItemCell() cellSize].width <= [GetNativeData()->GetColumnPtr() width])
2967                     break;
2968             }
2969             // set data (the style is set by the previous loop); on OSX the
2970             // date has to be specified with respect to UTC; in wxWidgets the
2971             // date is always entered in the local timezone; so, we have to do
2972             // a conversion from the local to UTC timezone when adding the
2973             // seconds to 1970-01-01 UTC:
2974             [GetNativeData()->GetItemCell() setObjectValue:[NSDate dateWithTimeIntervalSince1970:GetValue().GetDateTime().ToUTC().Subtract(wxDateTime(1,wxDateTime::Jan,1970)).GetSeconds().ToDouble()]];
2975         }
2976         return true;
2977     }
2978     else
2979     {
2980         wxFAIL_MSG(wxString("Date renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
2981         return false;
2982     }
2983 }
2984
2985 void
2986 wxDataViewDateRenderer::OSXOnCellChanged(NSObject *value,
2987                                          const wxDataViewItem& item,
2988                                          unsigned col)
2989 {
2990     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
2991     model->ChangeValue(ObjectToDate(value), item, col);
2992 }
2993
2994 IMPLEMENT_ABSTRACT_CLASS(wxDataViewDateRenderer,wxDataViewRenderer)
2995
2996 // ---------------------------------------------------------
2997 // wxDataViewIconTextRenderer
2998 // ---------------------------------------------------------
2999 wxDataViewIconTextRenderer::wxDataViewIconTextRenderer(const wxString& varianttype,
3000                                                        wxDataViewCellMode mode,
3001                                                        int align)
3002      : wxDataViewRenderer(varianttype,mode)
3003 {
3004     wxImageTextCell* cell;
3005
3006
3007     cell = [[wxImageTextCell alloc] init];
3008     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
3009     SetNativeData(new wxDataViewRendererNativeData(cell));
3010     [cell release];
3011 }
3012
3013 bool wxDataViewIconTextRenderer::MacRender()
3014 {
3015     if (GetValue().GetType() == GetVariantType())
3016     {
3017         wxDataViewIconText iconText;
3018
3019         wxImageTextCell* cell;
3020
3021         cell = (wxImageTextCell*) GetNativeData()->GetItemCell();
3022         iconText << GetValue();
3023         if (iconText.GetIcon().IsOk())
3024             [cell setImage:[[wxBitmap(iconText.GetIcon()).GetNSImage() retain] autorelease]];
3025         else
3026             [cell setImage:nil];
3027         [cell setStringValue:[[wxCFStringRef(iconText.GetText()).AsNSString() retain] autorelease]];
3028         return true;
3029     }
3030     else
3031     {
3032         wxFAIL_MSG(wxString("Icon & text renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
3033         return false;
3034     }
3035 }
3036
3037 void
3038 wxDataViewIconTextRenderer::OSXOnCellChanged(NSObject *value,
3039                                              const wxDataViewItem& item,
3040                                              unsigned col)
3041 {
3042     wxVariant valueIconText;
3043     valueIconText << wxDataViewIconText(ObjectToString(value));
3044
3045     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
3046     model->ChangeValue(valueIconText, item, col);
3047 }
3048
3049 IMPLEMENT_ABSTRACT_CLASS(wxDataViewIconTextRenderer,wxDataViewRenderer)
3050
3051 // ---------------------------------------------------------
3052 // wxDataViewToggleRenderer
3053 // ---------------------------------------------------------
3054 wxDataViewToggleRenderer::wxDataViewToggleRenderer(const wxString& varianttype,
3055                                                    wxDataViewCellMode mode,
3056                                                    int align)
3057     : wxDataViewRenderer(varianttype,mode)
3058 {
3059     NSButtonCell* cell;
3060
3061
3062     cell = [[NSButtonCell alloc] init];
3063     [cell setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
3064     [cell setButtonType:NSSwitchButton];
3065     [cell setImagePosition:NSImageOnly];
3066     SetNativeData(new wxDataViewRendererNativeData(cell));
3067     [cell release];
3068 }
3069
3070 bool wxDataViewToggleRenderer::MacRender()
3071 {
3072     if (GetValue().GetType() == GetVariantType())
3073     {
3074         [GetNativeData()->GetItemCell() setIntValue:GetValue().GetLong()];
3075         return true;
3076     }
3077     else
3078     {
3079         wxFAIL_MSG(wxString("Toggle renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
3080         return false;
3081     }
3082 }
3083
3084 void
3085 wxDataViewToggleRenderer::OSXOnCellChanged(NSObject *value,
3086                                            const wxDataViewItem& item,
3087                                            unsigned col)
3088 {
3089     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
3090     model->ChangeValue(ObjectToBool(value), item, col);
3091 }
3092
3093 IMPLEMENT_ABSTRACT_CLASS(wxDataViewToggleRenderer,wxDataViewRenderer)
3094
3095 // ---------------------------------------------------------
3096 // wxDataViewProgressRenderer
3097 // ---------------------------------------------------------
3098 wxDataViewProgressRenderer::wxDataViewProgressRenderer(const wxString& label,
3099                                                        const wxString& varianttype,
3100                                                        wxDataViewCellMode mode,
3101                                                        int align)
3102     : wxDataViewRenderer(varianttype,mode,align)
3103 {
3104     wxUnusedVar(label);
3105
3106     NSLevelIndicatorCell* cell;
3107
3108     cell = [[NSLevelIndicatorCell alloc] initWithLevelIndicatorStyle:NSContinuousCapacityLevelIndicatorStyle];
3109     [cell setMinValue:0];
3110     [cell setMaxValue:100];
3111     SetNativeData(new wxDataViewRendererNativeData(cell));
3112     [cell release];
3113 }
3114
3115 bool wxDataViewProgressRenderer::MacRender()
3116 {
3117     if (GetValue().GetType() == GetVariantType())
3118     {
3119         [GetNativeData()->GetItemCell() setIntValue:GetValue().GetLong()];
3120         return true;
3121     }
3122     else
3123     {
3124         wxFAIL_MSG(wxString("Progress renderer cannot render value because of wrong value type; value type: ") << GetValue().GetType());
3125         return false;
3126     }
3127 }
3128
3129 void
3130 wxDataViewProgressRenderer::OSXOnCellChanged(NSObject *value,
3131                                              const wxDataViewItem& item,
3132                                              unsigned col)
3133 {
3134     wxDataViewModel *model = GetOwner()->GetOwner()->GetModel();
3135     model->ChangeValue(ObjectToLong(value), item, col);
3136 }
3137
3138 IMPLEMENT_ABSTRACT_CLASS(wxDataViewProgressRenderer,wxDataViewRenderer)
3139
3140 // ---------------------------------------------------------
3141 // wxDataViewColumn
3142 // ---------------------------------------------------------
3143
3144 wxDataViewColumn::wxDataViewColumn(const wxString& title,
3145                                    wxDataViewRenderer* renderer,
3146                                    unsigned int model_column,
3147                                    int width,
3148                                    wxAlignment align,
3149                                    int flags)
3150      : wxDataViewColumnBase(renderer, model_column),
3151        m_NativeDataPtr(new wxDataViewColumnNativeData()),
3152        m_title(title)
3153 {
3154     InitCommon(width, align, flags);
3155     if (renderer && !renderer->IsCustomRenderer() &&
3156         (renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
3157         renderer->SetAlignment(align);
3158 }
3159
3160 wxDataViewColumn::wxDataViewColumn(const wxBitmap& bitmap,
3161                                    wxDataViewRenderer* renderer,
3162                                    unsigned int model_column,
3163                                    int width,
3164                                    wxAlignment align,
3165                                    int flags)
3166     : wxDataViewColumnBase(bitmap, renderer, model_column),
3167       m_NativeDataPtr(new wxDataViewColumnNativeData())
3168 {
3169     InitCommon(width, align, flags);
3170     if (renderer && !renderer->IsCustomRenderer() &&
3171         (renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
3172         renderer->SetAlignment(align);
3173 }
3174
3175 wxDataViewColumn::~wxDataViewColumn()
3176 {
3177     delete m_NativeDataPtr;
3178 }
3179
3180 int wxDataViewColumn::GetWidth() const
3181 {
3182     return [m_NativeDataPtr->GetNativeColumnPtr() width];
3183 }
3184
3185 bool wxDataViewColumn::IsSortKey() const
3186 {
3187     NSTableColumn *nsCol = GetNativeData()->GetNativeColumnPtr();
3188     return nsCol && ([nsCol sortDescriptorPrototype] != nil);
3189 }
3190
3191 void wxDataViewColumn::SetAlignment(wxAlignment align)
3192 {
3193     m_alignment = align;
3194     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setAlignment:ConvertToNativeHorizontalTextAlignment(align)];
3195     if (m_renderer && !m_renderer->IsCustomRenderer() &&
3196         (m_renderer->GetAlignment() == wxDVR_DEFAULT_ALIGNMENT))
3197         m_renderer->SetAlignment(align);
3198 }
3199
3200 void wxDataViewColumn::SetBitmap(const wxBitmap& bitmap)
3201 {
3202     // bitmaps and titles cannot exist at the same time - if the bitmap is set
3203     // the title is removed:
3204     m_title = wxEmptyString;
3205     wxDataViewColumnBase::SetBitmap(bitmap);
3206     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setImage:[[bitmap.GetNSImage() retain] autorelease]];
3207 }
3208
3209 void wxDataViewColumn::SetMaxWidth(int maxWidth)
3210 {
3211     m_maxWidth = maxWidth;
3212     [m_NativeDataPtr->GetNativeColumnPtr() setMaxWidth:maxWidth];
3213 }
3214
3215 void wxDataViewColumn::SetMinWidth(int minWidth)
3216 {
3217     m_minWidth = minWidth;
3218     [m_NativeDataPtr->GetNativeColumnPtr() setMinWidth:minWidth];
3219 }
3220
3221 void wxDataViewColumn::SetReorderable(bool reorderable)
3222 {
3223     wxUnusedVar(reorderable);
3224 }
3225
3226 void wxDataViewColumn::SetHidden(bool hidden)
3227 {
3228     // How to set flag here?
3229
3230     [m_NativeDataPtr->GetNativeColumnPtr() setHidden:hidden];
3231 }
3232
3233 bool wxDataViewColumn::IsHidden() const
3234 {
3235     return [m_NativeDataPtr->GetNativeColumnPtr() isHidden];
3236 }
3237
3238 void wxDataViewColumn::SetResizeable(bool resizable)
3239 {
3240     wxDataViewColumnBase::SetResizeable(resizable);
3241     if (resizable)
3242         [m_NativeDataPtr->GetNativeColumnPtr() setResizingMask:NSTableColumnUserResizingMask];
3243     else
3244         [m_NativeDataPtr->GetNativeColumnPtr() setResizingMask:NSTableColumnNoResizing];
3245 }
3246
3247 void wxDataViewColumn::SetSortable(bool sortable)
3248 {
3249     // wxDataViewColumnBase::SetSortable(sortable);
3250     // Avoid endless recursion and just set the flag here
3251     if (sortable)
3252         m_flags |= wxDATAVIEW_COL_SORTABLE;
3253     else
3254         m_flags &= ~wxDATAVIEW_COL_SORTABLE;
3255 }
3256
3257 void wxDataViewColumn::SetSortOrder(bool ascending)
3258 {
3259     if (m_ascending != ascending)
3260     {
3261         m_ascending = ascending;
3262         if (IsSortKey())
3263         {
3264             // change sorting order:
3265             NSArray*          sortDescriptors;
3266             NSSortDescriptor* sortDescriptor;
3267             NSTableColumn*    tableColumn;
3268
3269             tableColumn     = m_NativeDataPtr->GetNativeColumnPtr();
3270             sortDescriptor  = [[NSSortDescriptor alloc] initWithKey:[[tableColumn sortDescriptorPrototype] key] ascending:m_ascending];
3271             sortDescriptors = [NSArray arrayWithObject:sortDescriptor];
3272             [tableColumn setSortDescriptorPrototype:sortDescriptor];
3273             [[tableColumn tableView] setSortDescriptors:sortDescriptors];
3274             [sortDescriptor release];
3275         }
3276     }
3277 }
3278
3279 void wxDataViewColumn::SetTitle(const wxString& title)
3280 {
3281     // bitmaps and titles cannot exist at the same time - if the title is set
3282     // the bitmap is removed:
3283     wxDataViewColumnBase::SetBitmap(wxBitmap());
3284     m_title = title;
3285     [[m_NativeDataPtr->GetNativeColumnPtr() headerCell] setStringValue:[[wxCFStringRef(title).AsNSString() retain] autorelease]];
3286 }
3287
3288 void wxDataViewColumn::SetWidth(int width)
3289 {
3290     m_width = width;
3291
3292     switch ( width )
3293     {
3294         case wxCOL_WIDTH_AUTOSIZE:
3295 #if MAC_OS_X_VERSION_MIN_REQUIRED >= MAC_OS_X_VERSION_10_5
3296             if ( GetOwner() )
3297             {
3298                 wxCocoaDataViewControl *peer = static_cast<wxCocoaDataViewControl*>(GetOwner()->GetPeer());
3299                 peer->FitColumnWidthToContent(GetOwner()->GetColumnPosition(this));
3300                 break;
3301             }
3302 #endif
3303             // fall through if unsupported (OSX < 10.5) or not yet settable
3304
3305         case wxCOL_WIDTH_DEFAULT:
3306             width = wxDVC_DEFAULT_WIDTH;
3307             // fall through
3308
3309         default:
3310             [m_NativeDataPtr->GetNativeColumnPtr() setWidth:width];
3311             break;
3312     }
3313 }
3314
3315 void wxDataViewColumn::SetNativeData(wxDataViewColumnNativeData* newNativeDataPtr)
3316 {
3317     delete m_NativeDataPtr;
3318     m_NativeDataPtr = newNativeDataPtr;
3319 }
3320
3321 #endif // (wxUSE_DATAVIEWCTRL == 1) && !defined(wxUSE_GENERICDATAVIEWCTRL)