CyteKit/dispatchEvent.mm

   1 /* Cydia - iPhone UIKit Front-End for Debian APT
   2  * Copyright (C) 2008-2011  Jay Freeman (saurik)
   3 */
   4
   5 /* Modified BSD License {{{ */
   6 /*
   7  *        Redistribution and use in source and binary
   8  * forms, with or without modification, are permitted
   9  * provided that the following conditions are met:
  10  *
  11  * 1. Redistributions of source code must retain the
  12  *    above copyright notice, this list of conditions
  13  *    and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the
  15  *    above copyright notice, this list of conditions
  16  *    and the following disclaimer in the documentation
  17  *    and/or other materials provided with the
  18  *    distribution.
  19  * 3. The name of the author may not be used to endorse
  20  *    or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
  24  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
  25  * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
  28  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29  * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  30  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  31  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  33  * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
  34  * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  35  * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  36  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  37 */
  38 /* }}} */
  39
  40 #include "CyteKit/dispatchEvent.h"
  41 #include "CyteKit/WebThreadLocked.hpp"
  42
  43 #include <WebKit/WebFrame.h>
  44 #include <WebKit/WebScriptObject.h>
  45 #include <WebKit/WebView.h>
  46
  47 #include <objc/runtime.h>
  48
  49 #include <CydiaSubstrate/CydiaSubstrate.h>
  50
  51 @implementation UIWebDocumentView (CyteDispatchEvent)
  52
  53 - (void) dispatchEvent:(NSString *)event {
  54     WebThreadLocked lock;
  55
  56     NSString *script([NSString stringWithFormat:@
  57         "(function() {"
  58             "var event = this.document.createEvent('Events');"
  59             "event.initEvent('%@', false, false);"
  60             "this.document.dispatchEvent(event);"
  61         "})();"
  62     , event]);
  63
  64     NSMutableArray *frames([NSMutableArray arrayWithObjects:
  65         [[self webView] mainFrame]
  66     , nil]);
  67
  68     while (WebFrame *frame = [frames lastObject]) {
  69         WebScriptObject *object([frame windowObject]);
  70         [object evaluateWebScript:script];
  71         [frames removeLastObject];
  72         [frames addObjectsFromArray:[frame childFrames]];
  73     }
  74 }
  75
  76 @end
  77
  78 MSHook(void, UIWebBrowserView$_webTouchEventsRecognized$, UIWebBrowserView *self, SEL _cmd, UIWebTouchEventsGestureRecognizer *recognizer) {
  79     _UIWebBrowserView$_webTouchEventsRecognized$(self, _cmd, recognizer);
  80
  81     if ([recognizer type] == 8)
  82     //if ([[recognizer _typeDescription] isEqualToString:@"WebEventTouchEnd"])
  83         [self dispatchEvent:@"CydiaTouchEnd"];
  84 }
  85
  86 __attribute__((__constructor__)) static void $() {
  87     if (Class $UIWebBrowserView = objc_getClass("UIWebBrowserView")) {
  88         if (Method method = class_getInstanceMethod($UIWebBrowserView, @selector(_webTouchEventsRecognized:))) {
  89             _UIWebBrowserView$_webTouchEventsRecognized$ = reinterpret_cast<void (*)(UIWebBrowserView *, SEL, id)>(method_getImplementation(method));
  90             method_setImplementation(method, reinterpret_cast<IMP>(&$UIWebBrowserView$_webTouchEventsRecognized$));
  91         }
  92     }
  93 }