tests: refactor the bison invocations.

[bison.git] / tests / local.at

diff --git a/tests/local.at b/tests/local.at
index 1baf6616f75321b53db704b4cd8824ee2b804a35..62e05709d7f923be4149130cbec4d47f25a9e932 100644 (file)
--- a/tests/local.at
+++ b/tests/local.at
@@ -20,6 +20,15 @@
 m4_version_prereq([2.58])
 
 
+# m4_null_if(VAL, IF-TRUE, IF-FALSE)
+# ----------------------------------
+# If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
+m4_define([m4_null_if],
+[m4_case(m4_quote($1),
+         [0], [$2],
+         [],  [$2],
+         [$3])])
+
 ## ------------- ##
 ## Basic tests.  ##
 ## ------------- ##
@@ -145,6 +154,8 @@ m4_pushdef([AT_API_prefix],
 [m4_bmatch([$3], [%define api\.prefix ".*"],
            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
            [yy])])
+m4_pushdef([AT_API_PREFIX],
+[m4_toupper(AT_API_prefix)])
 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
@@ -165,10 +176,10 @@ m4_pushdef([AT_PURE_LEX_IF],
 
 m4_pushdef([AT_YYSTYPE],
 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
-               [[YYSTYPE]])])
+               [AT_API_PREFIX[STYPE]])])
 m4_pushdef([AT_YYLTYPE],
 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
-               [[YYLTYPE]])])
+               [AT_API_PREFIX[LTYPE]])])
 
 
 AT_PURE_LEX_IF(
@@ -221,6 +232,7 @@ m4_popdef([AT_LOC])
 m4_popdef([AT_PURE_LEX_IF])
 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 m4_popdef([AT_YYERROR_ARG_LOC_IF])
+m4_popdef([AT_API_PREFIX])
 m4_popdef([AT_API_prefix])
 m4_popdef([AT_NAME_PREFIX])
 m4_popdef([AT_GLR_OR_PARAM_IF])
@@ -336,7 +348,7 @@ static
 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 m4_define([AT_YYERROR_FORMALS],
 [m4_case(AT_LANG,
-[c], [AT_YYERROR_ARG_LOC_IF([YYLTYPE *llocp, ])[const char *msg]])[]dnl
+[c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE *llocp, ])[const char *msg]])[]dnl
 ])
 
 m4_define([AT_YYERROR_PROTOTYPE],
@@ -401,6 +413,9 @@ void
 
 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 # -------------------------------------------------
+# High-level routine that may call bison several times, under different
+# conditions.
+#
 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 # shell constructs (such as redirection or pipes) that would prevent
 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
@@ -421,13 +436,20 @@ void
 #
 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 m4_define([AT_BISON_CHECK],
-[m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
-       m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
+[m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 AT_BISON_CHECK_NO_XML($@)])
 
 m4_define([AT_BISON_WERROR_MSG],
           [[bison: warnings being treated as errors]])
 
+
+# AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
+# --------------------------------------------------
+# Low-level macro to run bison once.
+m4_define([AT_BISON_CHECK_],
+[AT_CHECK(AT_QUELL_VALGRIND[[ bison ]]$@)])
+
+
 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 # --------------------------------------------------------
 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
@@ -448,8 +470,7 @@ m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
           ]AT_DATA([expout], [$3])[
 
           # Run with -Werror.
-          ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
-                    [[1]], [expout], [stderr])[
+          ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 
           # Build expected stderr up to and including the "warnings being
           # treated as errors" message.
@@ -483,16 +504,13 @@ m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 
           # Now check --warnings=error.
           cp stderr experr
-          ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
-                    [[1]], [expout], [experr])[
+          ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 
           # Now check -Wnone and --warnings=none by making sure that
           # -Werror doesn't change the exit status when -Wnone or
           # --warnings=none is specified.
-          ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
-                    [[0]], [expout])[
-          ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
-                    -Werror]], [[0]], [expout])[
+          ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
+          ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 
           ]AT_RESTORE_SPECIAL_FILES[
         fi
@@ -515,11 +533,11 @@ m4_define([AT_BISON_CHECK_XML],
                             [--xml=[^][ ]*], [])])dnl
   # Don't combine these Bison invocations since we want to be sure that
   # --report=all isn't required to get the full XML file.
-  AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
-             --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
-           [[0]], [ignore], [ignore])
-  AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
-           [[0]], [ignore], [ignore])
+  AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
+                  --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
+                  [[0]], [ignore], [ignore])
+  AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
+                 [[0]], [ignore], [ignore])
   m4_popdef([AT_BISON_ARGS])dnl
   [cp xml-tests/test.output expout]
   AT_CHECK([[$XSLTPROC \
@@ -593,7 +611,8 @@ AT_CHECK(m4_join([ ],
 # is not installed.
 m4_define([AT_JAVA_COMPILE],
 [AT_KEYWORDS(java)
-AT_SKIP_IF([[test -z "$CONF_JAVA$CONF_JAVAC"]])
+AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
+AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
          [[0]], [ignore], [ignore])])