[wxWidgets.git] / wxwin.m4

dnl ---------------------------------------------------------------------------
dnl Macros for wxWindows detection. Typically used in configure.in as:
dnl
dnl     AC_ARG_ENABLE(...)
dnl     AC_ARG_WITH(...)
dnl        ...
dnl     AM_OPTIONS_WXCONFIG
dnl        ...
dnl        ...
dnl     AM_PATH_WXCONFIG(2.3.4, wxWin=1)
dnl     if test "$wxWin" != 1; then
dnl        AC_MSG_ERROR([
dnl                wxWindows must be installed on your system
dnl                but wx-config script couldn't be found.
dnl
dnl                Please check that wx-config is in path, the directory
dnl                where wxWindows libraries are installed (returned by
dnl                'wx-config --libs' command) is in LD_LIBRARY_PATH or
dnl                equivalent variable and wxWindows version is 2.3.4 or above.
dnl        ])
dnl     fi
dnl     CPPFLAGS="$CPPFLAGS $WX_CPPFLAGS"
dnl     CXXFLAGS="$CXXFLAGS $WX_CXXFLAGS_ONLY"
dnl     CFLAGS="$CFLAGS $WX_CFLAGS_ONLY"
dnl
dnl     LDFLAGS="$LDFLAGS $WX_LIBS"
dnl ---------------------------------------------------------------------------

dnl ---------------------------------------------------------------------------
dnl AM_OPTIONS_WXCONFIG
dnl
dnl adds support for --wx-prefix, --wx-exec-prefix, --with-wxdir and
dnl --wx-config command line options
dnl ---------------------------------------------------------------------------

AC_DEFUN([AM_OPTIONS_WXCONFIG],
[
    AC_ARG_WITH(wxdir,
                [  --with-wxdir=PATH       Use uninstalled version of wxWindows in PATH],
                [ wx_config_name="$withval/wx-config"
                  wx_config_args="--inplace"])
    AC_ARG_WITH(wx-config,
                [  --with-wx-config=CONFIG wx-config script to use (optional)],
                wx_config_name="$withval" )
    AC_ARG_WITH(wx-prefix,
                [  --with-wx-prefix=PREFIX Prefix where wxWindows is installed (optional)],
                wx_config_prefix="$withval", wx_config_prefix="")
    AC_ARG_WITH(wx-exec-prefix,
                [  --with-wx-exec-prefix=PREFIX
                          Exec prefix where wxWindows is installed (optional)],
                wx_config_exec_prefix="$withval", wx_config_exec_prefix="")
])

dnl ---------------------------------------------------------------------------
dnl AM_PATH_WXCONFIG(VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
dnl                  [, WX-LIBS [, ADDITIONAL-WX-CONFIG-FLAGS]]]])
dnl
dnl Test for wxWindows, and define WX_C*FLAGS, WX_LIBS and WX_LIBS_STATIC
dnl (the latter is for static linking against wxWindows). Set WX_CONFIG_NAME
dnl environment variable to override the default name of the wx-config script
dnl to use. Set WX_CONFIG_PATH to specify the full path to wx-config - in this
dnl case the macro won't even waste time on tests for its existence.
dnl
dnl Optional WX-LIBS argument contains comma- or space-separated list of
dnl wxWindows libraries to link against (it may include contrib libraries). If
dnl it is not specified then WX_LIBS and WX_LIBS_STATIC will contain flags to
dnl link with all of the core wxWindows libraries.
dnl
dnl Optional ADDITIONAL-WX-CONFIG-FLAGS argument is appended to wx-config
dnl invocation command in present. It can be used to fine-tune lookup of
dnl best wxWidgets build available.
dnl
dnl Example use:
dnl   AM_PATH_WXCONFIG([2.6.0], [wxWin=1], [wxWin=0], [html,core,net]
dnl                    [--unicode --debug])
dnl ---------------------------------------------------------------------------

dnl
dnl Get the cflags and libraries from the wx-config script
dnl
AC_DEFUN([AM_PATH_WXCONFIG],
[
  dnl do we have wx-config name: it can be wx-config or wxd-config or ...
  if test x${WX_CONFIG_NAME+set} != xset ; then
     WX_CONFIG_NAME=wx-config
  fi

  if test "x$wx_config_name" != x ; then
     WX_CONFIG_NAME="$wx_config_name"
  fi

  dnl deal with optional prefixes
  if test x$wx_config_exec_prefix != x ; then
     wx_config_args="$wx_config_args --exec-prefix=$wx_config_exec_prefix"
     WX_LOOKUP_PATH="$wx_config_exec_prefix/bin"
  fi
  if test x$wx_config_prefix != x ; then
     wx_config_args="$wx_config_args --prefix=$wx_config_prefix"
     WX_LOOKUP_PATH="$WX_LOOKUP_PATH:$wx_config_prefix/bin"
  fi
  if test "$cross_compiling" = "yes"; then
     wx_config_args="$wx_config_args --host=$host_alias"
  fi

  dnl don't search the PATH if WX_CONFIG_NAME is absolute filename
  if test -x "$WX_CONFIG_NAME" ; then
     AC_MSG_CHECKING(for wx-config)
     WX_CONFIG_PATH="$WX_CONFIG_NAME"
     AC_MSG_RESULT($WX_CONFIG_PATH)
  else
     AC_PATH_PROG(WX_CONFIG_PATH, $WX_CONFIG_NAME, no, "$WX_LOOKUP_PATH:$PATH")
  fi

  if test "$WX_CONFIG_PATH" != "no" ; then
    WX_VERSION=""
    no_wx=""

    min_wx_version=ifelse([$1], ,2.2.1,$1)
    if test -z "$5" ; then
      AC_MSG_CHECKING([for wxWindows version >= $min_wx_version])
    else
      AC_MSG_CHECKING([for wxWindows version >= $min_wx_version ($5)])
    fi

    WX_CONFIG_WITH_ARGS="$WX_CONFIG_PATH $wx_config_args $5 $4"

    WX_VERSION=`$WX_CONFIG_WITH_ARGS --version 2>/dev/null`
    wx_config_major_version=`echo $WX_VERSION | \
           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
    wx_config_minor_version=`echo $WX_VERSION | \
           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
    wx_config_micro_version=`echo $WX_VERSION | \
           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`

    wx_requested_major_version=`echo $min_wx_version | \
           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
    wx_requested_minor_version=`echo $min_wx_version | \
           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
    wx_requested_micro_version=`echo $min_wx_version | \
           sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`

    wx_ver_ok=""
    if test "x$WX_VERSION" != x ; then
      if test $wx_config_major_version -gt $wx_requested_major_version; then
        wx_ver_ok=yes
      else
        if test $wx_config_major_version -eq $wx_requested_major_version; then
           if test $wx_config_minor_version -gt $wx_requested_minor_version; then
              wx_ver_ok=yes
           else
              if test $wx_config_minor_version -eq $wx_requested_minor_version; then
                 if test $wx_config_micro_version -ge $wx_requested_micro_version; then
                    wx_ver_ok=yes
                 fi
              fi
           fi
        fi
      fi
    fi

    if test "x$wx_ver_ok" = x ; then
      no_wx=yes
    else
      WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs`
      WX_LIBS_STATIC=`$WX_CONFIG_WITH_ARGS --static --libs`

      dnl starting with version 2.2.6 wx-config has --cppflags argument
      wx_has_cppflags=""
      if test $wx_config_major_version -gt 2; then
        wx_has_cppflags=yes
      else
        if test $wx_config_major_version -eq 2; then
           if test $wx_config_minor_version -gt 2; then
              wx_has_cppflags=yes
           else
              if test $wx_config_minor_version -eq 2; then
                 if test $wx_config_micro_version -ge 6; then
                    wx_has_cppflags=yes
                 fi
              fi
           fi
        fi
      fi

      if test "x$wx_has_cppflags" = x ; then
         dnl no choice but to define all flags like CFLAGS
         WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags`
         WX_CPPFLAGS=$WX_CFLAGS
         WX_CXXFLAGS=$WX_CFLAGS

         WX_CFLAGS_ONLY=$WX_CFLAGS
         WX_CXXFLAGS_ONLY=$WX_CFLAGS
      else
         dnl we have CPPFLAGS included in CFLAGS included in CXXFLAGS
         WX_CPPFLAGS=`$WX_CONFIG_WITH_ARGS --cppflags`
         WX_CXXFLAGS=`$WX_CONFIG_WITH_ARGS --cxxflags`
         WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags`

         WX_CFLAGS_ONLY=`echo $WX_CFLAGS | sed "s@^$WX_CPPFLAGS *@@"`
         WX_CXXFLAGS_ONLY=`echo $WX_CXXFLAGS | sed "s@^$WX_CFLAGS *@@"`
      fi
    fi

    if test "x$no_wx" = x ; then
       AC_MSG_RESULT(yes (version $WX_VERSION))
       ifelse([$2], , :, [$2])
    else
       if test "x$WX_VERSION" = x; then
          dnl no wx-config at all
          AC_MSG_RESULT(no)
       else
          AC_MSG_RESULT(no (version $WX_VERSION is not new enough))
       fi

       WX_CFLAGS=""
       WX_CPPFLAGS=""
       WX_CXXFLAGS=""
       WX_LIBS=""
       WX_LIBS_STATIC=""
       ifelse([$3], , :, [$3])
    fi
  fi

  AC_SUBST(WX_CPPFLAGS)
  AC_SUBST(WX_CFLAGS)
  AC_SUBST(WX_CXXFLAGS)
  AC_SUBST(WX_CFLAGS_ONLY)
  AC_SUBST(WX_CXXFLAGS_ONLY)
  AC_SUBST(WX_LIBS)
  AC_SUBST(WX_LIBS_STATIC)
  AC_SUBST(WX_VERSION)
])
Commit	Line	Data
debc175a VS	1	dnl ---------------------------------------------------------------------------
	2	dnl Macros for wxWindows detection. Typically used in configure.in as:
	3	dnl
5ff72dc4 VZ	4	dnl AC_ARG_ENABLE(...)
	5	dnl AC_ARG_WITH(...)
	6	dnl ...
	7	dnl AM_OPTIONS_WXCONFIG
	8	dnl ...
	9	dnl ...
	10	dnl AM_PATH_WXCONFIG(2.3.4, wxWin=1)
debc175a VS	11	dnl if test "$wxWin" != 1; then
debc175a VS	12	dnl AC_MSG_ERROR([
5ff72dc4 VZ	13	dnl wxWindows must be installed on your system
	14	dnl but wx-config script couldn't be found.
	15	dnl
	16	dnl Please check that wx-config is in path, the directory
	17	dnl where wxWindows libraries are installed (returned by
	18	dnl 'wx-config --libs' command) is in LD_LIBRARY_PATH or
	19	dnl equivalent variable and wxWindows version is 2.3.4 or above.
debc175a VS	20	dnl ])
	21	dnl fi
	22	dnl CPPFLAGS="$CPPFLAGS $WX_CPPFLAGS"
	23	dnl CXXFLAGS="$CXXFLAGS $WX_CXXFLAGS_ONLY"
	24	dnl CFLAGS="$CFLAGS $WX_CFLAGS_ONLY"
5ff72dc4	25	dnl
debc175a VS	26	dnl LDFLAGS="$LDFLAGS $WX_LIBS"
	27	dnl ---------------------------------------------------------------------------
	28
	29	dnl ---------------------------------------------------------------------------
	30	dnl AM_OPTIONS_WXCONFIG
	31	dnl
5ff72dc4 VZ	32	dnl adds support for --wx-prefix, --wx-exec-prefix, --with-wxdir and
5ff72dc4 VZ	33	dnl --wx-config command line options
debc175a VS	34	dnl ---------------------------------------------------------------------------
debc175a VS	35
79f8a0d8	36	AC_DEFUN([AM_OPTIONS_WXCONFIG],
debc175a	37	[
5ff72dc4 VZ	38	AC_ARG_WITH(wxdir,
	39	[ --with-wxdir=PATH Use uninstalled version of wxWindows in PATH],
	40	[ wx_config_name="$withval/wx-config"
	41	wx_config_args="--inplace"])
	42	AC_ARG_WITH(wx-config,
	43	[ --with-wx-config=CONFIG wx-config script to use (optional)],
	44	wx_config_name="$withval" )
	45	AC_ARG_WITH(wx-prefix,
	46	[ --with-wx-prefix=PREFIX Prefix where wxWindows is installed (optional)],
	47	wx_config_prefix="$withval", wx_config_prefix="")
	48	AC_ARG_WITH(wx-exec-prefix,
	49	[ --with-wx-exec-prefix=PREFIX
	50	Exec prefix where wxWindows is installed (optional)],
	51	wx_config_exec_prefix="$withval", wx_config_exec_prefix="")
debc175a VS	52	])
	53
	54	dnl ---------------------------------------------------------------------------
c5be79d9	55	dnl AM_PATH_WXCONFIG(VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
8708fa76	56	dnl [, WX-LIBS [, ADDITIONAL-WX-CONFIG-FLAGS]]]])
debc175a VS	57	dnl
	58	dnl Test for wxWindows, and define WX_C*FLAGS, WX_LIBS and WX_LIBS_STATIC
	59	dnl (the latter is for static linking against wxWindows). Set WX_CONFIG_NAME
	60	dnl environment variable to override the default name of the wx-config script
	61	dnl to use. Set WX_CONFIG_PATH to specify the full path to wx-config - in this
	62	dnl case the macro won't even waste time on tests for its existence.
c5be79d9	63	dnl
8708fa76 VS	64	dnl Optional WX-LIBS argument contains comma- or space-separated list of
	65	dnl wxWindows libraries to link against (it may include contrib libraries). If
	66	dnl it is not specified then WX_LIBS and WX_LIBS_STATIC will contain flags to
	67	dnl link with all of the core wxWindows libraries.
	68	dnl
	69	dnl Optional ADDITIONAL-WX-CONFIG-FLAGS argument is appended to wx-config
	70	dnl invocation command in present. It can be used to fine-tune lookup of
	71	dnl best wxWidgets build available.
c5be79d9 VS	72	dnl
c5be79d9 VS	73	dnl Example use:
8708fa76 VS	74	dnl AM_PATH_WXCONFIG([2.6.0], [wxWin=1], [wxWin=0], [html,core,net]
8708fa76 VS	75	dnl [--unicode --debug])
debc175a VS	76	dnl ---------------------------------------------------------------------------
	77
	78	dnl
	79	dnl Get the cflags and libraries from the wx-config script
	80	dnl
79f8a0d8	81	AC_DEFUN([AM_PATH_WXCONFIG],
debc175a VS	82	[
	83	dnl do we have wx-config name: it can be wx-config or wxd-config or ...
	84	if test x${WX_CONFIG_NAME+set} != xset ; then
	85	WX_CONFIG_NAME=wx-config
	86	fi
5ff72dc4	87
debc175a VS	88	if test "x$wx_config_name" != x ; then
	89	WX_CONFIG_NAME="$wx_config_name"
	90	fi
	91
	92	dnl deal with optional prefixes
	93	if test x$wx_config_exec_prefix != x ; then
	94	wx_config_args="$wx_config_args --exec-prefix=$wx_config_exec_prefix"
8e1aefe0	95	WX_LOOKUP_PATH="$wx_config_exec_prefix/bin"
debc175a VS	96	fi
	97	if test x$wx_config_prefix != x ; then
	98	wx_config_args="$wx_config_args --prefix=$wx_config_prefix"
8e1aefe0	99	WX_LOOKUP_PATH="$WX_LOOKUP_PATH:$wx_config_prefix/bin"
debc175a	100	fi
48112931 VS	101	if test "$cross_compiling" = "yes"; then
	102	wx_config_args="$wx_config_args --host=$host_alias"
	103	fi
debc175a	104
8e1aefe0 VS	105	dnl don't search the PATH if WX_CONFIG_NAME is absolute filename
	106	if test -x "$WX_CONFIG_NAME" ; then
	107	AC_MSG_CHECKING(for wx-config)
	108	WX_CONFIG_PATH="$WX_CONFIG_NAME"
	109	AC_MSG_RESULT($WX_CONFIG_PATH)
	110	else
	111	AC_PATH_PROG(WX_CONFIG_PATH, $WX_CONFIG_NAME, no, "$WX_LOOKUP_PATH:$PATH")
debc175a VS	112	fi
	113
	114	if test "$WX_CONFIG_PATH" != "no" ; then
	115	WX_VERSION=""
	116	no_wx=""
	117
	118	min_wx_version=ifelse([$1], ,2.2.1,$1)
8708fa76 VS	119	if test -z "$5" ; then
	120	AC_MSG_CHECKING([for wxWindows version >= $min_wx_version])
	121	else
	122	AC_MSG_CHECKING([for wxWindows version >= $min_wx_version ($5)])
	123	fi
debc175a	124
8708fa76	125	WX_CONFIG_WITH_ARGS="$WX_CONFIG_PATH $wx_config_args $5 $4"
debc175a	126
8708fa76	127	WX_VERSION=`$WX_CONFIG_WITH_ARGS --version 2>/dev/null`
debc175a VS	128	wx_config_major_version=`echo $WX_VERSION \| \
	129	sed 's/\([[0-9]]\).\([[0-9]]\).\([[0-9]]*\)/\1/'`
	130	wx_config_minor_version=`echo $WX_VERSION \| \
	131	sed 's/\([[0-9]]\).\([[0-9]]\).\([[0-9]]*\)/\2/'`
	132	wx_config_micro_version=`echo $WX_VERSION \| \
	133	sed 's/\([[0-9]]\).\([[0-9]]\).\([[0-9]]*\)/\3/'`
	134
	135	wx_requested_major_version=`echo $min_wx_version \| \
	136	sed 's/\([[0-9]]\).\([[0-9]]\).\([[0-9]]*\)/\1/'`
	137	wx_requested_minor_version=`echo $min_wx_version \| \
	138	sed 's/\([[0-9]]\).\([[0-9]]\).\([[0-9]]*\)/\2/'`
	139	wx_requested_micro_version=`echo $min_wx_version \| \
	140	sed 's/\([[0-9]]\).\([[0-9]]\).\([[0-9]]*\)/\3/'`
	141
	142	wx_ver_ok=""
8708fa76 VS	143	if test "x$WX_VERSION" != x ; then
	144	if test $wx_config_major_version -gt $wx_requested_major_version; then
	145	wx_ver_ok=yes
	146	else
	147	if test $wx_config_major_version -eq $wx_requested_major_version; then
	148	if test $wx_config_minor_version -gt $wx_requested_minor_version; then
	149	wx_ver_ok=yes
	150	else
	151	if test $wx_config_minor_version -eq $wx_requested_minor_version; then
	152	if test $wx_config_micro_version -ge $wx_requested_micro_version; then
	153	wx_ver_ok=yes
	154	fi
	155	fi
	156	fi
	157	fi
debc175a VS	158	fi
	159	fi
	160
	161	if test "x$wx_ver_ok" = x ; then
	162	no_wx=yes
	163	else
8708fa76 VS	164	WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs`
8708fa76 VS	165	WX_LIBS_STATIC=`$WX_CONFIG_WITH_ARGS --static --libs`
debc175a VS	166
	167	dnl starting with version 2.2.6 wx-config has --cppflags argument
	168	wx_has_cppflags=""
	169	if test $wx_config_major_version -gt 2; then
	170	wx_has_cppflags=yes
	171	else
	172	if test $wx_config_major_version -eq 2; then
	173	if test $wx_config_minor_version -gt 2; then
	174	wx_has_cppflags=yes
	175	else
	176	if test $wx_config_minor_version -eq 2; then
	177	if test $wx_config_micro_version -ge 6; then
	178	wx_has_cppflags=yes
	179	fi
	180	fi
	181	fi
	182	fi
	183	fi
	184
	185	if test "x$wx_has_cppflags" = x ; then
	186	dnl no choice but to define all flags like CFLAGS
	187	WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags`
	188	WX_CPPFLAGS=$WX_CFLAGS
	189	WX_CXXFLAGS=$WX_CFLAGS
	190
	191	WX_CFLAGS_ONLY=$WX_CFLAGS
	192	WX_CXXFLAGS_ONLY=$WX_CFLAGS
	193	else
	194	dnl we have CPPFLAGS included in CFLAGS included in CXXFLAGS
	195	WX_CPPFLAGS=`$WX_CONFIG_WITH_ARGS --cppflags`
	196	WX_CXXFLAGS=`$WX_CONFIG_WITH_ARGS --cxxflags`
	197	WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags`
	198
	199	WX_CFLAGS_ONLY=`echo $WX_CFLAGS \| sed "s@^$WX_CPPFLAGS *@@"`
	200	WX_CXXFLAGS_ONLY=`echo $WX_CXXFLAGS \| sed "s@^$WX_CFLAGS *@@"`
	201	fi
	202	fi
	203
	204	if test "x$no_wx" = x ; then
	205	AC_MSG_RESULT(yes (version $WX_VERSION))
	206	ifelse([$2], , :, [$2])
	207	else
	208	if test "x$WX_VERSION" = x; then
5ff72dc4 VZ	209	dnl no wx-config at all
5ff72dc4 VZ	210	AC_MSG_RESULT(no)
debc175a	211	else
5ff72dc4	212	AC_MSG_RESULT(no (version $WX_VERSION is not new enough))
debc175a VS	213	fi
	214
	215	WX_CFLAGS=""
	216	WX_CPPFLAGS=""
	217	WX_CXXFLAGS=""
	218	WX_LIBS=""
	219	WX_LIBS_STATIC=""
	220	ifelse([$3], , :, [$3])
	221	fi
	222	fi
	223
	224	AC_SUBST(WX_CPPFLAGS)
	225	AC_SUBST(WX_CFLAGS)
	226	AC_SUBST(WX_CXXFLAGS)
	227	AC_SUBST(WX_CFLAGS_ONLY)
	228	AC_SUBST(WX_CXXFLAGS_ONLY)
	229	AC_SUBST(WX_LIBS)
	230	AC_SUBST(WX_LIBS_STATIC)
	231	AC_SUBST(WX_VERSION)
	232	])