Use the new @media to rethink how legacy works.

[cydget.git] / CydgetLoader.mm

/* Cydget - open-source AwayView plugin multiplexer
 * Copyright (C) 2009-2014  Jay Freeman (saurik)
*/

/* GNU General Public License, Version 3 {{{ */
/*
 * Cydia is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published
 * by the Free Software Foundation, either version 3 of the License,
 * or (at your option) any later version.
 *
 * Cydia is distributed in the hope that it will be useful, but
 * WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with Cydia.  If not, see <http://www.gnu.org/licenses/>.
**/
/* }}} */

#include <CydiaSubstrate/CydiaSubstrate.h>

#include <Foundation/Foundation.h>
#include <UIKit/UIKit.h>

#import <SpringBoard/SBAwayController.h>
#import <SpringBoard/SBAwayView.h>
#import <SpringBoard/SBAwayWindow.h>
#import <SpringBoard/SpringBoard.h>

#include "Handle.hpp"

#define _trace() \
    NSLog(@"_trace(%s:%u)@%s %zd", __FILE__, __LINE__, __FUNCTION__, active_)
#define _not(type) \
    static_cast<type>(~type())

typedef void *GSEventRef;

extern "C" void UIKeyboardEnableAutomaticAppearance();
extern "C" void UIKeyboardDisableAutomaticAppearance();

MSClassHook(SpringBoard)

MSClassHook(SBAwayController)
MSClassHook(SBAwayView)
MSClassHook(SBAwayWindow)
MSClassHook(SBLockScreenManager)
MSClassHook(SBLockScreenView)
MSClassHook(SBLockScreenViewController)
MSClassHook(SBScreenFadeAnimationController)
MSClassHook(SBUserAgent)

MSInitialize {
    if (kCFCoreFoundationVersionNumber < 800) {
        $SBUserAgent = $SBAwayController;
        $SBLockScreenManager = $SBAwayController;
        $SBLockScreenView = $SBAwayView;
    }
}

@interface SBLockScreenNowPlayingPluginController : NSObject
- (BOOL) isNowPlayingPluginActive;
@end

@interface SBLockScreenViewController : UIViewController
- (SBLockScreenView *) lockScreenView;
- (BOOL) isShowingMediaControls;
- (void) _toggleMediaControls;
@end

@interface SBLockScreenManager : NSObject
+ (SBLockScreenManager *) sharedInstance;
- (SBLockScreenViewController *) lockScreenViewController;
@end

static bool menu_;

static _H<NSDictionary> settings_;
static _H<NSMutableArray> cydgets_;
static size_t active_;
static unsigned online_;
static bool nowplaying_;

static bool NowPlaying() {
    if (kCFCoreFoundationVersionNumber < 800)
        return false;
    if (!nowplaying_)
        return false;

    SBLockScreenViewController *controller([[$SBLockScreenManager sharedInstance] lockScreenViewController]);
    if (controller != nil) {
        SBLockScreenNowPlayingPluginController *now(MSHookIvar<SBLockScreenNowPlayingPluginController *>(controller, "_nowPlayingController"));
        if (now != nil && [now isNowPlayingPluginActive])
            return true;
    }

    return false;
}

@interface CydgetController : NSObject {
}

+ (NSDictionary *) currentConfiguration;
+ (NSString *) currentPath;

@end

@implementation CydgetController

+ (NSDictionary *) currentConfiguration {
    NSDictionary *cydget([cydgets_ objectAtIndex:active_]);
    return [cydget objectForKey:@"CYConfiguration"] ?: [cydget objectForKey:@"Configuration"];
}

+ (NSDictionary *) currentPath {
    NSDictionary *cydget([cydgets_ objectAtIndex:active_]);
    return [cydget objectForKey:@"CYPath"];
}

@end

@interface SBUserAgent : NSObject
+ (SBUserAgent *) sharedUserAgent;
- (void) enableLockScreenBundleNamed:(NSString *)bundle activationContext:(id)context;
- (void) disableLockScreenBundleNamed:(NSString *)bundle deactivationContext:(id)context;
@end

@interface UIPeripheralHost : NSObject
+ (UIPeripheralHost *) sharedInstance;
+ (void) _releaseSharedInstance;
@end

MSClassHook(UIPeripheralHost)

@interface UITextEffectsWindow : UIWindow
+ (UIWindow *) sharedTextEffectsWindow;
@end

@implementation NSDictionary (CydgetLoader)

- (NSString *) cydget {
    return [self objectForKey:@"CYPlugin"] ?: [self objectForKey:@"Plugin"];
}

- (void) enableCydget {
    if (NSString *plugin = [self cydget]) {
        ++online_;

        if (kCFCoreFoundationVersionNumber < 600)
            UIKeyboardEnableAutomaticAppearance();

        [[UITextEffectsWindow sharedTextEffectsWindow] setWindowLevel:1000];

        if (kCFCoreFoundationVersionNumber < 800)
            [[$SBAwayController sharedAwayController] enableLockScreenBundleWithName:plugin];
        else
            [[$SBUserAgent sharedUserAgent] enableLockScreenBundleNamed:plugin activationContext:nil];
    }
}

- (void) disableCydget {
    if (NSString *plugin = [self cydget]) {
        if (kCFCoreFoundationVersionNumber < 800)
            [[$SBAwayController sharedAwayController] disableLockScreenBundleWithName:plugin];
        else
            [[$SBUserAgent sharedUserAgent] disableLockScreenBundleNamed:plugin deactivationContext:nil];

        [$UIPeripheralHost _releaseSharedInstance];

        if (kCFCoreFoundationVersionNumber < 600)
            UIKeyboardDisableAutomaticAppearance();

        --online_;
    }
}

@end

// avoid rendering a keyboard onto the default SBAwayView while automatic keyboard is online
MSInstanceMessageHook0(UIView *, SBAwayView, inputView) {
    // XXX: there is a conceptual error here
    if (online_ == 0 && false || kCFCoreFoundationVersionNumber > 600)
        return MSOldCall();

    return [[[UIView alloc] init] autorelease];
}

// by default, keyboard actions are redirected to SBAwayController and press menu button
MSInstanceMessageHook1(void, SpringBoard, handleKeyEvent, GSEventRef, event) {
    if (online_ == 0 || kCFCoreFoundationVersionNumber > 600)
        return MSOldCall(event);

    return MSSuperCall(event);
}

bool media_;

MSInstanceMessageHook0(void, SBLockScreenViewController, _toggleMediaControls) {
    if (!media_)
        MSOldCall();
}

MSInstanceMessageHook0(BOOL, SBLockScreenViewController, handleMenuButtonDoubleTap) {
    menu_ = false;
    BOOL value(MSOldCall());
    if (kCFCoreFoundationVersionNumber >= 800)
        [self _toggleMediaControls];
    return value;
}

MSInstanceMessageHook0(BOOL, SBLockScreenManager, handleMenuButtonTap) {
    media_ = true;
    BOOL value(MSOldCall());
    media_ = false;

    if (!value && menu_) {
        if (active_ != _not(size_t))
            [[cydgets_ objectAtIndex:active_] disableCydget];
        active_ = (active_ + 1) % [cydgets_ count];
        [[cydgets_ objectAtIndex:active_] enableCydget];
        // XXX: or siri doesn't disappear correctly
        return kCFCoreFoundationVersionNumber >= 800 ? value : YES;
    }

    return value;
}

void Activate_() {
    menu_ = false;
    if (NowPlaying()) {
        for (active_ = 0; active_ != [cydgets_ count]; ++active_)
            if ([[[cydgets_ objectAtIndex:active_] objectForKey:@"CYName"] isEqualToString:@"AwayView"])
                break;
        if (active_ == [cydgets_ count])
            active_ = _not(size_t);
    }
    if (active_ != _not(size_t))
        [[cydgets_ objectAtIndex:active_] enableCydget];
}

static void Undim_(SBAwayController *self) {
    if ([self isDimmed]) {
        Activate_();
        [[[self awayView] window] makeKeyWindow];
    }
}

MSInstanceMessageHook1(void, SBLockScreenViewController, startLockScreenFadeInAnimationForSource, int, source) {
    Activate_();
    MSOldCall(source);
}

MSInstanceMessageHook0(void, SBAwayController, undimScreen) {
    Undim_(self);
    MSOldCall();
}

MSInstanceMessageHook1(void, SBAwayController, undimScreen, BOOL, undim) {
    Undim_(self);
    MSOldCall(undim);
}

static void Deactivate_() {
    if (active_ != _not(size_t))
        [[cydgets_ objectAtIndex:active_] disableCydget];
    active_ = 0;
}

MSHook(void, BKSDisplayServicesSetScreenBlanked, BOOL blanked) {
    if (blanked)
        Deactivate_();
    _BKSDisplayServicesSetScreenBlanked(blanked);
}

MSInitialize {
    MSHookFunction("_BKSDisplayServicesSetScreenBlanked", MSHake(BKSDisplayServicesSetScreenBlanked));
}

MSInstanceMessageHook1(void, SBUserAgent, dimScreen, BOOL, dim) {
    Deactivate_();
    MSOldCall(dim);
}

MSInstanceMessageHook0(void, SpringBoard, _menuButtonWasHeld) {
    menu_ = false;
    MSOldCall();
}

MSInstanceMessageHook1(void, SpringBoard, _menuButtonDown, GSEventRef, event) {
    menu_ = true;
    MSOldCall(event);
}

MSInstanceMessageHook1(void, SpringBoard, menuButtonDown, GSEventRef, event) {
    menu_ = true;
    MSOldCall(event);
}

MSInstanceMessageHook1(void, SBAwayView, addGestureRecognizer, id, recognizer) {
    if (online_ == 0 || kCFCoreFoundationVersionNumber > 600)
        return MSOldCall(recognizer);
}

MSInstanceMessageHook1(void, SBAwayWindow, sendGSEvent, GSEventRef, event) {
    if (online_ == 0 || kCFCoreFoundationVersionNumber > 600)
        return MSOldCall(event);

    return MSSuperCall(event);
}

#define Cydgets_ @"/System/Library/LockCydgets"

static void CydgetSetup() {
    NSString *plist([NSString stringWithFormat:@"%@/Library/Preferences/com.saurik.Cydget.plist", NSHomeDirectory()]);
    settings_ = [NSMutableDictionary dictionaryWithContentsOfFile:plist] ?: [NSMutableDictionary dictionary];

    nowplaying_ = [[settings_ objectForKey:@"NowPlaying"] boolValue];

    NSArray *cydgets([settings_ objectForKey:@"LockCydgets"] ?: [NSArray arrayWithObjects:[NSDictionary dictionaryWithObjectsAndKeys:
        @"Welcome", @"Name", [NSNumber numberWithBool:YES], @"Active", nil
    ], [NSDictionary dictionaryWithObjectsAndKeys:
        @"AwayView", @"Name", [NSNumber numberWithBool:YES], @"Active", nil
    ], nil]);

    cydgets_ = [NSMutableArray arrayWithCapacity:4];
    for (NSDictionary *cydget in cydgets)
        if ([[cydget objectForKey:@"Active"] boolValue]) {
            NSString *name([cydget objectForKey:@"Name"]);
            NSString *path([NSString stringWithFormat:@"%@/%@.cydget/Info.plist", Cydgets_, name]);
            if (NSMutableDictionary *info = [NSMutableDictionary dictionaryWithContentsOfFile:path]) {
                [info setObject:name forKey:@"CYName"];
                [info setObject:path forKey:@"CYPath"];
                [cydgets_ addObject:info];
            }
        }

    if ([cydgets_ count] == 0)
        cydgets_ = nil;
}

// XXX: this could happen while it is unlocked
MSInstanceMessageHook1(id, SBLockScreenView, initWithFrame, CGRect, frame) {
    self = MSOldCall(frame);
    CydgetSetup();
    Activate_();
    return self;
}

MSInstanceMessageHook1(void, SBAwayController, _finishedUnlockAttemptWithStatus, BOOL, status) {
    if (status)
        Deactivate_();
    MSOldCall(status);
}

// this is called occasionally by -[SBAwayView updateInterface] and takes away our keyboard
MSInstanceMessageHook0(void, SBAwayView, _fixupFirstResponder) {
    if (online_ == 0)
        return MSOldCall();
}

MSInstanceMessageHook0(void, SBAwayView, updateInterface) {
    MSOldCall();

    NSDictionary *cydget([cydgets_ objectAtIndex:active_]);

    NSString *background([cydget objectForKey:@"CYBackground"]);
    if ([background isEqualToString:@"Wallpaper"]) {
        MSIvarHook(UIView *, _backgroundView);
        [_backgroundView setAlpha:1.0f];
    }

    if ([[cydget objectForKey:@"CYShowDateTime"] boolValue])
        [self addDateView];
}