configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the `configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^gl_[A-Z]])
  25
  26 AC_INIT([GNU Bison],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-bison@gnu.org])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2012])
  30 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  31                    [The copyright year for this package])
  32
  33 AC_CONFIG_AUX_DIR([build-aux])
  34 AC_CONFIG_MACRO_DIR([m4])
  35
  36 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  37 #
  38 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  39 #
  40 # To avoid 1.11, we make 1.11.1 the minimum version.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.11.1 dist-xz silent-rules]
  49                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  50                            [gnu], [gnits]))
  51 AM_SILENT_RULES([yes])
  52 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  53
  54 # Checks for the compiler.
  55 AC_PROG_CC_STDC
  56 AC_PROG_CXX
  57
  58 # Gnulib (early checks).
  59 gl_EARLY
  60
  61 # Gnulib uses '#pragma GCC diagnostic push' to silence some
  62 # warnings, but older gcc doesn't support this.
  63 AC_CACHE_CHECK([whether pragma GCC diagnostic push works],
  64   [lv_cv_gcc_pragma_push_works], [
  65   save_CFLAGS=$CFLAGS
  66   CFLAGS='-Wunknown-pragmas -Werror'
  67   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  68     #pragma GCC diagnostic push
  69     #pragma GCC diagnostic pop
  70   ]])],
  71   [lv_cv_gcc_pragma_push_works=yes],
  72   [lv_cv_gcc_pragma_push_works=no])
  73   CFLAGS=$save_CFLAGS])
  74
  75 AC_ARG_ENABLE([gcc-warnings],
  76 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  77 [case $enable_gcc_warnings in
  78    yes|no) ;;
  79    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  80  esac],
  81               [enable_gcc_warnings=no])
  82 if test "$enable_gcc_warnings" = yes; then
  83   warn_common='-Wall -Wextra -Wno-sign-compare -Wcast-align
  84     -Wformat -Wpointer-arith -Wwrite-strings'
  85   warn_c='-Wbad-function-cast -Wshadow -Wstrict-prototypes'
  86   warn_cxx='-Wnoexcept'
  87   AC_LANG_PUSH([C])
  88   # Clang supports many of GCC's -W options, but only issues warnings
  89   # on the ones it does not recognize.  In that case, gl_WARN_ADD
  90   # thinks the option is supported, and unknown options are then added
  91   # to CFLAGS.  But then, when -Werror is added in the test suite for
  92   # instance, the warning about the unknown option turns into an
  93   # error.
  94   #
  95   # This should be addressed by gnulib's gl_WARN_ADD, but in the
  96   # meanwhile, turn warnings about unknown options into errors in
  97   # CFLAGS, and restore CFLAGS after the tests.
  98   save_CFLAGS=$CFLAGS
  99   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
 100   for i in $warn_common $warn_c;
 101   do
 102     gl_WARN_ADD([$i], [WARN_CFLAGS])
 103   done
 104   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 105
 106   # Warnings for the test suite, and maybe for bison if GCC is modern
 107   # enough.
 108   gl_WARN_ADD([-Wmissing-declarations], [WARN_CFLAGS_TEST])
 109   gl_WARN_ADD([-Wmissing-prototypes], [WARN_CFLAGS_TEST])
 110   test $lv_cv_gcc_pragma_push_works = yes &&
 111     AS_VAR_APPEND([WARN_CFLAGS], [" $WARN_CFLAGS_TEST"])
 112
 113   # Warnings for the test suite only.
 114   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
 115   gl_WARN_ADD([-pedantic], [WARN_CFLAGS_TEST])
 116   CFLAGS=$save_CFLAGS
 117   AC_LANG_POP([C])
 118
 119
 120   AC_LANG_PUSH([C++])
 121   save_CXXFLAGS=$CXXFLAGS
 122   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 123   for i in $warn_common $warn_cxx;
 124   do
 125     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 126   done
 127   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 128               [AC_LANG_PROGRAM([], [nullptr])])
 129   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 130   # Warnings for the test suite only.
 131   gl_WARN_ADD([-Wundef], [WARN_CXXFLAGS_TEST])
 132   gl_WARN_ADD([-pedantic], [WARN_CXXFLAGS_TEST])
 133   CXXFLAGS=$save_CXXFLAGS
 134   AC_LANG_POP([C++])
 135 fi
 136
 137 BISON_TEST_FOR_WORKING_C_COMPILER
 138 BISON_C_COMPILER_POSIXLY_CORRECT
 139 BISON_TEST_FOR_WORKING_CXX_COMPILER
 140 BISON_CXX_COMPILER_POSIXLY_CORRECT
 141
 142 AC_ARG_ENABLE([yacc],
 143   [AC_HELP_STRING([--disable-yacc],
 144      [do not build a yacc command or an -ly library])],
 145   , [enable_yacc=yes])
 146 case $enable_yacc in
 147 yes)
 148   YACC_SCRIPT=yacc
 149   YACC_LIBRARY=liby.a;;
 150 *)
 151   YACC_SCRIPT=
 152   YACC_LIBRARY=;;
 153 esac
 154 AC_SUBST([YACC_SCRIPT])
 155 AC_SUBST([YACC_LIBRARY])
 156
 157 # Checks for programs.
 158 AM_MISSING_PROG([DOT], [dot])
 159 AC_PROG_LEX
 160 $LEX_IS_FLEX || AC_MSG_ERROR([Flex is required])
 161 AC_PROG_YACC
 162 AC_PROG_RANLIB
 163 AC_PROG_GNU_M4
 164 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 165 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 166 supports -g, otherwise to "".])
 167 AC_PATH_PROG([PERL], [perl])
 168 if test -z "$PERL"; then
 169    AC_MSG_ERROR([perl not found])
 170 fi
 171 AM_MISSING_PROG([HELP2MAN], [help2man])
 172 AC_PATH_PROG([XSLTPROC], [xsltproc])
 173 AC_SUBST([XSLTPROC])
 174
 175 # Checks for header files.
 176 AC_CHECK_HEADERS_ONCE([locale.h])
 177
 178 # Checks for compiler characteristics.
 179 AC_C_INLINE
 180
 181 # Gnulib (later checks).  Putting them here rather than right after
 182 # gl_EARLY avoids some redundant checks.
 183 gl_INIT
 184
 185 # Checks for library functions.
 186 AC_CHECK_FUNCS_ONCE([setlocale])
 187 AM_WITH_DMALLOC
 188 BISON_PREREQ_TIMEVAR
 189
 190 # Gettext.
 191 # We use gnulib, which is only guaranteed to work properly with the
 192 # latest Gettext.
 193 AM_GNU_GETTEXT([external], [need-ngettext])
 194 AM_GNU_GETTEXT_VERSION([0.18])
 195 BISON_I18N
 196
 197 # Internationalized parsers.
 198 AC_CONFIG_FILES([runtime-po/Makefile.in])
 199 # Autoconf macros for packages using internationalized parsers.
 200 aclocaldir='${datadir}/aclocal'
 201 AC_SUBST([aclocaldir])
 202
 203 # Create the benchmark script.
 204 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 205
 206 # Initialize the test suite.
 207 AC_CONFIG_TESTDIR(tests)
 208 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 209 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 210 AC_CHECK_PROGS([VALGRIND], [valgrind])
 211 case $VALGRIND:$host_os in
 212   '':*) ;;
 213   *:darwin*)
 214     # See README-hacking.
 215     # VALGRIND+=' --suppressions=$(abs_top_srcdir)/build-aux/darwin11.4.0.valgrind'
 216     VALGRIND=;;
 217   *:*)
 218     AC_SUBST([VALGRIND_PREBISON], ["$VALGRIND -q"]);;
 219 esac
 220
 221 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 222 # Needed by tests/atlocal.in.
 223 AC_SUBST([GCC])
 224
 225 gt_JAVACOMP([1.3])
 226 gt_JAVAEXEC
 227
 228 AC_CONFIG_FILES([Makefile
 229                  build-aux/Makefile
 230                  po/Makefile.in
 231                  data/Makefile
 232                  etc/Makefile
 233                  examples/Makefile
 234                     examples/calc++/Makefile
 235                  lib/Makefile src/Makefile
 236                  doc/Makefile
 237                    doc/yacc.1])
 238 AC_OUTPUT