Cydia/MIMEAddress.mm

   1 /* Cydia - iPhone UIKit Front-End for Debian APT
   2  * Copyright (C) 2008-2015  Jay Freeman (saurik)
   3 */
   4
   5 /* GNU General Public License, Version 3 {{{ */
   6 /*
   7  * Cydia is free software: you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published
   9  * by the Free Software Foundation, either version 3 of the License,
  10  * or (at your option) any later version.
  11  *
  12  * Cydia is distributed in the hope that it will be useful, but
  13  * WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with Cydia.  If not, see <http://www.gnu.org/licenses/>.
  19 **/
  20 /* }}} */
  21
  22 #include "Cydia/MIMEAddress.h"
  23
  24 #include <WebKit/WebScriptObject.h>
  25
  26 #include "CyteKit/RegEx.hpp"
  27
  28 @implementation MIMEAddress
  29
  30 - (NSString *) name {
  31     return name_;
  32 }
  33
  34 - (NSString *) address {
  35     return address_;
  36 }
  37
  38 - (void) setAddress:(NSString *)address {
  39     address_ = address;
  40 }
  41
  42 + (MIMEAddress *) addressWithString:(NSString *)string {
  43     return [[[MIMEAddress alloc] initWithString:string] autorelease];
  44 }
  45
  46 + (NSArray *) _attributeKeys {
  47     return [NSArray arrayWithObjects:
  48         @"address",
  49         @"name",
  50     nil];
  51 }
  52
  53 - (NSArray *) attributeKeys {
  54     return [[self class] _attributeKeys];
  55 }
  56
  57 + (BOOL) isKeyExcludedFromWebScript:(const char *)name {
  58     return ![[self _attributeKeys] containsObject:[NSString stringWithUTF8String:name]] && [super isKeyExcludedFromWebScript:name];
  59 }
  60
  61 - (id) initWithString:(NSString *)string {
  62     if ((self = [super init]) != nil) {
  63         const char *data = [string UTF8String];
  64         size_t size = [string lengthOfBytesUsingEncoding:NSUTF8StringEncoding];
  65
  66         static RegEx address_r("\"?(.*)\"? <([^>]*)>");
  67
  68         if (address_r(data, size)) {
  69             name_ = address_r[1];
  70             address_ = address_r[2];
  71         } else {
  72             name_ = string;
  73             address_ = nil;
  74         }
  75     } return self;
  76 }
  77
  78 @end