CyteKit/WebViewController.mm

   1 #include "CyteKit/UCPlatform.h"
   2 #include "CyteKit/WebViewController.h"
   3
   4 #include "CyteKit/MFMailComposeViewController-MailToURL.h"
   5
   6 #include "iPhonePrivate.h"
   7
   8 #include "CyteKit/Localize.h"
   9 #include "CyteKit/WebViewController.h"
  10 #include "CyteKit/PerlCompatibleRegEx.hpp"
  11 #include "CyteKit/WebThreadLocked.hpp"
  12
  13 //#include <QuartzCore/CALayer.h>
  14 // XXX: fix the minimum requirement
  15 extern NSString * const kCAFilterNearest;
  16
  17 #include <WebCore/WebCoreThread.h>
  18
  19 #include <WebKit/WebKitErrors.h>
  20 #include <WebKit/WebPreferences.h>
  21
  22 #include <WebKit/DOMCSSPrimitiveValue.h>
  23 #include <WebKit/DOMCSSStyleDeclaration.h>
  24 #include <WebKit/DOMDocument.h>
  25 #include <WebKit/DOMHTMLBodyElement.h>
  26 #include <WebKit/DOMRGBColor.h>
  27
  28 #include <dlfcn.h>
  29 #include <objc/runtime.h>
  30
  31 #define ForSaurik 0
  32 #define DefaultTimeout_ 120.0
  33
  34 #define ShowInternals 0
  35 #define LogBrowser 0
  36 #define LogMessages 0
  37
  38 #define lprintf(args...) fprintf(stderr, args)
  39
  40 // XXX: centralize these special class things to some file or mechanism?
  41 static Class $MFMailComposeViewController;
  42
  43 float CYScrollViewDecelerationRateNormal;
  44
  45 @interface WebView (Apple)
  46 - (void) _setLayoutInterval:(float)interval;
  47 - (void) _setAllowsMessaging:(BOOL)allows;
  48 @end
  49
  50 @interface WebPreferences (Apple)
  51 + (void) _setInitialDefaultTextEncodingToSystemEncoding;
  52 - (void) _setLayoutInterval:(NSInteger)interval;
  53 - (void) setOfflineWebApplicationCacheEnabled:(BOOL)enabled;
  54 @end
  55
  56 @implementation WebFrame (Cydia)
  57
  58 - (NSString *) description {
  59     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[[([self provisionalDataSource] ?: [self dataSource]) request] URL] absoluteString]];
  60 }
  61
  62 @end
  63
  64 /* Indirect Delegate {{{ */
  65 @interface IndirectDelegate : NSObject {
  66     _transient volatile id delegate_;
  67 }
  68
  69 - (void) setDelegate:(id)delegate;
  70 - (id) initWithDelegate:(id)delegate;
  71 @end
  72
  73 @implementation IndirectDelegate
  74
  75 - (void) setDelegate:(id)delegate {
  76     delegate_ = delegate;
  77 }
  78
  79 - (id) initWithDelegate:(id)delegate {
  80     delegate_ = delegate;
  81     return self;
  82 }
  83
  84 - (IMP) methodForSelector:(SEL)sel {
  85     if (IMP method = [super methodForSelector:sel])
  86         return method;
  87     fprintf(stderr, "methodForSelector:[%s] == NULL\n", sel_getName(sel));
  88     return NULL;
  89 }
  90
  91 - (BOOL) respondsToSelector:(SEL)sel {
  92     if ([super respondsToSelector:sel])
  93         return YES;
  94
  95     // XXX: WebThreadCreateNSInvocation returns nil
  96
  97 #if ShowInternals
  98     fprintf(stderr, "[%s]R?%s\n", class_getName(self->isa), sel_getName(sel));
  99 #endif
 100
 101     return delegate_ == nil ? NO : [delegate_ respondsToSelector:sel];
 102 }
 103
 104 - (NSMethodSignature *) methodSignatureForSelector:(SEL)sel {
 105     if (NSMethodSignature *method = [super methodSignatureForSelector:sel])
 106         return method;
 107
 108 #if ShowInternals
 109     fprintf(stderr, "[%s]S?%s\n", class_getName(self->isa), sel_getName(sel));
 110 #endif
 111
 112     if (delegate_ != nil)
 113         if (NSMethodSignature *sig = [delegate_ methodSignatureForSelector:sel])
 114             return sig;
 115
 116     // XXX: I fucking hate Apple so very very bad
 117     return [NSMethodSignature signatureWithObjCTypes:"v@:"];
 118 }
 119
 120 - (void) forwardInvocation:(NSInvocation *)inv {
 121     SEL sel = [inv selector];
 122     if (delegate_ != nil && [delegate_ respondsToSelector:sel])
 123         [inv invokeWithTarget:delegate_];
 124 }
 125
 126 @end
 127 /* }}} */
 128
 129 @implementation CyteWebViewController
 130
 131 #if ShowInternals
 132 #include "CyteKit/UCInternal.h"
 133 #endif
 134
 135 + (void) _initialize {
 136     [WebPreferences _setInitialDefaultTextEncodingToSystemEncoding];
 137
 138     dlopen("/System/Library/Frameworks/MessageUI.framework/MessageUI", RTLD_GLOBAL | RTLD_LAZY);
 139     $MFMailComposeViewController = objc_getClass("MFMailComposeViewController");
 140
 141     if (float *_UIScrollViewDecelerationRateNormal = reinterpret_cast<float *>(dlsym(RTLD_DEFAULT, "UIScrollViewDecelerationRateNormal")))
 142         CYScrollViewDecelerationRateNormal = *_UIScrollViewDecelerationRateNormal;
 143     else // XXX: this actually might be fast on some older systems: we should look into this
 144         CYScrollViewDecelerationRateNormal = 0.998;
 145 }
 146
 147 - (void) dealloc {
 148 #if LogBrowser
 149     NSLog(@"[CyteWebViewController dealloc]");
 150 #endif
 151
 152     if ([loading_ count] != 0)
 153         [delegate_ releaseNetworkActivityIndicator];
 154
 155     [super dealloc];
 156 }
 157
 158 - (NSString *) description {
 159     return [NSString stringWithFormat:@"<%s: %p, %@>", class_getName([self class]), self, [[request_ URL] absoluteString]];
 160 }
 161
 162 - (CyteWebView *) webView {
 163     return (CyteWebView *) [self view];
 164 }
 165
 166 - (NSURL *) URLWithURL:(NSURL *)url {
 167     return url;
 168 }
 169
 170 - (NSURLRequest *) requestWithURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 171     return [NSURLRequest
 172         requestWithURL:[self URLWithURL:url]
 173         cachePolicy:policy
 174         timeoutInterval:DefaultTimeout_
 175     ];
 176 }
 177
 178 - (void) setRequest:(NSURLRequest *)request {
 179     _assert(request_ == nil);
 180     request_ = request;
 181 }
 182
 183 - (void) setURL:(NSURL *)url {
 184     [self setRequest:[self requestWithURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy]];
 185 }
 186
 187 - (void) loadURL:(NSURL *)url cachePolicy:(NSURLRequestCachePolicy)policy {
 188     [self loadRequest:[self requestWithURL:url cachePolicy:policy]];
 189 }
 190
 191 - (void) loadURL:(NSURL *)url {
 192     [self loadURL:url cachePolicy:NSURLRequestUseProtocolCachePolicy];
 193 }
 194
 195 - (void) loadRequest:(NSURLRequest *)request {
 196 #if LogBrowser
 197     NSLog(@"loadRequest:%@", request);
 198 #endif
 199
 200     error_ = false;
 201     ready_ = true;
 202
 203     WebThreadLocked lock;
 204     [[self webView] loadRequest:request];
 205 }
 206
 207 - (void) reloadURLWithCache:(BOOL)cache {
 208     if (request_ == nil)
 209         return;
 210
 211     NSMutableURLRequest *request([request_ mutableCopy]);
 212     [request setCachePolicy:(cache ? NSURLRequestUseProtocolCachePolicy : NSURLRequestReloadIgnoringLocalCacheData)];
 213
 214     request_ = request;
 215
 216     if ([request_ HTTPBody] == nil && [request_ HTTPBodyStream] == nil)
 217         [self loadRequest:request_];
 218     else {
 219         UIAlertView *alert = [[[UIAlertView alloc]
 220             initWithTitle:UCLocalize("RESUBMIT_FORM")
 221             message:nil
 222             delegate:self
 223             cancelButtonTitle:UCLocalize("CANCEL")
 224             otherButtonTitles:
 225                 UCLocalize("SUBMIT"),
 226             nil
 227         ] autorelease];
 228
 229         [alert setContext:@"submit"];
 230         [alert show];
 231     }
 232 }
 233
 234 - (void) reloadURL {
 235     [self reloadURLWithCache:YES];
 236 }
 237
 238 - (void) reloadData {
 239     [super reloadData];
 240
 241     if (ready_)
 242         [self dispatchEvent:@"CydiaReloadData"];
 243     else
 244         [self reloadURLWithCache:YES];
 245 }
 246
 247 - (void) setButtonImage:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 248     custom_ = button;
 249     style_ = style;
 250     function_ = function;
 251
 252     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 253 }
 254
 255 - (void) setButtonTitle:(NSString *)button withStyle:(NSString *)style toFunction:(id)function {
 256     custom_ = button;
 257     style_ = style;
 258     function_ = function;
 259
 260     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 261 }
 262
 263 - (void) removeButton {
 264     custom_ = [NSNull null];
 265     [self performSelectorOnMainThread:@selector(applyRightButton) withObject:nil waitUntilDone:NO];
 266 }
 267
 268 - (void) scrollToBottomAnimated:(NSNumber *)animated {
 269     CGSize size([scroller_ contentSize]);
 270     CGPoint offset([scroller_ contentOffset]);
 271     CGRect frame([scroller_ frame]);
 272
 273     if (size.height - offset.y < frame.size.height + 20.f) {
 274         CGRect rect = {{0, size.height-1}, {size.width, 1}};
 275         [scroller_ scrollRectToVisible:rect animated:[animated boolValue]];
 276     }
 277 }
 278
 279 - (void) _setViewportWidth {
 280     [[[self webView] _documentView] setViewportSize:CGSizeMake(width_, UIWebViewGrowsAndShrinksToFitHeight) forDocumentTypes:0x10];
 281 }
 282
 283 - (void) setViewportWidth:(float)width {
 284     width_ = width != 0 ? width : [[self class] defaultWidth];
 285     [self _setViewportWidth];
 286 }
 287
 288 - (void) _setViewportWidthOnMainThread:(NSNumber *)width {
 289     [self setViewportWidth:[width floatValue]];
 290 }
 291
 292 - (void) setViewportWidthOnMainThread:(float)width {
 293     [self performSelectorOnMainThread:@selector(_setViewportWidthOnMainThread:) withObject:[NSNumber numberWithFloat:width] waitUntilDone:NO];
 294 }
 295
 296 - (void) webViewUpdateViewSettings:(UIWebView *)view {
 297     [self _setViewportWidth];
 298 }
 299
 300 - (void) mailComposeController:(MFMailComposeViewController*)controller didFinishWithResult:(MFMailComposeResult)result error:(NSError*)error {
 301     [self dismissModalViewControllerAnimated:YES];
 302 }
 303
 304 - (void) _setupMail:(MFMailComposeViewController *)controller {
 305 }
 306
 307 - (void) _openMailToURL:(NSURL *)url {
 308     if ($MFMailComposeViewController != nil && [$MFMailComposeViewController canSendMail]) {
 309         MFMailComposeViewController *controller([[[$MFMailComposeViewController alloc] init] autorelease]);
 310         [controller setMailComposeDelegate:self];
 311
 312         [controller setMailToURL:url];
 313
 314         [self _setupMail:controller];
 315
 316         [self presentModalViewController:controller animated:YES];
 317         return;
 318     }
 319
 320     UIApplication *app([UIApplication sharedApplication]);
 321     if ([app respondsToSelector:@selector(openURL:asPanel:)])
 322         [app openURL:url asPanel:YES];
 323     else
 324         [app openURL:url];
 325 }
 326
 327 - (bool) _allowJavaScriptPanel {
 328     return true;
 329 }
 330
 331 - (bool) allowsNavigationAction {
 332     return allowsNavigationAction_;
 333 }
 334
 335 - (void) setAllowsNavigationAction:(bool)value {
 336     allowsNavigationAction_ = value;
 337 }
 338
 339 - (void) setAllowsNavigationActionByNumber:(NSNumber *)value {
 340     [self setAllowsNavigationAction:[value boolValue]];
 341 }
 342
 343 - (void) popViewControllerWithNumber:(NSNumber *)value {
 344     UINavigationController *navigation([self navigationController]);
 345     if ([navigation topViewController] == self)
 346         [navigation popViewControllerAnimated:[value boolValue]];
 347 }
 348
 349 - (void) _didFailWithError:(NSError *)error forFrame:(WebFrame *)frame {
 350     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 351     [self _didFinishLoading];
 352
 353     if ([[error domain] isEqualToString:NSURLErrorDomain] && [error code] == NSURLErrorCancelled)
 354         return;
 355
 356     if ([[error domain] isEqualToString:WebKitErrorDomain] && [error code] == WebKitErrorFrameLoadInterruptedByPolicyChange) {
 357         request_ = stage2_;
 358         stage1_ = nil;
 359         stage2_ = nil;
 360         return;
 361     }
 362
 363     if ([frame parentFrame] == nil) {
 364         [self loadURL:[NSURL URLWithString:[NSString stringWithFormat:@"%@?%@",
 365             [[NSURL fileURLWithPath:[[NSBundle mainBundle] pathForResource:@"error" ofType:@"html"]] absoluteString],
 366             [[error localizedDescription] stringByAddingPercentEscapes]
 367         ]]];
 368
 369         error_ = true;
 370     }
 371 }
 372
 373 - (void) pushRequest:(NSURLRequest *)request asPop:(bool)pop {
 374     NSURL *url([request URL]);
 375
 376     // XXX: filter to internal usage?
 377     CyteViewController *page([delegate_ pageForURL:url forExternal:NO]);
 378
 379     if (page == nil) {
 380         CyteWebViewController *browser([[[class_ alloc] init] autorelease]);
 381         [browser setRequest:request];
 382         page = browser;
 383     }
 384
 385     [page setDelegate:delegate_];
 386
 387     if (!pop) {
 388         [[self navigationItem] setTitle:title_];
 389
 390         [[self navigationController] pushViewController:page animated:YES];
 391     } else {
 392         UINavigationController *navigation([[[UINavigationController alloc] initWithRootViewController:page] autorelease]);
 393
 394         [navigation setDelegate:delegate_];
 395
 396         [[page navigationItem] setLeftBarButtonItem:[[[UIBarButtonItem alloc]
 397             initWithTitle:UCLocalize("CLOSE")
 398             style:UIBarButtonItemStylePlain
 399             target:page
 400             action:@selector(close)
 401         ] autorelease]];
 402
 403         [[self navigationController] presentModalViewController:navigation animated:YES];
 404     }
 405 }
 406
 407 // CyteWebViewDelegate {{{
 408 - (void) webView:(WebView *)view addMessageToConsole:(NSDictionary *)message {
 409 #if LogMessages
 410     static Pcre irritating("^(?"
 411         ":" "The page at .* displayed insecure content from .*\\."
 412         "|" "Unsafe JavaScript attempt to access frame with URL .* from frame with URL .*\\. Domains, protocols and ports must match\\."
 413     ")\\n$");
 414
 415     if (NSString *data = [message objectForKey:@"message"])
 416         if (irritating(data))
 417             return;
 418
 419     NSLog(@"addMessageToConsole:%@", message);
 420 #endif
 421 }
 422
 423 - (void) webView:(WebView *)view decidePolicyForNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 424 #if LogBrowser
 425     NSLog(@"decidePolicyForNavigationAction:%@ request:%@ frame:%@", action, request, frame);
 426 #endif
 427
 428     if ([frame parentFrame] == nil) {
 429         if (!error_) {
 430             NSURL *url(request == nil ? nil : [request URL]);
 431
 432             if (request_ != nil && ![[request_ URL] isEqual:url] && ![self allowsNavigationAction]) {
 433                 if (url != nil)
 434                     [self pushRequest:request asPop:NO];
 435                 [listener ignore];
 436             }
 437         }
 438     }
 439 }
 440
 441 - (void) webView:(WebView *)view didDecidePolicy:(CYWebPolicyDecision)decision forNavigationAction:(NSDictionary *)action request:(NSURLRequest *)request frame:(WebFrame *)frame {
 442     if ([frame parentFrame] == nil)
 443         if (decision == CYWebPolicyDecisionUse)
 444             if (!error_) {
 445                 stage1_ = request_;
 446                 request_ = request;
 447             }
 448 }
 449
 450 - (void) webView:(WebView *)view decidePolicyForNewWindowAction:(NSDictionary *)action request:(NSURLRequest *)request newFrameName:(NSString *)frame decisionListener:(id<WebPolicyDecisionListener>)listener {
 451 #if LogBrowser
 452     NSLog(@"decidePolicyForNewWindowAction:%@ request:%@ newFrameName:%@", action, request, frame);
 453 #endif
 454
 455     NSURL *url([request URL]);
 456     if (url == nil)
 457         return;
 458
 459     if ([frame isEqualToString:@"_open"])
 460         [delegate_ openURL:url];
 461     else {
 462         NSString *scheme([[url scheme] lowercaseString]);
 463         if ([scheme isEqualToString:@"mailto"])
 464             [self _openMailToURL:url];
 465         else
 466             [self pushRequest:request asPop:[frame isEqualToString:@"_popup"]];
 467     }
 468
 469     [listener ignore];
 470 }
 471
 472 - (void) webView:(WebView *)view didClearWindowObject:(WebScriptObject *)window forFrame:(WebFrame *)frame {
 473 }
 474
 475 - (void) webView:(WebView *)view didCommitLoadForFrame:(WebFrame *)frame {
 476 #if LogBrowser
 477     NSLog(@"didCommitLoadForFrame:%@", frame);
 478 #endif
 479
 480     if ([frame parentFrame] == nil) {
 481     }
 482 }
 483
 484 - (void) webView:(WebView *)view didFailLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 485 #if LogBrowser
 486     NSLog(@"didFailLoadWithError:%@ forFrame:%@", error, frame);
 487 #endif
 488
 489     [self _didFailWithError:error forFrame:frame];
 490 }
 491
 492 - (void) webView:(WebView *)view didFailProvisionalLoadWithError:(NSError *)error forFrame:(WebFrame *)frame {
 493 #if LogBrowser
 494     NSLog(@"didFailProvisionalLoadWithError:%@ forFrame:%@", error, frame);
 495 #endif
 496
 497     [self _didFailWithError:error forFrame:frame];
 498 }
 499
 500 - (void) webView:(WebView *)view didFinishLoadForFrame:(WebFrame *)frame {
 501     [loading_ removeObject:[NSValue valueWithNonretainedObject:frame]];
 502
 503     if ([frame parentFrame] == nil) {
 504         stage1_ = nil;
 505         stage2_ = nil;
 506
 507         if (DOMDocument *document = [frame DOMDocument])
 508             if (DOMNodeList<NSFastEnumeration> *bodies = [document getElementsByTagName:@"body"])
 509                 for (DOMHTMLBodyElement *body in (id) bodies) {
 510                     DOMCSSStyleDeclaration *style([document getComputedStyle:body pseudoElement:nil]);
 511
 512                     UIColor *uic(nil);
 513
 514                     if (DOMCSSPrimitiveValue *color = static_cast<DOMCSSPrimitiveValue *>([style getPropertyCSSValue:@"background-color"])) {
 515                         if ([color primitiveType] == DOM_CSS_RGBCOLOR) {
 516                             DOMRGBColor *rgb([color getRGBColorValue]);
 517
 518                             float red([[rgb red] getFloatValue:DOM_CSS_NUMBER]);
 519                             float green([[rgb green] getFloatValue:DOM_CSS_NUMBER]);
 520                             float blue([[rgb blue] getFloatValue:DOM_CSS_NUMBER]);
 521                             float alpha([[rgb alpha] getFloatValue:DOM_CSS_NUMBER]);
 522
 523                             if (red == 0xc7 && green == 0xce && blue == 0xd5)
 524                                 uic = [UIColor pinStripeColor];
 525                             else if (alpha != 0)
 526                                 uic = [UIColor
 527                                     colorWithRed:(red / 255)
 528                                     green:(green / 255)
 529                                     blue:(blue / 255)
 530                                     alpha:alpha
 531                                 ];
 532                         }
 533                     }
 534
 535                     [scroller_ setBackgroundColor:(uic ?: [UIColor clearColor])];
 536                     break;
 537                 }
 538     }
 539
 540     [self _didFinishLoading];
 541 }
 542
 543 - (void) webView:(WebView *)view didReceiveTitle:(NSString *)title forFrame:(WebFrame *)frame {
 544     if ([frame parentFrame] != nil)
 545         return;
 546
 547     title_ = title;
 548
 549     [[self navigationItem] setTitle:title_];
 550 }
 551
 552 - (void) webView:(WebView *)view didStartProvisionalLoadForFrame:(WebFrame *)frame {
 553 #if LogBrowser
 554     NSLog(@"didStartProvisionalLoadForFrame:%@", frame);
 555 #endif
 556
 557     [loading_ addObject:[NSValue valueWithNonretainedObject:frame]];
 558
 559     if ([frame parentFrame] == nil) {
 560         title_ = nil;
 561         custom_ = nil;
 562         style_ = nil;
 563         function_ = nil;
 564
 565         allowsNavigationAction_ = true;
 566
 567         stage2_ = stage1_;
 568         stage1_ = nil;
 569
 570         [self setHidesNavigationBar:NO];
 571
 572         // XXX: do we still need to do this?
 573         [[self navigationItem] setTitle:nil];
 574     }
 575
 576     [self _didStartLoading];
 577 }
 578
 579 - (NSURLRequest *) webView:(WebView *)view resource:(id)identifier willSendRequest:(NSURLRequest *)request redirectResponse:(NSURLResponse *)response fromDataSource:(WebDataSource *)source {
 580 #if LogBrowser
 581     NSLog(@"resource:%@ willSendRequest:%@ redirectResponse:%@ fromDataSource:%@", identifier, request, response, source);
 582 #endif
 583
 584     return request;
 585 }
 586
 587 - (bool) webView:(WebView *)view shouldRunJavaScriptAlertPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 588     return [self _allowJavaScriptPanel];
 589 }
 590
 591 - (bool) webView:(WebView *)view shouldRunJavaScriptConfirmPanelWithMessage:(NSString *)message initiatedByFrame:(WebFrame *)frame {
 592     return [self _allowJavaScriptPanel];
 593 }
 594
 595 - (bool) webView:(WebView *)view shouldRunJavaScriptTextInputPanelWithPrompt:(NSString *)prompt defaultText:(NSString *)text initiatedByFrame:(WebFrame *)frame {
 596     return [self _allowJavaScriptPanel];
 597 }
 598
 599 - (void) webViewClose:(WebView *)view {
 600     [self close];
 601 }
 602 // }}}
 603
 604 - (void) close {
 605     [[[self navigationController] parentViewController] dismissModalViewControllerAnimated:YES];
 606 }
 607
 608 - (void) alertView:(UIAlertView *)alert clickedButtonAtIndex:(NSInteger)button {
 609     NSString *context([alert context]);
 610
 611     if ([context isEqualToString:@"sensitive"]) {
 612         switch (button) {
 613             case 1:
 614                 sensitive_ = [NSNumber numberWithBool:YES];
 615             break;
 616
 617             case 2:
 618                 sensitive_ = [NSNumber numberWithBool:NO];
 619             break;
 620         }
 621
 622         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 623     } else if ([context isEqualToString:@"challenge"]) {
 624         id<NSURLAuthenticationChallengeSender> sender([challenge_ sender]);
 625
 626         switch (button) {
 627             case 1: {
 628                 NSString *username([[alert textFieldAtIndex:0] text]);
 629                 NSString *password([[alert textFieldAtIndex:1] text]);
 630
 631                 NSURLCredential *credential([NSURLCredential credentialWithUser:username password:password persistence:NSURLCredentialPersistenceForSession]);
 632
 633                 [sender useCredential:credential forAuthenticationChallenge:challenge_];
 634             } break;
 635
 636             case 2:
 637                 [sender cancelAuthenticationChallenge:challenge_];
 638             break;
 639
 640             _nodefault
 641         }
 642
 643         challenge_ = nil;
 644
 645         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 646     } else if ([context isEqualToString:@"submit"]) {
 647         if (button == [alert cancelButtonIndex]) {
 648         } else if (button == [alert firstOtherButtonIndex]) {
 649             if (request_ != nil) {
 650                 WebThreadLocked lock;
 651                 [[self webView] loadRequest:request_];
 652             }
 653         }
 654
 655         [alert dismissWithClickedButtonIndex:-1 animated:YES];
 656     }
 657 }
 658
 659 - (UIBarButtonItemStyle) rightButtonStyle {
 660     if (style_ == nil) normal:
 661         return UIBarButtonItemStylePlain;
 662     else if ([style_ isEqualToString:@"Normal"])
 663         return UIBarButtonItemStylePlain;
 664     else if ([style_ isEqualToString:@"Highlighted"])
 665         return UIBarButtonItemStyleDone;
 666     else goto normal;
 667 }
 668
 669 - (UIBarButtonItem *) customButton {
 670     if (custom_ == nil)
 671         return nil;
 672     else if (custom_ == [NSNull null])
 673         return (UIBarButtonItem *) [NSNull null];
 674
 675     return [[[UIBarButtonItem alloc]
 676         initWithTitle:static_cast<NSString *>(custom_.operator NSObject *())
 677         style:[self rightButtonStyle]
 678         target:self
 679         action:@selector(customButtonClicked)
 680     ] autorelease];
 681 }
 682
 683 - (UIBarButtonItem *) leftButton {
 684     UINavigationItem *item([self navigationItem]);
 685     if ([item backBarButtonItem] != nil && ![item hidesBackButton])
 686         return nil;
 687
 688     if (UINavigationController *navigation = [self navigationController])
 689         if ([[navigation parentViewController] modalViewController] == navigation)
 690             return [[[UIBarButtonItem alloc]
 691                 initWithTitle:UCLocalize("CLOSE")
 692                 style:UIBarButtonItemStylePlain
 693                 target:self
 694                 action:@selector(close)
 695             ] autorelease];
 696
 697     return nil;
 698 }
 699
 700 - (void) applyLeftButton {
 701     [[self navigationItem] setLeftBarButtonItem:[self leftButton]];
 702 }
 703
 704 - (UIBarButtonItem *) rightButton {
 705     return reloaditem_;
 706 }
 707
 708 - (void) applyLoadingTitle {
 709     [[self navigationItem] setTitle:UCLocalize("LOADING")];
 710 }
 711
 712 - (void) layoutRightButton {
 713     [[loadingitem_ view] addSubview:indicator_];
 714     [[loadingitem_ view] bringSubviewToFront:indicator_];
 715 }
 716
 717 - (void) applyRightButton {
 718     if ([self isLoading]) {
 719         [[self navigationItem] setRightBarButtonItem:loadingitem_ animated:YES];
 720         [self performSelector:@selector(layoutRightButton) withObject:nil afterDelay:0];
 721
 722         [indicator_ startAnimating];
 723         [self applyLoadingTitle];
 724     } else {
 725         [indicator_ stopAnimating];
 726
 727         UIBarButtonItem *button([self customButton]);
 728         if (button == nil)
 729             button = [self rightButton];
 730         else if (button == (UIBarButtonItem *) [NSNull null])
 731             button = nil;
 732
 733         [[self navigationItem] setRightBarButtonItem:button animated:YES];
 734     }
 735 }
 736
 737 - (void) didStartLoading {
 738     // Overridden in subclasses.
 739 }
 740
 741 - (void) _didStartLoading {
 742     [self applyRightButton];
 743
 744     if ([loading_ count] != 1)
 745         return;
 746
 747     [delegate_ retainNetworkActivityIndicator];
 748     [self didStartLoading];
 749 }
 750
 751 - (void) didFinishLoading {
 752     // Overridden in subclasses.
 753 }
 754
 755 - (void) _didFinishLoading {
 756     if ([loading_ count] != 0)
 757         return;
 758
 759     [self applyRightButton];
 760     [[self navigationItem] setTitle:title_];
 761
 762     [delegate_ releaseNetworkActivityIndicator];
 763     [self didFinishLoading];
 764 }
 765
 766 - (bool) isLoading {
 767     return [loading_ count] != 0;
 768 }
 769
 770 - (id) initWithWidth:(float)width ofClass:(Class)_class {
 771     if ((self = [super init]) != nil) {
 772         width_ = width;
 773         class_ = _class;
 774
 775         allowsNavigationAction_ = true;
 776
 777         loading_ = [NSMutableSet setWithCapacity:5];
 778         indirect_ = [[[IndirectDelegate alloc] initWithDelegate:self] autorelease];
 779
 780         reloaditem_ = [[[UIBarButtonItem alloc]
 781             initWithTitle:UCLocalize("RELOAD")
 782             style:[self rightButtonStyle]
 783             target:self
 784             action:@selector(reloadButtonClicked)
 785         ] autorelease];
 786
 787         loadingitem_ = [[[UIBarButtonItem alloc]
 788             initWithTitle:@" "
 789             style:UIBarButtonItemStylePlain
 790             target:self
 791             action:@selector(reloadButtonClicked)
 792         ] autorelease];
 793
 794         indicator_ = [[[UIActivityIndicatorView alloc] initWithActivityIndicatorStyle:UIActivityIndicatorViewStyleWhite] autorelease];
 795         [indicator_ setFrame:CGRectMake(15, 5, [indicator_ frame].size.width, [indicator_ frame].size.height)];
 796         [indicator_ setAutoresizingMask:UIViewAutoresizingFlexibleLeftMargin];
 797
 798         [self applyLeftButton];
 799         [self applyRightButton];
 800     } return self;
 801 }
 802
 803 - (NSString *) applicationNameForUserAgent {
 804     return nil;
 805 }
 806
 807 - (void) loadView {
 808     CGRect bounds([[UIScreen mainScreen] applicationFrame]);
 809
 810     webview_ = [[[CyteWebView alloc] initWithFrame:bounds] autorelease];
 811     [webview_ setDelegate:self];
 812     [self setView:webview_];
 813
 814     if ([webview_ respondsToSelector:@selector(setDataDetectorTypes:)])
 815         [webview_ setDataDetectorTypes:UIDataDetectorTypeAutomatic];
 816     else
 817         [webview_ setDetectsPhoneNumbers:NO];
 818
 819     [webview_ setScalesPageToFit:YES];
 820
 821     UIWebDocumentView *document([webview_ _documentView]);
 822
 823     // XXX: I think this improves scrolling; the hardcoded-ness sucks
 824     [document setTileSize:CGSizeMake(320, 500)];
 825
 826     [document setBackgroundColor:[UIColor clearColor]];
 827
 828     // XXX: this is terribly (too?) expensive
 829     [document setDrawsBackground:NO];
 830
 831     WebView *webview([document webView]);
 832     WebPreferences *preferences([webview preferences]);
 833
 834     // XXX: I have no clue if I actually /want/ this modification
 835     if ([webview respondsToSelector:@selector(_setLayoutInterval:)])
 836         [webview _setLayoutInterval:0];
 837     else if ([preferences respondsToSelector:@selector(_setLayoutInterval:)])
 838         [preferences _setLayoutInterval:0];
 839
 840     [preferences setCacheModel:WebCacheModelDocumentBrowser];
 841     [preferences setJavaScriptCanOpenWindowsAutomatically:YES];
 842     [preferences setOfflineWebApplicationCacheEnabled:YES];
 843
 844     if (NSString *agent = [self applicationNameForUserAgent])
 845         [webview setApplicationNameForUserAgent:agent];
 846
 847     if ([webview respondsToSelector:@selector(setShouldUpdateWhileOffscreen:)])
 848         [webview setShouldUpdateWhileOffscreen:NO];
 849
 850 #if LogMessages
 851     if ([document respondsToSelector:@selector(setAllowsMessaging:)])
 852         [document setAllowsMessaging:YES];
 853     if ([webview respondsToSelector:@selector(_setAllowsMessaging:)])
 854         [webview _setAllowsMessaging:YES];
 855 #endif
 856
 857     if ([webview_ respondsToSelector:@selector(_scrollView)]) {
 858         scroller_ = [webview_ _scrollView];
 859
 860         [scroller_ setDirectionalLockEnabled:YES];
 861         [scroller_ setDecelerationRate:CYScrollViewDecelerationRateNormal];
 862         [scroller_ setDelaysContentTouches:NO];
 863
 864         [scroller_ setCanCancelContentTouches:YES];
 865     } else if ([webview_ respondsToSelector:@selector(_scroller)]) {
 866         UIScroller *scroller([webview_ _scroller]);
 867         scroller_ = (UIScrollView *) scroller;
 868
 869         [scroller setDirectionalScrolling:YES];
 870         // XXX: we might be better off /not/ setting this on older systems
 871         [scroller setScrollDecelerationFactor:CYScrollViewDecelerationRateNormal]; /* 0.989324 */
 872         [scroller setScrollHysteresis:0]; /* 8 */
 873
 874         [scroller setThumbDetectionEnabled:NO];
 875
 876         // use NO with UIApplicationUseLegacyEvents(YES)
 877         [scroller setEventMode:YES];
 878
 879         // XXX: this is handled by setBounces, right?
 880         //[scroller setAllowsRubberBanding:YES];
 881     }
 882
 883     [scroller_ setFixedBackgroundPattern:YES];
 884     [scroller_ setBackgroundColor:[UIColor clearColor]];
 885     [scroller_ setClipsSubviews:YES];
 886
 887     [scroller_ setBounces:YES];
 888     [scroller_ setScrollingEnabled:YES];
 889     [scroller_ setShowBackgroundShadow:NO];
 890
 891     [self setViewportWidth:width_];
 892
 893     UITableView *table([[[UITableView alloc] initWithFrame:[webview_ bounds] style:UITableViewStyleGrouped] autorelease]);
 894     [table setScrollsToTop:NO];
 895     [webview_ insertSubview:table atIndex:0];
 896
 897     [table setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
 898     [webview_ setAutoresizingMask:(UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight)];
 899
 900     ready_ = false;
 901 }
 902
 903 - (void) releaseSubviews {
 904     webview_ = nil;
 905     scroller_ = nil;
 906
 907     [super releaseSubviews];
 908 }
 909
 910 - (id) initWithWidth:(float)width {
 911     return [self initWithWidth:width ofClass:[self class]];
 912 }
 913
 914 - (id) init {
 915     return [self initWithWidth:0];
 916 }
 917
 918 - (id) initWithURL:(NSURL *)url {
 919     if ((self = [self init]) != nil) {
 920         [self setURL:url];
 921     } return self;
 922 }
 923
 924 - (void) callFunction:(WebScriptObject *)function {
 925     WebThreadLocked lock;
 926
 927     WebView *webview([[[self webView] _documentView] webView]);
 928     WebFrame *frame([webview mainFrame]);
 929
 930     JSGlobalContextRef context([frame globalContext]);
 931     JSObjectRef object([function JSObject]);
 932     JSObjectCallAsFunction(context, object, NULL, 0, NULL, NULL);
 933 }
 934
 935 - (void) reloadButtonClicked {
 936     [self reloadURLWithCache:YES];
 937 }
 938
 939 - (void) _customButtonClicked {
 940     [self reloadButtonClicked];
 941 }
 942
 943 - (void) customButtonClicked {
 944 #if !AlwaysReload
 945     if (function_ != nil)
 946         [self callFunction:function_];
 947     else
 948 #endif
 949     [self _customButtonClicked];
 950 }
 951
 952 + (float) defaultWidth {
 953     return 980;
 954 }
 955
 956 - (void) setNavigationBarStyle:(NSString *)name {
 957     UIBarStyle style;
 958     if ([name isEqualToString:@"Black"])
 959         style = UIBarStyleBlack;
 960     else
 961         style = UIBarStyleDefault;
 962
 963     [[[self navigationController] navigationBar] setBarStyle:style];
 964 }
 965
 966 - (void) setNavigationBarTintColor:(UIColor *)color {
 967     [[[self navigationController] navigationBar] setTintColor:color];
 968 }
 969
 970 - (void) setBadgeValue:(id)value {
 971     [[[self navigationController] tabBarItem] setBadgeValue:value];
 972 }
 973
 974 - (void) setHidesBackButton:(bool)value {
 975     [[self navigationItem] setHidesBackButton:value];
 976     [self applyLeftButton];
 977 }
 978
 979 - (void) setHidesBackButtonByNumber:(NSNumber *)value {
 980     [self setHidesBackButton:[value boolValue]];
 981 }
 982
 983 - (void) dispatchEvent:(NSString *)event {
 984     [[self webView] dispatchEvent:event];
 985 }
 986
 987 - (bool) hidesNavigationBar {
 988     return hidesNavigationBar_;
 989 }
 990
 991 - (void) _setHidesNavigationBar:(bool)value animated:(bool)animated {
 992     if (visible_)
 993         [[self navigationController] setNavigationBarHidden:(value && [self hidesNavigationBar]) animated:animated];
 994 }
 995
 996 - (void) setHidesNavigationBar:(bool)value {
 997     if (hidesNavigationBar_ != value) {
 998         hidesNavigationBar_ = value;
 999         [self _setHidesNavigationBar:YES animated:YES];
1000     }
1001 }
1002
1003 - (void) setHidesNavigationBarByNumber:(NSNumber *)value {
1004     [self setHidesNavigationBar:[value boolValue]];
1005 }
1006
1007 - (void) viewWillAppear:(BOOL)animated {
1008     visible_ = true;
1009
1010     if ([self hidesNavigationBar])
1011         [self _setHidesNavigationBar:YES animated:animated];
1012
1013     [self dispatchEvent:@"CydiaViewWillAppear"];
1014     [super viewWillAppear:animated];
1015 }
1016
1017 - (void) viewDidAppear:(BOOL)animated {
1018     [super viewDidAppear:animated];
1019     [self dispatchEvent:@"CydiaViewDidAppear"];
1020 }
1021
1022 - (void) viewWillDisappear:(BOOL)animated {
1023     [self dispatchEvent:@"CydiaViewWillDisappear"];
1024     [super viewWillDisappear:animated];
1025
1026     if ([self hidesNavigationBar])
1027         [self _setHidesNavigationBar:NO animated:animated];
1028
1029     visible_ = false;
1030 }
1031
1032 - (void) viewDidDisappear:(BOOL)animated {
1033     [super viewDidDisappear:animated];
1034     [self dispatchEvent:@"CydiaViewDidDisappear"];
1035 }
1036
1037 @end