ObjectiveC/Library.mm

   1 #if defined(__APPLE__) && defined(__arm__)
   2 #include <substrate.h>
   3 #else
   4 #include <objc/objc-api.h>
   5 #endif
   6
   7 #include "ObjectiveC/Internal.hpp"
   8
   9 #ifdef __APPLE__
  10 #include "Struct.hpp"
  11 #endif
  12
  13 #include <Foundation/Foundation.h>
  14
  15 #include <objc/Protocol.h>
  16
  17 #include "cycript.hpp"
  18
  19 #include "ObjectiveC/Internal.hpp"
  20
  21 #ifdef __APPLE__
  22 #include <CoreFoundation/CoreFoundation.h>
  23 #include <JavaScriptCore/JSStringRefCF.h>
  24 #include <WebKit/WebScriptObject.h>
  25 #endif
  26
  27 #include "Error.hpp"
  28 #include "JavaScript.hpp"
  29 #include "String.hpp"
  30
  31 #include <cmath>
  32 #include <map>
  33
  34 #define CYObjectiveTry_(context) { \
  35     JSContextRef context_(context); \
  36     try
  37 #define CYObjectiveTry { \
  38     try
  39 #define CYObjectiveCatch \
  40     catch (const CYException &error) { \
  41         @throw CYCastNSObject(NULL, context_, error.CastJSValue(context_)); \
  42     } \
  43 }
  44
  45 #define CYPoolTry { \
  46     id _saved(nil); \
  47     NSAutoreleasePool *_pool([[NSAutoreleasePool alloc] init]); \
  48     @try
  49 #define CYPoolCatch(value) \
  50     @catch (NSException *error) { \
  51         _saved = [error retain]; \
  52         throw CYJSError(context, CYCastJSValue(context, error)); \
  53         return value; \
  54     } @finally { \
  55         [_pool release]; \
  56         if (_saved != nil) \
  57             [_saved autorelease]; \
  58     } \
  59 }
  60
  61 #ifndef __APPLE__
  62 #define class_getSuperclass GSObjCSuper
  63 #define class_getInstanceVariable GSCGetInstanceVariableDefinition
  64 #define class_getName GSNameFromClass
  65
  66 #define class_removeMethods(cls, list) GSRemoveMethodList(cls, list, YES)
  67
  68 #define ivar_getName(ivar) ((ivar)->ivar_name)
  69 #define ivar_getOffset(ivar) ((ivar)->ivar_offset)
  70 #define ivar_getTypeEncoding(ivar) ((ivar)->ivar_type)
  71
  72 #define method_getName(method) ((method)->method_name)
  73 #define method_getImplementation(method) ((method)->method_imp)
  74 #define method_getTypeEncoding(method) ((method)->method_types)
  75 #define method_setImplementation(method, imp) ((void) ((method)->method_imp = (imp)))
  76
  77 #undef objc_getClass
  78 #define objc_getClass GSClassFromName
  79
  80 #define objc_getProtocol GSProtocolFromName
  81
  82 #define object_getClass GSObjCClass
  83
  84 #define object_getInstanceVariable(object, name, value) ({ \
  85     objc_ivar *ivar(class_getInstanceVariable(object_getClass(object), name)); \
  86     if (ivar != NULL) \
  87         GSObjCGetVariable(object, ivar_getOffset(ivar), sizeof(void *), value); \
  88     ivar; \
  89 })
  90
  91 #define object_setIvar(object, ivar, value) ({ \
  92     void *data = (value); \
  93     GSObjCSetVariable(object, ivar_getOffset(ivar), sizeof(void *), &data); \
  94 })
  95
  96 #define protocol_getName(protocol) [(protocol) name]
  97 #endif
  98
  99 JSValueRef CYSendMessage(apr_pool_t *pool, JSContextRef context, id self, Class super, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception);
 100
 101 extern sqlite3 *Bridge_;
 102
 103 /* Objective-C Pool Release {{{ */
 104 apr_status_t CYPoolRelease_(void *data) {
 105     id object(reinterpret_cast<id>(data));
 106     [object release];
 107     return APR_SUCCESS;
 108 }
 109
 110 id CYPoolRelease_(apr_pool_t *pool, id object) {
 111     if (object == nil)
 112         return nil;
 113     else if (pool == NULL)
 114         return [object autorelease];
 115     else {
 116         apr_pool_cleanup_register(pool, object, &CYPoolRelease_, &apr_pool_cleanup_null);
 117         return object;
 118     }
 119 }
 120
 121 template <typename Type_>
 122 Type_ CYPoolRelease(apr_pool_t *pool, Type_ object) {
 123     return (Type_) CYPoolRelease_(pool, (id) object);
 124 }
 125 /* }}} */
 126 /* Objective-C Strings {{{ */
 127 const char *CYPoolCString(apr_pool_t *pool, JSContextRef context, NSString *value) {
 128     if (pool == NULL)
 129         return [value UTF8String];
 130     else {
 131         size_t size([value maximumLengthOfBytesUsingEncoding:NSUTF8StringEncoding] + 1);
 132         char *string(new(pool) char[size]);
 133         if (![value getCString:string maxLength:size encoding:NSUTF8StringEncoding])
 134             throw CYJSError(context, "[NSString getCString:maxLength:encoding:] == NO");
 135         return string;
 136     }
 137 }
 138
 139 JSStringRef CYCopyJSString(JSContextRef context, NSString *value) {
 140 #ifdef __APPLE__
 141     return JSStringCreateWithCFString(reinterpret_cast<CFStringRef>(value));
 142 #else
 143     CYPool pool;
 144     return CYCopyJSString(CYPoolCString(pool, context, value));
 145 #endif
 146 }
 147
 148 JSStringRef CYCopyJSString(JSContextRef context, NSObject *value) {
 149     if (value == nil)
 150         return NULL;
 151     // XXX: this definition scares me; is anyone using this?!
 152     NSString *string([value description]);
 153     return CYCopyJSString(context, string);
 154 }
 155
 156 NSString *CYCopyNSString(const CYUTF8String &value) {
 157 #ifdef __APPLE__
 158     return (NSString *) CFStringCreateWithBytes(kCFAllocatorDefault, reinterpret_cast<const UInt8 *>(value.data), value.size, kCFStringEncodingUTF8, true);
 159 #else
 160     return [[NSString alloc] initWithBytes:value.data length:value.size encoding:NSUTF8StringEncoding];
 161 #endif
 162 }
 163
 164 NSString *CYCopyNSString(JSContextRef context, JSStringRef value) {
 165 #ifdef __APPLE__
 166     return (NSString *) JSStringCopyCFString(kCFAllocatorDefault, value);
 167 #else
 168     CYPool pool;
 169     return CYCopyNSString(CYPoolUTF8String(pool, context, value));
 170 #endif
 171 }
 172
 173 NSString *CYCopyNSString(JSContextRef context, JSValueRef value) {
 174     return CYCopyNSString(context, CYJSString(context, value));
 175 }
 176
 177 NSString *CYCastNSString(apr_pool_t *pool, const CYUTF8String &value) {
 178     return CYPoolRelease(pool, CYCopyNSString(value));
 179 }
 180
 181 NSString *CYCastNSString(apr_pool_t *pool, SEL sel) {
 182     const char *name(sel_getName(sel));
 183     return CYPoolRelease(pool, CYCopyNSString(CYUTF8String(name, strlen(name))));
 184 }
 185
 186 NSString *CYCastNSString(apr_pool_t *pool, JSContextRef context, JSStringRef value) {
 187     return CYPoolRelease(pool, CYCopyNSString(context, value));
 188 }
 189
 190 CYUTF8String CYCastUTF8String(NSString *value) {
 191     NSData *data([value dataUsingEncoding:NSUTF8StringEncoding allowLossyConversion:NO]);
 192     return CYUTF8String(reinterpret_cast<const char *>([data bytes]), [data length]);
 193 }
 194 /* }}} */
 195
 196 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value);
 197
 198 void CYThrow(JSContextRef context, NSException *error, JSValueRef *exception) {
 199     if (exception == NULL)
 200         throw error;
 201     *exception = CYCastJSValue(context, error);
 202 }
 203
 204 size_t CYGetIndex(NSString *value) {
 205     return CYGetIndex(CYCastUTF8String(value));
 206 }
 207
 208 bool CYGetOffset(apr_pool_t *pool, JSContextRef context, NSString *value, ssize_t &index) {
 209     return CYGetOffset(CYPoolCString(pool, context, value), index);
 210 }
 211
 212 static JSClassRef Instance_;
 213 static JSClassRef Internal_;
 214 static JSClassRef Message_;
 215 static JSClassRef Messages_;
 216 static JSClassRef Selector_;
 217 static JSClassRef Super_;
 218
 219 static JSClassRef ObjectiveC_Classes_;
 220 static JSClassRef ObjectiveC_Protocols_;
 221
 222 #ifdef __APPLE__
 223 static JSClassRef ObjectiveC_Image_Classes_;
 224 static JSClassRef ObjectiveC_Images_;
 225 #endif
 226
 227 static JSObjectRef Instance_prototype_;
 228
 229 #ifdef __APPLE__
 230 static Class NSCFBoolean_;
 231 static Class NSCFType_;
 232 static Class NSMessageBuilder_;
 233 static Class NSZombie_;
 234 #else
 235 static Class NSBoolNumber_;
 236 #endif
 237
 238 static Class NSArray_;
 239 static Class NSDictionary_;
 240 static Class Object_;
 241
 242 static Type_privateData *Object_type;
 243 static Type_privateData *Selector_type;
 244
 245 Type_privateData *Instance::GetType() const {
 246     return Object_type;
 247 }
 248
 249 Type_privateData *Selector_privateData::GetType() const {
 250     return Selector_type;
 251 }
 252
 253 // XXX: trick this out with associated objects!
 254 JSValueRef CYGetClassPrototype(JSContextRef context, id self) {
 255     if (self == nil)
 256         return Instance_prototype_;
 257
 258     // XXX: I need to think through multi-context
 259     typedef std::map<id, JSValueRef> CacheMap;
 260     static CacheMap cache_;
 261
 262     JSValueRef &value(cache_[self]);
 263     if (value != NULL)
 264         return value;
 265
 266     JSClassRef _class(NULL);
 267     JSValueRef prototype;
 268
 269     if (self == NSArray_)
 270         prototype = Array_prototype_;
 271     else if (self == NSDictionary_)
 272         prototype = Object_prototype_;
 273     else
 274         prototype = CYGetClassPrototype(context, class_getSuperclass(self));
 275
 276     JSObjectRef object(JSObjectMake(context, _class, NULL));
 277     JSObjectSetPrototype(context, object, prototype);
 278
 279     JSValueProtect(context, object);
 280     value = object;
 281     return object;
 282 }
 283
 284 JSObjectRef Messages::Make(JSContextRef context, Class _class, bool array) {
 285     JSObjectRef value(JSObjectMake(context, Messages_, new Messages(_class)));
 286     if (_class == NSArray_)
 287         array = true;
 288     if (Class super = class_getSuperclass(_class))
 289         JSObjectSetPrototype(context, value, Messages::Make(context, super, array));
 290     /*else if (array)
 291         JSObjectSetPrototype(context, value, Array_prototype_);*/
 292     return value;
 293 }
 294
 295 JSObjectRef Internal::Make(JSContextRef context, id object, JSObjectRef owner) {
 296     return JSObjectMake(context, Internal_, new Internal(object, context, owner));
 297 }
 298
 299 namespace cy {
 300 JSObjectRef Super::Make(JSContextRef context, id object, Class _class) {
 301     JSObjectRef value(JSObjectMake(context, Super_, new Super(object, _class)));
 302     return value;
 303 } }
 304
 305 JSObjectRef Instance::Make(JSContextRef context, id object, Flags flags) {
 306     JSObjectRef value(JSObjectMake(context, Instance_, new Instance(object, flags)));
 307     JSObjectSetPrototype(context, value, CYGetClassPrototype(context, object_getClass(object)));
 308     return value;
 309 }
 310
 311 Instance::~Instance() {
 312     if ((flags_ & Transient) == 0)
 313         // XXX: does this handle background threads correctly?
 314         // XXX: this simply does not work on the console because I'm stupid
 315         [GetValue() performSelector:@selector(release) withObject:nil afterDelay:0];
 316 }
 317
 318 struct Message_privateData :
 319     cy::Functor
 320 {
 321     SEL sel_;
 322
 323     Message_privateData(SEL sel, const char *type, IMP value = NULL) :
 324         cy::Functor(type, reinterpret_cast<void (*)()>(value)),
 325         sel_(sel)
 326     {
 327     }
 328 };
 329
 330 JSObjectRef CYMakeInstance(JSContextRef context, id object, bool transient) {
 331     Instance::Flags flags;
 332
 333     if (transient)
 334         flags = Instance::Transient;
 335     else {
 336         flags = Instance::None;
 337         object = [object retain];
 338     }
 339
 340     return Instance::Make(context, object, flags);
 341 }
 342
 343 @interface NSMethodSignature (Cycript)
 344 - (NSString *) _typeString;
 345 @end
 346
 347 @interface NSObject (Cycript)
 348
 349 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 350 - (JSType) cy$JSType;
 351
 352 - (NSObject *) cy$toJSON:(NSString *)key;
 353 - (NSString *) cy$toCYON;
 354 - (NSString *) cy$toKey;
 355
 356 - (bool) cy$hasProperty:(NSString *)name;
 357 - (NSObject *) cy$getProperty:(NSString *)name;
 358 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value;
 359 - (bool) cy$deleteProperty:(NSString *)name;
 360 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context;
 361
 362 @end
 363
 364 @protocol Cycript
 365 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context;
 366 @end
 367
 368 NSString *CYCastNSCYON(id value) {
 369     NSString *string;
 370
 371     if (value == nil)
 372         string = @"nil";
 373     else {
 374         Class _class(object_getClass(value));
 375         SEL sel(@selector(cy$toCYON));
 376
 377         if (objc_method *toCYON = class_getInstanceMethod(_class, sel))
 378             string = reinterpret_cast<NSString *(*)(id, SEL)>(method_getImplementation(toCYON))(value, sel);
 379         else if (objc_method *methodSignatureForSelector = class_getInstanceMethod(_class, @selector(methodSignatureForSelector:))) {
 380             if (reinterpret_cast<NSMethodSignature *(*)(id, SEL, SEL)>(method_getImplementation(methodSignatureForSelector))(value, @selector(methodSignatureForSelector:), sel) != nil)
 381                 string = [value cy$toCYON];
 382             else goto fail;
 383         } else fail: {
 384             if (false);
 385 #ifdef __APPLE__
 386             else if (value == NSZombie_)
 387                 string = @"_NSZombie_";
 388             else if (_class == NSZombie_)
 389                 string = [NSString stringWithFormat:@"<_NSZombie_: %p>", value];
 390             // XXX: frowny /in/ the pants
 391             else if (value == NSMessageBuilder_ || value == Object_)
 392                 string = nil;
 393 #endif
 394             else
 395                 string = [NSString stringWithFormat:@"%@", value];
 396         }
 397
 398         // XXX: frowny pants
 399         if (string == nil)
 400             string = @"undefined";
 401     }
 402
 403     return string;
 404 }
 405
 406 #ifdef __APPLE__
 407 struct PropertyAttributes {
 408     CYPool pool_;
 409
 410     const char *name;
 411
 412     const char *variable;
 413
 414     const char *getter_;
 415     const char *setter_;
 416
 417     bool readonly;
 418     bool copy;
 419     bool retain;
 420     bool nonatomic;
 421     bool dynamic;
 422     bool weak;
 423     bool garbage;
 424
 425     PropertyAttributes(objc_property_t property) :
 426         variable(NULL),
 427         getter_(NULL),
 428         setter_(NULL),
 429         readonly(false),
 430         copy(false),
 431         retain(false),
 432         nonatomic(false),
 433         dynamic(false),
 434         weak(false),
 435         garbage(false)
 436     {
 437         name = property_getName(property);
 438         const char *attributes(property_getAttributes(property));
 439
 440         for (char *state, *token(apr_strtok(apr_pstrdup(pool_, attributes), ",", &state)); token != NULL; token = apr_strtok(NULL, ",", &state)) {
 441             switch (*token) {
 442                 case 'R': readonly = true; break;
 443                 case 'C': copy = true; break;
 444                 case '&': retain = true; break;
 445                 case 'N': nonatomic = true; break;
 446                 case 'G': getter_ = token + 1; break;
 447                 case 'S': setter_ = token + 1; break;
 448                 case 'V': variable = token + 1; break;
 449             }
 450         }
 451
 452         /*if (variable == NULL) {
 453             variable = property_getName(property);
 454             size_t size(strlen(variable));
 455             char *name(new(pool_) char[size + 2]);
 456             name[0] = '_';
 457             memcpy(name + 1, variable, size);
 458             name[size + 1] = '\0';
 459             variable = name;
 460         }*/
 461     }
 462
 463     const char *Getter() {
 464         if (getter_ == NULL)
 465             getter_ = apr_pstrdup(pool_, name);
 466         return getter_;
 467     }
 468
 469     const char *Setter() {
 470         if (setter_ == NULL && !readonly) {
 471             size_t length(strlen(name));
 472
 473             char *temp(new(pool_) char[length + 5]);
 474             temp[0] = 's';
 475             temp[1] = 'e';
 476             temp[2] = 't';
 477
 478             if (length != 0) {
 479                 temp[3] = toupper(name[0]);
 480                 memcpy(temp + 4, name + 1, length - 1);
 481             }
 482
 483             temp[length + 3] = ':';
 484             temp[length + 4] = '\0';
 485             setter_ = temp;
 486         }
 487
 488         return setter_;
 489     }
 490
 491 };
 492 #endif
 493
 494 #ifdef __APPLE__
 495 NSObject *NSCFType$cy$toJSON(id self, SEL sel, NSString *key) {
 496     return [(NSString *) CFCopyDescription((CFTypeRef) self) autorelease];
 497 }
 498 #endif
 499
 500 #ifndef __APPLE__
 501 @interface CYWebUndefined : NSObject {
 502 }
 503
 504 + (CYWebUndefined *) undefined;
 505
 506 @end
 507
 508 @implementation CYWebUndefined
 509
 510 + (CYWebUndefined *) undefined {
 511     static CYWebUndefined *instance_([[CYWebUndefined alloc] init]);
 512     return instance_;
 513 }
 514
 515 @end
 516
 517 #define WebUndefined CYWebUndefined
 518 #endif
 519
 520 /* Bridge: CYJSObject {{{ */
 521 @interface CYJSObject : NSMutableDictionary {
 522     JSObjectRef object_;
 523     JSContextRef context_;
 524 }
 525
 526 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 527
 528 - (NSObject *) cy$toJSON:(NSString *)key;
 529
 530 - (NSUInteger) count;
 531 - (id) objectForKey:(id)key;
 532 - (NSEnumerator *) keyEnumerator;
 533 - (void) setObject:(id)object forKey:(id)key;
 534 - (void) removeObjectForKey:(id)key;
 535
 536 @end
 537 /* }}} */
 538 /* Bridge: CYJSArray {{{ */
 539 @interface CYJSArray : NSMutableArray {
 540     JSObjectRef object_;
 541     JSContextRef context_;
 542 }
 543
 544 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context;
 545
 546 - (NSUInteger) count;
 547 - (id) objectAtIndex:(NSUInteger)index;
 548
 549 - (void) addObject:(id)anObject;
 550 - (void) insertObject:(id)anObject atIndex:(NSUInteger)index;
 551 - (void) removeLastObject;
 552 - (void) removeObjectAtIndex:(NSUInteger)index;
 553 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)anObject;
 554
 555 @end
 556 /* }}} */
 557
 558 NSObject *CYCastNSObject_(apr_pool_t *pool, JSContextRef context, JSObjectRef object) {
 559     JSValueRef exception(NULL);
 560     bool array(JSValueIsInstanceOfConstructor(context, object, Array_, &exception));
 561     CYThrow(context, exception);
 562     id value(array ? [CYJSArray alloc] : [CYJSObject alloc]);
 563     return CYPoolRelease(pool, [value initWithJSObject:object inContext:context]);
 564 }
 565
 566 NSObject *CYCastNSObject(apr_pool_t *pool, JSContextRef context, JSObjectRef object) {
 567     if (!JSValueIsObjectOfClass(context, object, Instance_))
 568         return CYCastNSObject_(pool, context, object);
 569     else {
 570         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
 571         return internal->GetValue();
 572     }
 573 }
 574
 575 NSNumber *CYCopyNSNumber(JSContextRef context, JSValueRef value) {
 576     return [[NSNumber alloc] initWithDouble:CYCastDouble(context, value)];
 577 }
 578
 579 #ifndef __APPLE__
 580 @interface NSBoolNumber : NSNumber {
 581 }
 582 @end
 583 #endif
 584
 585 id CYNSObject(apr_pool_t *pool, JSContextRef context, JSValueRef value, bool cast) {
 586     id object;
 587     bool copy;
 588
 589     switch (JSType type = JSValueGetType(context, value)) {
 590         case kJSTypeUndefined:
 591             object = [WebUndefined undefined];
 592             copy = false;
 593         break;
 594
 595         case kJSTypeNull:
 596             return NULL;
 597         break;
 598
 599         case kJSTypeBoolean:
 600 #ifdef __APPLE__
 601             object = (id) (CYCastBool(context, value) ? kCFBooleanTrue : kCFBooleanFalse);
 602             copy = false;
 603 #else
 604             object = [[NSBoolNumber alloc] initWithBool:CYCastBool(context, value)];
 605             copy = true;
 606 #endif
 607         break;
 608
 609         case kJSTypeNumber:
 610             object = CYCopyNSNumber(context, value);
 611             copy = true;
 612         break;
 613
 614         case kJSTypeString:
 615             object = CYCopyNSString(context, value);
 616             copy = true;
 617         break;
 618
 619         case kJSTypeObject:
 620             // XXX: this might could be more efficient
 621             object = CYCastNSObject(pool, context, (JSObjectRef) value);
 622             copy = false;
 623         break;
 624
 625         default:
 626             throw CYJSError(context, "JSValueGetType() == 0x%x", type);
 627         break;
 628     }
 629
 630     if (cast != copy)
 631         return object;
 632     else if (copy)
 633         return CYPoolRelease(pool, object);
 634     else
 635         return [object retain];
 636 }
 637
 638 NSObject *CYCastNSObject(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
 639     return CYNSObject(pool, context, value, true);
 640 }
 641
 642 NSObject *CYCopyNSObject(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
 643     return CYNSObject(pool, context, value, false);
 644 }
 645
 646 /* Bridge: NSArray {{{ */
 647 @implementation NSArray (Cycript)
 648
 649 - (NSString *) cy$toCYON {
 650     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 651     [json appendString:@"["];
 652
 653     bool comma(false);
 654 #ifdef __APPLE__
 655     for (id object in self) {
 656 #else
 657     for (size_t index(0), count([self count]); index != count; ++index) {
 658         id object([self objectAtIndex:index]);
 659 #endif
 660         if (comma)
 661             [json appendString:@","];
 662         else
 663             comma = true;
 664         if (object == nil || [object cy$JSType] != kJSTypeUndefined)
 665             [json appendString:CYCastNSCYON(object)];
 666         else {
 667             [json appendString:@","];
 668             comma = false;
 669         }
 670     }
 671
 672     [json appendString:@"]"];
 673     return json;
 674 }
 675
 676 - (bool) cy$hasProperty:(NSString *)name {
 677     if ([name isEqualToString:@"length"])
 678         return true;
 679
 680     size_t index(CYGetIndex(name));
 681     if (index == _not(size_t) || index >= [self count])
 682         return [super cy$hasProperty:name];
 683     else
 684         return true;
 685 }
 686
 687 - (NSObject *) cy$getProperty:(NSString *)name {
 688     if ([name isEqualToString:@"length"]) {
 689         NSUInteger count([self count]);
 690 #ifdef __APPLE__
 691         return [NSNumber numberWithUnsignedInteger:count];
 692 #else
 693         return [NSNumber numberWithUnsignedInt:count];
 694 #endif
 695     }
 696
 697     size_t index(CYGetIndex(name));
 698     if (index == _not(size_t) || index >= [self count])
 699         return [super cy$getProperty:name];
 700     else
 701         return [self objectAtIndex:index];
 702 }
 703
 704 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 705     [super cy$getPropertyNames:names inContext:context];
 706
 707     for (size_t index(0), count([self count]); index != count; ++index) {
 708         id object([self objectAtIndex:index]);
 709         if (object == nil || [object cy$JSType] != kJSTypeUndefined) {
 710             char name[32];
 711             sprintf(name, "%zu", index);
 712             JSPropertyNameAccumulatorAddName(names, CYJSString(name));
 713         }
 714     }
 715 }
 716
 717 @end
 718 /* }}} */
 719 /* Bridge: NSBoolNumber {{{ */
 720 #ifndef __APPLE__
 721 @implementation NSBoolNumber (Cycript)
 722
 723 - (JSType) cy$JSType {
 724     return kJSTypeBoolean;
 725 }
 726
 727 - (NSObject *) cy$toJSON:(NSString *)key {
 728     return self;
 729 }
 730
 731 - (NSString *) cy$toCYON {
 732     return [self boolValue] ? @"true" : @"false";
 733 }
 734
 735 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context { CYObjectiveTry_(context) {
 736     return CYCastJSValue(context, (bool) [self boolValue]);
 737 } CYObjectiveCatch }
 738
 739 @end
 740 #endif
 741 /* }}} */
 742 /* Bridge: NSDictionary {{{ */
 743 @implementation NSDictionary (Cycript)
 744
 745 - (NSString *) cy$toCYON {
 746     NSMutableString *json([[[NSMutableString alloc] init] autorelease]);
 747     [json appendString:@"{"];
 748
 749     bool comma(false);
 750 #ifdef __APPLE__
 751     for (id key in self) {
 752 #else
 753     NSEnumerator *keys([self keyEnumerator]);
 754     while (id key = [keys nextObject]) {
 755 #endif
 756         if (comma)
 757             [json appendString:@","];
 758         else
 759             comma = true;
 760         [json appendString:[key cy$toKey]];
 761         [json appendString:@":"];
 762         NSObject *object([self objectForKey:key]);
 763         [json appendString:CYCastNSCYON(object)];
 764     }
 765
 766     [json appendString:@"}"];
 767     return json;
 768 }
 769
 770 - (bool) cy$hasProperty:(NSString *)name {
 771     return [self objectForKey:name] != nil;
 772 }
 773
 774 - (NSObject *) cy$getProperty:(NSString *)name {
 775     return [self objectForKey:name];
 776 }
 777
 778 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 779     [super cy$getPropertyNames:names inContext:context];
 780
 781 #ifdef __APPLE__
 782     for (NSString *key in self) {
 783 #else
 784     NSEnumerator *keys([self keyEnumerator]);
 785     while (NSString *key = [keys nextObject]) {
 786 #endif
 787         JSPropertyNameAccumulatorAddName(names, CYJSString(context, key));
 788     }
 789 }
 790
 791 @end
 792 /* }}} */
 793 /* Bridge: NSMutableArray {{{ */
 794 @implementation NSMutableArray (Cycript)
 795
 796 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 797     if ([name isEqualToString:@"length"]) {
 798         // XXX: is this not intelligent?
 799         NSNumber *number(reinterpret_cast<NSNumber *>(value));
 800 #ifdef __APPLE__
 801         NSUInteger size([number unsignedIntegerValue]);
 802 #else
 803         NSUInteger size([number unsignedIntValue]);
 804 #endif
 805         NSUInteger count([self count]);
 806         if (size < count)
 807             [self removeObjectsInRange:NSMakeRange(size, count - size)];
 808         else if (size != count) {
 809             WebUndefined *undefined([WebUndefined undefined]);
 810             for (size_t i(count); i != size; ++i)
 811                 [self addObject:undefined];
 812         }
 813         return true;
 814     }
 815
 816     size_t index(CYGetIndex(name));
 817     if (index == _not(size_t))
 818         return [super cy$setProperty:name to:value];
 819
 820     id object(value ?: [NSNull null]);
 821
 822     size_t count([self count]);
 823     if (index < count)
 824         [self replaceObjectAtIndex:index withObject:object];
 825     else {
 826         if (index != count) {
 827             WebUndefined *undefined([WebUndefined undefined]);
 828             for (size_t i(count); i != index; ++i)
 829                 [self addObject:undefined];
 830         }
 831
 832         [self addObject:object];
 833     }
 834
 835     return true;
 836 }
 837
 838 - (bool) cy$deleteProperty:(NSString *)name {
 839     size_t index(CYGetIndex(name));
 840     if (index == _not(size_t) || index >= [self count])
 841         return [super cy$deleteProperty:name];
 842     [self replaceObjectAtIndex:index withObject:[WebUndefined undefined]];
 843     return true;
 844 }
 845
 846 @end
 847 /* }}} */
 848 /* Bridge: NSMutableDictionary {{{ */
 849 @implementation NSMutableDictionary (Cycript)
 850
 851 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 852     [self setObject:(value ?: [NSNull null]) forKey:name];
 853     return true;
 854 }
 855
 856 - (bool) cy$deleteProperty:(NSString *)name {
 857     if ([self objectForKey:name] == nil)
 858         return false;
 859     else {
 860         [self removeObjectForKey:name];
 861         return true;
 862     }
 863 }
 864
 865 @end
 866 /* }}} */
 867 /* Bridge: NSNumber {{{ */
 868 @implementation NSNumber (Cycript)
 869
 870 - (JSType) cy$JSType {
 871 #ifdef __APPLE__
 872     // XXX: this just seems stupid
 873     if ([self class] == NSCFBoolean_)
 874         return kJSTypeBoolean;
 875 #endif
 876     return kJSTypeNumber;
 877 }
 878
 879 - (NSObject *) cy$toJSON:(NSString *)key {
 880     return self;
 881 }
 882
 883 - (NSString *) cy$toCYON {
 884     return [self cy$JSType] != kJSTypeBoolean ? [self stringValue] : [self boolValue] ? @"true" : @"false";
 885 }
 886
 887 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context { CYObjectiveTry_(context) {
 888     return [self cy$JSType] != kJSTypeBoolean ? CYCastJSValue(context, [self doubleValue]) : CYCastJSValue(context, [self boolValue]);
 889 } CYObjectiveCatch }
 890
 891 @end
 892 /* }}} */
 893 /* Bridge: NSNull {{{ */
 894 @implementation NSNull (Cycript)
 895
 896 - (JSType) cy$JSType {
 897     return kJSTypeNull;
 898 }
 899
 900 - (NSObject *) cy$toJSON:(NSString *)key {
 901     return self;
 902 }
 903
 904 - (NSString *) cy$toCYON {
 905     return @"null";
 906 }
 907
 908 @end
 909 /* }}} */
 910 /* Bridge: NSObject {{{ */
 911 @implementation NSObject (Cycript)
 912
 913 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context { CYObjectiveTry_(context) {
 914     return CYMakeInstance(context, self, false);
 915 } CYObjectiveCatch }
 916
 917 - (JSType) cy$JSType {
 918     return kJSTypeObject;
 919 }
 920
 921 - (NSObject *) cy$toJSON:(NSString *)key {
 922     return [self description];
 923 }
 924
 925 - (NSString *) cy$toCYON {
 926     return [[self cy$toJSON:@""] cy$toCYON];
 927 }
 928
 929 - (NSString *) cy$toKey {
 930     return [self cy$toCYON];
 931 }
 932
 933 - (bool) cy$hasProperty:(NSString *)name {
 934     return false;
 935 }
 936
 937 - (NSObject *) cy$getProperty:(NSString *)name {
 938     return nil;
 939 }
 940
 941 - (bool) cy$setProperty:(NSString *)name to:(NSObject *)value {
 942     return false;
 943 }
 944
 945 - (bool) cy$deleteProperty:(NSString *)name {
 946     return false;
 947 }
 948
 949 - (void) cy$getPropertyNames:(JSPropertyNameAccumulatorRef)names inContext:(JSContextRef)context {
 950 }
 951
 952 @end
 953 /* }}} */
 954 /* Bridge: NSProxy {{{ */
 955 @implementation NSProxy (Cycript)
 956
 957 - (NSObject *) cy$toJSON:(NSString *)key {
 958     return [self description];
 959 }
 960
 961 - (NSString *) cy$toCYON {
 962     return [[self cy$toJSON:@""] cy$toCYON];
 963 }
 964
 965 @end
 966 /* }}} */
 967 /* Bridge: NSString {{{ */
 968 @implementation NSString (Cycript)
 969
 970 - (JSType) cy$JSType {
 971     return kJSTypeString;
 972 }
 973
 974 - (NSObject *) cy$toJSON:(NSString *)key {
 975     return self;
 976 }
 977
 978 - (NSString *) cy$toCYON {
 979     std::ostringstream str;
 980     CYUTF8String string(CYCastUTF8String(self));
 981     CYStringify(str, string.data, string.size);
 982     std::string value(str.str());
 983     return CYCastNSString(NULL, CYUTF8String(value.c_str(), value.size()));
 984 }
 985
 986 - (NSString *) cy$toKey {
 987     if (CYIsKey(CYCastUTF8String(self)))
 988         return self;
 989     return [self cy$toCYON];
 990 }
 991
 992 @end
 993 /* }}} */
 994 /* Bridge: WebUndefined {{{ */
 995 @implementation WebUndefined (Cycript)
 996
 997 - (JSType) cy$JSType {
 998     return kJSTypeUndefined;
 999 }
1000
1001 - (NSObject *) cy$toJSON:(NSString *)key {
1002     return self;
1003 }
1004
1005 - (NSString *) cy$toCYON {
1006     return @"undefined";
1007 }
1008
1009 - (JSValueRef) cy$JSValueInContext:(JSContextRef)context { CYObjectiveTry_(context) {
1010     return CYJSUndefined(context);
1011 } CYObjectiveCatch }
1012
1013 @end
1014 /* }}} */
1015
1016 static bool CYIsClass(id self) {
1017 #ifdef __APPLE__
1018     // XXX: this is a lame object_isClass
1019     return class_getInstanceMethod(object_getClass(self), @selector(alloc)) != NULL;
1020 #else
1021     return GSObjCIsClass(self);
1022 #endif
1023 }
1024
1025 Class CYCastClass(apr_pool_t *pool, JSContextRef context, JSValueRef value) {
1026     id self(CYCastNSObject(pool, context, value));
1027     if (CYIsClass(self))
1028         return (Class) self;
1029     throw CYJSError(context, "got something that is not a Class");
1030     return NULL;
1031 }
1032
1033 NSArray *CYCastNSArray(JSContextRef context, JSPropertyNameArrayRef names) {
1034     CYPool pool;
1035     size_t size(JSPropertyNameArrayGetCount(names));
1036     NSMutableArray *array([NSMutableArray arrayWithCapacity:size]);
1037     for (size_t index(0); index != size; ++index)
1038         [array addObject:CYCastNSString(pool, context, JSPropertyNameArrayGetNameAtIndex(names, index))];
1039     return array;
1040 }
1041
1042 JSValueRef CYCastJSValue(JSContextRef context, NSObject *value) { CYPoolTry {
1043     if (value == nil)
1044         return CYJSNull(context);
1045     else if ([value respondsToSelector:@selector(cy$JSValueInContext:)])
1046         return [value cy$JSValueInContext:context];
1047     else
1048         return CYMakeInstance(context, value, false);
1049 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1050
1051 @implementation CYJSObject
1052
1053 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry {
1054     if ((self = [super init]) != nil) {
1055         object_ = object;
1056         context_ = CYGetJSContext(context);
1057         //XXX:JSGlobalContextRetain(context_);
1058         JSValueProtect(context_, object_);
1059     } return self;
1060 } CYObjectiveCatch }
1061
1062 - (void) dealloc { CYObjectiveTry {
1063     JSValueUnprotect(context_, object_);
1064     //XXX:JSGlobalContextRelease(context_);
1065     [super dealloc];
1066 } CYObjectiveCatch }
1067
1068 - (NSObject *) cy$toJSON:(NSString *)key { CYObjectiveTry {
1069     JSValueRef toJSON(CYGetProperty(context_, object_, toJSON_));
1070     if (!CYIsCallable(context_, toJSON))
1071         return [super cy$toJSON:key];
1072     else {
1073         JSValueRef arguments[1] = {CYCastJSValue(context_, key)};
1074         JSValueRef value(CYCallAsFunction(context_, (JSObjectRef) toJSON, object_, 1, arguments));
1075         // XXX: do I really want an NSNull here?!
1076         return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1077     }
1078 } CYObjectiveCatch }
1079
1080 - (NSString *) cy$toCYON { CYObjectiveTry {
1081     CYPool pool;
1082     JSValueRef exception(NULL);
1083     const char *cyon(CYPoolCCYON(pool, context_, object_));
1084     CYThrow(context_, exception);
1085     if (cyon == NULL)
1086         return [super cy$toCYON];
1087     else
1088         return [NSString stringWithUTF8String:cyon];
1089 } CYObjectiveCatch }
1090
1091 - (NSUInteger) count { CYObjectiveTry {
1092     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1093     size_t size(JSPropertyNameArrayGetCount(names));
1094     JSPropertyNameArrayRelease(names);
1095     return size;
1096 } CYObjectiveCatch }
1097
1098 - (id) objectForKey:(id)key { CYObjectiveTry {
1099     // XXX: are NSDictionary keys always NSString *?
1100     JSValueRef value(CYGetProperty(context_, object_, CYJSString(context_, (NSString *) key)));
1101     if (JSValueIsUndefined(context_, value))
1102         return nil;
1103     return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1104 } CYObjectiveCatch }
1105
1106 - (NSEnumerator *) keyEnumerator { CYObjectiveTry {
1107     JSPropertyNameArrayRef names(JSObjectCopyPropertyNames(context_, object_));
1108     NSEnumerator *enumerator([CYCastNSArray(context_, names) objectEnumerator]);
1109     JSPropertyNameArrayRelease(names);
1110     return enumerator;
1111 } CYObjectiveCatch }
1112
1113 - (void) setObject:(id)object forKey:(id)key { CYObjectiveTry {
1114     // XXX: are NSDictionary keys always NSString *?
1115     CYSetProperty(context_, object_, CYJSString(context_, (NSString *) key), CYCastJSValue(context_, (NSString *) object));
1116 } CYObjectiveCatch }
1117
1118 - (void) removeObjectForKey:(id)key { CYObjectiveTry {
1119     JSValueRef exception(NULL);
1120     // XXX: are NSDictionary keys always NSString *?
1121     (void) JSObjectDeleteProperty(context_, object_, CYJSString(context_, (NSString *) key), &exception);
1122     CYThrow(context_, exception);
1123 } CYObjectiveCatch }
1124
1125 @end
1126
1127 @implementation CYJSArray
1128
1129 - (id) initWithJSObject:(JSObjectRef)object inContext:(JSContextRef)context { CYObjectiveTry {
1130     if ((self = [super init]) != nil) {
1131         object_ = object;
1132         context_ = CYGetJSContext(context);
1133         //XXX:JSGlobalContextRetain(context_);
1134         JSValueProtect(context_, object_);
1135     } return self;
1136 } CYObjectiveCatch }
1137
1138 - (void) dealloc { CYObjectiveTry {
1139     JSValueUnprotect(context_, object_);
1140     //XXX:JSGlobalContextRelease(context_);
1141     [super dealloc];
1142 } CYObjectiveCatch }
1143
1144 - (NSUInteger) count { CYObjectiveTry {
1145     return CYCastDouble(context_, CYGetProperty(context_, object_, length_));
1146 } CYObjectiveCatch }
1147
1148 - (id) objectAtIndex:(NSUInteger)index { CYObjectiveTry {
1149     size_t bounds([self count]);
1150     if (index >= bounds)
1151         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray objectAtIndex:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1152     JSValueRef exception(NULL);
1153     JSValueRef value(JSObjectGetPropertyAtIndex(context_, object_, index, &exception));
1154     CYThrow(context_, exception);
1155     return CYCastNSObject(NULL, context_, value) ?: [NSNull null];
1156 } CYObjectiveCatch }
1157
1158 - (void) addObject:(id)object { CYObjectiveTry {
1159     JSValueRef exception(NULL);
1160     JSValueRef arguments[1];
1161     arguments[0] = CYCastJSValue(context_, (NSObject *) object);
1162     JSObjectCallAsFunction(context_, Array_push_, object_, 1, arguments, &exception);
1163     CYThrow(context_, exception);
1164 } CYObjectiveCatch }
1165
1166 - (void) insertObject:(id)object atIndex:(NSUInteger)index { CYObjectiveTry {
1167     size_t bounds([self count] + 1);
1168     if (index >= bounds)
1169         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray insertObject:atIndex:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1170     JSValueRef exception(NULL);
1171     JSValueRef arguments[3];
1172     arguments[0] = CYCastJSValue(context_, index);
1173     arguments[1] = CYCastJSValue(context_, 0);
1174     arguments[2] = CYCastJSValue(context_, (NSObject *) object);
1175     JSObjectCallAsFunction(context_, Array_splice_, object_, 3, arguments, &exception);
1176     CYThrow(context_, exception);
1177 } CYObjectiveCatch }
1178
1179 - (void) removeLastObject { CYObjectiveTry {
1180     JSValueRef exception(NULL);
1181     JSObjectCallAsFunction(context_, Array_pop_, object_, 0, NULL, &exception);
1182     CYThrow(context_, exception);
1183 } CYObjectiveCatch }
1184
1185 - (void) removeObjectAtIndex:(NSUInteger)index { CYObjectiveTry {
1186     size_t bounds([self count]);
1187     if (index >= bounds)
1188         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray removeObjectAtIndex:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1189     JSValueRef exception(NULL);
1190     JSValueRef arguments[2];
1191     arguments[0] = CYCastJSValue(context_, index);
1192     arguments[1] = CYCastJSValue(context_, 1);
1193     JSObjectCallAsFunction(context_, Array_splice_, object_, 2, arguments, &exception);
1194     CYThrow(context_, exception);
1195 } CYObjectiveCatch }
1196
1197 - (void) replaceObjectAtIndex:(NSUInteger)index withObject:(id)object { CYObjectiveTry {
1198     size_t bounds([self count]);
1199     if (index >= bounds)
1200         @throw [NSException exceptionWithName:NSRangeException reason:[NSString stringWithFormat:@"*** -[CYJSArray replaceObjectAtIndex:withObject:]: index (%zu) beyond bounds (%zu)", index, bounds] userInfo:nil];
1201     CYSetProperty(context_, object_, index, CYCastJSValue(context_, (NSObject *) object));
1202 } CYObjectiveCatch }
1203
1204 @end
1205
1206 // XXX: use objc_getAssociatedObject and objc_setAssociatedObject on 10.6
1207 struct CYInternal :
1208     CYData
1209 {
1210     JSObjectRef object_;
1211
1212     CYInternal() :
1213         object_(NULL)
1214     {
1215     }
1216
1217     ~CYInternal() {
1218         // XXX: delete object_? ;(
1219     }
1220
1221     static CYInternal *Get(id self) {
1222         CYInternal *internal(NULL);
1223         if (object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal)) == NULL) {
1224             // XXX: do something epic? ;P
1225         }
1226
1227         return internal;
1228     }
1229
1230     static CYInternal *Set(id self) {
1231         CYInternal *internal(NULL);
1232         if (objc_ivar *ivar = object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal))) {
1233             if (internal == NULL) {
1234                 internal = new CYInternal();
1235                 object_setIvar(self, ivar, reinterpret_cast<id>(internal));
1236             }
1237         } else {
1238             // XXX: do something epic? ;P
1239         }
1240
1241         return internal;
1242     }
1243
1244     bool HasProperty(JSContextRef context, JSStringRef name) {
1245         if (object_ == NULL)
1246             return false;
1247         return JSObjectHasProperty(context, object_, name);
1248     }
1249
1250     JSValueRef GetProperty(JSContextRef context, JSStringRef name) {
1251         if (object_ == NULL)
1252             return NULL;
1253         return CYGetProperty(context, object_, name);
1254     }
1255
1256     void SetProperty(JSContextRef context, JSStringRef name, JSValueRef value) {
1257         if (object_ == NULL)
1258             object_ = JSObjectMake(context, NULL, NULL);
1259         CYSetProperty(context, object_, name, value);
1260     }
1261 };
1262
1263 static JSObjectRef CYMakeSelector(JSContextRef context, SEL sel) {
1264     Selector_privateData *internal(new Selector_privateData(sel));
1265     return JSObjectMake(context, Selector_, internal);
1266 }
1267
1268 static SEL CYCastSEL(JSContextRef context, JSValueRef value) {
1269     if (JSValueIsObjectOfClass(context, value, Selector_)) {
1270         Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1271         return reinterpret_cast<SEL>(internal->value_);
1272     } else
1273         return CYCastPointer<SEL>(context, value);
1274 }
1275
1276 void *CYObjectiveC_ExecuteStart(JSContextRef context) {
1277     // XXX: deal with exceptions!
1278     return (void *) [[NSAutoreleasePool alloc] init];
1279 }
1280
1281 void CYObjectiveC_ExecuteEnd(JSContextRef context, void *handle) {
1282     // XXX: deal with exceptions!
1283     return [(NSAutoreleasePool *) handle release];
1284 }
1285
1286 JSValueRef CYObjectiveC_RuntimeProperty(JSContextRef context, CYUTF8String name) { CYPoolTry {
1287     if (name == "nil")
1288         return Instance::Make(context, nil);
1289     if (Class _class = objc_getClass(name.data))
1290         return CYMakeInstance(context, _class, true);
1291     return NULL;
1292 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1293
1294 static void CYObjectiveC_CallFunction(JSContextRef context, ffi_cif *cif, void (*function)(), uint8_t *value, void **values) { @try {
1295     ffi_call(cif, function, value, values);
1296 } @catch (NSException *error ) {
1297     throw CYJSError(context, CYCastJSValue(context, error));
1298 } }
1299
1300 static bool CYObjectiveC_PoolFFI(apr_pool_t *pool, JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, JSValueRef value) { CYPoolTry  {
1301     switch (type->primitive) {
1302         case sig::object_P:
1303         case sig::typename_P:
1304             *reinterpret_cast<id *>(data) = CYCastNSObject(pool, context, value);
1305         break;
1306
1307         case sig::selector_P:
1308             *reinterpret_cast<SEL *>(data) = CYCastSEL(context, value);
1309         break;
1310
1311         default:
1312             return false;
1313     }
1314
1315     return true;
1316 } CYPoolCatch(false) return /*XXX*/ NULL; }
1317
1318 static JSValueRef CYObjectiveC_FromFFI(JSContextRef context, sig::Type *type, ffi_type *ffi, void *data, bool initialize, JSObjectRef owner) { CYPoolTry {
1319     switch (type->primitive) {
1320         case sig::object_P:
1321             if (NSObject *object = *reinterpret_cast<NSObject **>(data)) {
1322                 JSValueRef value(CYCastJSValue(context, object));
1323                 if (initialize)
1324                     [object release];
1325                 return value;
1326             } else goto null;
1327
1328         case sig::typename_P:
1329             return CYMakeInstance(context, *reinterpret_cast<Class *>(data), true);
1330
1331         case sig::selector_P:
1332             if (SEL sel = *reinterpret_cast<SEL *>(data))
1333                 return CYMakeSelector(context, sel);
1334             else goto null;
1335
1336         null:
1337             return CYJSNull(context);
1338         default:
1339             return NULL;
1340     }
1341 } CYPoolCatch(NULL) return /*XXX*/ NULL; }
1342
1343 static bool CYImplements(id object, Class _class, SEL selector, bool devoid) {
1344     if (objc_method *method = class_getInstanceMethod(_class, selector)) {
1345         if (!devoid)
1346             return true;
1347 #if OBJC_API_VERSION >= 2
1348         char type[16];
1349         method_getReturnType(method, type, sizeof(type));
1350 #else
1351         const char *type(method_getTypeEncoding(method));
1352 #endif
1353         if (type[0] != 'v')
1354             return true;
1355     }
1356
1357     // XXX: possibly use a more "awesome" check?
1358     return false;
1359 }
1360
1361 static const char *CYPoolTypeEncoding(apr_pool_t *pool, JSContextRef context, SEL sel, objc_method *method) {
1362     if (method != NULL)
1363         return method_getTypeEncoding(method);
1364
1365     const char *name(sel_getName(sel));
1366
1367     sqlite3_stmt *statement;
1368
1369     _sqlcall(sqlite3_prepare(Bridge_,
1370         "select "
1371             "\"bridge\".\"value\" "
1372         "from \"bridge\" "
1373         "where"
1374             " \"bridge\".\"mode\" = -1 and"
1375             " \"bridge\".\"name\" = ?"
1376         " limit 1"
1377     , -1, &statement, NULL));
1378
1379     _trace();
1380     _sqlcall(sqlite3_bind_text(statement, 1, name, -1, SQLITE_STATIC));
1381
1382     const char *value;
1383     if (_sqlcall(sqlite3_step(statement)) == SQLITE_DONE) {
1384     _trace();
1385         value = NULL;}
1386     else {
1387     _trace();
1388         value = sqlite3_column_pooled(pool, statement, 0);
1389         }
1390
1391     _sqlcall(sqlite3_finalize(statement));
1392
1393     if (value != NULL)
1394         return value;
1395 _trace();
1396     return NULL;
1397 }
1398
1399 static void MessageClosure_(ffi_cif *cif, void *result, void **arguments, void *arg) {
1400     Closure_privateData *internal(reinterpret_cast<Closure_privateData *>(arg));
1401
1402     JSContextRef context(internal->context_);
1403
1404     size_t count(internal->cif_.nargs);
1405     JSValueRef values[count];
1406
1407     for (size_t index(0); index != count; ++index)
1408         values[index] = CYFromFFI(context, internal->signature_.elements[1 + index].type, internal->cif_.arg_types[index], arguments[index]);
1409
1410     JSObjectRef _this(CYCastJSObject(context, values[0]));
1411
1412     JSValueRef value(CYCallAsFunction(context, internal->function_, _this, count - 2, values + 2));
1413     CYPoolFFI(NULL, context, internal->signature_.elements[0].type, internal->cif_.rtype, result, value);
1414 }
1415
1416 static JSObjectRef CYMakeMessage(JSContextRef context, SEL sel, IMP imp, const char *type) {
1417     Message_privateData *internal(new Message_privateData(sel, type, imp));
1418     return JSObjectMake(context, Message_, internal);
1419 }
1420
1421 static IMP CYMakeMessage(JSContextRef context, JSValueRef value, const char *type) {
1422     JSObjectRef function(CYCastJSObject(context, value));
1423     Closure_privateData *internal(CYMakeFunctor_(context, function, type, &MessageClosure_));
1424     return reinterpret_cast<IMP>(internal->GetValue());
1425 }
1426
1427 static bool Messages_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1428     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1429     Class _class(internal->GetValue());
1430
1431     CYPool pool;
1432     const char *name(CYPoolCString(pool, context, property));
1433
1434     if (SEL sel = sel_getUid(name))
1435         if (class_getInstanceMethod(_class, sel) != NULL)
1436             return true;
1437
1438     return false;
1439 }
1440
1441 static JSValueRef Messages_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1442     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1443     Class _class(internal->GetValue());
1444
1445     CYPool pool;
1446     const char *name(CYPoolCString(pool, context, property));
1447
1448     if (SEL sel = sel_getUid(name))
1449         if (objc_method *method = class_getInstanceMethod(_class, sel))
1450             return CYMakeMessage(context, sel, method_getImplementation(method), method_getTypeEncoding(method));
1451
1452     return NULL;
1453 }
1454
1455 static bool Messages_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) {
1456     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1457     Class _class(internal->GetValue());
1458
1459     CYPool pool;
1460     const char *name(CYPoolCString(pool, context, property));
1461
1462     SEL sel(sel_registerName(name));
1463
1464     objc_method *method(class_getInstanceMethod(_class, sel));
1465
1466     const char *type;
1467     IMP imp;
1468
1469     if (JSValueIsObjectOfClass(context, value, Message_)) {
1470         Message_privateData *message(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate((JSObjectRef) value)));
1471         type = sig::Unparse(pool, &message->signature_);
1472         imp = reinterpret_cast<IMP>(message->GetValue());
1473     } else {
1474         type = CYPoolTypeEncoding(pool, context, sel, method);
1475         imp = CYMakeMessage(context, value, type);
1476     }
1477
1478     if (method != NULL)
1479         method_setImplementation(method, imp);
1480     else {
1481 #ifdef GNU_RUNTIME
1482         GSMethodList list(GSAllocMethodList(1));
1483         GSAppendMethodToList(list, sel, type, imp, YES);
1484         GSAddMethodList(_class, list, YES);
1485         GSFlushMethodCacheForClass(_class);
1486 #else
1487         class_addMethod(_class, sel, imp, type);
1488 #endif
1489     }
1490
1491     return true;
1492 }
1493
1494 #if 0 && OBJC_API_VERSION < 2
1495 static bool Messages_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
1496     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1497     Class _class(internal->GetValue());
1498
1499     CYPool pool;
1500     const char *name(CYPoolCString(pool, context, property));
1501
1502     if (SEL sel = sel_getUid(name))
1503         if (objc_method *method = class_getInstanceMethod(_class, sel)) {
1504             objc_method_list list = {NULL, 1, {method}};
1505             class_removeMethods(_class, &list);
1506             return true;
1507         }
1508
1509     return false;
1510 }
1511 #endif
1512
1513 static void Messages_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1514     Messages *internal(reinterpret_cast<Messages *>(JSObjectGetPrivate(object)));
1515     Class _class(internal->GetValue());
1516
1517 #if OBJC_API_VERSION >= 2
1518     unsigned int size;
1519     objc_method **data(class_copyMethodList(_class, &size));
1520     for (size_t i(0); i != size; ++i)
1521         JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(data[i]))));
1522     free(data);
1523 #else
1524     for (objc_method_list *methods(_class->methods); methods != NULL; methods = methods->method_next)
1525         for (int i(0); i != methods->method_count; ++i)
1526             JSPropertyNameAccumulatorAddName(names, CYJSString(sel_getName(method_getName(&methods->method_list[i]))));
1527 #endif
1528 }
1529
1530 static bool Instance_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1531     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1532     id self(internal->GetValue());
1533
1534     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1535         return true;
1536
1537     CYPool pool;
1538     NSString *name(CYCastNSString(pool, context, property));
1539
1540     if (CYInternal *internal = CYInternal::Get(self))
1541         if (internal->HasProperty(context, property))
1542             return true;
1543
1544     Class _class(object_getClass(self));
1545
1546     CYPoolTry {
1547         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1548         if (CYImplements(self, _class, @selector(cy$hasProperty:), false))
1549             if ([self cy$hasProperty:name])
1550                 return true;
1551     } CYPoolCatch(false)
1552
1553     const char *string(CYPoolCString(pool, context, name));
1554
1555 #ifdef __APPLE__
1556     if (class_getProperty(_class, string) != NULL)
1557         return true;
1558 #endif
1559
1560     if (SEL sel = sel_getUid(string))
1561         if (CYImplements(self, _class, sel, true))
1562             return true;
1563
1564     return false;
1565 }
1566
1567 static JSValueRef Instance_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1568     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1569     id self(internal->GetValue());
1570
1571     if (JSStringIsEqualToUTF8CString(property, "$cyi"))
1572         return Internal::Make(context, self, object);
1573
1574     CYPool pool;
1575     NSString *name(CYCastNSString(pool, context, property));
1576
1577     if (CYInternal *internal = CYInternal::Get(self))
1578         if (JSValueRef value = internal->GetProperty(context, property))
1579             return value;
1580
1581     CYPoolTry {
1582         if (NSObject *data = [self cy$getProperty:name])
1583             return CYCastJSValue(context, data);
1584     } CYPoolCatch(NULL)
1585
1586     const char *string(CYPoolCString(pool, context, name));
1587     Class _class(object_getClass(self));
1588
1589 #ifdef __APPLE__
1590     if (objc_property_t property = class_getProperty(_class, string)) {
1591         PropertyAttributes attributes(property);
1592         SEL sel(sel_registerName(attributes.Getter()));
1593         return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false, exception);
1594     }
1595 #endif
1596
1597     if (SEL sel = sel_getUid(string))
1598         if (CYImplements(self, _class, sel, true))
1599             return CYSendMessage(pool, context, self, NULL, sel, 0, NULL, false, exception);
1600
1601     return NULL;
1602 } CYCatch }
1603
1604 static bool Instance_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1605     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1606     id self(internal->GetValue());
1607
1608     CYPool pool;
1609
1610     NSString *name(CYCastNSString(pool, context, property));
1611     NSObject *data(CYCastNSObject(pool, context, value));
1612
1613     CYPoolTry {
1614         if ([self cy$setProperty:name to:data])
1615             return true;
1616     } CYPoolCatch(NULL)
1617
1618     const char *string(CYPoolCString(pool, context, name));
1619     Class _class(object_getClass(self));
1620
1621 #ifdef __APPLE__
1622     if (objc_property_t property = class_getProperty(_class, string)) {
1623         PropertyAttributes attributes(property);
1624         if (const char *setter = attributes.Setter()) {
1625             SEL sel(sel_registerName(setter));
1626             JSValueRef arguments[1] = {value};
1627             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false, exception);
1628             return true;
1629         }
1630     }
1631 #endif
1632
1633     size_t length(strlen(string));
1634
1635     char set[length + 5];
1636
1637     set[0] = 's';
1638     set[1] = 'e';
1639     set[2] = 't';
1640
1641     if (string[0] != '\0') {
1642         set[3] = toupper(string[0]);
1643         memcpy(set + 4, string + 1, length - 1);
1644     }
1645
1646     set[length + 3] = ':';
1647     set[length + 4] = '\0';
1648
1649     if (SEL sel = sel_getUid(set))
1650         if (CYImplements(self, _class, sel, false)) {
1651             JSValueRef arguments[1] = {value};
1652             CYSendMessage(pool, context, self, NULL, sel, 1, arguments, false, exception);
1653         }
1654
1655     if (CYInternal *internal = CYInternal::Set(self)) {
1656         internal->SetProperty(context, property, value);
1657         return true;
1658     }
1659
1660     return false;
1661 } CYCatch }
1662
1663 static bool Instance_deleteProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1664     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1665     id self(internal->GetValue());
1666
1667     CYPoolTry {
1668         NSString *name(CYCastNSString(NULL, context, property));
1669         return [self cy$deleteProperty:name];
1670     } CYPoolCatch(NULL)
1671 } CYCatch return /*XXX*/ NULL; }
1672
1673 static void Instance_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1674     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1675     id self(internal->GetValue());
1676
1677     CYPool pool;
1678     Class _class(object_getClass(self));
1679
1680 #ifdef __APPLE__
1681     {
1682         unsigned int size;
1683         objc_property_t *data(class_copyPropertyList(_class, &size));
1684         for (size_t i(0); i != size; ++i)
1685             JSPropertyNameAccumulatorAddName(names, CYJSString(property_getName(data[i])));
1686         free(data);
1687     }
1688 #endif
1689
1690     CYPoolTry {
1691         // XXX: this is an evil hack to deal with NSProxy; fix elsewhere
1692         if (CYImplements(self, _class, @selector(cy$getPropertyNames:inContext:), false))
1693             [self cy$getPropertyNames:names inContext:context];
1694     } CYPoolCatch()
1695 }
1696
1697 static JSObjectRef Instance_callAsConstructor(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1698     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
1699     JSObjectRef value(Instance::Make(context, [internal->GetValue() alloc], Instance::Uninitialized));
1700     return value;
1701 } CYCatch }
1702
1703 static bool Instance_hasInstance(JSContextRef context, JSObjectRef constructor, JSValueRef instance, JSValueRef *exception) { CYTry {
1704     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) constructor)));
1705     Class _class(internal->GetValue());
1706     if (!CYIsClass(_class))
1707         return false;
1708
1709     if (JSValueIsObjectOfClass(context, instance, Instance_)) {
1710         Instance *linternal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) instance)));
1711         // XXX: this isn't always safe
1712         return [linternal->GetValue() isKindOfClass:_class];
1713     }
1714
1715     return false;
1716 } CYCatch }
1717
1718 static bool Internal_hasProperty(JSContextRef context, JSObjectRef object, JSStringRef property) {
1719     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1720     CYPool pool;
1721
1722     id self(internal->GetValue());
1723     const char *name(CYPoolCString(pool, context, property));
1724
1725     if (object_getInstanceVariable(self, name, NULL) != NULL)
1726         return true;
1727
1728     return false;
1729 }
1730
1731 static JSValueRef Internal_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1732     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1733     CYPool pool;
1734
1735     id self(internal->GetValue());
1736     const char *name(CYPoolCString(pool, context, property));
1737
1738     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
1739         Type_privateData type(pool, ivar_getTypeEncoding(ivar));
1740         // XXX: if this fails and throws an exception the person we are throwing it to gets the wrong exception
1741         return CYFromFFI(context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar));
1742     }
1743
1744     return NULL;
1745 } CYCatch }
1746
1747 static bool Internal_setProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef value, JSValueRef *exception) { CYTry {
1748     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1749     CYPool pool;
1750
1751     id self(internal->GetValue());
1752     const char *name(CYPoolCString(pool, context, property));
1753
1754     if (objc_ivar *ivar = object_getInstanceVariable(self, name, NULL)) {
1755         Type_privateData type(pool, ivar_getTypeEncoding(ivar));
1756         CYPoolFFI(pool, context, type.type_, type.GetFFI(), reinterpret_cast<uint8_t *>(self) + ivar_getOffset(ivar), value);
1757         return true;
1758     }
1759
1760     return false;
1761 } CYCatch }
1762
1763 static void Internal_getPropertyNames_(Class _class, JSPropertyNameAccumulatorRef names) {
1764     if (Class super = class_getSuperclass(_class))
1765         Internal_getPropertyNames_(super, names);
1766
1767 #if OBJC_API_VERSION >= 2
1768     unsigned int size;
1769     objc_ivar **data(class_copyIvarList(_class, &size));
1770     for (size_t i(0); i != size; ++i)
1771         JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(data[i])));
1772     free(data);
1773 #else
1774     if (objc_ivar_list *ivars = _class->ivars)
1775         for (int i(0); i != ivars->ivar_count; ++i)
1776             JSPropertyNameAccumulatorAddName(names, CYJSString(ivar_getName(&ivars->ivar_list[i])));
1777 #endif
1778 }
1779
1780 static void Internal_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1781     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1782     CYPool pool;
1783
1784     id self(internal->GetValue());
1785     Class _class(object_getClass(self));
1786
1787     Internal_getPropertyNames_(_class, names);
1788 }
1789
1790 static JSValueRef Internal_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
1791     Internal *internal(reinterpret_cast<Internal *>(JSObjectGetPrivate(object)));
1792     return internal->GetOwner();
1793 }
1794
1795 static JSValueRef ObjectiveC_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1796     CYPool pool;
1797     NSString *name(CYCastNSString(pool, context, property));
1798     if (Class _class = NSClassFromString(name))
1799         return CYMakeInstance(context, _class, true);
1800     return NULL;
1801 } CYCatch }
1802
1803 static void ObjectiveC_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1804 #ifdef __APPLE__
1805     size_t size(objc_getClassList(NULL, 0));
1806     Class *data(reinterpret_cast<Class *>(malloc(sizeof(Class) * size)));
1807
1808   get:
1809     size_t writ(objc_getClassList(data, size));
1810     if (size < writ) {
1811         size = writ;
1812         if (Class *copy = reinterpret_cast<Class *>(realloc(data, sizeof(Class) * writ))) {
1813             data = copy;
1814             goto get;
1815         } else goto done;
1816     }
1817
1818     for (size_t i(0); i != writ; ++i)
1819         JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(data[i])));
1820
1821   done:
1822     free(data);
1823 #else
1824     void *state(NULL);
1825     while (Class _class = objc_next_class(&state))
1826         JSPropertyNameAccumulatorAddName(names, CYJSString(class_getName(_class)));
1827 #endif
1828 }
1829
1830 #if OBJC_API_VERSION >= 2
1831 static JSValueRef ObjectiveC_Image_Classes_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1832     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
1833
1834     CYPool pool;
1835     const char *name(CYPoolCString(pool, context, property));
1836     unsigned int size;
1837     const char **data(objc_copyClassNamesForImage(internal, &size));
1838     JSValueRef value;
1839     for (size_t i(0); i != size; ++i)
1840         if (strcmp(name, data[i]) == 0) {
1841             if (Class _class = objc_getClass(name)) {
1842                 value = CYMakeInstance(context, _class, true);
1843                 goto free;
1844             } else
1845                 break;
1846         }
1847     value = NULL;
1848   free:
1849     free(data);
1850     return value;
1851 } CYCatch }
1852
1853 static void ObjectiveC_Image_Classes_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1854     const char *internal(reinterpret_cast<const char *>(JSObjectGetPrivate(object)));
1855     unsigned int size;
1856     const char **data(objc_copyClassNamesForImage(internal, &size));
1857     for (size_t i(0); i != size; ++i)
1858         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
1859     free(data);
1860 }
1861
1862 static JSValueRef ObjectiveC_Images_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1863     CYPool pool;
1864     const char *name(CYPoolCString(pool, context, property));
1865     unsigned int size;
1866     const char **data(objc_copyImageNames(&size));
1867     for (size_t i(0); i != size; ++i)
1868         if (strcmp(name, data[i]) == 0) {
1869             name = data[i];
1870             goto free;
1871         }
1872     name = NULL;
1873   free:
1874     free(data);
1875     if (name == NULL)
1876         return NULL;
1877     JSObjectRef value(JSObjectMake(context, NULL, NULL));
1878     CYSetProperty(context, value, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Image_Classes_, const_cast<char *>(name)));
1879     return value;
1880 } CYCatch }
1881
1882 static void ObjectiveC_Images_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1883     unsigned int size;
1884     const char **data(objc_copyImageNames(&size));
1885     for (size_t i(0); i != size; ++i)
1886         JSPropertyNameAccumulatorAddName(names, CYJSString(data[i]));
1887     free(data);
1888 }
1889 #endif
1890
1891 static JSValueRef ObjectiveC_Protocols_getProperty(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
1892     CYPool pool;
1893     const char *name(CYPoolCString(pool, context, property));
1894     if (Protocol *protocol = objc_getProtocol(name))
1895         return CYMakeInstance(context, protocol, true);
1896     return NULL;
1897 } CYCatch }
1898
1899 static void ObjectiveC_Protocols_getPropertyNames(JSContextRef context, JSObjectRef object, JSPropertyNameAccumulatorRef names) {
1900 #if OBJC_API_VERSION >= 2
1901     unsigned int size;
1902     Protocol **data(objc_copyProtocolList(&size));
1903     for (size_t i(0); i != size; ++i)
1904         JSPropertyNameAccumulatorAddName(names, CYJSString(protocol_getName(data[i])));
1905     free(data);
1906 #else
1907     // XXX: fix this!
1908 #endif
1909 }
1910
1911 #ifdef __APPLE__
1912 static bool stret(ffi_type *ffi_type) {
1913     return ffi_type->type == FFI_TYPE_STRUCT && (
1914         ffi_type->size > OBJC_MAX_STRUCT_BY_VALUE ||
1915         struct_forward_array[ffi_type->size] != 0
1916     );
1917 }
1918 #endif
1919
1920 JSValueRef CYSendMessage(apr_pool_t *pool, JSContextRef context, id self, Class _class, SEL _cmd, size_t count, const JSValueRef arguments[], bool initialize, JSValueRef *exception) { CYTry {
1921     const char *type;
1922
1923     if (_class == NULL)
1924         _class = object_getClass(self);
1925
1926     IMP imp;
1927
1928     if (objc_method *method = class_getInstanceMethod(_class, _cmd)) {
1929         imp = method_getImplementation(method);
1930         type = method_getTypeEncoding(method);
1931     } else {
1932         imp = NULL;
1933
1934         CYPoolTry {
1935             NSMethodSignature *method([self methodSignatureForSelector:_cmd]);
1936             if (method == nil)
1937                 throw CYJSError(context, "unrecognized selector %s sent to object %p", sel_getName(_cmd), self);
1938             type = CYPoolCString(pool, context, [method _typeString]);
1939         } CYPoolCatch(NULL)
1940     }
1941
1942     void *setup[2];
1943     setup[0] = &self;
1944     setup[1] = &_cmd;
1945
1946     sig::Signature signature;
1947     sig::Parse(pool, &signature, type, &Structor_);
1948
1949     ffi_cif cif;
1950     sig::sig_ffi_cif(pool, &sig::ObjectiveC, &signature, &cif);
1951
1952     if (imp == NULL) {
1953 #ifdef __APPLE__
1954         if (stret(cif.rtype))
1955             imp = class_getMethodImplementation_stret(_class, _cmd);
1956         else
1957             imp = class_getMethodImplementation(_class, _cmd);
1958 #else
1959         objc_super super = {self, _class};
1960         imp = objc_msg_lookup_super(&super, _cmd);
1961 #endif
1962     }
1963
1964     void (*function)() = reinterpret_cast<void (*)()>(imp);
1965     return CYCallFunction(pool, context, 2, setup, count, arguments, initialize, exception, &signature, &cif, function);
1966 } CYCatch }
1967
1968 static JSValueRef $objc_msgSend(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
1969     if (count < 2)
1970         throw CYJSError(context, "too few arguments to objc_msgSend");
1971
1972     CYPool pool;
1973
1974     bool uninitialized;
1975
1976     id self;
1977     SEL _cmd;
1978     Class _class;
1979
1980     if (JSValueIsObjectOfClass(context, arguments[0], Super_)) {
1981         cy::Super *internal(reinterpret_cast<cy::Super *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
1982         self = internal->GetValue();
1983         _class = internal->class_;;
1984         uninitialized = false;
1985     } else if (JSValueIsObjectOfClass(context, arguments[0], Instance_)) {
1986         Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate((JSObjectRef) arguments[0])));
1987         self = internal->GetValue();
1988         _class = nil;
1989         uninitialized = internal->IsUninitialized();
1990         if (uninitialized)
1991             internal->value_ = nil;
1992     } else {
1993         self = CYCastNSObject(pool, context, arguments[0]);
1994         _class = nil;
1995         uninitialized = false;
1996     }
1997
1998     if (self == nil)
1999         return CYJSNull(context);
2000
2001     _cmd = CYCastSEL(context, arguments[1]);
2002
2003     return CYSendMessage(pool, context, self, _class, _cmd, count - 2, arguments + 2, uninitialized, exception);
2004 } CYCatch }
2005
2006 /* Hook: objc_registerClassPair {{{ */
2007 #if defined(__APPLE__) && defined(__arm__)
2008 // XXX: replace this with associated objects
2009
2010 MSHook(void, CYDealloc, id self, SEL sel) {
2011     CYInternal *internal;
2012     object_getInstanceVariable(self, "cy$internal_", reinterpret_cast<void **>(&internal));
2013     if (internal != NULL)
2014         delete internal;
2015     _CYDealloc(self, sel);
2016 }
2017
2018 MSHook(void, objc_registerClassPair, Class _class) {
2019     Class super(class_getSuperclass(_class));
2020     if (super == NULL || class_getInstanceVariable(super, "cy$internal_") == NULL) {
2021         class_addIvar(_class, "cy$internal_", sizeof(CYInternal *), log2(sizeof(CYInternal *)), "^{CYInternal}");
2022         MSHookMessage(_class, @selector(dealloc), MSHake(CYDealloc));
2023     }
2024
2025     _objc_registerClassPair(_class);
2026 }
2027
2028 static JSValueRef objc_registerClassPair_(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2029     if (count != 1)
2030         throw CYJSError(context, "incorrect number of arguments to objc_registerClassPair");
2031     CYPool pool;
2032     NSObject *value(CYCastNSObject(pool, context, arguments[0]));
2033     if (value == NULL || !CYIsClass(value))
2034         throw CYJSError(context, "incorrect number of arguments to objc_registerClassPair");
2035     Class _class((Class) value);
2036     $objc_registerClassPair(_class);
2037     return CYJSUndefined(context);
2038 } CYCatch }
2039 #endif
2040 /* }}} */
2041
2042 static JSValueRef Selector_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2043     JSValueRef setup[count + 2];
2044     setup[0] = _this;
2045     setup[1] = object;
2046     memcpy(setup + 2, arguments, sizeof(JSValueRef) * count);
2047     return $objc_msgSend(context, NULL, NULL, count + 2, setup, exception);
2048 }
2049
2050 static JSValueRef Message_callAsFunction(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2051     CYPool pool;
2052     Message_privateData *internal(reinterpret_cast<Message_privateData *>(JSObjectGetPrivate(object)));
2053
2054     // XXX: handle Instance::Uninitialized?
2055     id self(CYCastNSObject(pool, context, _this));
2056
2057     void *setup[2];
2058     setup[0] = &self;
2059     setup[1] = &internal->sel_;
2060
2061     return CYCallFunction(pool, context, 2, setup, count, arguments, false, exception, &internal->signature_, &internal->cif_, internal->GetValue());
2062 }
2063
2064 static JSObjectRef Super_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2065     if (count != 2)
2066         throw CYJSError(context, "incorrect number of arguments to Super constructor");
2067     CYPool pool;
2068     id self(CYCastNSObject(pool, context, arguments[0]));
2069     Class _class(CYCastClass(pool, context, arguments[1]));
2070     return cy::Super::Make(context, self, _class);
2071 } CYCatch }
2072
2073 static JSObjectRef Selector_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2074     if (count != 1)
2075         throw CYJSError(context, "incorrect number of arguments to Selector constructor");
2076     CYPool pool;
2077     const char *name(CYPoolCString(pool, context, arguments[0]));
2078     return CYMakeSelector(context, sel_registerName(name));
2079 } CYCatch }
2080
2081 static JSObjectRef Instance_new(JSContextRef context, JSObjectRef object, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2082     if (count > 1)
2083         throw CYJSError(context, "incorrect number of arguments to Instance constructor");
2084     id self(count == 0 ? nil : CYCastPointer<id>(context, arguments[0]));
2085     return Instance::Make(context, self);
2086 } CYCatch }
2087
2088 static JSValueRef CYValue_getProperty_value(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2089     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(object)));
2090     return CYCastJSValue(context, reinterpret_cast<uintptr_t>(internal->value_));
2091 }
2092
2093 static JSValueRef CYValue_callAsFunction_$cya(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2094     CYValue *internal(reinterpret_cast<CYValue *>(JSObjectGetPrivate(_this)));
2095     Type_privateData *typical(internal->GetType());
2096
2097     sig::Type *type;
2098     ffi_type *ffi;
2099
2100     if (typical == NULL) {
2101         type = NULL;
2102         ffi = NULL;
2103     } else {
2104         type = typical->type_;
2105         ffi = typical->ffi_;
2106     }
2107
2108     return CYMakePointer(context, &internal->value_, _not(size_t), type, ffi, object);
2109 }
2110
2111 static JSValueRef Instance_getProperty_constructor(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2112     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2113     return Instance::Make(context, (id) object_getClass(internal->GetValue()));
2114 }
2115
2116 static JSValueRef Instance_getProperty_protocol(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) { CYTry {
2117     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2118     id self(internal->GetValue());
2119     if (!CYIsClass(self))
2120         return CYJSUndefined(context);
2121     return CYGetClassPrototype(context, self);
2122 } CYCatch }
2123
2124 static JSValueRef Instance_getProperty_messages(JSContextRef context, JSObjectRef object, JSStringRef property, JSValueRef *exception) {
2125     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(object)));
2126     id self(internal->GetValue());
2127     if (!CYIsClass(self))
2128         return CYJSUndefined(context);
2129     return Messages::Make(context, (Class) self);
2130 }
2131
2132 static JSValueRef Instance_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2133     if (!JSValueIsObjectOfClass(context, _this, Instance_))
2134         return NULL;
2135
2136     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2137     return CYCastJSValue(context, CYJSString(context, CYCastNSCYON(internal->GetValue())));
2138 } CYCatch }
2139
2140 static JSValueRef Instance_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2141     if (!JSValueIsObjectOfClass(context, _this, Instance_))
2142         return NULL;
2143
2144     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2145
2146     CYPoolTry {
2147         NSString *key;
2148         if (count == 0)
2149             key = nil;
2150         else
2151             key = CYCastNSString(NULL, context, CYJSString(context, arguments[0]));
2152         // XXX: check for support of cy$toJSON?
2153         return CYCastJSValue(context, CYJSString(context, [internal->GetValue() cy$toJSON:key]));
2154     } CYPoolCatch(NULL)
2155 } CYCatch return /*XXX*/ NULL; }
2156
2157 static JSValueRef Instance_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2158     if (!JSValueIsObjectOfClass(context, _this, Instance_))
2159         return NULL;
2160
2161     Instance *internal(reinterpret_cast<Instance *>(JSObjectGetPrivate(_this)));
2162
2163     CYPoolTry {
2164         // XXX: this seems like a stupid implementation; what if it crashes? why not use the CYONifier backend?
2165         return CYCastJSValue(context, CYJSString(context, [internal->GetValue() description]));
2166     } CYPoolCatch(NULL)
2167 } CYCatch return /*XXX*/ NULL; }
2168
2169 static JSValueRef Selector_callAsFunction_toString(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2170     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2171     return CYCastJSValue(context, sel_getName(internal->GetValue()));
2172 } CYCatch }
2173
2174 static JSValueRef Selector_callAsFunction_toJSON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) {
2175     return Selector_callAsFunction_toString(context, object, _this, count, arguments, exception);
2176 }
2177
2178 static JSValueRef Selector_callAsFunction_toCYON(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2179     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2180     const char *name(sel_getName(internal->GetValue()));
2181
2182     CYPoolTry {
2183         NSString *string([NSString stringWithFormat:@"@selector(%s)", name]);
2184         return CYCastJSValue(context, CYJSString(context, string));
2185     } CYPoolCatch(NULL)
2186 } CYCatch return /*XXX*/ NULL; }
2187
2188 static JSValueRef Selector_callAsFunction_type(JSContextRef context, JSObjectRef object, JSObjectRef _this, size_t count, const JSValueRef arguments[], JSValueRef *exception) { CYTry {
2189     if (count != 1)
2190         throw CYJSError(context, "incorrect number of arguments to Selector.type");
2191
2192     CYPool pool;
2193     Selector_privateData *internal(reinterpret_cast<Selector_privateData *>(JSObjectGetPrivate(_this)));
2194     SEL sel(internal->GetValue());
2195
2196     objc_method *method;
2197     if (Class _class = CYCastClass(pool, context, arguments[0]))
2198         method = class_getInstanceMethod(_class, sel);
2199     else
2200         method = NULL;
2201
2202     if (const char *type = CYPoolTypeEncoding(pool, context, sel, method))
2203         return CYCastJSValue(context, CYJSString(type));
2204
2205     return CYJSNull(context);
2206 } CYCatch }
2207
2208 static JSStaticValue Selector_staticValues[2] = {
2209     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontDelete},
2210     {NULL, NULL, NULL, 0}
2211 };
2212
2213 static JSStaticValue Instance_staticValues[5] = {
2214     {"constructor", &Instance_getProperty_constructor, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2215     {"messages", &Instance_getProperty_messages, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2216     {"prototype", &Instance_getProperty_protocol, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2217     {"value", &CYValue_getProperty_value, NULL, kJSPropertyAttributeReadOnly | kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2218     {NULL, NULL, NULL, 0}
2219 };
2220
2221 static JSStaticFunction Instance_staticFunctions[5] = {
2222     {"$cya", &CYValue_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2223     {"toCYON", &Instance_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2224     {"toJSON", &Instance_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2225     {"toString", &Instance_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2226     {NULL, NULL, 0}
2227 };
2228
2229 static JSStaticFunction Internal_staticFunctions[2] = {
2230     {"$cya", &Internal_callAsFunction_$cya, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2231     {NULL, NULL, 0}
2232 };
2233
2234 static JSStaticFunction Selector_staticFunctions[5] = {
2235     {"toCYON", &Selector_callAsFunction_toCYON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2236     {"toJSON", &Selector_callAsFunction_toJSON, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2237     {"toString", &Selector_callAsFunction_toString, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2238     {"type", &Selector_callAsFunction_type, kJSPropertyAttributeDontEnum | kJSPropertyAttributeDontDelete},
2239     {NULL, NULL, 0}
2240 };
2241
2242 void CYObjectiveC_SetupContext(JSContextRef context) {
2243     JSObjectRef global(CYGetGlobalObject(context));
2244     apr_pool_t *pool(CYGetGlobalPool());
2245
2246     Object_type = new(pool) Type_privateData("@");
2247     Selector_type = new(pool) Type_privateData(":");
2248
2249 #ifdef __APPLE__
2250     NSCFBoolean_ = objc_getClass("NSCFBoolean");
2251     NSCFType_ = objc_getClass("NSCFType");
2252     NSMessageBuilder_ = objc_getClass("NSMessageBuilder");
2253     NSZombie_ = objc_getClass("_NSZombie_");
2254 #else
2255     NSBoolNumber_ = objc_getClass("NSBoolNumber");
2256 #endif
2257
2258     NSArray_ = objc_getClass("NSArray");
2259     NSDictionary_ = objc_getClass("NSDictionary");
2260     Object_ = objc_getClass("Object");
2261
2262     JSClassDefinition definition;
2263
2264     definition = kJSClassDefinitionEmpty;
2265     definition.className = "Instance";
2266     definition.staticValues = Instance_staticValues;
2267     definition.staticFunctions = Instance_staticFunctions;
2268     definition.hasProperty = &Instance_hasProperty;
2269     definition.getProperty = &Instance_getProperty;
2270     definition.setProperty = &Instance_setProperty;
2271     definition.deleteProperty = &Instance_deleteProperty;
2272     definition.getPropertyNames = &Instance_getPropertyNames;
2273     definition.callAsConstructor = &Instance_callAsConstructor;
2274     definition.hasInstance = &Instance_hasInstance;
2275     definition.finalize = &CYFinalize;
2276     Instance_ = JSClassCreate(&definition);
2277
2278     definition = kJSClassDefinitionEmpty;
2279     definition.className = "Internal";
2280     definition.staticFunctions = Internal_staticFunctions;
2281     definition.hasProperty = &Internal_hasProperty;
2282     definition.getProperty = &Internal_getProperty;
2283     definition.setProperty = &Internal_setProperty;
2284     definition.getPropertyNames = &Internal_getPropertyNames;
2285     definition.finalize = &CYFinalize;
2286     Internal_ = JSClassCreate(&definition);
2287
2288     definition = kJSClassDefinitionEmpty;
2289     definition.className = "Message";
2290     definition.staticFunctions = cy::Functor::StaticFunctions;
2291     definition.callAsFunction = &Message_callAsFunction;
2292     definition.finalize = &CYFinalize;
2293     Message_ = JSClassCreate(&definition);
2294
2295     definition = kJSClassDefinitionEmpty;
2296     definition.className = "Messages";
2297     definition.hasProperty = &Messages_hasProperty;
2298     definition.getProperty = &Messages_getProperty;
2299     definition.setProperty = &Messages_setProperty;
2300 #if 0 && OBJC_API_VERSION < 2
2301     definition.deleteProperty = &Messages_deleteProperty;
2302 #endif
2303     definition.getPropertyNames = &Messages_getPropertyNames;
2304     definition.finalize = &CYFinalize;
2305     Messages_ = JSClassCreate(&definition);
2306
2307     definition = kJSClassDefinitionEmpty;
2308     definition.className = "Selector";
2309     definition.staticValues = Selector_staticValues;
2310     definition.staticFunctions = Selector_staticFunctions;
2311     definition.callAsFunction = &Selector_callAsFunction;
2312     definition.finalize = &CYFinalize;
2313     Selector_ = JSClassCreate(&definition);
2314
2315     definition = kJSClassDefinitionEmpty;
2316     definition.className = "Super";
2317     definition.staticFunctions = Internal_staticFunctions;
2318     definition.finalize = &CYFinalize;
2319     Super_ = JSClassCreate(&definition);
2320
2321     definition = kJSClassDefinitionEmpty;
2322     definition.className = "ObjectiveC::Classes";
2323     definition.getProperty = &ObjectiveC_Classes_getProperty;
2324     definition.getPropertyNames = &ObjectiveC_Classes_getPropertyNames;
2325     ObjectiveC_Classes_ = JSClassCreate(&definition);
2326
2327     definition = kJSClassDefinitionEmpty;
2328     definition.className = "ObjectiveC::Protocols";
2329     definition.getProperty = &ObjectiveC_Protocols_getProperty;
2330     definition.getPropertyNames = &ObjectiveC_Protocols_getPropertyNames;
2331     ObjectiveC_Protocols_ = JSClassCreate(&definition);
2332
2333     JSObjectRef ObjectiveC(JSObjectMake(context, NULL, NULL));
2334     CYSetProperty(context, global, CYJSString("ObjectiveC"), ObjectiveC);
2335
2336     CYSetProperty(context, ObjectiveC, CYJSString("classes"), JSObjectMake(context, ObjectiveC_Classes_, NULL));
2337     CYSetProperty(context, ObjectiveC, CYJSString("protocols"), JSObjectMake(context, ObjectiveC_Protocols_, NULL));
2338
2339 #if OBJC_API_VERSION >= 2
2340     definition = kJSClassDefinitionEmpty;
2341     definition.className = "ObjectiveC::Images";
2342     definition.getProperty = &ObjectiveC_Images_getProperty;
2343     definition.getPropertyNames = &ObjectiveC_Images_getPropertyNames;
2344     ObjectiveC_Images_ = JSClassCreate(&definition);
2345
2346     definition = kJSClassDefinitionEmpty;
2347     definition.className = "ObjectiveC::Image::Classes";
2348     definition.getProperty = &ObjectiveC_Image_Classes_getProperty;
2349     definition.getPropertyNames = &ObjectiveC_Image_Classes_getPropertyNames;
2350     ObjectiveC_Image_Classes_ = JSClassCreate(&definition);
2351
2352     CYSetProperty(context, ObjectiveC, CYJSString("images"), JSObjectMake(context, ObjectiveC_Images_, NULL));
2353 #endif
2354
2355     JSObjectRef Instance(JSObjectMakeConstructor(context, Instance_, &Instance_new));
2356     JSObjectRef Message(JSObjectMakeConstructor(context, Message_, NULL));
2357     JSObjectRef Selector(JSObjectMakeConstructor(context, Selector_, &Selector_new));
2358     JSObjectRef Super(JSObjectMakeConstructor(context, Super_, &Super_new));
2359
2360     Instance_prototype_ = (JSObjectRef) CYGetProperty(context, Instance, prototype_);
2361     JSValueProtect(context, Instance_prototype_);
2362
2363     CYSetProperty(context, global, CYJSString("Instance"), Instance);
2364     CYSetProperty(context, global, CYJSString("Selector"), Selector);
2365     CYSetProperty(context, global, CYJSString("Super"), Super);
2366
2367 #if defined(__APPLE__) && defined(__arm__)
2368     CYSetProperty(context, global, CYJSString("objc_registerClassPair"), JSObjectMakeFunctionWithCallback(context, CYJSString("objc_registerClassPair"), &objc_registerClassPair_));
2369     MSHookFunction(&objc_registerClassPair, MSHake(objc_registerClassPair));
2370 #endif
2371
2372     CYSetProperty(context, global, CYJSString("objc_msgSend"), JSObjectMakeFunctionWithCallback(context, CYJSString("objc_msgSend"), &$objc_msgSend));
2373
2374     JSObjectSetPrototype(context, (JSObjectRef) CYGetProperty(context, Message, prototype_), Function_prototype_);
2375     JSObjectSetPrototype(context, (JSObjectRef) CYGetProperty(context, Selector, prototype_), Function_prototype_);
2376
2377 #ifdef __APPLE__
2378     class_addMethod(NSCFType_, @selector(cy$toJSON:), reinterpret_cast<IMP>(&NSCFType$cy$toJSON), "@12@0:4@8");
2379 #endif
2380 }
2381
2382 static CYHooks CYObjectiveCHooks = {
2383     &CYObjectiveC_ExecuteStart,
2384     &CYObjectiveC_ExecuteEnd,
2385     &CYObjectiveC_RuntimeProperty,
2386     &CYObjectiveC_CallFunction,
2387     &CYObjectiveC_SetupContext,
2388     &CYObjectiveC_PoolFFI,
2389     &CYObjectiveC_FromFFI,
2390 };
2391
2392 struct CYObjectiveC {
2393     CYObjectiveC() {
2394         hooks_ = &CYObjectiveCHooks;
2395     }
2396 } CYObjectiveC;