Register cydget:// and cydget-cgi:// as local schemes.

[cydget.git] / Tweak.mm

/* Cydget - open-source AwayView plugin multiplexer
 * Copyright (C) 2009-2011  Jay Freeman (saurik)
*/

/*
 *        Redistribution and use in source and binary
 * forms, with or without modification, are permitted
 * provided that the following conditions are met:
 *
 * 1. Redistributions of source code must retain the
 *    above copyright notice, this list of conditions
 *    and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the
 *    above copyright notice, this list of conditions
 *    and the following disclaimer in the documentation
 *    and/or other materials provided with the
 *    distribution.
 * 3. The name of the author may not be used to endorse
 *    or promote products derived from this software
 *    without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS''
 * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING,
 * BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
 * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 * ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE
 * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
 * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
 * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
 * LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
 * TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
 * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/

#include <substrate.h>

#include <Foundation/Foundation.h>
#include <GraphicsServices/GraphicsServices.h>
#include <UIKit/UIKit.h>

#import <SpringBoard/SBAwayController.h>
#import <SpringBoard/SBAwayView.h>
#import <SpringBoard/SBAwayWindow.h>
#import <SpringBoard/SpringBoard.h>

MSClassHook(SpringBoard)

MSClassHook(SBAwayController)
MSClassHook(SBAwayView)
MSClassHook(SBAwayViewController)
MSClassHook(SBAwayWindow)

#define _trace() \
    NSLog(@"_trace(%s:%u)@%s %d", __FILE__, __LINE__, __FUNCTION__, active_)
#define _not(type) \
    static_cast<type>(~type())

static bool menu_;

static _H<NSArray> settings_;
static _H<NSArray> cydgets_;
static size_t active_;
static unsigned online_;

@interface CydgetController : NSObject {
}

+ (NSDictionary *) currentConfiguration;

@end

@implementation CydgetController

+ (NSDictionary *) currentConfiguration {
    NSDictionary *cydget([cydgets_ objectAtIndex:active_]);
    return [cydget objectForKey:@"CYConfiguration"] ?: [cydget objectForKey:@"Configuration"];
}

@end

@interface NSDictionary (Cydgets)
- (void) enableCydget:(SBAwayController *)away;
- (void) disableCydget:(SBAwayController *)away;
@end

@interface UIPeripheralHost : NSObject
+ (UIPeripheralHost *) sharedInstance;
+ (void) _releaseSharedInstance;
@end

MSClassHook(UIPeripheralHost)

@interface UITextEffectsWindow : UIWindow
+ (UIWindow *) sharedTextEffectsWindow;
@end

@implementation NSDictionary (Cydgets)

- (void) enableCydget:(SBAwayController *)away {
    if (NSString *plugin = [self objectForKey:@"CYPlugin"] ?: [self objectForKey:@"Plugin"]) {
        ++online_;
        UIKeyboardEnableAutomaticAppearance();

        [[UITextEffectsWindow sharedTextEffectsWindow] setWindowLevel:1000];

        [away enableLockScreenBundleWithName:plugin];
    }
}

- (void) disableCydget:(SBAwayController *)away {
    if (NSString *plugin = [self objectForKey:@"CYPlugin"] ?: [self objectForKey:@"Plugin"]) {
        [away disableLockScreenBundleWithName:plugin];

        [$UIPeripheralHost _releaseSharedInstance];

        UIKeyboardDisableAutomaticAppearance();
        --online_;
    }
}

@end

// avoid rendering a keyboard onto the default SBAwayView while automatic keyboard is online
MSInstanceMessageHook0(UIView *, SBAwayView, inputView) {
    // XXX: there is a conceptual error here
    if (online_ == 0 && false)
        return MSOldCall();

    return [[[UIView alloc] init] autorelease];
}

// by default, keyboard actions are redirected to SBAwayController and press menu button
MSInstanceMessageHook1(void, SpringBoard, handleKeyEvent, GSEventRef, event) {
    if (online_ == 0)
        return MSOldCall(event);

    return MSSuperCall(event);
}

MSInstanceMessageHook0(BOOL, SBAwayController, handleMenuButtonTap) {
    if (!MSOldCall() && menu_) {
        [[cydgets_ objectAtIndex:active_] disableCydget:self];
        active_ = (active_ + 1) % [cydgets_ count];
        [[cydgets_ objectAtIndex:active_] enableCydget:self];
    }

    return YES;
}

MSInstanceMessageHook0(void, SBAwayController, _undimScreen) {
    menu_ = false;
    [[cydgets_ objectAtIndex:active_] enableCydget:self];
    [[[self awayView] window] makeKeyWindow];
    return MSOldCall();
}

static void Deactivate_(SBAwayController *self) {
    [[cydgets_ objectAtIndex:active_] disableCydget:self];
    active_ = 0;
}

MSInstanceMessageHook1(void, SBAwayController, dimScreen, BOOL, dim) {
    Deactivate_([$SBAwayController sharedAwayController]);
    MSOldCall(dim);
}

MSInstanceMessageHook1(void, SpringBoard, menuButtonUp, GSEventRef, event) {
    menu_ = true;
    MSOldCall(event);
}

MSInstanceMessageHook1(void, SBAwayView, addGestureRecognizer, id, recognizer) {
    if (online_ == 0)
        return MSOldCall(recognizer);
}

MSInstanceMessageHook1(void, SBAwayWindow, sendGSEvent, GSEventRef, event) {
    NSLog(@"sendGSEvent");
    if (online_ == 0)
        return MSOldCall(event);

    return MSSuperCall(event);
}

#define Cydgets_ @"/System/Library/LockCydgets"

static void CydgetSetup() {
    NSString *plist([NSString stringWithFormat:@"%@/Library/Preferences/com.saurik.Cydget.plist", NSHomeDirectory()]);
    settings_ = [NSMutableDictionary dictionaryWithContentsOfFile:plist] ?: [NSMutableDictionary dictionary];

    NSArray *cydgets([settings_ objectForKey:@"LockCydgets"] ?: [NSArray arrayWithObjects:[NSDictionary dictionaryWithObjectsAndKeys:
        @"Welcome", @"Name", [NSNumber numberWithBool:YES], @"Active", nil
    ], [NSDictionary dictionaryWithObjectsAndKeys:
        @"AwayView", @"Name", [NSNumber numberWithBool:YES], @"Active", nil
    ], nil]);

    cydgets_ = [NSMutableArray arrayWithCapacity:4];
    for (NSDictionary *cydget in cydgets)
        if ([[cydget objectForKey:@"Active"] boolValue])
            if (NSDictionary *info = [NSDictionary dictionaryWithContentsOfFile:[NSString stringWithFormat:@"%@/%@.cydget/Info.plist", Cydgets_, [cydget objectForKey:@"Name"]]])
                [cydgets_ addObject:info];

    if ([cydgets_ count] == 0)
        cydgets_ = nil;
}

// XXX: this could happen while it is unlocked
MSInstanceMessageHook1(id, SBAwayView, initWithFrame, CGRect, frame) {
    self = MSOldCall(frame);
    CydgetSetup();
    [[cydgets_ objectAtIndex:active_] enableCydget:[$SBAwayController sharedAwayController]];
    return self;
}

MSInstanceMessageHook1(void, SBAwayController, _finishedUnlockAttemptWithStatus, BOOL, status) {
    if (status)
        Deactivate_(self);
    MSOldCall(status);
}

// this is called occasionally by -[SBAwayView updateInterface] and takes away our keyboard
MSInstanceMessageHook0(void, SBAwayView, _fixupFirstResponder) {
    if (online_ == 0)
        return MSOldCall();
}

MSInstanceMessageHook0(void, SBAwayView, updateInterface) {
    MSOldCall();

    NSDictionary *cydget([cydgets_ objectAtIndex:active_]);

    NSString *background([cydget objectForKey:@"CYBackground"]);
    if ([background isEqualToString:@"Wallpaper"]) {
        MSIvarHook(UIView *, _backgroundView);
        [_backgroundView setAlpha:1.0f];
    }

    if ([[cydget objectForKey:@"CYShowDateTime"] boolValue])
        [self addDateView];
}